財務関数 1

このカテゴリーには、LibreOffice Calcの財務に関する関数があります。

ACCRINT

定期的に利息が支払われる証券の未収利息額 (補充利息) を返します。

Syntax

ACCRINT(Issue; FirstInterest; Settlement; Rate; [Par]; Frequency [; Basis])

発行 は、証券の発行日です。

最初の利払日 は、証券の利息が最初に支払われる日付です。

受領日 は、それまでの利息を計算する日付です。

利率 は、名目年利率 (利札利率) です

Par (optional) is the par value of the security. If omitted, a default value of 1000 is used.

note

We recommend that you always specify the value that you require for ACCRINT’s Par argument, rather than allowing Calc to apply an arbitrary default. This will make your formula easier to understand and easier to maintain.


利息支払回数 は、年間の利息支払回数です。1、2、または 4 になります。

基準 はオプションのリストから選択され、どのように年が計算されるかを示します。

基準

計算

0 or missing

US 方式 (NASD) 、30日×12ヶ月

1

ひと月または1年の正確な日数

2

ひと月の正確な日数、1年は 360 日

3

ひと月の正確な日数、1年は 365 日

4

ヨーロッパ方式、30日×12ヶ月


Example

次の未収利息額を求めます。2001年2月28日に証券が発行され、最初の利息支払日が2001年8月31日、受領日が2001年5月1日となっています。利率は 0.1 または 10%、額面は 1000 通貨単位です。利息は半年毎に支払われます (頻度 2) 。基準は米国方式 (0) とします。

=ACCRINT("2001-02-28";"2001-08-31";"2001-05-01";0.1;1000;2;0) は 16.94444 を返します。

ACCRINTM

満期日に利息が一括で支払われる証券の未収利息を計算します。

Syntax

ACCRINTM(Issue; Settlement; Rate [; Par [; Basis]])

発行 は、証券の発行日です。

受領日 は、それまでの利息を計算する日付です。

利率 は、名目年利率 (利札利率) です。

Par (optional) is the par value of the security. If omitted, a default value of 1000 is used.

note

We recommend that you always specify the value that you require for ACCRINTM’s Par argument, rather than allowing Calc to apply an arbitrary default. This will make your formula easier to understand and easier to maintain.


基準 はオプションのリストから選択され、どのように年が計算されるかを示します。

基準

計算

0 or missing

US 方式 (NASD) 、30日×12ヶ月

1

ひと月または1年の正確な日数

2

ひと月の正確な日数、1年は 360 日

3

ひと月の正確な日数、1年は 365 日

4

ヨーロッパ方式、30日×12ヶ月


Example

次の未収利息額を求めます。2001年4月1日に証券が発行され、満期日が2001年6月15日となっています。利率は 0.1 または 10%、額面は 1000 通貨単位です。利息は日毎に計算されます(3)。

=ACCRINTM("2001-04-01";"2001-06-15";0.1;1000;3) は 20.54795 を返します。

AMORDEGRC

会計期ごとの減価償却費を逓減償却法で計算します。AMORLINC 関数とは異なり、この関数は減価償却耐用期間とは関係がない減価償却係数を使用します。

Syntax

AMORDEGRC(Cost; DatePurchased; FirstPeriod; Salvage; Period; Rate [; Basis])

取得価額 は、取得価額です。

購入日 は、取得日です。

最初の会計期 は、最初の会計期の最終日です。

残存 は、耐用年数が終了した時点での固定資産の残存価額です。

期間 は、検討対象の会計期です。

利率 は、減価償却率です。

基準 はオプションのリストから選択され、どのように年が計算されるかを示します。

基準

計算

0 or missing

US 方式 (NASD) 、30日×12ヶ月

1

ひと月または1年の正確な日数

2

ひと月の正確な日数、1年は 360 日

3

ひと月の正確な日数、1年は 365 日

4

ヨーロッパ方式、30日×12ヶ月


Example

An asset was acquired on 2020-02-01 at a cost of 2000 currency units. The end date of the first settlement period was 2020-12-31. The salvage value of the asset at the end of its depreciable life will be 10 currency units. The rate of depreciation is 0.1 (10%) and the year is calculated using the US method (Basis 0). Assuming degressive depreciation, what is the amount of depreciation in the fourth depreciation period?

=AMORDEGRC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) returns a depreciation amount of 163 currency units.

note

Be aware that Basis 2 is not supported by Microsoft Excel. Hence, if you use Basis 2 and export your document to XLSX format, it will return an error when opened in Excel.


AMORLINC

各会計期における定額減価償却費を計算します。資産を会計期の途中で購入した場合、日割り計算による減価償却費が計算されます。

Syntax

AMORLINC(Cost; DatePurchased; FirstPeriod; Salvage; Period; Rate [; Basis])

取得価額 は、取得価額を意味します。

購入日 は、取得日です。

最初の会計期 は、最初の会計期の最終日です。

残存 は、耐用年数が終了した時点での固定資産の残存価額です。

期間 は、検討対象の会計期です。

利率 は、減価償却率です。

基準 はオプションのリストから選択され、どのように年が計算されるかを示します。

基準

計算

0 or missing

US 方式 (NASD) 、30日×12ヶ月

1

ひと月または1年の正確な日数

2

ひと月の正確な日数、1年は 360 日

3

ひと月の正確な日数、1年は 365 日

4

ヨーロッパ方式、30日×12ヶ月


Example

An asset was acquired on 2020-02-01 at a cost of 2000 currency units. The end date of the first settlement period was 2020-12-31. The salvage value of the asset at the end of its depreciable life will be 10 currency units. The rate of depreciation is 0.1 (10%) and the year is calculated using the US method (Basis 0). Assuming linear depreciation, what is the amount of depreciation in the fourth depreciation period?

=AMORLINC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) returns a depreciation amount of 200 currency units.

note

Be aware that Basis 2 is not supported by Microsoft Excel. Hence, if you use Basis 2 and export your document to XLSX format, it will return an error when opened in Excel.


DB

指定された期間の資産の減価償却費を倍率法で計算します。

この償却法を使用すると、償却の初期に償却費が高くなります。償却価額は、償却期間ごとに、取得価格からすでに差し引かれた償却費の分減少します。

Syntax

DB(Cost; Salvage; Life; Period [; Month])

取得価額 は、資産を購入した時点での価格です。

残存価額 は、減価償却後の資産の価格です。

耐用年数 は、資産を償却する期間を定義します。

期間 は、各期間の長さです。長さは償却期間と同じ単位で指定する必要があります。

(オプション) は、減価償却の最初の年の月数を意味します。省略すると、12 を指定したとみなされます。

Example

A computer system with an initial cost of 25,000 currency units is to be depreciated over a three-year period. The salvage value is to be 1,000 currency units. The first period of depreciation comprises 6 months. What is the fixed-declining balance depreciation of the computer system in the second period, which is a full year starting from the end of the first six-month period?

=DB(25000; 1000; 3; 2; 6) returns 11,037.95 currency units.

DDB

指定された期間の資産の減価償却費を倍率法で計算します。

この償却法を使うと、定額償却法とは対照的に、初期の償却費が高くなります。償却価額は償却期間ごとに減少します。この方法は通常、購入後に価値が急速に落ちる資産 (自動車やコンピューターなど) に使用します。この方法では、帳簿価格は決してゼロにならないので注意します。

Syntax

DDB(Cost; Salvage; Life; Period [; Factor])

取得価額 には、資産を購入した時点での価格を指定します。

残存価額 には、耐用年数が終了した時点での資産の価格を指定します。

寿命は資産がどれくらい長い期間 (たとえば年または月)使用されるかの値です。

期間 は、値が計算される期間のことです。

(オプション) には、減価償却率を指定します。何も入力しなかった場合は 2 を指定したとみなされます。

Example

購入価格 7,500,000 円の情報処理装置を5年間毎月減価償却するとします。残存価格は 100 円、率は 2 とします。

=DDB(75000;1;60;12;2) = 1,721.81 通貨単位。したがって、購入後の 1 か月間の二倍減価償却費は、1,721.81 通貨単位になります。

DISC

証券に対する割引率を計算します。

Syntax

DISC(Settlement; Maturity; Price; Redemption [; Basis])

受領日 は、証券の購入日です。

満期日 は、証券が満期になる (満了する) 日付です。

取得価額 は、額面の 100 通貨単位あたりの証券の取得価額です。

償還価額 は、額面の 100 通貨単位あたりの証券の償還価額です。

基準 はオプションのリストから選択され、どのように年が計算されるかを示します。

基準

計算

0 or missing

US 方式 (NASD) 、30日×12ヶ月

1

ひと月または1年の正確な日数

2

ひと月の正確な日数、1年は 360 日

3

ひと月の正確な日数、1年は 365 日

4

ヨーロッパ方式、30日×12ヶ月


Example

次の場合の割引率を求めます。証券受領日は 2001 年 1 月 25 日、満期日は 2001 年 11 月 15日、現在価値 (支払額) は 97 で、償還価値は 100 です。日毎残高を計算する (基準 3) 場合の決済額。

=DISC("2001-01-25";"2001-11-15";97;100;3) は 0.0372 もしくは 3.72% を 返します。

DURATION

固定金利証券の期間の年数を計算します。

Syntax

DURATION(Settlement; Maturity; Coupon; Yield; Frequency [; Basis])

受領日 は、証券の購入日です。

満期日 は、証券が満期になる (満了する) 日付です。

利札 は、利札年利率 (名目利率) です。

利回り は、証券の年利回りです。

利息支払回数 は、年間の利息支払回数です。1、2、または 4 になります。

基準 はオプションのリストから選択され、どのように年が計算されるかを示します。

基準

計算

0 or missing

US 方式 (NASD) 、30日×12ヶ月

1

ひと月または1年の正確な日数

2

ひと月の正確な日数、1年は 360 日

3

ひと月の正確な日数、1年は 365 日

4

ヨーロッパ方式、30日×12ヶ月


Example

証券を 2001 年 1 月 1 日に購入し、満期日は 2006 年 1 月 1 日です。名目利率は 8% です。利回りは 9.0% です。利息は半年に一度支払われます (年間の利息支払回数は 2 回)。1 日単位の未払い利息計算 (基準 3) を使用して、修正された期間を求めます。

=DURATION("2001-01-01";"2006-01-01";0.08;0.09;2;3) returns 4.2 years.

EFFECT

名目年利率に対する 1 年あたりの実効利率を計算します。

名目年利が月々、四半期、またはその他の計算期間の終わりに支払われるのに対し、金利は通常期間内に先払いされるため、実効年利は金利支払いの回数と共に多くなります。

Syntax

EFFECT(Nom; P)

Nom は、名目利率です。

P は、1年あたりの利子の支払い回数です。

Example

名目年利率が 9.75% で、複利計算期間が 4 に指定されている場合の実際の利率 (実効年利率) を求めます。

=EFFECT(9.75%;4) = 10.11% The annual effective rate is therefore 10.11%.

EFFECT_ADD

指定された名目年利率と 1 年当たりの利息支払回数を元に、実効年利率を計算します。

note

The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.


Syntax

EFFECT_ADD(名目年利率; NPerY)

名目利率 は、名目年利率です。

NPerY は、年間の利息支払回数です。

Example

名目利率 5.25%、四半期ごとの利息支払の場合の実効年利率を求めます。

=EFFECT_ADD(0.0525;4) は、0.053543、または 5.3534% を返します。

IRR

投資に対する内部利益率を計算します。これらの値は一定期間のキャッシュフロー値を表し、少なくとも 1 つの値が負 (支払) であり、かつ、少なくとも 1 つの値が正 (収入) である必要があります。

If the payments take place at irregular intervals, use the XIRR function.

Syntax

IRR(Values [; Guess])

は値を含む配列です。

推定値 (オプション) は推定値です。内部的な利益率を計算するときには、反復方法が使用されます。ほんの数個しか値を提供できない場合、この反復を有効にするには、初期推定値を指定する必要があります。

note

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.


Example

セル内容が A1=-10000、A2=3500、A3=7600、および A4=1000 とすると、式 =IRR(A1:A4) の結果は 11.33% です。

warning

Because of the iterative method used, it is possible for IRR to fail and return Error 523, with "Error: Calculation does not converge" in the status bar. In that case, try another value for Guess.


ISPMT

利率が一定の分割払いにおける金利を計算します。

Syntax

ISPMT(利率; 期間; 合計期間; 投資)

利率 は期間の利率を指定します。

期間 は金利支払額を求めるための分割払いの回数です。

合計期間 は、支払い期間の合計です。

投資額 は現在の投資額です。

Example

年利 12% の 2 年ローンで \120000 を支払う場合、最初の 1 年半にどれだけ金利を支払うかを計算します。

=ISPMT(1%;18;24;120000) = -300 通貨単位。1.5 年後の月利は、300 通貨単位です。

PV

一連の支払から生じた投資の現在価値を返します。

この関数は、期間ごとに一定金額を受け取りるために、現在投資する必要のある金額を計算します。オプションで、最終的に残す金額を指定することもできます。また、支払い日を期間の最初または最後のどちらかに指定することもできます。

値には、数値、式、参照が入力できます。例えば、毎年 8% 受け取る金利を月を単位として入力するには、利率 に 8%/12 と入力します。LibreOffice Calc は自動的に正しい係数を計算します。

Syntax

PV(Rate; NPer; Pmt [; FV [; Type]])

利率は、期間ごとの利率を定義します。

NPer は、期間の合計 (支払い期間) です。

Pmt は、期間ごとの定期支払いです。

将来価値 (オプション) には、最後の支払いを行った後に残る現金の収支を定義します。

支払期日 (オプション) は支払期日です。支払期日 = 1 は、各期の期首を意味し、支払期日 = 0 (標準設定) は、各期の期末を意味します。

In the LibreOffice Calc functions, parameters marked as "optional" can be left out only when no parameter follows. For example, in a function with four parameters, where the last two parameters are marked as "optional", you can leave out parameter 4 or parameters 3 and 4, but you cannot leave out parameter 3 alone.

Example

年 8% の利率で月々 50,000 円支払う投資の現在価値を求めます。支払い期間は48ヶ月で、その後に 2,000,000 円残るようにします。

=PV(8%/12;48;500;20000) = -35,019.37 通貨単位。指定された条件では、48 か月間毎月 500 通貨単位を受け取り、最後に 20,000 通貨単位を残すには、本日、35,019.37 通貨単位を預ける必要があります。照合を行うと、48 x 500 通貨単位 + 20,000 通貨単位 = 44,000 通貨単位となります。この金額と預けた 35,000 通貨単位の差が、支払利息を表します。

数式に数値ではなく参照を入力すると、簡単に様々な状況 (What-if) のシナリオが計算できます。定数の参照は、絶対参照で指定してください。この計算の例については、減価償却関数を参照してください。

RECEIVED

固定金利証券に対してある時点で支払われる金額を計算します。

Syntax

RECEIVED(Settlement; Maturity; Investment; Discount [; Basis])

受領日 は、証券の購入日です。

満期日 は、証券が満期になる (満了する) 日付です。

投資 は、購入額の合計です。

割引 は、証券購入時の割引率です。

基準 はオプションのリストから選択され、どのように年が計算されるかを示します。

基準

計算

0 or missing

US 方式 (NASD) 、30日×12ヶ月

1

ひと月または1年の正確な日数

2

ひと月の正確な日数、1年は 360 日

3

ひと月の正確な日数、1年は 365 日

4

ヨーロッパ方式、30日×12ヶ月


Example

受領日: 1999年2月15日、満期日: 1999年5月15日、 投資額: ¥1,000,000、割引率: 5.75 パーセント、 基準: 実際の日数/360 = 2。

満期日に支払われる金額の計算は次のようになります:

=RECEIVED("1999-02-15";"1999-05-15";1000;0.0575;2) は 1014.420266 を返します。

SYD

定額逓減を使って、減価償却費を計算します。

この関数は、ある対象物の減価償却期間内における1期間の減価償却費を返します。定額逓減法では、期間ごとに一定の額が総減価償却費から減算されていきます。

Syntax

SYD(取得価額; 残存; 耐用年数; 期間)

取得価額 は、資産を購入した時点での価格です。

残存価額 は、減価償却後の資産の価格です。

耐用年数 は、資産を使用できる年数、つまり償却の対象となる資産の寿命年数です。

期間 は、減価償却費を求める期間です。

Example

減価償却費 5,000,000 円のビデオ装置を5年間毎年減価償却し、残存価格は 1,000,000 円とします。最初の年の減価償却費を求めます。

=SYD(50000;10000;5;1) = 13,333.33 通貨単位。1 年目の減価償却費は、13,333.33 通貨単位です。

期間ごとの減価償却費がひと目でわかるように、減価償却表を定義すると便利です。LibreOffice Calc のいろいろな減価償却数式を並べて入力すると、場合による最適な償却方法がわかります。表は次のように作成します:

A

B

C

D

E

1

初期取得価額

残存価額

耐用年数

期間

Deprec. SYD

2

50,000 通貨単位

10,000 通貨単位

5

1

13,333.33 通貨単位

3

2

10,666.67の通貨単位

4

3

8,000.00 通貨単位

5

4

5,333.33 通貨単位

6

5

2,666.67 通貨単位

7

6

0.00 通貨単位

8

7

9

8

10

9

11

10

12

13

>0

合計

40,000.00 通貨単位


E2 に次の数式を入力します:

=SYD($A$2;$B$2;$C$2;D2)

この数式を E10 まで複写します (E2 を選択して、右下の角をマウスで下にドラッグします) 。

セル E13 には、確認のためにすべての減価償却費の合計を出す数式を入力します。E8:E11 の負の値は計算対象にしてはならないため、SUMIF 関数を使用してセル A13 に条件 >0 を入力します。E13 入力する数式は次の通りです:

=SUMIF(E2:E11;A13)

これで 10 年間の減価償却費を計算したり、残存価額を \100 にしたり、あるいはその他の減価償却費を入力したりすることができます。

財務関数 2 へ

財務関数 3 へ

Functions by Category

ご支援をお願いします!