Tekstinės funkcijos

Šioje sekcijoje galite rasti Tekstinių funkcijų aprašymus.

Using double quotation marks in formulas

To include a text string in a formula, place the text string between two double quotation marks (") and Calc takes the characters in the string without attempting to interpret them. For example, the formula ="Hello world!" displays the text string Hello world! in the cell, with no surrounding double quotation marks.

The more complex formula =CONCATENATE("Life is really simple, "; "but we insist on making it complicated "; "(Confucius).") concatenates three individual strings in double quotation marks, outputting Life is really simple, but we insist on making it complicated (Confucius).

To place a literal double quotation mark within a string inside a formula, two methods can be used:

1. You can "escape" the double quotation mark with an additional double quotation mark, and Calc treats the escaped double quotation mark as a literal value. For example, the formula ="My name is ""John Doe""." outputs the string My name is "John Doe". Another simple example is the formula =UNICODE("""") which returns 34, the decimal value of the Unicode quotation mark character (U+0022) — here the first and fourth double quotation marks indicate the beginning and end of the string, while the second double quotation mark escapes the third.

2. You can use the CHAR function or the UNICHAR function to insert a double quotation mark. For example, the formula =UNICHAR(34) & "The Catcher in the Rye" & UNICHAR(34) & " is a famous book by J. D. Salinger." displays the string "The Catcher in the Rye" is a famous book by J. D. Salinger.

Be aware that Calc's AutoCorrect function may modify double quotation marks. AutoCorrect should not change the double quotation marks within formula cells but may change those used in non-formula cells containing text. For example, if you copy a string that is surrounded by some other form of typographical double quotation marks, such as the left double quotation mark (U+201C) and the right double quotation mark (U+201D), and then paste into a formula cell, an error may result. Open the Double Quotes area of the Tools - AutoCorrect Options - Localized Options dialog to set the characters used to automatically correct the start and end typographical double quotation marks. Uncheck the Replace toggle button to disable the feature.

BAHTTEXT

Konvertuoja skaičių į tajų tekstą, įskaitant tajų valiutos pavadinimus.

BAHTTEXT(skaičius)

Skaičius yra bet koks skaičius. „Baht“ yra pridedamas prie integralinės skaičiaus dalies, „Satang“ yra pridedamas prie dešimtainės skaičiaus dalies.

=BAHTTEXT(12.65) grąžina tekstinę eilutę tajų ženklais su reikšme „Dvylika Baht ir šešiasdešimt penki Satag“.

COM.MICROSOFT.BAHTTEXT

BASE

Converts a positive integer to a specified base into a text from the numbering system. The digits 0-9 and the letters A-Z are used.

BASE(skaičius; intervalas [; minimalus ilgis])

Skaičius - teigiamas sveikasis skaičius, kuris bus konvertuojamas.

Radix indicates the base of the numeral system. It may be any positive integer between 2 and 36.

Minimalus skaičius(neprivaloma) nurodo minimalią galimą skaitmenų kiekio reikšmę. Jei tekstas trumpesnis nei minimali reikšmė, gale bus pridedami nuliai.

=BASE(17;10;4) grąžina 0017 dešimtainių skaičių sistemoje

=BASE(17;2) grąžins 10001 dešimtainių skaičių sistemoje.

=BASE(255;16;4) grąžina 00FF šešioliktainėje sistemoje.

DECIMAL

CHAR

Konvertuoja skaičių į ženklą priklausomai nuo pasirinktos kodų lentelės. Skaičius gali būti dviejų skaitmenų arba trijų skaitmenų.

CHAR(Skaičius)

Skaičius – skaičius tarp 1 ir 255 nusakantis ženklo kodo reikšmę.

=CHAR(100) grąžina ženklą d.

="abc" & CHAR(10) & "def" grąžina naujos eilutės ženklą į eilutę.

CLEAN

Visi nespausdinimo ženklai yra pašalinami iš eilutės.

CLEAN(„Tekstas“)

Tekstas – nurodo tekstą iš kurio reikia pašalinti visus nespausdinamus ženklus.

=LEN(CLEAN(CHAR(7) & "LibreOffice Calc" & CHAR(8))) returns 16, showing that the CLEAN function removes the non-printable Unicode U+0007 ("BEL") and U+0008 ("BS") characters at the beginning and end of the string argument. CLEAN does not remove spaces.

CODE

Grąžina skaitinį kodą pirmam ženklui teksto eilutėje.

CODE(„tekstas“)

Tekstas – tekstas, kurio pirmojo rašmens skaitinis kodas yra nurodomas.

=CODE(„Hieronymus“) grąžins 72,=CODE(„hieroglyphic“) grąžins 104.

CONCATENATE

Sujungia kelias teksto eilutes į vieną teksto eilutę.

CONCATENATE(1 eilutė [; 2 eilutė [; … [; 255 eilutė]]])

1 eilutė[; 2 eilutė][; … ;[255 eilutė]] – eilutės arba nuorodos į langelius su eilutėmis.

=CONCATENATE("Sveiki,";"sėkmingai";"sugrįžę";"namo!") returns: Sveiki, sėkmingai sugrįžę namo!

DECIMAL

Converts text that represents a number in a numeral system with the given base radix to a positive integer. The radix must be in the range 2 to 36. Spaces and tabs are ignored. The Text field is not case-sensitive.

If the radix is 16, a leading x or X or 0x or 0X, and an appended h or H, are disregarded. If the radix is 2, an appended b or B is disregarded. Other characters that do not belong to the numeral system generate an error.

DECIMAL("Tekstas"; pagrindas)

Text is the text to be converted.

Radix indicates the base of the numeral system. It may be any positive integer between 2 and 36.

=DECIMAL("17";10) grąžina 17.

=DECIMAL("FACE";16) grąžina 64206.

=DECIMAL("0101";2) grąžina 5

BASE

DOLLAR

Converts a number to a string representing the amount in the currency format, rounded to a specified decimal places, using the decimal separator that corresponds to the current locale setting. In the Value field enter the number to be converted. Optionally, you may enter the number of decimal places in the Decimals field. If no value is specified, all numbers in currency format will be displayed with two decimal places.

Sistemos nustatymuose nurodykite valiutos formatą.

DOLLAR(reikšmė [; dešimtainiai])

Reikšmė – skaičius, nuoroda į langelį su skaičiumi arba formule, kurios rezultatas yra skaičius.

Dešimtainės skiltys – papildomas parametras, kuris nurodo, kiek skaitmenų po kablelio turi būti rodoma.

=DOLLAR(255) returns $255.00 for the English (USA) locale and USD (dollar) currency; ￥255.00 for the Japanese locale and JPY (yen) currency; or 255,00 € for the German (Germany) locale and EUR (euro) currency.

=DOLLAR(367.456;2) returns $367.46.

EXACT

Palygina dvi tekstines eilutes ir grąžina TIESA, jei jos yra vienodos. Ši funkcija skiria didžiąsias ir mažąsias raides.

EXACT("Tekstas 1"; "Tekstas 2")

Tekstas 1 – pirmojo lyginamojo teksto nuoroda.

Tekstas 2 – antrojo lyginamojo teksto nuoroda.

=EXACT("microsystems";"Microsystems") grąžina NETIESA.

FIND

Grąžina tekstinės eilutės, esančios kitoje eilutėje, vietą. Galite nurodyti, nuo kurios vietos pradėti ieškoti. Ieškoma frazė gali būti skaičiai ar bet kokių ženklų eilutė. Paieška skiria didžiąsias ir mažąsias raides

FIND("rasti tekstą"; "tekstas" [; vieta])

Paieškos tekstas – nurodomas ieškomas tekstas.

Tekstas – nurodomas tekstas, kur vykdoma paieška.

Vieta (papildomas) – vieta tekste, nuo kurios pradedama paieška.

=FIND(76;998877665544) grąžina 6.

FIXED

Returns a number as text with a specified number of decimal places and optional thousands separators.

FIXED(Number; [Decimals = 2 [; NoThousandsSeparators = FALSE]])

Number is rounded to Decimals places (after the decimal separator) and the result formatted as text, using locale-specific settings.

Decimals (optional) refers to the number of decimal places to be displayed. If Decimals is negative, Number is rounded to ABS(Decimals) places to the left from the decimal point. If Decimals is a fraction, it is truncated actually ignoring what is the closest integer.

NoThousandsSeparators (optional) determines whether the thousands separator is used. If it is TRUE or non-zero, then group separators are omitted from the resulting string. If the parameter is equal to 0 or if it is missing altogether, the thousands separators of your current locale setting are displayed.

=FIXED(1234567,89;3) grąžina 1234567,890 kaip teksto eilutę.

=FIXED(123456.789;;TRUE) returns 123456.79 as a text string.

=FIXED(12345.6789;-2) returns 12,300 as a text string.

=FIXED(12134567.89;-3;1) returns 12135000 as a text string.

=FIXED(12345.789;3/4) returns 12,346 as a text string.

=FIXED(12345.789;8/5) returns 12,345.8 as a text string.

LEFT

Grąžina pirmą ženklą ar ženklus, ar tekstą.

LEFT("tekstas" [; skaičius])

Tekstas – tekstas, kuriame reikia nustatyti nepilną žodį.

Skaičius (papildomas) – nurodomas ženklų skaičius. Jei šis parametras nenurodytas, funkcija grąžina vieną ženklą.

=LEFT("išvestis";2) grąžina „iš”.

LEFTB

Grąžina pirmą DBCS teksto ženklą.

LEFTB("tekstas" [; baitų skaičius])

Tekstas – tekstas, kuriame reikia nustatyti nepilną žodį.

Baitai (papildomas) – nurodomas ženklų, kuriuos norite ištraukti, skaičius baitais. Jei šis parametras nenurodytas, funkcija grąžina vieną ženklą.

=LEFTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).

=LEFTB("中国";2) returns "中" (2 bytes constitute one complete DBCS character).

=LEFTB("中国";3) returns "中 " (3 bytes constitute one DBCS character and a half; the last character returned is therefore a space character).

=LEFTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).

=LEFTB("office";3) returns "off" (3 non-DBCS characters each consisting of 1 byte).

LEN

Grąžina eilutės ilgį įskaitant tarpus.

LEN("tekstas")

Tekstas – tekstas, kurio ilgis skaičiuojamas.

=LEN("Labas vakaras") grąžina 13.

=LEN(12345.67) grąžina 8.

LENB

Funkcija skirta dviejų baitų kalboms (DBCS). Grąžina eilutės ilgį baitais.

LENB("tekstas")

Tekstas – tekstas, kurio ilgis skaičiuojamas.

=LENB("中") grąžina 2 (1 DBCS ženklas užima 2 baitus).

=LENB("中国") grąžina 4 (1 DBCS ženklas užima 2 baitus).

=LENTB("perėja") grąžina 6 (kiekvienas kalbos ženklas užima vieną baitą).

=LENB("Labas vakaras") grąžina 13.

=LENB(12345.67) grąžina 8.

LOWER

Konvertuoja visas didžiąsias raides tekste į mažąsias.

LOWER("tekstas")

Tekstas 1 – konvertuojamo teksto nuoroda.

=LOWER("SaULė") grąžina „saulė“.

MID

Grąžina teksto eilutę. Parametras nurodo, nuo kurios eilutės vietos pradedamas konvertavimas.

MID("tekstas"; pradžia; skaičius)

Tekstas – teksto eilutė, kuri ar kurios dalis konvertuojama.

Pradžia – pirmojo ženklo, nuo kurio pradedamas konvertavimas, vieta.

Skaičius – ženklų, kurie bus konvertuojami, skaičius.

=MID("mėnulis";2;2) grąžina „ėn“

MIDB

Grąžina DBCS teksto eilutę. Parametras nurodo, nuo kurios eilutės vietos pradedamas konvertavimas ir kiek ženklų bus konvertuojama.

MIDB("tekstas"; pradžia; baitai)

Tekstas – teksto eilutė, kuri ar kurios dalis konvertuojama.

Pradžia – pirmojo ženklo, nuo kurio pradedamas konvertavimas, vieta.

Baitai – nurodomas grąžinamas ženklų skaičius baitais.

=MIDB("中国";1;0) returns "" (0 bytes is always an empty string).

=MIDB("中国";1;1) returns " " (1 byte is only half a DBCS character and therefore the result is a space character).

=MIDB("中国";1;2) returns "中" (2 bytes constitute one complete DBCS character).

=MIDB("中国";1;3) returns "中 " (3 bytes constitute one and a half DBCS character; the last byte results in a space character).

=MIDB("中国";1;4) returns "中国" (4 bytes constitute two complete DBCS characters).

=MIDB("中国";2;1) returns " " (byte position 2 is not at the beginning of a character in a DBCS string; 1 space character is returned).

=MIDB("中国";2;2) returns " " (byte position 2 points to the last half of the first character in the DBCS string; the 2 bytes asked for therefore constitutes the last half of the first character and the first half of the second character in the string; 2 space characters are therefore returned).

=MIDB("中国";2;3) returns " 国" (byte position 2 is not at the beginning of a character in a DBCS string; a space character is returned for byte position 2).

=MIDB("中国";3;1) returns " " (byte position 3 is at the beginning of a character in a DBCS string, but 1 byte is only half a DBCS character and a space character is therefore returned instead).

=MIDB("中国";3;2) returns "国" (byte position 3 is at the beginning of a character in a DBCS string, and 2 bytes constitute one DBCS character).

=MIDB("office";2;3) returns "ffi" (byte position 2 is at the beginning of a character in a non-DBCS string, and 3 bytes of a non-DBCS string constitute 3 characters).

PROPER

Pirmąsias visų eilutės žodžių raides pakeičia didžiosiomis.

PROPER("tekstas")

Tekstas – konvertuojamo teksto nuoroda.

=PROPER("dokumento paieška") grąžina frazę „Dokumento Paieška“.

REPLACE

Pakeičia nurodytą teksto eilutės dalį kita teksto eilute. Ši funkcija naudojama visiems ženklams (jie automatiškai konvertuojami į tekstą). Funkcijos rezultatas visada yra tekstas. Jei vėliau norėsite gautus skaitinius ženklus naudoti skaičiavimuose, tai turėsite konvertuoti juos į skaičių formatą naudodami VAlUE funkciją.

Tekstas, kuriame yra skaičių, turi būti rašomas tarp angliškų kabučių, jei norite, kad jis būtų automatiškai konvertuojamas į teksto formatą.

REPLACE("tekstas"; vieta; ilgis; "naujas tekstas")

Tekstas – teksto, kurio dalis bus keičiama, nuoroda.

Vieta – teksto vieta, nuo kurios bus pradedamas keitimas.

Ilgis – keičiamų ženklų tekste skaičius.

Naujas tekstas – teksto, į kurį bus keičiamas nurodyta teksto dalis, nuoroda.

=REPLACE("1234567";1;1;"444") grąžina „444234567“. Į naują tekstą 444 keičiamas pirmasis nurodyto teksto ženklas.

REPT

Pakartoja ženklų eilutę nurodytą skaičių kartų.

REPT("tekstas"; skaičius)

Tekstas – tekstas, kurio kopijos kuriamos.

Skaičius – teksto kopijų skaičius.

=REPT("Labas rytas";2) grąžina „Labas rytasLabas rytas“.

RIGHT

Grąžina paskutinį teksto ženklų ženklą.

RIGHT("tekstas" [; skaičius])

Tekstas – tekstas, kurio dešinioji pusė bus grąžinta.

Number (optional) is the number of characters from the right part of the text. If this parameter is not defined, one character is returned.

=RIGHT("Saulė";2) grąžina „lė“.

RIGHTB

Grąžina nurodytą baitų skaičių DBCS ženklų eilutės dešinės dalies paskutinių ženklų.

RIGHTB("tekstas" [; baitų skaičius])

Tekstas – tekstas, kurios dešinioji pusė bus grąžinta.

Number_bytes (optional) specifies the number of characters you want RIGHTB to extract, based on bytes. If this parameter is not defined, one byte is returned.

=RIGHTB("中国";1) grąžina „ “ (nurodyta grąžinti pusę DBCS ženklo, todėl grąžinamas tarpo ženklas).

=RIGHTB("中国";2) grąžina „国“ (2 baitai apima vieną DBCS ženklą).

=IGHTB("中国";3) grąžina „ 国“ (3 baitai apima pusantro DBCS ženklo, todėl grąžinamas tarpas vienas ženklas).

=RIGHTB("中国";4) grąžina „中国“ (4 baitai apima du DBCS ženklus).

=RIGHTB("perėja";3) grąžina "per" (kiekvienas ženklas užima vieną baitą).

SEARCH

Grąžina nurodytos tekstinės eilutės vietą. Galite papildomai nurodyti paieškos pradžios vietą. Ieškomas tekstas gali būti skaitinė arba bet kokia ženklų seka. Funkcija nekreipia dėmesio į didžiąsias ir mažąsias raides. Jei teksto neranda, grąžina 519 klaidos pranešimą (#VALUE).

SEARCH("rasti tekstą"; "tekstas" [; vieta])

Ieškomas tekstas – tekstas, kuris bus ieškomas.

Tekstas – tekstinė paieškos sritis.

Vieta (papildomas) – vieta tekste, nuo kurios pradedama paieška.

=SEARCH(54;998877665544) grąžina 10.

SUBSTITUTE

Pakeičia seną tekstą nauju.

SUBSTITUTE("tekstas"; "paieškos tekstas"; "naujas tekstas" [; tikslumas])

Tekstas – tekstas, kurio dalis bus pakeista.

Ieškomas tekstas – teksto dalis, kuri bus keičiama (kiek kartų bus keičiama).

Naujas tekstas – tekstas, kuriuo bus pakeistas surastas tekstas.

Tikslumas (papildomas) – nustato, kiek kartų surastas tekstas bus keičiamas. Jei šis parametras nenurodytas, keičiamas visas surastas tekstas.

=SUBSTITUTE("123123123";"3";"abc") grąžina „12abc12abc12abc“.

=SUBSTITUTE("123123123";"3";"abc";2) grąžina „12312abc123“

T

Ši funkcija grąžina ieškomą tekstą ar tuščią eilutę, jei tekstas nerastas.

T(reikšmė)

Jei reikšmė yra teksto eilutė arba teksto srities nuoroda, tai T grąžina teksto eilutę. Kitu atveju grąžina tuščią teksto eilutę.

=T(12345) grąžina tuščią eilutę.

=T("12345") grąžina eilutę „12345“.

TEXT

Reikšmes konvertuoja į nurodyto formato tekstą.

TEXT(reikšmė; formatas)

Reikšmė – konvertuojama tekstinė arba skaitinė reikšmė.

Formatas – tekstas, kuris apibrėžia formatą. Naudokite dešimtainius ar tūkstančių skirtukus kaip numatyta formatuojamo langelio kalboje.

=TEXT(12,34567;"###,##") grąžina tekstą „12,35“

=TEXT(12,34567;"000,00") grąžina tekstą „012,35“

=TEXT("xyz";"=== @ ===") grąžina tekstą === xyz ===

TRIM

Pašalina eilutėje nereikalingus tarpus, palieka tik po vieną tarpą tarp žodžių.

TRIM ("tekstas")

Tekstas – tekstas, kuriame bus šalinami tarpai.

=TRIM(" Sveikas, pasauli! ") grąžina „Sveikas, pasauli!“ be tarpų. Palieka tik tarpą tarp žodžių.

UNICHAR

Konvertuoja kodo skaičių į Unikodą arba raidę.

UNICHAR(skaičius)

=UNICHAR(169) grąžina autorių teisių ženklą ©.

UNICODE

Grąžina pirmojo Unikodo ženklo tekstinėje eilutėje skaitinę reikšmę.

UNICODE("tekstas")

=UNICODE("©") grąžina autorių teisių ženklo Unikodo skaitinę reikšmę 169.

UPPER

Konvertuoja eilutę tekstiniame laukelyje į eilutę, kurios visi ženklai užrašomi didžiosiomis raidėmis.

UPPER("tekstas")

Tekstas – nurodomas tekstas, kurį norite pakeisti didžiosiomis raidėmis.

=UPPER("Labas rytas") grąžina „LABAS RYTAS“.