Funzione SOMMA.PIÙ.SE

Restituisce la somma dei valori delle celle in un intervallo che soddisfa più criteri in intervalli multipli.

tip

La funzione è disponibile da LibreOffice 4.0.


Sintassi

SOMMA.PIÙ.SE(Intervallo_Funz; Intervallo1; Criterio1[; Intervallo2; Criterio2][; … ; [Intervallo127; Criterio127]])

Intervallo_Funz – argomento obbligatorio. È un intervallo di celle, il nome di un'area indicata, la dicitura di una colonna o di una riga che contiene valori per il calcolo della somma.

Intervallo1: argomento obbligatorio. È un intervallo di celle, il nome di un'area indicata, la dicitura di una colonna o di una riga a cui deve essere applicato il criterio corrispondente.

Criterio1: argomento richiesto. Un'espressione che rappresenta una condizione logica o un riferimento di cella a tale espressione. L'espressione può contenere testo, numeri, espressioni regolari o caratteri jolly (se abilitati nelle opzioni di calcolo).

Intervallo2 – opzionale. Intervallo2 e tutto ciò che segue hanno lo stesso significato di Intervallo1.

Criterio2 – opzionale. Criterio2 e tutto ciò che segue hanno lo stesso significato di Criterio1.

La ricerca supporta caratteri jolly o espressioni regolari. Attivando le espressioni regolari potete, per esempio, digitare "all.*", per trovare la prima posizione di "all" seguita da qualsiasi altro carattere. Se volete ricercare un testo che è anch'esso un'espressione regolare, dovete far precedere qualsiasi carattere da un carattere "\", oppure racchiudere il testo all'interno \Q...\E. Potete attivare o disattivare la stima automatica dei caratteri jolly o delle espressioni regolari in - LibreOffice Calc - Calcola.

warning

Quando utilizzate funzioni in cui uno o più argomenti sono stringhe di criteri di ricerca che rappresentano un'espressione regolare, il primo tentativo è convertire i criteri della stringa in numeri. Per esempio, ".0" sarà convertito in 0.0 e via discorrendo. Se coincide, la corrispondenza non sarà una corrispondenza di espressione regolare ma una corrispondenza numerica. Tuttavia, quando si passa a un'impostazione regionale in cui il separatore decimale non è il punto, tale passaggio fa funzionare la conversione in espressione regolare. Per forzare la stima dell'espressione regolare, anziché di quella numerica, utilizzate delle espressioni che non possano essere confuse con una numerica, tipo ".[0]", ".\0" oppure "(?i).0".


Intervallo_Funz e Intervallo1, Intervallo2... devono possedere la stessa dimensione, in caso contrario la funzione restituisce err:502 - Argomento non valido.

note

La relazione logica tra i criteri definibili come E logico (congiunzione). In altre parole, se, e solo se, tutti i criteri sono soddisfatti, viene inserito nel calcolo un valore derivante dalla cella corrispondente del Intervallo_Func specificato.


La funzione può possedere fino a 255 argomenti, nel senso che potete specificare 127 intervalli di criteri e i criteri a essi relativi.

Se una cella contenesse VERO, sarebbe considerata 1; se contenesse FALSO, sarebbe considerata 0 (zero).

Icona di nota

Questa funzione appartiene all'Open Document Format for Office Applications (OpenDocument), versione standard 1.2 (ISO/IEC 26300:2-2015).


Esempio

Considerate la tabella seguente

A

B

C

1

Nome prodotto

Vendite

Ricavo

2

matita

20

65

3

penna

35

85

4

notebook

20

190

5

libro

17

180

6

astuccio

non

non


warning

In tutti gli esempi riportati sotto, gli intervalli per il calcolo contengono la riga #6, che viene ignorata poiché contiene testo.


Uso semplice

=SOMMA.PIÙ.SE(B2:B6;B2:B6;">=20")

Calcola la somma dei valori dell'intervallo B2:B6, maggiori o uguali a 20. Restituisce 75, perché la quinta riga non soddisfa il criterio.

=SOMMA.PIÙ.SE(C2:C6;B2:B6;">=20";C2:C6;">70")

Calcola la somma dei valori dell'intervallo C2:C6 maggiori di 70 e che corrispondono alle celle dell'intervallo B2:B6 con valori maggiori o uguali a 20. Restituisce 275, perché la seconda e la quinta riga non soddisfano almeno un criterio.

Uso delle espressioni regolari e delle funzioni annidate

=SOMMA.PIÙ.SE(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Calcola la somma dei valori dell'intervallo C2:C6 che corrispondono a tutti i valori dell'intervallo B2:B6, eccetto il suo minimo e massimo. Restituisce 255, perché la terza e la quinta riga non soddisfano almeno un criterio.

=SOMMA.PIÙ.SE(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Calcola la somma dei valori dell'intervallo C2:C6 che corrispondono a tutte le celle dell'intervallo A2:B6 che iniziano con "pen" e a tutte le celle dell'intervallo B2:B6, eccetto il suo massimo. Restituisce 65, perché solo la seconda riga soddisfa tutti i criteri.

Fare riferimento a una cella come criterio

Per cambiare in modo facile un criterio, potete specificarlo in una cella separata, utilizzando un riferimento alla cella all'interno della condizione della funzione SOMMA.PIÙ.SE. Per esempio, la funzione sopra citata può essere riscritta nel modo seguente:

=SOMMA.PIÙ.SE(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Se E2 = pen, la funzione restituisce 65, perché il collegamento alla cella è sostituito dal suo contenuto.

Aprire file con esempio:

Sosteneteci!