Funzione MEDIA.SE

Restituisce la media aritmetica di tutte le celle all'interno di un intervallo che soddisfi una determinata condizione. La funzione MEDIA.SE somma tutti i risultati che corrispondono al test logico e divide per la quantità dei valori selezionati.

tip

La funzione è disponibile da LibreOffice 4.0.


Sintassi

MEDIA.SE(Intervallo; Criterio [; intervallo_media ])

Intervallo ‚Äď argomento obbligatorio. Pu√≤ essere una matrice, il nome di un'area indicata, la dicitura di una colonna o di una riga che contiene numeri per l'esecuzione della media oppure numeri o testo per la condizione.

Criterio: è un riferimento, un numero o un testo di una singola cella. Viene utilizzato nei confronti col contenuto delle celle.

Un riferimento a una cella vuota viene interpretato come valore numerico 0.

Un'espressione che corrisponde può essere:

La ricerca supporta i caratteri jolly o le espressioni regolari. Se queste ultime sono attivate, √® possibile inserire "all.*" per trovare, ad esempio, la prima posizione di "all" seguito da qualsiasi carattere. Se si intende ricercare un testo che sia anche un'espressione regolare, √® necessario far precedere sempre il metacarattere o l'operatore dell'espressione dal carattere "\", oppure racchiudere il testo tra \Q...\E. √ą possibile attivare o disattivare l'analisi dei caratteri jolly o delle espressioni regolari in - LibreOffice Calc - Calcola.

warning

Quando si utilizzano funzioni in cui uno o pi√Ļ argomenti sono stringhe di criteri di ricerca che rappresentano un'espressione regolare, innanzitutto si cerca di convertire i criteri della stringa in numeri. Per esempio, ".0" sar√† convertito in 0.0 e cos√¨ via. In caso di esito positivo, la corrispondenza non sar√† quella di un'espressione regolare ma una corrispondenza numerica. Tuttavia, quando si passa a un'impostazione regionale in cui il separatore decimale non √® il punto, tale passaggio fa funzionare la conversione in espressione regolare. Per forzare la valutazione dell'espressione regolare, anzich√© di quella numerica, utilizzare un'espressione che non possa essere erroneamente interpretata come numerica, per es., ".[0]", ".\0" oppure "(?i).0".


intervallo_media ‚Äď argomento opzionale. √ą un intervallo di valori per il calcolo della media.

note

Se intervallo_media non è specificato, Intervallo viene utilizzato per entrambi il calcolo della media e la ricerca in base alla condizione. Se intervallo_media è specificato, Intervallo viene utilizzato solo per il test della condizione, mentre intervallo_media viene utilizzato per il calcolo della media.


note

Questa funzione appartiene all'Open Document Format for Office Applications (OpenDocument), versione standard 1.2 (ISO/IEC 26300:2-2015).


warning

Se all'interno di un intervallo di valori per il calcolo della media, una cella fosse vuota o contenesse del testo, la funzione AVERAGEIF ignorerebbe tale cella.
Se l'intero intervallo fosse vuoto, contenesse solo testo o tutti i valori al suo interno non soddisfassero la condizione (o qualsiasi loro combinazione), la funzione restituirebbe l'errore #DIV/0!.


Esempio

Considerate la tabella seguente

A

B

C

1

Nome prodotto

Vendite

Ricavo

2

matita

20

65

3

penna

35

85

4

notebook

20

190

5

libro

17

180

6

astuccio

non

non


warning

In tutti gli esempi riportati sotto, gli intervalli per il calcolo contengono la riga #6, che viene ignorata poiché contiene testo.


Uso semplice

=MEDIA.SE(B2:B6;"<35")

Calcola la media per i valori dell'intervallo B2:B6, minori di 35. Restituisce 19, perché la seconda riga non è inclusa nel calcolo.

=MEDIA.SE(B2:B6;"<"&MAX(B2:B6))

Calcola la media per i valori dello stesso intervallo minori del valore massimo dello stesso intervallo. Restituisce 19, perché il valore maggiore (la seconda riga) non è incluso nel calcolo.

=MEDIA.SE(B2:B6;">"&PICCOLO(B2:B6;1))

Calcola la media per i valori dello stesso intervallo maggiori del primo valore pi√Ļ piccolo dello stesso intervallo. Restituisce 25, perch√© il primo valore pi√Ļ piccolo (la quarta riga) non √® incluso nel calcolo.

Uso di intervallo_media

=MEDIA.SE(B2:B6;"<35";C2:C6)

La funzione ricerca quali valori sono minori di 35 all'interno dell'intervallo B2:B6, e calcola la media dei valori corrispondenti dall'intervallo C2:C6. Restituisce 145, perché la seconda riga non è inclusa nel calcolo.

=MEDIA.SE(B2:B6;">"&MIN(B2:B6);C2:C6)

La funzione ricerca quali valori dall'intervallo B2:B6 sono maggiori del valore minimo all'interno dell'intervallo B2:B6, e calcola la media dei valori corrispondenti dall'intervallo C2:C6. Restituisce 113,3, perché la quarta riga (in cui è presente il valore minimo all'interno dell'intervallo B2:B6) non è inclusa nel calcolo.

=MEDIA.SE(B2:B6;"<"&GRANDE(B2:B6;2);C2:C6)

La funzione ricerca quali valori dall'intervallo B2:B6 sono minori del secondo valore maggiore all'interno dell'intervallo B2:B6, e calcola la media dei valori corrispondenti dall'intervallo C2:C6. Restituisce 180, perché solo la quarta riga è inclusa nel calcolo.

Uso delle espressioni regolari

=MEDIA.SE(A2:A6;"pen";B2:B6)

La funzione ricerca quali celle dall'intervallo A2:A6 contengono la parola ‚Äúpen‚ÄĚ, e calcola la media dei valori corrispondenti dall'intervallo B2:B6. Restituisce 35, perch√© solo la seconda riga √® inclusa nel calcolo. La ricerca √® eseguita nell'intervallo A2:A6, ma vengono restituiti solo i valori dall'intervallo B2:B6.

=MEDIA.SE(A2:A6;"pen.*";B2:B6)

La funzione ricerca quali celle dall'intervallo A2:A6 iniziano con ‚Äúpen‚ÄĚ, e terminano con un qualsiasi altro numero di altri caratteri, e calcola la media dei valori corrispondenti dall'intervallo B2:B6. Restituisce 27,5, perch√© al momento solo ‚Äúpencil‚ÄĚ soddisfa la condizione, e sia la prima sia la seconda riga sono incluse nel calcolo.

=MEDIA.SE(A2:A6;".*book.*";B2:B6)

La funzione ricerca quali celle dall'intervallo A2:A6 iniziano con ‚Äúbook‚ÄĚ, e iniziano e terminano con un qualsiasi altro numero di altri caratteri, e calcola la media dei valori corrispondenti dall'intervallo B2:B6. Restituisce 18,5, perch√© solo la terza e la quarta riga sono incluse nel calcolo.

Fare riferimento a una cella come criterio

Per cambiare in modo facile un criterio, potete specificarlo in una cella separata, utilizzando un riferimento alla cella all'interno della condizione della funzione MEDIA.SE.

=MEDIA.SE(A2:A6;".*"&E2&".*";B2:B6)

La funzione ricerca quali celle dall'intervallo A2:A6 contengono una combinazione di caratteri specificati in E2, che iniziano e terminano con un qualsiasi altro numero di altri caratteri, e calcola la media dei valori corrispondenti dall'intervallo B2:B6. Se E2 = book, la funzione restituisce 18,5.

=MEDIA.SE(B2:B6;"<"&E2;C2:C6)

La funzione ricerca quali celle dall'intervallo B2:A6 sono minori del valore specificato in E2, e calcola la media dei valori corrispondenti dall'intervallo C2:C6. Se E2 = 35, la funzione restituisce 145.

Sosteneteci!