Text Functions
This section contains descriptions of the Text functions.
Using double quotation marks in formulas
To include a text string in a formula, place the text string between two double quotation marks (") and Calc takes the characters in the string without attempting to interpret them. For example, the formula ="Hello world!" displays the text string Hello world! in the cell, with no surrounding double quotation marks.
The more complex formula =CONCATENATE("Life is really simple, "; "but we insist on making it complicated "; "(Confucius).") concatenates three individual strings in double quotation marks, outputting Life is really simple, but we insist on making it complicated (Confucius).
To place a literal double quotation mark within a string inside a formula, two methods can be used:
-
You can "escape" the double quotation mark with an additional double quotation mark, and Calc treats the escaped double quotation mark as a literal value. For example, the formula ="My name is ""John Doe""." outputs the string My name is "John Doe". Another simple example is the formula =UNICODE("""") which returns 34, the decimal value of the Unicode quotation mark character (U+0022) — here the first and fourth double quotation marks indicate the beginning and end of the string, while the second double quotation mark escapes the third.
-
You can use the CHAR function or the UNICHAR function to insert a double quotation mark. For example, the formula =UNICHAR(34) & "The Catcher in the Rye" & UNICHAR(34) & " is a famous book by J. D. Salinger." displays the string "The Catcher in the Rye" is a famous book by J. D. Salinger.
Be aware that Calc's AutoCorrect function may modify double quotation marks. AutoCorrect should not change the double quotation marks within formula cells but may change those used in non-formula cells containing text. For example, if you copy a string that is surrounded by some other form of typographical double quotation marks, such as the left double quotation mark (U+201C) and the right double quotation mark (U+201D), and then paste into a formula cell, an error may result. Open the Double Quotes area of the dialog to set the characters used to automatically correct the start and end typographical double quotation marks. Uncheck the toggle button to disable the feature.
BAHTTEXT
បម្លែងលេខទៅជាអត្ថបទថៃ រួមទាំងឈ្មោះរូបិយបណ្ណថៃផងដែរ ។
BAHTTEXT(លេខ)
លេខ ជាលេខខ្លះៗ ។ "Baht" បានបន្ថែម ផ្នែកមួយចំនួននៃលេខ និង "Satang" បានបន្ថែមជាផ្នែកទសភាគនៃលេខ ។
=BAHTTEXT(12.65) ត្រឡប់ខ្សែអក្សរជាតួអក្សរថៃ ដែលមានន័យថា "១២ បាត និង ៦៥ សាតាង" ។
COM.MICROSOFT.BAHTTEXT
BASE
Converts a positive integer to a specified base into a text from the numbering system. The digits 0-9 and the letters A-Z are used.
BASE(Number; Radix [; MinimumLength])
លេខ គឺជាចំនួនគត់វិជ្ជមានដែលត្រូវបម្លែង ។
Radix indicates the base of the numeral system. It may be any positive integer between 2 and 36.
ប្រវែងអប្បបរមា (ជាជម្រើស) កំណត់ប្រវែងអប្បបរមារបស់លំដាប់តួអក្សរដែលត្រូវបានបង្កើត ។ ប្រសិនបើអត្ថបទខ្លីជាងប្រវែងអប្បបរមាដែលបានបង្ហាញ សូន្យត្រូវបានបន្ថែមទៅខាងឆ្វេងនៃខ្សែអក្សរ ។
=BASE(17;10;4) ត្រឡប់ 0017 នៅក្នុងប្រព័ន្ធទសភាគ ។
=BASE(17;2) ត្រឡប់ 10001 នៅក្នុងប្រព័ន្ធគោលពីរ ។
=BASE(255;16;4) ត្រឡប់ 00FF នៅក្នុងប្រព័ន្ធគោលដប់ប្រាំមួយ ។
CHAR
បម្លែងចំនួនមួយទៅជាតួអក្សរមួយ ដោយផ្អែកលើតារាងកូដ ។ ចំនួនអាចជាចំនួនគត់ពីរតួលេខ ឬបីតួលេខ ។
CHAR(ចំនួន)
ចំនួន គឺជាចំនួនដែលមានចន្លោះពី 1 និង 255 បង្ហាញតម្លៃកូដសម្រាប់តួអក្សរ ។
=CHAR(100) ត្រឡប់តួអក្សរ d ។
="abc" & CHAR(10) & "def" បញ្ចូលតួអក្សរបន្ទាត់ថ្មីក្នុងខ្សែអក្សរ ។
CLEAN
តួអក្សរមិនបោះពុម្ពទាំងអស់ ត្រូវបានយកចេញពីខ្សែអក្សរ ។
CLEAN("អត្ថបទ")
អត្ថបទ សំដៅលើអត្ថបទដែលត្រូវយកតួអក្សរដែលមិនអាចបោះពុម្ពបានចេញទាំងអស់ ។
=LEN(CLEAN(CHAR(7) & "LibreOffice Calc" & CHAR(8))) returns 16, showing that the CLEAN function removes the non-printable Unicode U+0007 ("BEL") and U+0008 ("BS") characters at the beginning and end of the string argument. CLEAN does not remove spaces.
CODE
ត្រឡប់កូដជាលេខ សម្រាប់តួអក្សរដំបូងក្នុងខ្សែអត្ថបទមួយ ។
CODE("អត្ថបទ")
អត្ថបទ ជាអត្ថបទ ដែលកូដនៃតួអក្សរដំបូងនឹងត្រូវបានរក ។
=CODE("Hieronymus") returns 72, =CODE("hieroglyphic") ត្រឡប់ 104 ។
កូដដែលប្រើទីនេះ មិនសំដៅលើ ASCII ទេ ប៉ុន្តែសំដៅទៅតារាងកូដដែលបានផ្ទុកបច្ចុប្បន្ន ។
CONCATENATE
ផ្សំខ្សែអក្សរអត្ថបទជាច្រើន ទៅជាខ្សែអក្សរមួយ ។
CONCATENATE(String 1 [; String 2 [; … [; String 255]]])
String 1[; String 2][; … ;[String 255]] are strings or references to cells containing strings.
=CONCATENATE("Good ";"Morning ";"Mrs. ";"Doe") ត្រឡប់ ៖ Good Morning Mrs. Doe.
DECIMAL
Converts text that represents a number in a numeral system with the given base radix to a positive integer. The radix must be in the range 2 to 36. Spaces and tabs are ignored. The Text field is not case-sensitive.
If the radix is 16, a leading x or X or 0x or 0X, and an appended h or H, are disregarded. If the radix is 2, an appended b or B is disregarded. Other characters that do not belong to the numeral system generate an error.
DECIMAL("អត្ថបទ"; គោល)
Text is the text to be converted.
Radix indicates the base of the numeral system. It may be any positive integer between 2 and 36.
=DECIMAL("17";10) ត្រឡប់ 17 ។
=DECIMAL("FACE";16) ត្រឡប់ 64206 ។
=DECIMAL("0101";2) ត្រឡប់ 5 ។
DOLLAR
Converts a number to a string representing the amount in the currency format, rounded to a specified decimal places, using the decimal separator that corresponds to the current locale setting. In the Value field enter the number to be converted. Optionally, you may enter the number of decimal places in the Decimals field. If no value is specified, all numbers in currency format will be displayed with two decimal places.
អ្នកកំណត់ទ្រង់ទ្រាយរូបិយប័ណ្ណក្នុងការកំណត់ប្រព័ន្ធរបស់អ្នក ។
DOLLAR(Value [; Decimals])
តម្លៃ គឺជាលេខ យោងទៅក្រឡាដែលមានលេខ ឬរូបមន្តដែលត្រឡប់លេខ ។
ទសភាគ គឺជាចំនួនជាជម្រើសរបស់ខ្ទង់ទសភាគ ។
=DOLLAR(255) returns $255.00 for the English (USA) locale and USD (dollar) currency; ￥255.00 for the Japanese locale and JPY (yen) currency; or 255,00 € for the German (Germany) locale and EUR (euro) currency.
=DOLLAR(367.456;2) returns $367.46.
EXACT
ប្រៀបធៀបខ្សែអត្ថបទពីរ និងត្រឡប់ TRUE បើពួកវាដូចគ្នា ។ អនុគមន៍នេះប្រកាន់តួអក្សរតូចធំ ។
EXACT("អត្ថបទ1"; "អត្ថបទ2")
អត្ថបទ 1 យោងទៅអត្ថបទដំបូងត្រូវប្រៀបធៀប ។
អត្ថបទ 2 គឺជាអត្ថបទទីពីរត្រូវប្រៀបធៀប ។
=EXACT("ប្រព័ន្ធម៉ៃក្រូ";"ប្រព័ន្ធម៉ៃក្រូ") ត្រឡប់ FALSE ។
FIND
Returns the position of a string of text within another string.You can also define where to begin the search. The search term can be a number or any string of characters. The search is case-sensitive.
FIND("FindText"; "Text" [; Position])
អត្ថបទស្វែងរក យោងទៅអត្ថបទដែលរកឃើញ ។
អត្ថបទ គឺជាអត្ថបទដែលការស្វែងរកកើតឡើង ។
ទីតាំង (ជាជម្រើស) គឺជាទីតាំងនៅក្នុងអត្ថបទដែលចាប់ផ្ដើមការស្វែងរក ។
=FIND(76;998877665544) ត្រឡប់ 6 ។
FIXED
Returns a number as text with a specified number of decimal places and optional thousands separators.
FIXED(Number; [Decimals = 2 [; NoThousandsSeparators = FALSE]])
Number is rounded to Decimals places (after the decimal separator) and the result formatted as text, using locale-specific settings.
Decimals (optional) refers to the number of decimal places to be displayed. If Decimals is negative, Number is rounded to ABS(Decimals) places to the left from the decimal point. If Decimals is a fraction, it is truncated actually ignoring what is the closest integer.
NoThousandsSeparators (optional) determines whether the thousands separator is used. If it is TRUE or non-zero, then group separators are omitted from the resulting string. If the parameter is equal to 0 or if it is missing altogether, the thousands separators of your current locale setting are displayed.
=FIXED(1234567.89;3) ត្រឡប់ 1,234,567.890 ជាខ្សែអក្សរអត្ថបទ ។
=FIXED(123456.789;;TRUE) returns 123456.79 as a text string.
=FIXED(12345.6789;-2) returns 12,300 as a text string.
=FIXED(12134567.89;-3;1) returns 12135000 as a text string.
=FIXED(12345.789;3/4) returns 12,346 as a text string.
=FIXED(12345.789;8/5) returns 12,345.8 as a text string.
LEFT
ត្រឡប់តួអក្សរដំបូង ឬតួអក្សររបស់អត្ថបទមួយ ។
LEFT("Text" [; Number])
អត្ថបទ គឺជាអត្ថបទដែលពាក្យដោយផ្នែកចាប់ផ្ដើមត្រូវបានកំណត់ ។
ចំនួន (ជាជម្រើស) បញ្ជាក់លម្អិតចំនួនតួអក្សរសម្រាប់អត្ថបទចាប់ផ្តើម ។ បើប៉ារ៉ាម៉ែត្រនេះមិនត្រូវបានកំណត់ នោះតួអក្សរមួយនឹងត្រូវបានត្រឡប់ ។
=LEFT("output";3) ត្រឡប់ “out” ។
LEFTB
Returns the first characters of a DBCS text.
LEFTB("Text" [; Number_bytes])
Text is the text where the initial partial words are to be determined.
Number_bytes (optional) specifies the number of characters you want LEFTB to extract, based on bytes. If this parameter is not defined, one character is returned.
=LEFTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).
=LEFTB("中国";2) returns "中" (2 bytes constitute one complete DBCS character).
=LEFTB("中国";3) returns "中 " (3 bytes constitute one DBCS character and a half; the last character returned is therefore a space character).
=LEFTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).
=LEFTB("office";3) returns "off" (3 non-DBCS characters each consisting of 1 byte).
LEN
ត្រឡប់ប្រវែងនៃខ្សែអក្សររួមទាំងចន្លោះ ។
LEN("អត្ថបទ")
អត្ថបទ គឺជាអត្ថបទដែលប្រវែងរបស់វាត្រូវបានកំណត់ ។
=LEN("Good Afternoon") ត្រឡប់ 14 ។
=LEN(12345.67) ត្រឡប់ 8 ។
LENB
For double-byte character set (DBCS) languages, returns the number of bytes used to represent the characters in a text string.
LENB("Text")
អត្ថបទ គឺជាអត្ថបទដែលប្រវែងរបស់វាត្រូវបានកំណត់ ។
LENB("中") returns 2 (1 DBCS character consisting of 2 bytes).
LENB("中国") returns 4 (2 DBCS characters each consisting of 2 bytes).
LENB("office") returns 6 (6 non-DBCS characters each consisting of 1 byte).
=LENB("Good Afternoon") returns 14.
=LENB(12345.67) returns 8.
LOWER
បម្លែងតួអក្សរធំទាំងអស់ក្នុងខ្សែអត្ថបទមួយ ទៅជាអក្សរតូច ។
LOWER("អត្ថបទ")
អត្ថបទ យោងទៅអត្ថបទត្រូវបម្លែង ។
=LOWER("Sun") ត្រឡប់ sun ។
MID
ត្រឡប់ខ្សែអក្សរអត្ថបទមួយរបស់អត្ថបទ ។ ប៉ារ៉ាម៉ែត្របញ្ជាក់ទីតាំងចាប់ផ្ដើម និងចំនួនតួអក្សរ ។
MID("អត្ថបទ"; ចាប់ផ្ដើម; ចំនួន)
អត្ថបទ គឺជាអត្ថបទដែលមានតួអក្សរត្រូវស្រង់ចេញ ។
ចាប់ផ្ដើម គឺជាទីតាំងរបស់តួអក្សរដំបូងនៅក្នុងអត្ថបទត្រូវស្រង់ចេញ ។
ចំនួន បញ្ជាក់ចំនួនតួអក្សរនៅក្នុងផ្នែករបស់អត្ថបទ ។
=MID("office";2;2) returns ff.
MIDB
Returns a text string of a DBCS text. The parameters specify the starting position and the number of characters.
MIDB("Text"; Start; Number_bytes)
អត្ថបទ គឺជាអត្ថបទដែលមានតួអក្សរត្រូវស្រង់ចេញ ។
Start is the position of the first character in the text to extract.
Number_bytes specifies the number of characters MIDB will return from text, in bytes.
=MIDB("中国";1;0) returns "" (0 bytes is always an empty string).
=MIDB("中国";1;1) returns " " (1 byte is only half a DBCS character and therefore the result is a space character).
=MIDB("中国";1;2) returns "中" (2 bytes constitute one complete DBCS character).
=MIDB("中国";1;3) returns "中 " (3 bytes constitute one and a half DBCS character; the last byte results in a space character).
=MIDB("中国";1;4) returns "中国" (4 bytes constitute two complete DBCS characters).
=MIDB("中国";2;1) returns " " (byte position 2 is not at the beginning of a character in a DBCS string; 1 space character is returned).
=MIDB("中国";2;2) returns " " (byte position 2 points to the last half of the first character in the DBCS string; the 2 bytes asked for therefore constitutes the last half of the first character and the first half of the second character in the string; 2 space characters are therefore returned).
=MIDB("中国";2;3) returns " 国" (byte position 2 is not at the beginning of a character in a DBCS string; a space character is returned for byte position 2).
=MIDB("中国";3;1) returns " " (byte position 3 is at the beginning of a character in a DBCS string, but 1 byte is only half a DBCS character and a space character is therefore returned instead).
=MIDB("中国";3;2) returns "国" (byte position 3 is at the beginning of a character in a DBCS string, and 2 bytes constitute one DBCS character).
=MIDB("office";2;3) returns "ffi" (byte position 2 is at the beginning of a character in a non-DBCS string, and 3 bytes of a non-DBCS string constitute 3 characters).
PROPER
សរសេរតួអក្សរដំបូងក្នុងពាក្យទាំងអស់នៃខ្សែអត្ថបទ ជាអក្សរធំ ។
PROPER("អត្ថបទ")
អត្ថបទ យោងទៅអត្ថបទត្រូវបម្លែង ។
=PROPER("the document foundation") returns The Document Foundation.
REPLACE
ជំនួសផ្នែកនៃខ្សែអត្ថបទដោយខ្សែអត្ថបទផ្សេងទៀត ។ អនុគមន៍នេះអាចត្រូវបានប្រើដើម្បីជំនួសទាំងតួអក្សរ និងលេខ (ដែលត្រូវបានបម្លែងជាអត្ថបទដោយស្វ័យប្រវត្តិ) ។ លទ្ធផលនៃអនុគមន៍ តែងតែត្រូវបានបង្ហាញជាអត្ថបទ ។ បើអ្នកមានបំណងចង់ប្រតិបត្តិការគណនាបន្ថែមទៀតជាមួយចំនួនមួយ ដែលត្រូវបានជំនួសដោយអត្ថបទ នោះអ្នកត្រូវតែបម្លែងវាត្រឡប់ទៅជាលេខវិញ ដោយប្រើអនុគមន៍ VALUE ។
អត្ថបទណាដែលមានលេខ ត្រូវតែត្រូវបានដាក់ក្នុងសញ្ញាសម្រង់ បើអ្នកមិនចង់ឲ្យវា ត្រូវបានបកប្រែជាចំនួនមួយ និងត្រូវបានបម្លែងជាអត្ថបទដោយស្វ័យប្រវត្តិ ។
REPLACE("អត្ថបទ"; ទីតាំង; ប្រវែង; "អត្ថបទថ្មី")
អត្ថបទ សំដៅលើអត្ថបទ ដែលផ្នែកមួយនឹងត្រូវបានជំនួស ។
ទីតាំង យោងទៅលើទីតាំងនៅក្នុងអត្ថបទ ដែលការជំនួសនឹងចាប់ផ្ដើម ។
ប្រវែង គឺជាចំនួនតួអក្សរនៅក្នុង អត្ថបទ ត្រូវជំនួស ។
អត្ថបទថ្មី យោងលើអត្ថបទដែលជំនួស អត្ថបទ ។
=REPLACE("1234567";1;1;"444") ត្រឡប់ "444234567" ។ តួអក្សរមួយនៅទីតាំង 1 ត្រូវបានជំនួសដោយការបំពេញ អត្ថបទថ្មី ។
REPT
ធ្វើខ្សែតួអក្សរមួយម្តងទៀតតាម ចំនួន ច្បាប់ចម្លងដែលបានផ្តល់ ។
REPT("អត្ថបទ"; លេខ)
អត្ថបទ គឺជាអត្ថបទត្រូវធ្វើឡើងវិញ ។
ចំនួន គឺជាចំនួនការធ្វើឡើងវិញ ។
=REPT("Good morning";2) ត្រឡប់ Good morningGood morning ។
Refer to the REPT wiki page for more details about this function.
RIGHT
ត្រឡប់តួអក្សរចុងក្រោយ ឬតួអក្សររបស់អត្ថបទ ។
RIGHT("Text" [; Number])
អត្ថបទ គឺជាអត្ថបទដែលផ្នែកខាងស្ដាំត្រូវបានកំណត់ ។
Number (optional) is the number of characters from the right part of the text. If this parameter is not defined, one character is returned.
=RIGHT("Sun";2) ត្រឡប់ un ។
RIGHTB
Returns the last character or characters of a text with double bytes characters sets (DBCS).
RIGHTB("Text" [; Number_bytes])
Text is the text of which the right part is to be determined.
Number_bytes (optional) specifies the number of characters you want RIGHTB to extract, based on bytes. If this parameter is not defined, one byte is returned.
RIGHTB("中国";1) returns " " (1 byte is only half a DBCS character and a space character is returned instead).
RIGHTB("中国";2) returns "国" (2 bytes constitute one complete DBCS character).
RIGHTB("中国";3) returns " 国" (3 bytes constitute one half DBCS character and one whole DBCS character; a space is returned for the first half).
RIGHTB("中国";4) returns "中国" (4 bytes constitute two complete DBCS characters).
RIGHTB("office";3) returns "ice" (3 non-DBCS characters each consisting of 1 byte).
SEARCH
Returns the position of a text segment within a character string. You can set the start of the search as an option. The search text can be a number or any sequence of characters. The search is not case-sensitive. If the text is not found, returns error 519 (#VALUE).
The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every regular expression metacharacter or operator with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in .
When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".
SEARCH("FindText"; "Text" [; Position])
អត្ថបទស្វែងរក គឺជាអត្ថបទដែលត្រូវស្វែងរក ។
អត្ថបទ គឺជាអត្ថបទដែលការស្វែងរកនឹងកើតឡើង ។
ទីតាំង (ជាជម្រើស) គឺជាទីតាំងនៅក្នុងអត្ថបទដែលការស្វែងរកត្រូវចាប់ផ្ដើម ។
=SEARCH(54;998877665544) ត្រឡប់ 10 ។
SUBSTITUTE
ជំនួសអត្ថបទថ្មីសម្រាប់អត្ថបទចាស់ក្នុងខ្សែអក្សរមួយ ។
SUBSTITUTE("Text"; "SearchText"; "NewText" [; Occurrence])
អត្ថបទ គឺជាអត្ថបទដែលផ្នែកអត្ថបទត្រូវបានផ្លាស់ប្ដូរ ។
អត្ថបទស្វែងរកគឺជាផ្នែកអត្ថបទដែលត្រូវបានជំនួស (ច្រើនដង) ។
អត្ថបទថ្មី គឺជាអត្ថបទដែលត្រូវជំនួសផ្នែកអត្ថបទ ។
ការកើតឡើង (ជាជម្រើស) បង្ហាញការកើតឡើងណាមួយនៃអត្ថបទស្វែងរកត្រូវបានជំនួស ។ ប្រសិនបើប៉ារ៉ាម៉ែត្រនេះបាត់ អត្ថបទស្វែងរកត្រូវបានជំនួសទាំងអស់ ។
=SUBSTITUTE("123123123";"3";"abc") ត្រឡប់ 12abc12abc12abc ។
=SUBSTITUTE("123123123";"3";"abc";2) ត្រឡប់ 12312abc123 ។
T
អនុគមន៍នេះត្រឡប់អត្ថបទគោលដៅ ឬខ្សែអក្សរអត្ថបទទទេ ប្រសិនបើគោលដៅមិនមែនជាអត្ថបទ ។
T(តម្លៃ)
ប្រសិនបើតម្លៃ គឺជាខ្សែអត្ថបទ ឬយោងលើខ្សែអក្សរអត្ថបទ T ត្រឡប់ខ្សែអត្ថបទនោះ បើមិនដូច្នេះទេ វាត្រឡប់ខ្សែអត្ថបទទទេ ។
=T(12345) ត្រឡប់ខ្សែអក្សរទទេ ។
=T("12345") ត្រឡប់ខ្សែអក្សរ 12345 ។
TEXT
Converts a value into text according to a given format.
TEXT(Value; Format)
Value is the value (numerical or textual) to be converted.
ទ្រង់ទ្រាយ ជាអត្ថបទដែលកំណត់ទ្រង់ទ្រាយ ។ ប្រើចំនួនទសភាគ និងអ្នកបំបែកខ្ទង់ពាន់ ដោយអាស្រ័យតាមសំណុំភាសាក្នុងទ្រង់ទ្រាយក្រឡា ។
=TEXT(12.34567;"###.##") ត្រឡប់អត្ថបទ 12.35
=TEXT(12.34567;"000.00") ត្រឡប់អត្ថបទ 012.35
=TEXT("xyz";"=== @ ===") returns the text === xyz ===
See also Number format codes: custom format codes defined by the user.
TRIM
យកចន្លោះចេញពីតួអក្សរ ទុកតែចន្លោះតែមួយតួអក្សរនៅរវាងពាក្យ ។
TRIM("អត្ថបទ")
អត្ថបទ សំដៅលើអត្ថបទដែលលុបដកឃ្លាចេញ។
=TRIM(" hello world ") returns hello world without leading and trailing spaces and with single space between words.
UNICHAR
បម្លែងលេខកូដទៅជាតួអក្សរយូនីកូដសម្រាប់អក្សរ ។
UNICHAR(number)
=UNICHAR(169) ត្រឡប់តួអក្សររក្សាសិទ្ធិ © ។
See also the UNICODE() function.
UNICODE
ត្រឡប់កូដជាលេខ សម្រាប់តួអក្សរយូនីកូដក្នុងខ្សែអត្ថបទមួយ ។
UNICODE("Text")
=UNICODE("©") ត្រឡប់លេខយូនីកូដ ១៦៩ សម្រាប់តួអក្សររក្សាសិទ្ធិ ។
See also the UNICHAR() function.
UPPER
បម្លែងខ្សែអក្សរដែលបានបញ្ជាក់លម្អិតក្នុងវាល អត្ថបទ ទៅជាអក្សរធំ ។
UPPER("អត្ថបទ")
អត្ថបទ យោងលើអក្សរតូច ដែលអ្នកចង់បម្លែងទៅអក្សរធំ ។
=UPPER("Good Morning") ត្រឡប់ GOOD MORNING ។