Informacijos funkcijos

Šioje kategorijoje yra Informacijos funkcijos.

Jei norite tai atlikti…

Įterpimas → Funkcija → Kategorija Informacinės


Toliau lentelėje pateikiami kai kurių funkcijų aprašymų pavyzdžiai:

C

D

2

x value

y value

3

-5

-3

4

-2

0

5

-1

1

6

0

3

7

2

4

8

4

6

9

6

8

CELL

Grąžina informaciją apie langelio koordinates, turinio formatavimą.

Sintaksė

CELL("tipas" [; nuoroda])

Informacijos tipas – ženklų eilutė, nusakanti informacijos tipą. Ženklų eilutė turi būti anglų kalba. Neskiriamos didžiosios ir mažosios raidės.

Informacijos tipas

Paaiškinimas

COL

Grąžina nurodyto stulpelio numerį.

=CELL("COL";D2) grąžina 4.

ROW

Grąžina nurodytos eilutės numerį.

=CELL("ROW";D2) grąžina 2.

SHEET

Grąžina nurodyto lakšto numerį.

=CELL("Sheet";Sheet3.D2) grąžina 3.

ADDRESS

Grąžina absoliutųjį nurodyto langelio adresą.

=CELL("ADDRESS";D2) grąžina $D$2.

=CELL("ADDRESS";Lakštas3.D2) grąžina $Lakštas3.$D$2.

=CELL("ADDRESS";'X:\dr\test.ods'#$Lakštas1.D2) grąžina 'file:///X:/dr/test.ods'#$Lakštas1.$D$2.

FILENAME

Grąžina nurodyto langelio failo pavadinimą ir lakšto numerį.

=CELL("FILENAME";D2) grąžina file:///X:/dr/own.ods'#$Sheet1, jei dabartinio dokumento X:\dr\own.ods formulė yra Lakštas1.

=CELL("FILENAME";'X:\dr\test.ods'#$Lakštas1.D2) grąžina 'file:///X:/dr/test.ods'#$Lakštas1.

COORD

Grąžina langelio adresą Lotus™ žymenimis.

=CELL("COORD"; D2) grąžina $A:$D$2.

=CELL("COORD"; Sheet3.D2) grąžina $C:$D$2.

CONTENTS

Grąžina nurodyto langelio turinį be formatavimo.

TYPE

Grąžina langelio turinio tipą.

b = blank. tuščias langelis

I = label. Formulė kaip tekstas

v = value. Formulės rezultatas skaičius

WIDTH

Grąžina nurodyto stulpelio plotį. Pločio matavimo vienetas yra numatyto dydžio ir numatyto formato skaičius 0, t. y., kiek nulių telpa į langelio plotį.

PREFIX

Grąžina nurodyto langelio lygiuotę.

' = kairinė lygiuotė arba kairinė abipusė

" = dešininė lygiuotė

^ = centruota

\ = pasikartojantis (dabar neaktyvus)

PROTECT

Grąžina langelio apsaugos būseną.

1 = langelis apsaugotas

0 = langelis neapsaugotas

FORMAT

Grąžina ženklų eilutę, kuri nurodo skaičiaus formatą.

, = skaičius su dešimčių skirtuku

F = skaičius be dešimčių skirtuko

C = dabartinis formatas

S = eksponentinė skaičiaus išraiška, pvz. 1,234+E56

P = procentai

Anksčiau aprašytuose formatuose skaitmenų skaičius po kablelio nurodomas skaičiumi. Pavyzdžiui: skaičius formatu ###0,0 grąžina reikšmę 1, o formatu 00,000% grąžina P3

D1=MM-mmm-DD, MMMM-mm-DD ar panašus formatas

D2 = DD-mm

D3 = mm-MM

D4 = MMMM-mm-DD HH:MM:SS

D5 = mm-DD

D6 = HH:MM:SS

D7 = HH:MM

D8 = HH:MM:SS

D9 = HH:MM

G = kiti formatai

- (Minusas) gale reiškia, kad neigiamų skaičių spalva bus formatuojama.

() (skliaustai) gale reiškia, kad kodavimas prasideda skliaustais

COLOR

Grąžina 1, jie neigiamų skaičių spalva buvo formatuota, kitu atveju 0.

PARENTHESES

Grąžina 1, jei kodavimas prasideda su skliausteliu (, kitu atveju 0.

Nuoroda parodo, kuris langelis yra aktyvus. Jei rodoma langelių srities Nuuoroda, tai aktyvus langelis yra viršutiniame kairiajame srities langelyje. Jei nerodoma jokia Nuoroda, tai LibreOffice skaičiuoklė naudoja langelį, kuriame įrašyti ši formulė. „Microsoft Excel“ rodo nuorodą langelio, kuriame yra žymeklis.

CURRENT

Ši funkcija grąžina rezultatą įvertinant formulę, kurios dalis ji yra (kitaip tariant rezultatą, kai tik įvertinama). Dažniausiai naudojama kartu su STYLE() funkcija, kuri pasirinktą stilių pritaiko langeliui pagal jo turinį.

Sintaksė

CURRENT()

Pavyzdys

1+2+CURRENT()

Pavyzdyje grąžinama reikšmė 6. Formulė skaičiuoja iš kairės į dešinę: 1+2 lygu 3, kai dar nėra priskaičiuota CURRENT() reikšmė; todėl CURRENT() reikšmė yra 3, ir bendras rezultatas 6.

=A2+B2+STYLE(IF(CURRENT()>10;"Raudona";"Numatyta"))

Pavyzdyje grąžinama A2 + B2 (STYLE grąžina 0). Jei suma didesnė už 10, langelis nuspalvinamas raudonai. Daugiau paaiškinimų galite rasti funkcijos STYLE aprašyme.

=“choo&CURRENT()

Grąžinama „choochoo“.

Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

ORG.OPENOFFICE.CURRENT

FORMULA

Parodo formulės langelio formulę kaip tekstinę eilutę.

Ši funkcija nuolat perksičiuojama.

Sintaksė

FORMULA(Nuoroda)

Nuoroda langelio, kuriame yra formulės koordinatės.

Rodomas klaidų #N/A pranešimas, kai įvedama neteisingos langelio koordinatės arba langelyje nėra formulės.

Pavyzdys

Jei langelyje A8 yra formulė SUM(1;2;3), tai

=FORMULA(A8) grąžina tekstą „=SUM(1;2;3).

IFERROR

Returns the value if the cell does not contain an error value, or the alternative value if it does.

tip

Ši funkcija pasiekiama nuo „LibreOffice“ 4.0 versijos.


Sintaksė

IFERROR(reikšmė; alternatyvi reikšmė)

Reikšmė yra reikšmė arba išraiška, kurią grąžina funkcija, jeigu ji nėra klaidinga.

Alternatyvi_reikšmė yra reikšmė arba išraiška, kurią grąžina funkcija, kai Reikšmė yra klaidinga.

Pavyzdys

=IFERROR(C8;C9), kur langelyje C8 yra =1/0 grąžina langelio C9 reikšmę, nes veiksmas 1/0 yra klaidingas.

=IFERROR(C8;C9), kur langelyje C8 yra 13, grąžina 13, nes reikšmė langelyje C8 nėra klaidinga.

IFNA

Returns the value if the cell does not contain the #N/A (value not available) error value, or the alternative value if it does.

tip

Ši funkcija pasiekiama nuo „LibreOffice“ 4.0 versijos.


Sintaksė

IFNA(reikšmė; alternatyvi reikšmė)

Reikšmė – grąžinama reikšmė, jei nėra #N/A klaida.

Alternatyvi_reikšmė yra reikšmė arba išraiška, kurią grąžina funkcija, kai Reikšmė yra #N/A klaida.

Pavyzdys

=IFNA(D3;D4) grąžina langelio D3 reikšmę, jei langelyje nėra #N/A klaidos, arba langelio D4 reikšmę, jei langelyje D3 yra klaida.

INFO

Grąžina tam tikrą informaciją apie dabartinę aktyvią aplinką. Funkcija turi vieną tekstinį argumentą ir grąžina duomenis priklausomai nuo to tekstinio parametro.

Ši funkcija nuolat perksičiuojama.

Sintaksė

INFO("Tipas")

Lentelėje pateikiamas tekstinio parametro Tipas reikšmių sąrašas ir grąžinamos INFO funkcijos reikšmės.

„Tipo“ reikšmė

Grąžinama reikšmė

"osversion"

Visada „Windows (32-bit) NT 5.01“ dėl suderinamumo

"system"

The type of the operating system:
"ANDROID" for Google mobile operating system
"DRAGONFLY" for DragonFly operating system forked from FreeBSD
"EMSCRIPTEN" for browser WebAssembly system
"FREEBSD", "OPENBSD" or "NETBSD" for operating systems based on the Berkeley Software Distribution (BSD)
"HAIKU" for BeOS compatible operating system
"iOS" for Apple mobile operating system
"LINUX" for GNU/Linux based operating systems
"MACOSX" for Apple macOS
"SOLARIS" for Oracle Solaris operating system
"WNT" for Microsoft Windows

"release"

Produkto išleidimo identifikatorius, pavyzdžiui, „300m25(Build:9876)“

"numfile"

Visada 1 dėl suderinamumo

"recalc"

Dabartinės formulės perskaičiavimo veiksena „Automatinė“ arba „Rankinė" (lokalizuota „LibreOffice“ kalba)

note

Kitos skaičiuoklės dokumento aplinkos gali priimti parametro Tipas reikšmes, bet „LibreOffice“ skaičiuoklė priima tik anglų kalbos reikšmes.


Pavyzdys

=INFO(„išleidimas“) grąžina naudojamo produkto „LibreOffice“ versijos numerį.

=INFO(D5) su langelyje D5 esančia tekstine eilute sistema grąžina operacinės sistemos tipą.

ISBLANK

Grąžina TRUE, jei nuorodos langelis yra tuščias. Funkcija nustato, ar langelyje yra turinys. Langelis, kuriame yra formulė, nėra tuščias.

Įvykus klaidai, funkcija grąžina loginę arba skaitinę reikšmę.

Sintaksė

ISBLANK(Reikšmė)

Reikšmė – tikrinamas turinys.

Pavyzdys

=ISBLANK(D2) grąžina FALSE.

ISERR

Tikrina klaidos sąlygas, išskyrus klaidą #N/A, ir grąžina TRUE arba FALSE.

Įvykus klaidai, funkcija grąžina loginę arba skaitinę reikšmę.

Sintaksė

ISERR(Reikšmė)

Reikšmė yra bet kuri reikšmė arba išraiška, kuri tikrinama, ar tai klaidos reikšmė (išskyrus #N/A).

Pavyzdys

=ISERR(C8), kur langelyje C8 yra =1/0 grąžina TRUE, nes veiksmas 1/0 yra klaidingas.

=ISERR(C9), kur langelyje C9 yra =NA() grąžina FALSE, nes ISERR() ignoruoja klaidą #N/A.

ISERROR

Tikrina klaidas apimant ir klaidą #N/A. Grąžina TRUE arba FALSE.

Įvykus klaidai, funkcija grąžina loginę arba skaitinę reikšmę.

Sintaksė

ISERROR(Reikšmė)

Reikšmė yra arba nukreipia į tikrinamą reikšmę. ISERROR() grąžina TRUE, jei yra klaida, FALSE, jei klaidos nėra.

Pavyzdys

=ISERROR(C8), kur langelyje C8 yra =1/0 grąžina TRUE, nes veiksmas 1/0 yra klaidingas.

=ISERROR(C9), kur langelyje C9 yra NA() grąžina TRUE.

ISEVEN

Grąžina TRUE, jei reikšmė yra lyginis sveikasis skaičius, arba FALSE, jei reikšmė – nelyginis skaičius.

Sintaksė

ISEVEN(Reikšmė)

Reikšmė – tikrinama reikšmė.

Jei reikšmė yra nesveikasis skaičius, tai visi skaitmenys po kablelio yra ignoruojami. Taip pat ignoruojamas ir skaičiaus ženklas.

Pavyzdys

=ISEVEN(48) grąžina TRUE

=ISEVEN(33) grąžina FALSE

=ISEVEN(0) grąžina TRUE

=ISEVEN(-2,1) grąžina TRUE

=ISEVEN(3,999) grąžina FALSE

ISEVEN_ADD

Tikrina, ar skaičius lyginis. Grąžina 1, jei skaičius dalijasi iš 2 be liekanos.

note

Funkcijos, kurių pavadinimai baigiasi _ADD arba _EXCEL2003, grąžina tokius pačius rezultatus kaip ir atitinkamos Excel 2033 funkcijos be priesagos. Naudokitės funkcijomis be priesagos, kad gautumėte rezultatus pagal tarptautinius standartus.


Sintaksė

ISEVEN_ADD(Skaičius)

Skaičius – tikrinamas skaičius.

Pavyzdys

=ISEVEN_ADD(5) grąžina 0.

=ISEVEN_ADD(A1) grąžina 1, langelyje A1 yra skaičius 2.

ISFORMULA

Grąžina TRUE, jei langelyje yra formulė.

Įvykus klaidai, funkcija grąžina loginę arba skaitinę reikšmę.

Sintaksė

ISFORMULA(Nuoroda)

Nuoroda – tikrinamo langelio nuoroda.

Pavyzdys

=ISFORMULA(C4) grąžina FALSE, jei langelyje C4 yra skaičius 5.

ISLOGICAL

Tikrina, ar reikšmė yra loginė (TRUE arba FALSE).

Jei yra klaida, funkcija grąžina FALSE.

Sintaksė

ISLOGICAL(Reikšmė)

Grąžina TRUE, jei reikšmė loginė (TRUE arba FALSE), kitais atvejais FALSE.

Pavyzdys

=ISLOGICAL(99) grąžina False, nes 99 yra skaičius, o ne loginė reikšmė.

=ISLOGICAL(SNA(D4)) grąžina TRUE nepriklausomai nuo langelio D4 turinio, nes ISNA() grąžina loginę reikšmę.

ISNA

Grąžina TRUE, jei langelyje yra #N/A (negalima reikšmė) klaida.

Jei yra klaida, funkcija grąžina FALSE.

Sintaksė

ISNA(Reikšmė)

Reikšmė – tikrinama reikšmė.

Pavyzdys

=ISNA(D3) grąžina FALSE.

ISNONTEXT

Tikrina, ar langelio turinys yra tekstinis ar skaitinis ir grąžina FALSE, jei turinys yra tekstinis.

Jei yra klaida, funkcija grąžina TRUE.

Sintaksė

ISNONTEXT(Reikšmė)

Reikšmė – bet kokia reikšmė ar reiškinys, kuriam pritaikomas tikrinimo testas.

Pavyzdys

=ISNONTEXT(D2) grąžina FALSE, jei langelyje D2 yra tekstas, pvz. abcdef.

=ISNONTEXT(D9) grąžina TRUE, jei langelyje D9 yra skaičius, pvz. 8.

ISNUMBER

Grąžina TRUE, jei nuoroda yra į langelį su skaičiumi.

Įvykus klaidai, funkcija grąžina loginę arba skaitinę reikšmę.

Sintaksė

ISNUBER(Reikšmė)

Reikšmė – tikrinama reikšmė.

Pavyzdys

=ISNUMBER(C3) grąžina TRUE, jei langelyje C3 yra skaičius, pvz. 4.

=ISNUMBER(C2) grąžina FALSE, jei langelyje C2 yra tekstas, pvz. abcdef.

ISODD

Grąžina TRUE, jei reikšmė yra nelyginis sveikasis skaičius, arba FALSE, jei reikšmė – lyginis skaičius.

Sintaksė

ISODD(Reikšmė)

Reikšmė – tikrinama reikšmė.

Jei reikšmė yra nesveikasis skaičius, tai visi skaitmenys po kablelio yra ignoruojami. Taip pat ignoruojamas ir skaičiaus ženklas.

Pavyzdys

=ISODD(33) grąžina FALSE

=ISODD(48) grąžina FALSE

=ISODD(3,999) grąžina TRUE

=ISODD(-3,1) grąžina TRUE

ISODD_ADD

Grąžina TRUE (1), jei skaičius nesidalija iš 2.

note

Funkcijos, kurių pavadinimai baigiasi _ADD arba _EXCEL2003, grąžina tokius pačius rezultatus kaip ir atitinkamos Excel 2033 funkcijos be priesagos. Naudokitės funkcijomis be priesagos, kad gautumėte rezultatus pagal tarptautinius standartus.


Sintaksė

ISODD_ADD(Reikšmė)

Skaičius – tikrinamas skaičius.

Pavyzdys

=ISODD_ADD(5) grąžina 1.

ISREF

Tikrinama, ar argumentas yra nuoroda. Grąžina TRUE, jei argumentas yra nuoroda, kitu atveju FALSE. Ši funkcija netikrina nuorodos reikšmės.

Įvykus klaidai, funkcija grąžina loginę arba skaitinę reikšmę.

Sintaksė

ISREF(Reikšmė)

Reikšmė tikrinama reikšmė.

Pavyzdys

=ISREF(C5) grąžina TRUE, kadangi C5 yra langelio nuoroda.

=ISREF(“absdef“) visada grąžina FALSE, kadangi tekstas negali būti nuoroda.

ISREF(4) grąžina FALSE.

=ISREF(INDIRECT(“A6)) grąžina TRUE, kadangi INDIRECT yra funkcija, kuri turi nuorodą.

=ISREF(ADDRESS(1; 2; 3;“Lakštas2)) grąžina FALSE, nes ADDRESS yra funkcija, grąžinanti tekstinę informaciją, nors ji atrodo kaip nuoroda.

ISTEXT

Grąžina TRUE, jei langelyje yra tekstas.

Jei yra klaida, funkcija grąžina FALSE.

Sintaksė

ISTEXT(reikšmė)

Reikšmė – tikrinama reikšmė, skaičius, loginė reikšmė ar klaidos pranešimas.

Pavyzdys

=ISTEXT(D9) grąžina TRUE, jei langelyje D9 yra tekstas, pvz. abcdef.

=ISTEXT(C3) grąžina FALSE, jei langelyje C3 yra skaičius, pvz. 5.

N

Grąžina duoto parametro skaitinę reikšmę. Grąžina 0, jei parametras yra tekstas arba FALSE.

Jei yra klaida, funkcija grąžina klaidos reikšmę.

Sintaksė

N(Reikšmė)

Reikšmė – į skaičių konvertuojamas parametras. N() grąžina skaitinę reikšmę, jei gali. Loginę reikšmę TRUE arba FALSE grąžina kaip 1 arba 0. Tekstą grąžina kaip 0.

Pavyzdys

=N(123) grąžina 123

=N(TRUE(1)) grąžina 1

=N(FALSE()) grąžina 0

=N(abc) grąžina 0

=N(1/0) grąžina #DIV/0!

NA

Grąžina klaidos reikšmę #N/A.

Sintaksė

NA()

Pavyzdys

=NA() konvertuoja langelio turinį į #N/A.

TYPE

Grąžina langelio reikšmės tipą, kur 1 reiškia, kad langelyje yra skaičius, 2 – tekstas, 4 – loginė reikšmė, 8 – formulė, 16 – klaida, 64 – masyvas.

Įvykus klaidai, funkcija grąžina loginę arba skaitinę reikšmę.

Sintaksė

TYPE(Reikšmė)

Reikšmė – tam tikra reikšmė, kurios tipas nustatomas.

Pavyzdys (pateikiamas lentelėje)

=TYPE(C2) grąžina 2.

=TYPE(C9) grąžina 1.

Susijusios temos

Funkcijos pagal kategorijas

Paremkite mus!