ScriptForge.Timer service

The Timer service measures the amount of time it takes to run user scripts.

A Timer measures durations. It can be:

แƒ แƒฉแƒ”แƒ•แƒ˜แƒก แƒฎแƒแƒขแƒฃแƒšแƒ

Durations are expressed in seconds with a precision of 3 decimal digits (milliseconds). A duration value of 12.345 means 12 seconds and 345 milliseconds


Service invocation

Before using the Timer service the ScriptForge library needs to be loaded using:


    GlobalScope.BasicLibraries.LoadLibrary("ScriptForge")
  

The example below creates a Timer object named myTimer and starts it immediately.


    Dim myTimer As Variant
    myTimer = CreateScriptService("Timer", True)
    'The timer starts immediately when the second argument = True, default = False
  

It is recommended to free resources after use:


    Set myTimer = myTimer.Dispose()
  
note

This service is fully supported in both Basic and Python languages. All examples are expressed using the Basic programming language and can be easily converted to Python.


Properties

Name

Readonly

Type

Description

Duration

Yes

Double

The actual running time elapsed since start or between start and stop (does not consider suspended time)

IsStarted

Yes

Boolean

True when timer is started or suspended

IsSuspended

Yes

Boolean

True when timer is started and suspended

SuspendDuration

Yes

Double

The actual time elapsed while suspended since start or between start and stop

TotalDuration

Yes

Double

The actual time elapsed since start or between start and stop (including suspensions and running time)


แƒ แƒฉแƒ”แƒ•แƒ˜แƒก แƒฎแƒแƒขแƒฃแƒšแƒ

Note that the TotalDuration property is equivalent to summing the Duration and SuspendDuration properties.


Methods

All methods do not require arguments and return a Boolean value.

If the returned value is False, then nothing happened.

Name

Description

Returned value

Continue

Resumes the Timer if it has been suspended

False if the timer is not suspended

Restart

Terminates the Timer and discards its current property values, restarting as a new clean Timer

False if the timer is inactive

Start

Starts a new clean timer

False if the timer is already started

Suspend

Suspends a running timer

False if the timer is not started or already suspended

Terminate

Stops a running timer

False if the timer is neither started nor suspended


Example:


      myTimer.Start()
      Wait 500
      myTimer.Suspend()
      'The time elapsed while the Dialog box is open will be counted as suspended time
      MsgBox myTimer.Duration & " " & myTimer.SuspendDuration & " " & myTimer.TotalDuration
      myTimer.Continue()
      Wait 500
      'The time elapsed while the Dialog box is open will be counted as running time
      MsgBox myTimer.Duration & " " & myTimer.SuspendDuration & " " & myTimer.TotalDuration
      myTimer.Terminate()
      'Shows the final time measurements
      MsgBox myTimer.Duration & " " & myTimer.SuspendDuration & " " & myTimer.TotalDuration
    
note

If you call the Terminate method, subsequent calls for the Continue method will not resume time measurement. Similarly, after a Timer has been terminated, calling the Start method will restart it as if it were a clean new Timer.


Working with Multiple Timers

It is possible to instantiate multiple Timer services in parallel, which gives flexibility in measuring time in different parts of the code.

The following example illustrates how to create two Timer objects and start them separately.


    Dim myTimerA as Variant, myTimerB as Variant
    myTimerA = CreateScriptService("Timer")
    myTimerB = CreateScriptService("Timer")
    'Starts myTimerA
    myTimerA.Start()
    Wait 1000 'Wait 1 second (1,000 milliseconds)
    MsgBox myTimerA.Duration & " " & myTimerB.Duration
    'Starts myTimerB
    myTimerB.Start()
    Wait 1000
    MsgBox myTimerA.Duration & " " & myTimerB.Duration
    'Terminate both timers
    myTimerA.Terminate()
    myTimerB.Terminate()
  
warning

All ScriptForge Basic routines or identifiers that are prefixed with an underscore character "_" are reserved for internal use. They are not meant be used in Basic macros.


Please support us!