Darbo knygos funkcijos

Šiame skyriuje aprašomos darbo knygos funkcijos ir pateikiama pavyzdžių.

ERROR.TYPE

Grąžina klaidos tipo numerį arba klaidos reikšmę #N/A, jei klaidos nėra.

STYLE

Applies a style to the cell containing the formula.

ADDRESS

Grąžina langelio koordinatę (nuorodą) tekstu pagal nurodytą eilutę ir stulpelį. Galite nurodyti, ar adresas turi būti pateiktas absoliučiosiomis koordinatėmis ($A$1) ar santykinėmis (A1), ar mišriosiomis (A$1 arba $A1). Taip galite nurodyti ir lakštą.

Suderinamumui funkcijos ADDRESS ir INDIRECT palaiko papildomą parametrą, kuris nurodo, ar turi būti naudojamas koordinatės R1C1 užrašas vietoj įprasto A1.

Funkcijoje ADDRESS parametras yra įterpiamas kaip ketvirtas argumentas, o lakšto pavadinimo argumentas pastumiamas į penktą poziciją.

Funkcijoje INDIRECT parametras atsiranda antroje pozicijoje.

Jei įterpto argumento reikšmė yra 0, abi funkcijos naudoja R1C1 žymėjimą. Jei argumento reikšmė nėra nurodyta arba nelygi 0, naudojamas koordinačių žymėjimas A1.

Atveju, kai žymima R1C1, funkcija ADDRESS grąžina adreso nuorodą, naudodama šauktuko ženklą kaip lakšto pavadinimo skirtuką, o funkcija INDIRECT reikalauja šauktuko ženklo lakšto pavadinimui atskirti. Abi funkcijos lakšto pavadinimui atskirti naudoja tašką, jei naudojamas A1 žymėjimas.

ODF 1.0/1.1 formato dokumente, funkcija ADDRESS lakšto pavadinimą perstumia į penktą poziciją. Į ketvirtą argumento poziciją įterpiama reikšmė 1.

Jei funkcija ADDRESS turi ketvirtą argumentą, tai įrašant ODF 1.0/1.1 formato dokumentą jis bus pašalintas.

ADDRESS(eilutė; stulpelis [; modulis [; A1 [; "lakštas"]]])

Eilutė nurodo nuorodos eilutės numerį.

Stulpelis parodo nuorodos stulpelio numerį (ne raidę)

Abs parodo nuorodos tipą:

1: absoliučiosios koordinatės ($A$1)

2: eilutės numeris absoliučioji koordinatė; stulpelis santykinė koordinatė (A$1)

3: eilutė (santykinė); stulpelis (absoliučioji) ($A1)

4: santykinė (A1)

A1 (papildomas) – jei nurodytas 0, naudojamas R1C1 žymėjimas. Jei šis parametras praleistas arba nurodyta kita reikšmė, tai naudojamas A1 žymėjimas.

Lakštas parodo lakšto pavadinimą. Jis turi būtas rašomas tarp dvigubų angliškų kabučių.

Pavyzdys:

=ADDRESS(1;1;2;;"Sheet2") grąžina Sheet2.A$1

Jei pateikta formulė yra dabartinio lakšto langelyje B2 ir lakšto 2 langelyje A1 yra reikšmė -6, tai galite netiesiogiai nurodyti langelį, langelyje B2 įvedę =ABS(INDIRECT(B2)). Rezultatas yra absoliučioji koordinatė, nurodyta langelyje B2.

AREAS

Grąžina atskirų sričių skaičių. Sritys gali būti sudarytos iš gretimų langelių arba vieno langelio.

Funkcija reikalauja vieno argumento. Jei nurodote keletą sričių, turite atskirti jas skliausteliais. Kelios sritys gali būti atskiriamos „;“, bet skirtukas automatiškai bus pakeistas į „~“ operaciją. Šis veiksmas naudojamas sritims sujungti.

AREAS(nuoroda)

Langelio ar langelių srities nuoroda.

=AREAS((A1:B3;F2;G1)) grąžina 3. Įvesta formulė konvertuojama į =AREAS((A1:B3~F2~G1)).

=AREAS(All) grąžina 1, jei apibrėžėte sritį pavadinimu „Visos“ pasirinkę Duomenys → Nurodyti sritį.

CHOOSE

Grąžinama iki 30 reikšmių naudojjant indeksus.

CHOOSE(indeksas; 1 reikšmė [; 2 reikšmė [; ... [; 30 reikšmė]]])

Indeksas – nuoroda ar skaičius tarp 1 ir 30, nurodantis, kuri reikšmė iš sąrašo bus paimta.

1 reikšmė, 2 reikšmė, ..., 30 reikšmė – sąrašas reikšmių, pateiktų nuorodomis langelyje arba atskiros reikšmės.

=CHOOSE(A1;B1;B2;B3;"šiandien";"vakar";"rytoj") grąžina tekstą „šiandien“.

COLUMN

Returns the column number of a cell reference. If the reference is a cell the column number of the cell is returned; if the parameter is a cell area, the corresponding column numbers are returned in a single-row array if the formula is entered as an array formula. If the COLUMN function with an area reference parameter is not used for an array formula, only the column number of the first cell within the area is determined.

COLUMN([nuoroda])

Nuoroda – langelio ar langelių srities, kurios stulpelio numeris nustatomas, nuoroda.

Jei argumentas neįvestas, tai nustatomas langelio, kur įvesta formulė, stulpelio numeris.„LibreOffice“ skaičiuoklė automatiškai nustato esamo langelio nuorodą.

=COLUMN(A1) grąžina 1. A stulpelis yra pirmasis lentelės stulpelis.

=COLUMN(C3:E3) grąžina 3. C stulpelis yra trečiasis lentelės stulpelis.

=COLUMN(D3:G10) grąžina 4, kadangi D stulpelis yra 4 lentelės stulpelis ir funkcija COLUMN nebuvo įvesta kaip masyvo formulė. (Šiuo atveju visada grąžinama pirmojo masyvo reikšmė).

{=COLUMN(B2:B7)} ir =COLUMN(B2:B7) grąžina 2, nes nuorodos sritis apima tik antrą lentelės stulpelį. Kadangi vieno stulpelio sritys turi tik vieną stulpelį, tai nėra prasmės įvesti formulę kaip masyvo.

=COLUMN() grąžina 3, jei formulė įvesta langelyje, kuris yra C stulpelyje.

{=COLUMN(triušis)} grąžina vienos eilutės masyvą (3, 4), jei „triušis“ yra srities C1:D3 pavadinimas.

COLUMNS

Grąžina duotos nuorodos srities stulpelių skaičių.

COLUMNS(masyvas)

Masyvas – srities, kurios stulpelių skaičių reikia surasti, nuoroda. Argumentas gali būti ir vienas langelis.

=COLUMNS(B5) grąžina 1, nes langelis turi tik vieną stulpelį.

=COLUMNS(A1:C5) grąžina 3. Nuorodos sritis apima tris stulpelius.

=COLUMNS(triušis) grąžina 2, jei triušis yra srities C1:D3 pavadinimas.

DDE

Grąžina dinaminės nuorodos (DDE) saito rezultatą. Jei susietų sričių turinys ar dalis keičiama, tai grąžinama reikšmė taip pat keičiasi. Jei norite atnaujinti peržiūrą, pasirinkite Taisa → Saitai. Negalima naudoti „LibreOffice“ veikiančio „Windows“ operacinėje sistemoje dokumentams sukurtiems „Linux“.

DDE("serveris"; "failas"; "blokas" [; nurodo, kaip duomenys konvertuojami į skaičius])

Serveris – serverio aplinkos pavadinimas. „LibreOffice“ programos turi serverio pavadinimą „soffice“.

Failas – galutinis failo pavadinimas, įskaitant visą kelią.

Sritis – sritis, apimanti vertinamus duomenis.

Metodas – papildomas parametras, kuris kontroliuoja metodą, pagal kurį DDE serveris konvertuoja duomenis į skaičius.

Mode	Effect
0 arba nenurodyta	Skaičiaus formatas iš „numatyto“ langelio stiliaus
1	Duomenys visada interpretuojami pagal įprastus JAV anglų kalbos formatus
2	Duomenys gaunami kaip tekstas; negalima konvertuoti į skaičius

=DDE("soffice";"c:\office\document\data1.ods";"sheet1.A1") skaitomas Lakšto 1 langelio A1 turinys „LibreOffice“ skaičiuoklės darbo knygoje data1.ods.

Formulė =DDE("soffice";"c:\office\document\motto.odt";"Today's motto") grąžina devizą, kurį anksčiau įrašėte faile motto.odt. Tačiau pirmiau devizo tekstą turėjote nurodyti kaip pirmąją skyriaus Šiandienos devizas eilutę (tam pasirinkite „LibreOffice“ rašyklėje Įterpti → Skyrius). Jei devizą pakeistumėte ir įrašytumėte „LibreOffice“ rašyklės dokumente, devizas būtų atnaujintas visuose „LibreOffice“ skaičiuoklės langeliuose, kuriuose naudojote DDE saitą.

ERRORTYPE

Grąžina įvairiuose langeliuose atsirandančiąklaidos reikšmę atitinkantį skaičių. Šiuo skaičiumi galite keisti klaidos pranešimo tekstą.

ERRORTYPE(nuoroda)

Nuoroda – langelio su klaida koordinatės.

Jei langelyje A1 rodoma klaida Err:518, funkcija =ERRORTYPE(A1) grąžina 518.

ORG.OPENOFFICE.ERRORTYPE

GETPIVOTDATA

Funkcija grąžina suvestinės lentelės rezultatą. Reikšmė nurodoma naudojant lauko ir elemento pavadinimus, todėl išlieka, net jei suvestinė lentelė keičiama.

Galite naudoti dvi skirtingas sintakses šiai funkcijai aprašyti:

GETPIVOTDATA(duomenų laukas; suvestinė lentelė[; 1 laukas; 1 elementas][; ... [126 laukas; 126 elementas]])

arba

GETPIVOTDATA(suvestinė lentelė; apribojimai)

Antroji formulės sintaksė yra taikoma, jei duoti tik du parametrai, iš kurių pirmasis yra langelio ar langelių srities nuoroda. Pirmoji formulės sintaksė taikoma visais kitais atvejais. Funkcijų vediklis pateikia formulės variantą.

Pirma suntaksė

Duomenų laukas – pasirinkta viena iš suvestinės lentelės duomenų lauko eilučių. Eilutė gali būti nurodyta stulpelio pavadinimu arba duomenų laiku, kaip nurodyta lentelėje (kaip Suma → Pardavimai).

Suvestinė lentelė – langelio ar langelių srities nuoroda, kuri yra suvestinėje lentelėje arba apima suvestinę lentelę. Jei langelių sritis apima kelias suvestines lenteles, naudojama paskutinė kurta lentelė.

Jei nenurodyta pora laukas ir elementas, grąžinama visa galutinė suma. Priešingu atveju kiekviena pora prideda apribojimus, kuriuos turi tenkinti rezultatas. Laukas – suvestinės lentelės lauko pavadinimas. Elementas – to lauko elemento pavadinimas.

Jei suvestinėje lentelėje yra tik viena rezultato reikšmė, kuri atitinka apribojimus, arba tarpinis rezultatas, kuris apibendrina visas tinkamas reikšmes, šis rezultatas ir pateikiamas. Jei nėra tinkančio rezultato, tai grąžinama klaida. Šios sąlygos taikomos rezultatams, kurie įtraukti į suvestinę lentelę.

Jei pirminiuose duomenyse yra įrašų paslėptų suvestinės lentelės nustatymais, tie įrašai bus ignoruojami. Duomenų lauko ir elemento poros tvarka yra nereikšminga. Duomenų laukų ir elementų vardai nėra rašomi atsitiktinę tvarka.

Jei nenurodyta filtro reikšmė, naudojama pasirinkta lauko reikšmė. Nurodyta filtro reikšmė turi atitikti pasirinktą lauko reikšmę, arba grąžinama klaida. Filtro laukai yra suvestinės lentelės kairiajame viršutiniame kampe ir užpildomi iš suvestinės lentelė išdėstymo dialogo lango „Filtro“ srities. Reikšmė, kuri įtraukiama į skaičiavimus, gali būti pasirinkta kiekvienam filtrui.

Tarpinės sumos reikšmė suvestinėje lentelėje yra naudojama tik tada, jei ir funkcija „auto“ taip pat yra naudojama (išskyrus, jei kitaip nurodyta atitikmenyje, žiūrėti Antroji sintaksė žemiau).

Antra sintaksė

suvestinė lentelė turi tokia pat reikšmę kaip ir pirmoje sintaksėje.

Suvaržymas yra tarpais atskirtas sąrašas. Įvestys gali būti cituojamos (viengubomis kabutėmis). Visa eilutė turi būti kabutėse (dvigubose kabutėse), nebent eilutė yra nurodoma iš kito langelio.

Viena iš įvesčių gali būti duomenų lauko pavadinimas. Duomenų lauko pavadinimas gali likti neužpildytas, jei suvestinėje lentelėje yra tik vienas duomenų laukas, kitu atveju pavadinimas privalo būti įvestas.

Kiekviena kita įvestis nurodo formos Laukas[elementas] (su raidiniais ženklais ir laužtiniais skliaustais [ ]) apribojimą, arba tik Elementas, jei pavadinimas yra unikalus.

Funkcijos pavadinimas gali būti pridėtas formoje Laukas[Elementas;Funkcija], tai nurodys, kad ribojimas atitiks tik tarpinės sumos reikšmes, kurios yra naudojamos toje funkcijoje. Galimi funkcijos pavadinimai yra: Sum, Count, Average, Max, Min, Product, Count(tik skaičiai), StDev(imtis), StDevP(populiacija), Var(imtis) ir VarP(populiacija), neatsižvelgiant į atvejį.

HLOOKUP

Ieško langelių srities, esančios žemiau reikšmės ir nuorodos. Funkcija patikrina, ar pirmoji masyvo eilutė turi atitinkamą reikšmę. Funkcija grąžina reikšmę masyvo eilutėje, pavadintoje indeksas tame pačiame stulpelyje.

HLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Parametrų paaiškinimus rasite peržiūrėję VLOOKUP (stulpeliai ir eilutės sukeisti)

Suppose we have built a small database table occupying the cell range A1:DO4 and containing basic information about 118 chemical elements. The first column contains the row headings “Element”, “Symbol”, “Atomic Number”, and “Relative Atomic Mass”. Subsequent columns contain the relevant information for each of the elements, ordered left to right by atomic number. For example, cells B1:B4 contain “Hydrogen”, “H”, “1” and “1.008”, while cells DO1:DO4 contain “Oganesson”, “Og”, “118”, and “294”.

	A	B	C	D	...	DO
1	Element	Hydrogen	Helium	Lithium	...	Oganesson
2	Symbol	H	He	Li	...	Og
3	Atomic Number	1	2	3	...	118
4	Relative Atomic Mass	1.008	4.0026	6.94	...	294

=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) returns “Pb”, the symbol for lead.

=HLOOKUP("Gold"; $A$1:$DO$4; 3; 0) returns 79, the atomic number for gold.

=HLOOKUP("Carbon"; $A$1:$DO$4; 4; 0) returns 12.011, the relative atomic mass of carbon.

HYPERLINK

Spustelėjus langelį su hipersaitu, atveriama nuoroda.

If you use the optional CellValue parameter, the formula locates the URL, and then displays the text or number.

HYPERLINK("URL" [; CellValue])

URL specifies the link target. The optional CellValue parameter is the text or a number that is displayed in the cell and will be returned as the result. If the CellValue parameter is not specified, the URL is displayed in the cell text and will be returned as the result.

Tuštiems langeliams ar matricai rodomas skaičius 0.

=HYPERLINK("http://www.example.org") displays the text "http://www.example.org" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";"Click here") displays the text "Click here" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";12345) displays the number 12345 and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK($B4) where cell B4 contains http://www.example.org. The function adds http://www.example.org to the URL of the hyperlink cell and returns the same text which is used as formula result.

=HYPERLINK("http://www.";"Click ") & "example.org" displays the text Click example.org in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("#Sheet1.A1";"Go to top") displays the text Go to top and jumps to cell Sheet1.A1 in this document.

=HYPERLINK("file:///C:/writer.odt#Specification";"Go to Writer bookmark") displays the text "Go to Writer bookmark", loads the specified text document and jumps to bookmark "Specification".

=HYPERLINK("file:///C:/Documents/";"Open Documents folder") displays the text "Open Documents folder" and shows the folder contents using the standard file manager in your operating system.

INDEX

INDEX returns a reference, a value or an array of values from a reference range, specified by row and column index number or array of row and array of columns index numbers, and an optional range index.

INDEX() returns a reference if the argument is one or more references. When used in a cell in the form =INDEX(), the reference is resolved and the values displayed. When INDEX() is used in arguments of other functions, =FUNCTION(INDEX()...), the function gets the reference passed that was returned by INDEX(). Returning a reference is different from returning an array of values for functions that handles them differently.

INDEX(Reference [; [Row] [; [Column] [; Range]]])

Reference is a reference, entered either directly or by specifying a range name. If the reference consists of multiple ranges, you must enclose the list of references or range names in parentheses, or either use the tilde (~) range concatenation operator or define a named range with multiple areas.

Row (optional) represents the row or the array of row indexes of the reference range, for which to return a value. In case of zero or omitted (no specific row) all referenced rows are returned.

Column (optional) represents the column or array of column indexes of the reference range, for which to return a value. In case of zero or omitted (no specific column) all referenced columns are returned.

Range (optional) represents the index of the subrange if referring to a multiple range, default is 1.

{=INDEX({1,3,5;7,9,10},{2;1},1)} return a 2 row array containing 7 and 1. The row index {2;1} pick row 2 then row 1. The columns index 1 picks the first column.

{=INDEX(D3:G12,{1;2;3;4},{3,1})} return a 4 rows by 2 columns array. The row index array {1;2;3;4} picks rows 3 to 6 and {3;1} picks the third (F) and first column (D). Columns 1 and 3 of the source reference are swapped in the resulting array.

=INDEX(kainos;4;1) grąžina duomenų bazės srities, kurią galite nurodyti pasirinkę Duomenys → Apibrėžti, 4 eilutės ir 1 stulpelio reikšmę kaip kainos.

=INDEX(Suma X;4;1) grąžina srities Suma X, kuri apibrėžta Lakštas - Pavadintos sritys ir reiškiniai - Aprašyti, reikšmę į 4 eilutę ir 1 stulpelį.

{=INDEX(A1:B6;1)} returns the values of the first row of A1:B6. Enter the formula as an array formula.

{=INDEX(A1:B6;0;1)} returns the values of the first column of A1:B6. Enter the formula as an array formula.

=INDEX(A1:B6;1;1) nustato reikšmę, esančią viršutiniame kairiajame srities A1:B6 langelyje.

{=INDEX((A1:B6;C1:D6);0;0;2)} returns the values of the second range C1:D6 of the multiple range. Enter the formula as an array formula.

INDIRECT

Grąžinanuorodą, apibrėžtą teksto eilute. Ši funkcija taip pat gali naudojama atitinkamos eilutės srities nustatymui.

INDIRECT(nuoroda [; A1])

Nuoroda – nuoroda į langelį arba sritį (tekstiniu formatu), kurios turinys yra parodomas.

A1 (papildomas) – jei nurodytas 0, naudojamas R1C1 žymėjimas. Jei šis parametras praleistas arba nurodyta kita reikšmė, tai naudojamas A1 žymėjimas.

=INDIRECT(A1) lygu 100, jei A1 langelyje yra nuoroda C108, o langelyje C108 yra reikšmė 100.

=SUM(INDIRECT("a1:" & ADDRESS(1;3))) apskaičiuoja srities nuo A1 iki langelių, kurių adresas apibrėžtas 1 eilute ir 3 stulpeliu, sumą. Šiuo atveju apskaičiuoja srities A1:C1 sumą.

LAKŠTAS

Returns the sheet number of either a reference or a string representing a sheet name. If you do not enter any parameters, the result is the sheet number of the spreadsheet containing the formula.

SHEET([nuoroda])

Nuoroda papildomas parametras. Gali būti langelio srities nuoroda ar lakšto pavadinimo eilutė.

=SHEET(Sheet2.A1) returns 2 if Sheet2 is the second sheet in the spreadsheet document.

=SHEET("Sheet3") returns 3 if Sheet3 is the third sheet in the spreadsheet document.

LOOKUP

Grąžina langelio, vienos eilutės ar vieno stulpelio reikšmes. Papildomai grąžina priskirtą reikšmę (to paties indekso) atskirame stulpelyje ir eilutėje. Priešingai nei funkcijų VLOOKUP ir HLOOKUP šios funkcijos paieškos ir rezultato vektoriai gali būti skirtingose vietose; jie neturi būti gretimi. Be to, paieškos funkcijos LOOKUP vektorius turi būti išrikiuotas didėjančiai. Priešingu atveju paieška grąžins bet kurį naudotiną rezultatą.

LOOKUP(Lookup; SearchVector [; ResultVector])

Lookup is the value of any type to be looked for; entered either directly or as a reference.

Paieškos vektorius – viena eilutė arba stulpelis, kuriame ieškoma atitikties pagal kriterijų.

Rezultato vektorius – viena eilutė ar vienas stulpelis, kurio funkcijos rezultatas pateikiamas. Rezultatas pateikiamas rezultato vektoriaus langelyje su tuo pačiu indeksu kaip rastas paieškos vektoriuje.

=LOOKUP(A1;D1:D100;F1:F100) ieško atitinkamo langelio srityje D1:D100, kurio reikšmė yra lygi langelio A1 reikšmei. Funkcija suradusi nustato indeksą, pavyzdžiui, 12 srities langelis. Tuomet 12 langelio turinys grąžinamas kaip funkcijos rezultatas (rezultato vektoriuje).

MATCH

Grąžina santykinę elemento, kuris tenkina nurodytą reikšmę, vietą masyve . Funkcija grąžina reikšmės, rastos ieškomame masyve, vietos numerį.

MATCH(Search; LookupArray [; Type])

Search is the value which is to be searched for in the single-row or single-column array.

Paieškos masyvas – srities, kur vykdoma paieška nuoroda. Paieškos masyvas gali būti visa eilutė ar stulpelis, ar eilutės (stulpelio) dalis.

Tipas gali turėti reikšmes 1, 0 arba -1. Jei tipas lygus 1 arba jei nėra nurodytas, tai reiškia, kad pirmasis paieškos masyvo stulpelis yra išrikiuotas didėjančiai. Jei tipo reikšmė yra -1, tai laikoma, kad stulpelis išrikiuotas mažėjančiai. Tai suderinama su „Microsoft Excel“.

Jei tipas lygus 0, tai ieškomi tikslūs sutapimai. Jei randamos kelios paieškos kriterijaus atitiktys, funkcija grąžina pirmos tinkamos reikšmės indeksą.

If Type = 1 or the third parameter is missing, the index of the last value that is smaller or equal to the search criterion is returned. For Type = -1, the index of the last value that is larger or equal is returned.

=MATCH(200;D1:D100) ieškoma reikšmės 200 srityje D1:D100, išrikiuotoje pagal D stulpelį. Funkcija, suradusi tokią reikšmę, grąžina jos langelio eilutės numerį. Jei randama didesnė reikšmė, tai grąžinamas ankstesnės eilutės numeris.

OFFSET

Grąžina langelio reikšmę, paslinktą per nurodytą eilučių ir stulpelių skaičių nuo nurodytos vietos.

OFFSET(nuoroda; eilutės; stulpeliai [; aukštis [; plotis]])

Nuoroda – nuoroda, nuo kurios funkcija ieškos naujos nuorodos.

Eilutės – eilučių skaičius, per kurį nuoroda bus paslinkta aukštyn arba žemyn. Naudokite 0, jei eilutė turi likti ta pati.

Stulpelis – stulpelių skaičius, per kurį nuoroda bus paslinkta kairėn arba dešinėn. Naudokite 0, jei stulpelis turi likti tas pats.

Aukštis (papildomas) parametras, nurodantis vertikalų naujos srities aukštį.

Plotis (papildomas) parametras, nurodantis horizontalų naujos srities plotį.

Argumentai eilutės ir stulpeliai negali būti nulinė arba neigiama pradinė eilutė ar stulpelis.

Argumentai aukštis ir plotis negali būti nulinis ar neigiamas eilučių ar stulpelių skaičius.

„LibreOffice“ skaičiuoklėje papildomos funkcijos ir parametrai gali būti palikti kaip yra. Pavyzdžiui, jei funkcija turi keturis parametrus, kurių paskutiniai du yra pažymėti kaip papildomi, tai galima palikti nepakeistą parametrą 4 ar parametrus 3 ir 4, bet negalima palikti nepakeisto tik parametro 3.

=OFFSET(A1;2;2) grąžina langelio C3 (A1 pastumtas per dvi eilutes ir du stulpelius) reikšmę. Jei C3 yra 100, tai funkcija grąžina 100.

=OFFSET(B2:C3;1;1) grąžina nuorodą C3:D4, kurią funkcija gavo paslinkusi nuorodą B2:C3 per 1 eilutę žemyn ir 1 stulpelį dešinėn.

=OFFSET(B2:C3;1;1) grąžina nuorodą A1:B2, kurią funkcija gavo paslinkusi nuorodą B2:C3 per 1 eilutę aukštyn ir 1 stulpelį kairėn.

=OFFSET(B2:C3;0;0;3;4) grąžina nuorodą B2:E4, kurią funkcija gavo padidinusi sritį B2:C3 3 eilutėmis ir 4 stulpeliais.

=OFFSET(B2:C3;0;0;3;4) grąžina nuorodą B3:E5, kurią funkcija gavo paslinkusi sritį 1 eilutę žemyn ir padidinusi sritį B2:C3 3 eilutėmis ir 4 stulpeliais.

=SUM(OFFSET(A1;2;2;5;6)) apskaičiuoja srities, kurios pirmas langelis yra C3 ir yra 5 eilučių bei 6 stulpelių pločio, visų langelių reikšmių sumą.

ROW

Returns the row number of a cell reference. If the reference is a cell, it returns the row number of the cell. If the reference is a cell range, it returns the corresponding row numbers in a one-column Array if the formula is entered as an array formula. If the ROW function with a range reference is not used in an array formula, only the row number of the first range cell will be returned.

ROW([nuoroda])

Nuoroda – langelis, sritis ar srities pavadinimas.

Jei argumentas neįvestas, tai nustatomas langelio, kur įvesta formulė, eilutės numeris.„LibreOffice“ skaičiuoklė automatiškai nustato esamo langelio nuorodą.

=ROW(B3) grąžina 3, nes nuoroda rodo trečią lentelės eilutę.

{=ROW(D5:D8)} grąžina vieno stulpelio masyvą (5, 6, 7, 8).

=ROW(D5:D8) grąžina 5, nes ROW nebuvo įvesta kaip masyvo formulė ir rodomas tik pirmos srities eilutės numeris.

{=ROW(A1:E1)} and =ROW(A1:E1) abu grąžina 1.

=ROW() grąžina 3, jei formulė įvesta trečioje eilutėje.

{=ROW(triušis)} grąžina vienos eilutės masyvą (1, 2, 3), jei „triušis“ yra srities C1:D3 pavadinimas.

ROWS

Grąžina nurodytos srities eilučių skaičių.

ROWS(masyvas)

Masyvas – srities, kurios eilutės bus skaičiuojamos, nuoroda arba pavadinimas.

=Rows(B5) grąžina 1.

=ROWS(A10:B12) grąžina 3.

=ROWS(triušis) grąžina 3, jei sritis „triušis“ turi 3 eilutes.

SHEETS

Nustato, kiek lakštų yra nurodytoje srityje. Jei nenurodysite jokio parametro, tai grąžins lakštų, kurie yra dabartinėje darbo knygoje, skaičių.

SHEETS([nuoroda])

Nuoroda – lakšto ar srities nuoroda. Parametras papildomas.

=SHEETS(Lakštas 1.A1:Lakštas 3.G12) grąžina 3, jei Lakštas 1, Lakštas 2 ir Lakštas 3 yra nurodytoje srityje.

VLOOKUP

Vertical search with reference to adjacent cells to the right. This function checks if a specific value is contained in the first column of an array. The function then returns the value in the same row of the column named by Index. If the Sorted parameter is omitted or set to TRUE or one, it is assumed that the data is sorted in ascending order. In this case, if the exact Lookup is not found, the last value that is smaller than the criterion will be returned. If Sorted is set to FALSE or zero, an exact match must be found, otherwise the error Error: Value Not Available will be the result. Thus with a value of zero the data does not need to be sorted in ascending order.

=VLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Lookup is the value of any type looked for in the first column of the array.

Masyvas yra nuoroda apimanti tiek stulpelių, koks skaičius yra argumente.

Indeksas – masyvo stulpelio, kuriame yra rasta reikšmė, numeris. Pirmojo stulpelio numeris yra 1.

SortedRangeLookup is an optional parameter that indicates whether the first column in the array contains range boundaries instead of plain values. In this mode, the lookup returns the value in the row with first column having value equal to or less than Lookup. E.g., it could contain dates when some tax value had been changed, and so the values represent starting dates of a period when a specific tax value was effective. Thus, searching for a date that is absent in the first array column, but falls between some existing boundary dates, would give the lower of them, allowing to find out the data being effective to the searched date. Enter the Boolean value FALSE or zero if the first column is not a range boundary list. When this parameter is TRUE or not given, the first column in the array must be sorted in ascending order. Sorted columns can be searched much faster and the function always returns a value, even if the search value was not matched exactly, if it is greater than the lowest value of the sorted list. In unsorted lists, the search value must be matched exactly. Otherwise the function will return #N/A with message: Error: Value Not Available.

Tarkime, kad lentele pateikiate patiekalų sąrašą ir norite, kad ieškomo patiekalo numeris atsirastų langelyje A1, o atitinkančio numerį patiekalo pavadinimas – gretimame stulpelyje B1. Lentelėje pavadinimai ir numeriai yra masyvo srityje D1:E100. D1 langelyje įrašytas numeris 1, E1 įrašytas pavadinimas Daržovių sriuba, ir taip toliau visiems 100 meniu įrašų. Stulpelyje D numeriai yra išrikiuoti didėjančiai, todėl nėra būtina nurodyti papildomo parametro rikiavimas.

Įrašykite formulę langelyje B1:

=VLOOKUP(A1;D1:E100;2)

Kai tik įvesite formulę, langeliuose A1 ir B2 atsiras atitinkamas masyvo srities D1:E100 antro stulpelio tekstas. Jei formulėje įrašysite lentelėje neegzistuojančią reikšmę, tai pasirodys sekančio paieškos kriterijaus (numerio) rezultatas. Jei norite šito išvengti, nurodykite paskutinį funkcijos rikiavimo parametrą NETIESA. Tuomet, įvedus neegzistuojantį lentelėje numerį, bus sugeneruota klaida.