MINIFfunkcija

Grąžina mažiausią srities langelių reikšmę, kuri tenkina kriterijų.

Sintaksė

MINIFS(Func_Range; Range1; Criterion[; Range2; Criterion2][; … ; [Range127; Criterion127]])

Funkcijos sritis – būtinas argumentas. Gali būti langelių sritis, srities pavadinimas, stulpelio ar eilutės žymė, kurie nurodo į langelius su reikšmėmis, kurių skaičiuojama mažiausia reikšmė.

1 sritis – būtinas argumentas. Duomenų, kuriems taikomas kriterijus, langelių sritis, pavadintų langelių pavadinimas, stulpelio ar eilutės žymė.

Criterion: A criterion is a single cell Reference, Number or Text. It is used in comparisons with cell contents.

A reference to an empty cell is interpreted as the numeric value 0.

A matching expression can be:

A Number or Logical value. A matching cell content equals the Number or Logical value.
A value beginning with a comparator (<, <=, =, >, >=, <>).

For =, if the value is empty it matches empty cells.

For <>, if the value is empty it matches non-empty cells.

For <>, if the value is not empty it matches any cell content except the value, including empty cells.

Note: "=0" does not match empty cells.

For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.
Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

2 sritis – neprivaloma. 2 sritis ir visos paskesnė aprašomos taip pat, kaip ir 1 sritis.

Criterion2 – Optional. Criterion2 and all the following mean the same as Criterion.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in - LibreOffice Calc - Calculate.

Naudojant funkcijas, kuriose vienas ar keli argumentai yra paieškos kriterijų eilutės, kurios reiškia įprastą reiškinį, pirmiausia bandoma eilutės kriterijus paversti skaičiais. Pavyzdžiui, „.0“ į 0,0 ir pan. Jei pasiseks, atitiktys bus ne reguliarieji reiškiniai, o skaitiniai. Tačiau pereinant prie lokalės, kur trupmenos skirtukas nėra taškas, reguliariųjų reiškinių konvertavimas veiks. Jei norite, kad būtų įvertinamas įprastas reiškinys, o ne skaitinis, naudokite tokį reiškinį, kurio negalima klaidingai perskaityti kaip skaitinį, pvz., „.0]“ arba „.\0“ arba „(?i).0“.

Funkcijos sritis ir 1 sritis, 2 sritis... turi būti tokio paties dydžio, kitaip funkciją grąžina „Klaida:502“ – neteisingas argumentas.

Kriterijams galima naudoti loginę operaciją AND (konjunkciją). Kitais žodžiai, jei tenkinamas tik duotas kriterijus, į skaičiavimą įtraukiama atitinkamo langelio duotos Funkcijos srities reikšmė.

Funkcija gali turėti iki 255 argumentų, tai reiškia, kad galite nurodyti 127 kriterijų sritis ir jų kriterijus.

Jei langelyje yra reikšmė TRUE, tai traktuojama kaip 1, o FALSE – kaip 0 (nulis).

Pavyzdys

Aptarsime pateiktą lentelę

	A	B	C
1	Produkto pavadinimas	Pardavimai	Pajamos
2	pieštukas	20	65
3	plunksna	35	85
4	užrašinė	20	190
5	knyga	17	180
6	pieštuko veiksena	neigimas	neigimas

Žemiau pateiktuose pavyzdžiuose skaičiavimo sritys apima #6 eilutę, kurios nepaisoma, nes joje yra tekstas.

Įprastas naudojimas

=MINIFS(B2:B6;B2:B6;"<35")

Apskaičiuoja srities B2:B6 mažiausią reikšmę, kuri yra mažesnė ar lygi 20. Grąžina 17.

=MINIFS(C2:C6;B2:B6;">=20";C2:C6;">90")

Apskaičiuoja mažiausią srities C2:C6 reikšmę, kuri yra mažesnė nei 90 ir atitinka langelius B2:B6 su reikšmėmis, didesnėmis arba lygiomis 20. Grąžina 190.

Reguliariojo reiškinio ir įdėtosios funkcijos naudojimas

=MINIFS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Calculates the minimum of values of the range C2:C6 that correspond to all values of the range B2:B6 except its minimum and maximum. Returns 65.

=MINIFS(C2:C6;A2:A6;".*book";B2:B6;">"&MIN(B2:B6))

Calculates the minimum of values of the range C2:C6 that correspond to all cells of the A2:A6 range ending with "book" and to all cells of the B2:B6 range except its minimum. Returns 190.

Nuoroda į langelį kaip kriterijus

Jei norite pakeisti kriterijų, nurodykite jį atskirame langelyje ir naudokite langelio nuorodą skaičiuodami funkciją. Pavyzdžiui, ankstesnė funkcija atrodytų taip:

=MINIFS(C2:C6;A2:A6;".*"&E2;B2:B6;"<"&MAX(B2:B6))

Jei E2 = „knyga“, tai funkcija grąžina 180, nes turinys pakeistas į langelio nuorodą.

Atverti failą su pavyzdžiu:

Technical information

Ši funkcija pasiekiama nuo „LibreOffice“ 5.2 versijos.

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.MINIFS

MINIFS wiki page.

MAX, MAXA, MIN, MINA,

COUNTIFS, MINIF, MAXIFS, AVERAGEIFS, SUMIFS

Reguliariųjų reiškinių sąrašas