정보 함수

이 범주에는 통계 함수가 포함됩니다.

함수 설명의 일부 예는 다음 테이블의 데이터에 기초합니다.

	C	D
2	x 값	y 값
3	-5	-3
4	-2	0
5	-1	1
6	0	3
7	2	4
8	4	6
9	6	8

CELL

셀 주소, 서식 또는 내용에 대한 정보를 구합니다.

CELL("InfoType" [; Reference])

InfoType은 정보의 종류를 확실하게 하는 문구입니다. 해당 문구는 언제나 영어여야만 하며, 대소문자는 선택해서 입력될 수 있습니다.

InfoType	의미
COL	참조된 열의 번호가 됩니다. =CELL("COL";D2)는 4를 반환합니다.
ROW	참조된 행의 번호가 됩니다. =CELL("ROW";D2)은 2를 반환합니다.
SHEET	참조된 표의 번호가 됩니다. =CELL("Sheet";Sheet3.D2)은 3을 반환합니다.
ADDRESS	참조된 셀의 절대 번지가 됩니다. =CELL("ADDRESS";D2)은 $D$2를 반환합니다. =CELL("ADDRESS";Sheet3.D2)는 $Sheet3.$D$2의 결과값을 반환합니다. =CELL("ADDRESS";'X:\dr\test.ods'#$Sheet1.D2) returns 'file:///X:/dr/test.ods'#$Sheet1.$D$2.
FILENAME	참조된 셀의 표 이름과 파일 이름이 됩니다. =CELL("FILENAME";D2) returns 'file:///X:/dr/own.ods'#$Sheet1, if the formula in the current document X:\dr\own.ods is located in Sheet1. =CELL("FILENAME";'X:\dr\test.ods'#$Sheet1.D2) returns 'file:///X:/dr/test.ods'#$Sheet1.
COORD	Returns the complete cell address in Lotus™ notation. =CELL("COORD"; D2)는 $A:$D$2을 반환합니다. =CELL("COORD"; Sheet3.D2)는 $C:$D$2의 결과값을 반환합니다.
CONTENTS	결과로 포매팅 없이 참조된 셀의 내용이 산출됩니다.
TYPE	결과로 셀 내용의 타입이 산출됩니다. b = blank. 빈 셀 l = label. 텍스트, 수식 결과 텍스트로 v = value. 값, 수식 결과 숫자로
WIDTH	결과로 참조된 열의 너비가 산출됩니다. 측정 단위는 기본 크기의 기본 글꼴인 열에 맞는 영(0)의 갯수입니다.
PREFIX	참조된 셀을 맞춥니다. ' =왼쪽 또는 양쪽 맞춤 " = 오른쪽 맞춤 ^ = 가운데 맞춤 \ = 반복 (현재 대화식)
PROTECT	결과로 셀 보호 상태를 제공합니다. 1 = 셀이 보호됨 0 = 셀이 보호되지 않음
FORMAT	결과로 숫자 서식을 지정하는 문자열이 산출됩니다. , = 천단위 구분 기호가 있는 숫자 F = 천단위 구분 기호가 없는 숫자 C = 통화 형식 S = 지수 표시, 예를 들면 1.234+E56 P = 백분율 수치 위 서식에서 소수 구분 기호 뒤의 소수 자릿수는 숫자로 주어집니다. 예를 들어, 숫자 서식 #,##0.0은 1을 구하며 숫자 서식 00.000%은 P3을 구합니다. D1 = D-MMM-YY, D-MM-YY 그리고 유사한 서식 D2 = DD-MM D3 = MM-YY D4 = DD-MM-YYYY HH:MM:SS D5 = MM-DD D6 = HH:MM:SS AM/PM D7 = HH:MM AM/PM D8 = HH:MM:SS D9 = HH:MM G = 다른 모든 서식 끝에 - (마이너스) = 음수는 유색으로 서식 지정됩니다 끝에 () (괄호) = 서식 코드에 열려있는 괄호가 있습니다
COLOR	음수값이 유색으로 서식 지정되어 있으면 결과는 1이 되고 그렇지 않은 경우 0이 됩니다.
PARENTHESES	서식 코드에 열려있는 괄호 (가 포함되어 있으면 결과는 1이 되고, 그렇지 않으면 0이 됩니다.

참조(선택 가능)는 검사할 셀의 위치입니다. 참조가 영역이라면 왼쪽 상단에 있는 셀이 영역에 적용됩니다. #BOLD>참조가 없으면 LibreOffice Calc는 이 수식이 있는 셀의 위치를 사용합니다. 이 경우 Microsoft Excel은 커서가 위치하는 셀의 참조를 사용합니다.

CURRENT

이 함수는 수식에 포함된 날짜에 결과를 구합니다. 이 함수는 주로 STYLE() 함수와 함께 셀 내용에 따라 스타일을 다르게 적용할 때 사용됩니다.

CURRENT().

=1+2+CURRENT()

예제는 6을 반환합니다. 수식은 왼쪽에서 오른쪽으로 1+2=3 으로 계산되며 CURRENT() 함수를 만나면, 결과를 반환합니다. CURRENT() 에는 3이 있으므로, 원래의 3에 더해 6이 됩니다.

=A2+B2+STYLE(IF(CURRENT()>10;"Red";"Default"))

예제는 A2 + B2 의 값을 구합니다(여기서 STYLE 은 0). 그리고 합계가 10보다 크면, 셀에 적색 스타일이 적용됩니다. 더 자세한 내용은 STYLE 함수 부분을 참고하십시오.

="choo"&CURRENT()

예제는 choochoo 를 반환합니다.

ORG.OPENOFFICE.CURRENT

FORMULA

수식 셀의 수식을 텍스트 문자열로 표시합니다.

FORMULA(참조)

참조는 수식을 포함한 셀에 대한 참조입니다.

참조가 잘못되었거나 수식이 없는 셀을 참조하는 경우에는 오류 값 #N/A가 표시됩니다.

셀 A8 에 수식 =SUM(1;2;3) 가 있을 경우

=FORMULA(A8) 은 텍스트 =SUM(1;2;3) 을 반환합니다.

IFNA

Returns the value if the cell does not contain the #N/A (value not available) error value, or the alternative value if it does.

IFNA(Value; Alternate_value)

Value is the value or expression to be returned if it is not equal or results in an #N/A error.

Alternate_value is the value or expression to be returned if the expression or value of Value is equal or results in an #N/A error.

=IFNA(D3;D4) D3의 값이 #N/A 오류가 아닌 경우에 D3를 반환하며, 오류인 경우 D4의 값을 반환합니다.

INFO

현재 작업 환경에 대한 관련 정보를 반환합니다. 이 함수는 단일 텍스트 인수를 받은 다음 해당 매개 변수에 따라 데이터를 반환합니다.

INFO("유형")

다음 표에는 텍스트 매개 변수 Type 에 대한 값들과 INFO 함수의 반환값이 나열됩니다.

"유형"의 값	반환 값
"osversion"	호환성을 위해 항상 "Windows(32비트) NT 5.01"
"system"	The type of the operating system: "ANDROID" for Google mobile operating system "DRAGONFLY" for DragonFly operating system forked from FreeBSD "EMSCRIPTEN" for browser WebAssembly system "FREEBSD", "OPENBSD" or "NETBSD" for operating systems based on the Berkeley Software Distribution (BSD) "HAIKU" for BeOS compatible operating system "iOS" for Apple mobile operating system "LINUX" for GNU/Linux based operating systems "MACOSX" for Apple macOS "SOLARIS" for Oracle Solaris operating system "WNT" for Microsoft Windows
"release"	제품 릴리스 확인자, 예: "300m25(Build:9876)"
"numfile"	호환성을 위해 항상 1
"recalc"	현재 수식 재계산 모드("자동" 또는 "수동"(LibreOffice 언어로 지역화됨))

=INFO("release")는 사용하고 있는 LibreOffice 의 발표버전을 구합니다.

D5 셀이 system 문자열을 포함하는 경우 =INFO(D5) 수식은 운영체제 종류를 반환합니다.

ISBLANK

셀에 대한 참조가 비어 있는 경우 TRUE를 구합니다. 이 함수는 셀 내용이 비어 있는지 확인하는 데 사용됩니다. 수식이 포함된 셀은 빈 셀로 간주하지 않습니다.

ISBLANK(Values)

Number는 검사할 내용입니다.

=ISBLANK(D2)의 결과같은 FALSE입니다.

ISERR

#N/A 오류 값을 제외한 오류 조건을 검사하고 TRUE 또는 FALSE를 반환합니다.

ISERR(Values)

Value는 #N/A 이외의 오류 값이 있는지 확인하기 위해 테스트되는 임의의 값 또는 식입니다.

C8 셀이 =1/0의 수식을 포함하는 경우, 이 수식은 불가능한 수식이므로 =ISERR(C8)은 TRUE값을 반환합니다.

C9 셀이 =NA() 수식을 포함할 때 ISERR() 함수는 #N/A 오류를 무시하므로 =ISERR(C9)는 FALSE 값을 반환합니다.

ISERROR

#N/A 오류 값을 포함하여 오류 조건을 검사하고 TRUE 또는 FALSE를 반환합니다.

ISERROR(Values)

Value는 테스트할 값이거나 이 값을 참조합니다. ISERROR()는 오류가 있는 경우 TRUE를 반환하고 오류가 없으면 FALSE를 반환합니다.

C8 셀이 =1/0의 수식을 포함하는 경우, 이 수식은 불가능한 수식이므로 =ISERROR(C8)은 TRUE값을 반환합니다.

=ISERROR(C9)는 C9셀이 =NA() 값이기 때문에 TRUE를 반환합니다.

ISERROR

Returns the value if the cell does not contain an error value, or the alternative value if it does.

IFERROR(Value; Alternate_value)

Value is the value or expression to be returned if it is not equal or results in an error.

Alternate_value is the value or expression to be returned if the expression or value of Value is equal or results in an error.

C8 셀이 =1/0의 수식을 포함하는 경우, 이 수식은 불가능한 수식이므로 =ISERROR(C8)은 TRUE값을 반환합니다.

C8 셀이 =1/0의 수식을 포함하는 경우, 이 수식은 불가능한 수식이므로 =ISERROR(C8)은 TRUE값을 반환합니다.

ISEVEN

값이 짝수인 정수이면 TRUE를, 홀수이면 FALSE를 구합니다.

ISEVEN(Values)

Number는 검사할 값입니다.

만일 값가 정수가 아니면 소수점 이하의 값은 무시됩니다. 값의 부호도 무시됩니다.

=ISEVEN(48)은 TRUE를 반환합니다.

=ISEVEN(33)은 FALSE를 반환합니다.

=ISEVEN(0)은 0을 반환합니다.

=ISEVEN(-2.1)는 TRUE를 반환합니다.

=ISEVEN(3.999)는 FALSE를 반환합니다.

ISEVEN_ADD

짝수를 검사합니다. 숫자를 2로 나누었을 때 정수가 되면 TRUE(1)를 구합니다.

ISEVEN_ADD(Number)

Number는 테스트할 값입니다.

=ISEVEN_ADD(5)은 0을 반환합니다.

A1 셀의 값이 정수 2라면, =ISEVEN_ADD(A1)의 결과값은 1입니다.

ISFORMULA

셀이 수식 셀이면 TRUE를 구합니다.

ISFORMULA(참조)

참조는 수식이 포함되어 있는지 검사할 셀에 대한 참조를 지정합니다.

만일 C4 셀이 정수 5의 값을 가진다면 =ISFORMULA(C4)는 FALSE의 값을 반환합니다.

ISLOGICAL

논리값(TRUE 또는 FALSE)을 검사합니다.

오류 상황에서 함수는 FALSE 값을 반환합니다.

ISLOGICAL(Values)

Value가 논리값(TRUE 또는 FALSE)이면 TRUE를 반환하고, 그렇지 않으면 FALSE를 반환합니다.

99는 논리값이 아닌 정수이기 때문에 =ISLOGICAL(99)의 반환값은 FALSE입니다.

ISNA()는 논리값을 반환하기 때문에, D4 셀의 내용과 관계 없이 =ISLOGICAL(ISNA(D4))의 결과값은 TRUE입니다.

ISNA

셀에 #N/A(사용할 수 없는 값) 오류 값이 포함되어 있으면 TRUE를 구합니다.

오류 상황에서 함수는 FALSE 값을 반환합니다.

ISNA(Values)

Number는 검사할 숫자 또는 표현입니다.

=ISNA(D3)은 결과값으로 FALSE를 돌려줍니다.

ISNONTEXT

셀 내용이 텍스트인지 숫자인지를 검사하고 셀 내용이 텍스트인 경우 FALSE를 돌려줍니다.

오류 상황에서 함수는 TRUE 값을 반환합니다.

ISNONTEXT(Values)

Number는 텍스트에 관한 것인지 아니면 숫자 및 진리값에 관한 것인지 검사해야 할 값 또는 표현입니다.

만일 D2 셀의 값이 abcdef라면, =ISNONTEXT(D2)의 결과값은 FALSE가 됩니다.

만일 D9 셀의 값이 8이라면 =ISNONTEXT(D9)은 TRUE 값을 반환합니다.

ISNUMBER

값이 숫자를 나타내면 TRUE를 구합니다.

ISNUMBER(Values)

Number는 숫자인지 텍스트인지를 확인하기 위해 검사할 임의 식입니다.

만일 C3 셀이 정수 4의 값을 가지고 있다면 =ISNUMBER(C3)는 TRUE의 결과값을 반환합니다.

만일 C2 셀의 값이 abcdef라면, =ISNUMBER(C2)는 FALSE 값을 반환합니다.

ISODD

값이 홀수이면 TRUE를, 짝수이면 FALSE를 구합니다.

ISODD(수치)

Number는 검사할 값입니다.

만일 값가 정수가 아니면 소수점 이하의 값은 무시됩니다. 값의 부호도 무시됩니다.

=ISODD(33)는 TRUE를 반환합니다.

=ISODD(48)는 FALSE를 반환합니다.

=ISODD(3.999)는 TRUE를 반환합니다.

=ISODD(-3.1)는 TRUE를 반환합니다.

ISODD_ADD

숫자를 2로 나누었을 때 정수가 구해지지 않으면 TRUE(1)를 구합니다.

ISTODD_ADD(Number)

Number는 테스트할 값입니다.

=ISODD_ADD(5)은 1을 반환합니다.

ISREF

인수의 내용이 참조인지 여부를 검사합니다. 인수가 참조라면 TRUE를 반환하고 그렇지 않으면 FALSE를 반환합니다. 주어진 참조인 경우 이 함수는 값이 참조되는지 검사하지 않습니다.

ISREF(Values)

Number는 참조인지 여부를 확인하기 위해 검사할 값입니다.

C5 가 올바른 참조이므로 =ISREF(C5)은 TRUE 값을 갖습니다.

텍스트는 참조될 수 없으므로 =ISREF("abcdef")는 언제나 FALSE를 반환합니다.

=ISREF(4)는 FALSE를 반환합니다.

INDIRECT는 참조값을 반환하는 함수이기 때문에 =ISREF(INDIRECT("A6"))는 TRUE를 반환합니다.

ADDRESS 함수는 유효한 참조값을 반환할 것 처럼 보이지만, 실제로는 텍스트를 반환하기 때문에 =ISREF(ADDRESS(1; 1; 2;"Sheet2"))는 FALSE를 반환합니다.

ISTEXT

셀 내용이 텍스트를 나타낼 경우 TRUE를 구합니다.

오류 상황에서 함수는 FALSE 값을 반환합니다.

ISTEXT(Values)

Number는 텍스트에 관한 것인지 숫자에 관한 것인지 검사할 값으로서 숫자, 진리값 또는 오류값입니다.

=ISTEXT(D9)는 D9 셀이 abcdef값이라면 TRUE를 반환합니다.

=ISTEXT(C3)는 셀 C3의 값이 정수 3이면 FALSE 값을 반환합니다.

N

Returns the numeric value of the given parameter. Returns 0 if parameter is text or FALSE.

If an error occurs the function returns the error value.

N(Values)

Value is the parameter to be converted into a number. N() returns the numeric value if it can. It returns the logical values TRUE and FALSE as 1 and 0 respectively. It returns text as 0.

=N(123)은 123을 반환합니다.

=N(TRUE)는 1을 반환합니다.

=N(FALSE)는 0을 반환합니다.

=N("abc")는 0을 돌려줍니다.

=N(1/0)는 #DIV/0!의 값을 반환합니다.

NA

오류 값 #N/A를 구합니다.

NA()

=NA()는 셀의 값을 #N/A로 바꿉니다.

TYPE

Returns the type of value, where 1 = number, 2 = text, 4 = Boolean value, 8 = formula, 16 = error value, 64 = array.

TYPE(Values)

Value is a specific value for which the data type is determined.

예(위의 예제 테이블 참조)

=TYPE(C2)는 결과값으로 2를 반환합니다.

=TYPE(D9)는 1을 결과값으로 반환합니다.