ScriptForge.Array service

Provides a collection of methods for manipulating and transforming arrays of one dimension (vectors) and arrays of two dimensions (matrices). This includes set operations, sorting, importing from and exporting to text files.

Šios paslaugos metodai gali būti naudojami tik vienmačiams ir dvimačiams masyvams, vienintelė išimtis yra CountDims metodas, kuriam tinka bet kokio matmenų skaičiaus masyvai.

Masyvo elementai gali būti bet kurio tipo reikšmės, įskaitant ir pačius masyvus.

Paslaugos iškvietimas

Prieš naudojantis Array paslauga reikia įkelti ScriptForge biblioteką naudojantis:

    GlobalScope.BasicLibraries.loadLibrary("ScriptForge")
  

Įkėlus biblioteką bus sukurtas SF_Array objektas, kurį galima naudoti norint iškviesti metodus iš Array paslaugas.

Šie kodo fragmentai rodo įvairius būdus, kaip iškviesti metodus, esančius Array paslauga (pavyzdžiui, naudojamas metodas Pridėti):

    Dim arr : arr = Array(1, 2, 3)
    arr = SF_Array.Append(arr, 4)
  

    Dim arr : arr = Array(1, 2, 3)
    Dim svc : svc = SF_Array
    arr = svc.Append(arr, 4)
  

    Dim arr : arr = Array(1, 2, 3)
    Dim svc : svc = CreateScriptService("Array")
    arr = svc.Append(arr, 4)
  

Because Python has built-in list and tuple support, most of the methods in the Array service are available for Basic scripts only. The only exception is ImportFromCSVFile which is supported in both Basic and Python.

Pirmasis daugumos metodų argumentas yra masyvo objektas. Jis visada perduodamas nuoroda ir lieka nepakitęs. Tokie metodai, kaip „Append“, „Prepend“ ir pan., grąžina naują masyvo objektą.

Append

Įvedimo masyvo pabaigoje pridedami elementai, išvardyti kaip argumentai.

svc.Append(array_1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]

array_1d: The pre-existing array, may be empty.

arg0, arg1, ...: Items that will be appended to array_1d.

    Dim a As Variant
    a = SF_Array.Append(Array(1, 2, 3), 4, 5)
        ' (1, 2, 3, 4, 5)
  

AppendColumn

Dešinėje dviejų matmenų masyvo pusėje pridedamas naujas stulpelis. Gautas masyvas turi tuos pačius apatinius rėžius, kaip ir pradinio dviejų matmenų masyvo.

svc.AppendColumn(array_2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]

array_2d: The pre-existing array, may be empty. If that array has only one dimension, it is considered as the first column of the resulting two-dimensional array.

column: A 1-dimensional array with as many items as there are rows in array_2d.

    Dim a As Variant, b As variant
    a = SF_Array.AppendColumn(Array(1, 2, 3), Array(4, 5, 6))
        ' ((1, 4), (2, 5), (3, 6))
    b = SF_Array.AppendColumn(a, Array(7, 8, 9))
        ' ((1, 4, 7), (2, 5, 8), (3, 6, 9))
    c = SF_Array.AppendColumn(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
  

AppendRow

Dešinėje dviejų matmenų masyvo pusėje pridedamas naujas stulpelis. Gautas masyvas turi tuos pačius apatinius rėžius, kaip ir pradinio dviejų matmenų masyvo.

svc.AppendRow(array_2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*])

array_2d: The pre-existing array, may be empty. If that array has 1 dimension, it is considered as the first row of the resulting 2 dimension array.

row: A 1-dimensional array with as many items as there are columns in array_2d.

    Dim a As Variant, b As variant
    a = SF_Array.AppendRow(Array(1, 2, 3), Array(4, 5, 6))
        '  ((1, 2, 3), (4, 5, 6))
    b = SF_Array..AppendRow(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
  

Contains

Patikrinkite, ar vienmačiame masyve yra tam tikras skaičius, tekstas ar data. Lyginant tekstą galima skirti didžiąsias ir mažąsias raides, arba ne.
Rikiuoti pradiniai masyvai turi būti užpildyti vienarūšiais duomenimis, kas reiškia, kad visi elementai turi būti to paties paprastojo tipo (elementai Tušti ir Nuliniai draudžiami).
Metodo rezultatas yra neapibrėžtas, kai masyvas skelbiamas surikiuotu, o iš tikrųjų nėra.
Dvejetainė paieška atliekama sutvarkius masyvą, priešingu atveju jis tiesiog nuskaitomas iš viršaus į apačią ir ignoruojami elementai Tušti ir Nuliniai.

svc.Contains(array_1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ""): bool

array_1d: The array to scan.

tofind: A number, a date or a string to find.

casesensitive: Only for string comparisons (Default = False).

sortorder: It can be either "ASC", "DESC" or "" (not sorted). The default value is "".

    Dim a As Variant
    a = SF_Array.Contains(Array("A","B","c","D"), "C", SortOrder := "ASC") ' True
    SF_Array.Contains(Array("A","B","c","D"), "C", CaseSensitive := True) ' False
  

ConvertToDictionary

Store the content of a 2-columns array into a ScriptForge.Dictionary object.
The key will be extracted from the first column, the item from the second.

svc.ConvertToDictionary(array_2d: any[0..*, 0..1]): obj

array_2d: Data to be converted into a ScriptForge.Dictionary object.

• The first column must contain exclusively strings with a length greater than zero, in any order. These values will be used as labels in the dictionary.

• The second column contains the data that will be associated to the corresponding label in the dictionary.

    Dim a As Variant, b As Variant
    a = SF_Array.AppendColumn(Array("a", "b", "c"), Array(1, 2, 3))
    b = SF_Array.ConvertToDictionary(a)
    MsgBox b.Item("c") ' 3
  

Copy

Creates a copy of a 1D or 2D array.

svc.Copy(array_nd: any[0..*]): any[0..*]

svc.Copy(array_nd: any[0..*, 0..*]): any[0..*, 0..*]

array_nd: The 1D or 2D array to be copied.

A simple assignment of an Array object will copy its reference instead of creating a copy of the object's contents. See the example below:

    Dim a as Variant, b as Variant
    a = Array(1, 2, 3)
    ' The assignment below is made by reference
    b = a
    ' Hence changing values in "b" will also change "a"
    b(0) = 10
    MsgBox a(0) ' 10
  

By using the Copy method, a copy of the whole Array object is made. In the example below, a and b are different objects and changing values in b will not affect values in a.

    Dim a as Variant, b as Variant
    a = Array(1, 2, 3)
    ' Creates a copy of "a" using the "Copy" method
    b = SF_Array.Copy(a)
    b(0) = 10
    MsgBox a(0) ' 1
  

CountDims

Count the number of dimensions of an array. The result can be greater than two.
If the argument is not an array, returns -1
If the array is not initialized, returns 0.

svc.CountDims(array_nd: any): int

array_nd: The array to examine.

    Dim a(1 To 10, -3 To 12, 5)
    MsgBox SF_Array.CountDims(a) ' 3
  

Difference

Sukurkite rinkinį, kaip nulinį masyvą, taikydami skirtumo operatorių dviem pradiniams masyvams. Rezultatai gaunami iš pirmojo masyvo, o ne iš antrojo.
Gautas masyvas išrikiuojamas didėjimo tvarka.
Abi pradiniai masyvai turi būti užpildyti vienodai, jų elementai turi būti to paties tipo paprastieji duomenys. Draudžiami elementai Tušti ir Null.
Lyginant tekstą didžiosios ir mažosios raidės gali būti skiriamos arba neskiriamos.

svc.Difference(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

array1_1d: A 1-dimensional reference array, whose items are examined for removal.

array2_1d: A 1-dimensional array, whose items are subtracted from the first input array.

casesensitive: This argument is only applicable if the arrays are populated with strings (Default = False).

    Dim a As Variant
    a = SF_Array.Difference(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
        ' ("A", "B")
  

ExportToTextFile

Surašo visus masyvo elementus nuosekliai į teksto failą. Jei toks failas jau yra, bus užrašoma ant viršaus be perspėjimo.

svc.ExportToTextFile(array_1d: any[0..*], filename: str, [encoding: str]): bool

array_1d: The array to export. It must contain only strings.

filename: The name of the text file where the data will be written to. The name must be expressed according to the current FileNaming property of the SF_FileSystem service.

encoding: The character set that should be used. Use one of the names listed in IANA character sets. Note that LibreOffice may not implement all existing character sets (Default is "UTF-8").

    SF_Array.ExportToTextFile(Array("A","B","C","D"), "C:\Temp\A short file.txt")
  

ExtractColumn

Ištraukite iš dvimačio masyvo konkretų stulpelį kaip naują masyvą.
Šio masyvo apatinis LBound ir viršutinis UBound rėžiai yra tokie pat, kaip ir pirmojo pradinio masyvo.

svc.ExtractColumn(array_2d: any[0..*, 0..*], columnindex: int): any[0..*, 0..*]

array_2d: The array from which to extract.

columnindex: The column number to extract - must be in the interval [LBound, UBound].

    'Sukuria 3x3 matricą: |1, 2, 3|
    '                      |4, 5, 6|
    '                      |7, 8, 9|
    Dim mat as Variant, col as Variant
    mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
    mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
    mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
    'Ištraukia trečiąjį stulpelį: |3, 6, 9|
    col = SF_Array.ExtractColumn(mat, 2)
  

ExtractRow

Ištraukite iš dvimačio masyvo konkretų stulpelį kaip naują masyvą.
Šio masyvo apatinis LBound ir viršutinis UBound rėžiai yra tokie pat, kaip ir pirmojo pradinio masyvo.

svc.ExtractRow(array_2d: any[0..*, 0..*], rowindex: int): any[0..*, 0..*]

array_2d: The array from which to extract.

rowindex: The row number to extract - must be in the interval [LBound, UBound].

    'Sukuria 3x3 matricą: |1, 2, 3|
    '                      |4, 5, 6|
    '                      |7, 8, 9|
    Dim mat as Variant, row as Variant
    mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
    mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
    mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
    'Ištraukia pirmąją eilutę: |1, 2, 3|
    row = SF_Array.ExtractRow(mat, 0)
  

Flatten

Sudėkite visus atskirus masyvo elementus ir visus jo elementus į vieną naują masyvą. Tuščių dalinių masyvų nepaisoma. Daliniai masyvai, kurių matmenų skaičius yra didesnis nei vienas, nėra sugriaunami.

svc.Flatten(array_1d: any[0..*]): any[0..*]

array_1d: The pre-existing array, may be empty.

    Dim a As Variant
    a = SF_Array.Flatten(Array(Array(1, 2, 3), 4, 5))
        ' (1, 2, 3, 4, 5)
  

Norėdami susieti vienmatį masyvų rinkinį į vieną vienmatį masyvą, galite naudoti Flatten metodą kartu su kitais metodais, pvz., Pridėti arba Prepend.

Kitas pavyzdys, kaip metodai Flatten ir Append gali sujungti tris masyvus.

    'Šiam pavyzdžiui sukuria tris masyvus
    Dim a as Variant, b as Variant, c as Variant
    a = Array(1, 2, 3)
    b = Array(4, 5)
    c = Array(6, 7, 8, 9)
    'Sujungia tris masyvus į vieną vienmatį masyvą
    Dim arr as Variant
    arr = SF_Array.Flatten(SF_Array.Append(a, b, c))
    '(1, 2, 3, 4, 5, 6, 7, 8, 9)
  

ImportFromCSVFile

Importuokite kableliais atskirtus failo (CSV) duomenis. Kablelį galima pakeisti bet kuriuo simboliu.

Taikomas CSV formatas aprašytas dokumente IETF bendraisi formatas ir MIME tipas CSV failams.

Kiekvienoje failo eilutėje yra visas įrašas (eilučių skaidyti negalima).
Tačiau tokios sekos kaip \n, \t , ... lieka nepakeistos. Joms valdyti naudokite metodą SF_eilutė .Unescape ().

Metodas pateikia dviejų matmenų masyvą, kurio eilutės atitinka vieną faile perskaitytą įrašą, o stulpeliai – įrašo lauką. Stulpelių lauko tipų atitikimas netikrinamas. Geriausia identifikuojami skaičių ir datų tipai.

Jei eilutėje yra mažiau ar daugiau laukų nei pirmoje failo eilutėje, bus formuojama išimtis. Tačiau tuščius eilutės tiesiog nepaisomos. Jei failo dydis viršija elementų skaičiaus limitą (žr. kodo viduje), įspėjima ir masyvas sutrumpinamas.

svc.ImportFromCSVFile(filename: str, delimiter: str = ',', dateformat: str = ''): any[0..*]

filename: The name of the text file containing the data. The name must be expressed according to the current FileNaming property of the SF_FileSystem service.

delimiter: A single character, usually, a comma, a semicolon or a TAB character (Default = ",").

dateformat: A special mechanism handles dates when dateformat is either "YYYY-MM-DD", "DD-MM-YYYY" or "MM-DD-YYYY". The dash (-) may be replaced by a dot (.), a slash (/) or a space. Other date formats will be ignored. Dates defaulting to an empty string "" are considered as normal text.

Consider the CSV file "myFile.csv" with the following contents:

Name,DateOfBirth,Address,City

Anna,2002/03/31,"Rue de l'église, 21",Toulouse

Fred,1998/05/04,"Rue Albert Einstein, 113A",Carcassonne

The examples below in Basic and Python read the contents of the CSV file into an Array object.

    Dim arr As Variant
    arr = SF_Array.ImportFromCSVFile("C:\Temp\myFile.csv", DateFormat := "YYYY/MM/DD")
    MsgBox arr(0, 3) ' City
    MsgBox arr(1, 2) ' Rue de l'église, 21
    MsgBox arr(1, 3) ' Toulouse
  

    from scriptforge import CreateScriptService
    svc = CreateScriptService("Array")
    bas = CreateScriptService("Basic")
    arr = svc.ImportFromCSVFile(r"C:\Temp\myFile.csv", dateformat = "YYYY/MM/DD")
    bas.MsgBox(arr[0][3]) # City
    bas.MsgBox(arr[1][2]) # Rue de l'église, 21
    bas.MsgBox(arr[1][3]) # Toulouse
  

IndexOf

Vienmačiame masyve ieškokite skaičiaus, eilutės ar datos. Lyginant tekstą didžiosios ir mažosios raidės gali būti skiriamos.
Jei masyvas yra surikiuotas, jis turi būti užpildytas vienos rūšies duomenimis, o tai reiškia, kad visi elementai turi būti to paties paprastojo tipo (draudžiama naudoti Empty ir Null).
Metodo rezultatas yra neapibrėžtas, kai masyvas skelbimas surikiuotas, o iš tikrųjų taip nėra.
Dvejetainė paieška atliekama surikiuotuose masyvuose. Kitu atveju masyvai paprasčiausiai nuskaitomi iš viršaus į apačią ir ignoruojami elementai Empty ir Null.

Jei paieška nebuvo sėkminga, metodas grąžina ApRėžis (įvesties masyvas) - 1.

svc.IndexOf(array_1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ''): int

array_1d: The array to scan.

tofind: A number, a date or a string to find.

casesensitive: Only for string comparisons (Default = False).

sortorder: It can be either "ASC", "DESC" or "" (not sorted). The default value is "".

    MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", SortOrder := "ASC") ' 2
    MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", CaseSensitive := True) ' -1
  

Insert

Prieš nurodytą įvesties masyvo indeksą įterpkite elementus, nurodytus kaip argumentus.
Argumentai įterpiami aklai. Kiekvienas iš jų gali būti bet kokio paprastojo tipo duomuo arba masyvo dalis.

svc.Insert(array_1d: any[0..*], before: int, arg0: any, [arg1: any] ...): any[0..*]

array_1d: The pre-existing array, may be empty.

before: The index before which to insert; must be in the interval [LBound, UBound + 1].

arg0, arg1, ...: Items that will be inserted into array_1d.

    Dim a As Variant
    a = SF_Array.Insert(Array(1, 2, 3), 2, "a", "b")
        ' (1, 2, "a", "b", 3)
  

InsertSorted

Inserts into a sorted array a new item on its place.
The array must be filled homogeneously, meaning that all items must be scalars of the same type.
Empty and Null items are forbidden.

svc.InsertSorted(array_1d: any[0..*], item: any, sortorder: str = 'ASC', casesensitive: bool = False): any[0..*]

array_1d: The array into which the value will be inserted.

item: The scalar value to insert, of the same type as the existing array items.

sortorder: It can be either "ASC" (default) or "DESC".

casesensitive: Only for string comparisons (Default = False).

    Dim a As Variant
    a = SF_Array.InsertSorted(Array("A", "C", "a", "b"), "B", CaseSensitive := True)
        ' ("A", "B", "C", "a", "b")
  

Intersection

Sukurkite rinkinį, kaip nulinį masyvą, taikydami sankirtos aibės operatorių dviem pradiniams masyvams. Rezultatai įrašomi į abu masyvus.
Gautas masyvas rikiuojamas didėjimo tvarka.
Abi pradiniai masyvai turi būti užpildyti vienos rūšies duomenimis, kitaip tariant, visi elementai turi būti to paties paprastojo tipo duomenys. Draudžiami elementai yra Empty ir Null.
Lyginant tekstą didžiosios ir mažosios raidės gali būti skiriamos arba ne.

svc.Intersection(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

array1_1d: The first input array.

array2_1d: The second input array.

casesensitive: Applies to arrays populated with text items (Default = False).

    Dim a As Variant
    a = SF_Array.Intersection(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
        ' ("C", "b")
  

Join2D

Sujunkite dviejų matmenų masyvo elementus naudodami du skirtukus: vienas skirtas stulpeliams, kitas - eilutėms.

svc.Join2D(array_2d: any [0..*, 0..*], [columndelimiter: str], [rowdelimiter: str], [quote: str]): str

array_2d: Each item must be either text, a number, a date or a boolean.
Dates are transformed into the YYYY-MM-DD hh:mm:ss format.
Invalid items are replaced by a zero-length string.

columndelimiter: Delimits each column (default = Tab/Chr(9)).

rowdelimiter: Delimits each row (default = LineFeed/Chr(10))

quote: If True, protect strings with double quotes. The default is False.

    ' arr = | 1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5           |
    '       | 6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10 |
    Dim arr as Variant : arr = Array()
    arr = SF_Array.AppendRow(arr, Array(1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5))
    arr = SF_Array.AppendRow(arr, Array(6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10))
    Dim arrText as String
    arrText = SF_Array.Join2D(arr, ",", "/", False)
    ' 1,2,A,,51,2,A,,5/6,7,this is a string,9,106,7,this is a string,9,10
  

Prepend

Pridėkite įvesties masyvo pradžioje elementus, nurodytus kaip argumentai.

svc.Prepend(array_1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]

array_1d: The pre-existing array, may be empty.

arg0, arg1, ...: A list of items to prepend to array_1d.

    Dim a As Variant
    a = SF_Array.Prepend(Array(1, 2, 3), 4, 5)
        ' (4, 5, 1, 2, 3)
  

PrependColumn

Kairėje dviejų matmenų masyvo pusėje pridedamas naujas stulpelis. Gautas masyvas turi tuos pačius apatinius rėžius, kaip ir pradinis dviejų matmenų masyvas.

svc.PrependColumn(array_2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]

array_2d: The pre-existing array, may be empty. If that array has 1 dimension, it is considered as the last column of the resulting 2 dimension array.

column: A 1-dimensional array with as many items as there are rows in array_2d.

    Dim a As Variant, b As variant
    a = SF_Array.PrependColumn(Array(1, 2, 3), Array(4, 5, 6))
        ' ((4, 1), (5, 2), (6, 3))
    b = SF_Array.PrependColumn(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
  

PrependRow

Prepend a new row at the beginning of a 2-dimensional array. The resulting array has the same lower boundaries as the initial 2-dimensional array.

svc.PrependRow(array_2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*]

array_2d: The pre-existing array, may be empty. If that array has 1 dimension, it is considered as the last row of the resulting 2-dimensional array.

row: A 1-dimensional array containing as many items as there are columns in array_2d.

    Dim a As Variant, b As variant
    a = SF_Array.PrependRow(Array(1, 2, 3), Array(4, 5, 6))
        ' ((4, 5, 6), (1, 2, 3))
    b = SF_Array.PrependRow(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
  

RangeInit

Inicijuokite naują skaitinį nulinių reikšmių masyvą.

svc.RangeInit(from: num, upto: num, [bystep: num]): num[0..*]

from: Value of the first item.

upto: The last item should not exceed UpTo.

bystep: The difference between two successive items (Default = 1).

    Dim a As Variant
    a = SF_Array.RangeInit(10, 1, -1)
        ' (10, 9, 8, 7, 6, 5, 4, 3, 2, 1)
  

Reverse

Grąžinkite atvirkštinį vienmatį pradinį masyvą.

svc.Reverse(array_1d: any[0..*]): any[0..*]

array_1d: The array to reverse.

    Dim a As Variant
    a = SF_Array.Reverse(Array("a", 2, 3, 4))
        ' (4, 3, 2, "a")
  

Shuffle

Returns a random permutation of a one-dimensional array.

svc.Shuffle(array_1d: any[0..*]): any[0..*]

array_1d: The array to shuffle.

    Dim a As Variant
    a = SF_Array.Shuffle(Array(1, 2, 3, 4))
        ' Array "a" is now in random order, f.i. (2, 3, 1, 4)
  

Slice

Returns a subset of a one-dimensional array.

svc.Slice(array_1d: any[0..*], from: int, [upto: int]): any[0..*]

array_1d: The array to slice.

from: The lower index in array_1d of the subarray to extract (from included)

upto: The upper index in array_1d of the subarray to extract (upto included). The default value is the upper bound of array_1d. If upto < from then the returned array is empty.

    Dim a As Variant
    a = SF_Array.Slice(Array(1, 2, 3, 4, 5), 1, 3) ' (2, 3, 4)
  

Sort

Reikia surikiuoti vienmatį masyvą didėjimo arba mažėjimo tvarka. Lyginant tekstus didžiosios ir mažosios raidės arba skiriamos, arba ne.
Masyvas turi būti užpildytas vienodo tipo duomenimis, t. y. elementai turi būti to paties paprastojo tipo reikšmės. Leistini elementai
Empty ir Null. Paprastai Empty < už Null < už bet kurią kitą skaliarinę reikšmę.

svc.Sort(array_1d: any[0..*], sortorder: str, casesensitive: bool = False): any[0..*]

array_1d: The array to sort.

sortorder: It can be either "ASC" (default) or "DESC".

casesensitive: Only for string comparisons (Default = False).

    Dim a As Variant
    a = SF_Array.Sort(Array("a", "A", "b", "B", "C"), CaseSensitive := True)
        ' ("A", "B", "C", "a", "b")
  

SortColumns

Return a permutation of the columns of a two dimension array, sorted on the values of a given row.
The row must be filled homogeneously, which means that all items must be scalars of the same type.
Empty and Null items are allowed. Conventionally Empty < Null < any other scalar value.

svc.SortColumns(array_2d: any[0..*, 0..*], rowindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]

array_2d: The 2-dimensional array to sort.

rowindex: The index of the row that will be used as reference to sort the columns.

sortorder: It can be either "ASC" (default) or "DESC".

casesensitive: Only for string comparisons (Default = False).

    ' arr = | 5, 7, 3 |
    '       | 1, 9, 5 |
    '       | 6, 1, 8 |
    Dim arr as Variant : arr = Array(5, 7, 3)
    arr = SF_Array.AppendRow(arr, Array(1, 9, 5))
    arr = SF_Array.AppendRow(arr, Array(6, 1, 8))
    arr = SF_Array.SortColumns(arr, 2, "ASC")
    ' arr = | 7, 5, 3 |
    '       | 9, 1, 5 |
    '       | 1, 6, 8 |
  

SortRows

Return a permutation of the rows of a two dimension array, sorted on the values of a given column.
The column must be filled homogeneously, therefore all items must be scalars of the same type.
Empty and Null items are allowed. Conventionally Empty < Null < any other scalar value.

svc.SortRows(array_2d: any[0..*, 0..*], columnindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]

array_2d: The array to sort.

columnindex: The index of the column that will be used as reference to sort the rows.

sortorder: It can be either "ASC" (default) or "DESC".

casesensitive: Only for string comparisons (Default = False).

    ' arr = | 5, 7, 3 |
    '       | 1, 9, 5 |
    '       | 6, 1, 8 |
    Dim arr as Variant : arr = Array(5, 7, 3)
    arr = SF_Array.AppendRow(arr, Array(1, 9, 5))
    arr = SF_Array.AppendRow(arr, Array(6, 1, 8))
    arr = SF_Array.SortRows(arr, 0, "ASC")
    ' arr = | 1, 9, 5 |
    '       | 5, 7, 3 |
    '       | 6, 1, 8 |
  

Transpose

Swaps rows and columns in a two-dimensional array.

svc.Transpose(array_2d: any[0..*, 0..*]): any[0..*, 0..*]

array_2d: The 2-dimensional array to transpose.

    ' arr1 = | 1, 2 |
    '        | 3, 4 |
    '        | 5, 6 |
    arr1 = Array(1, 2)
    arr1 = SF_Array.AppendRow(arr1, Array(3, 4))
    arr1 = SF_Array.AppendRow(arr1, Array(5, 6))
    arr2 = SF_Array.Transpose(arr1)
    ' arr2 = | 1, 3, 5 |
    '        | 2, 4, 6 |
    MsgBox arr2(0, 2) ' 5
  

TrimArray

Remove from a one dimension array all Null, Empty and zero-length entries.
String items are trimmed with LibreOffice Basic Trim() function.

svc.TrimArray(array_1d: any[0..*]): any[0..*]

array_1d: The array to trim.

    Dim a As Variant
    a = SF_Array.TrimArray(Array("A", "B", Null, " D "))
        ' ("A", "B", "D")
  

Union

Builds a set, as a zero-based array, by applying the union operator on the two input arrays. Resulting items originate from any of both arrays.
The resulting array is sorted in ascending order.
Both input arrays must be filled homogeneously, their items must be scalars of the same type. Empty and Null items are forbidden.
Text comparison can be case sensitive or not.

svc.Union(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

array1_1d: The first input array.

array2_1d: The second input array.

casesensitive: Applicable only if the arrays are populated with strings (Default = False).

    Dim a As Variant
    a = SF_Array.Union(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
        ' ("A", "B", "C", "Z", "b")
  

Unique

Build a set of unique values derived from the input array.
The input array must be filled homogeneously, its items must be scalars of the same type. Empty and Null items are forbidden.
Text comparison can be case sensitive or not.

svc.Unique(array_1d: any[0..*], casesensitive: bool = False): any[0..*]

array_1d: The input array.

casesensitive: Applicable only if the array is populated with strings (Default = False).

    Dim a As Variant
    a = SF_Array.Unique(Array("A", "C", "A", "b", "B"), CaseSensitive := True)
        '  ("A", "B", "C", "b")
  

All ScriptForge Basic routines or identifiers that are prefixed with an underscore character "_" are reserved for internal use. They are not meant be used in Basic macros or Python scripts.