Funzione AGGREGA

La funzione restituisce un risultato aggregato dei calcoli all'interno dell'intervallo. Si possono usare diverse funzioni aggregate, come elencate di seguito. La funzione AGGREGA permette di omettere righe, errori, SUBTOTALE e altri risultati della funzione AGGREGA all'interno del calcolo.

Icona di nota

La funzione AGGREGA viene applicata agli intervalli verticali di dati con Filtro automatico attivato. Se quest'ultimo non è attivato, il ricalcolo automatico del risultato della funzione non funziona per le righe nascoste di recente. Non è pensata per funzionare con gli intervalli orizzontali, tuttavia può essere anche applicata loro, ma con alcune limitazioni. Nello specifico, la funzione AGGREGA applicata agli intervalli orizzontali di dati non riconosce le colonne nascoste, sebbene ometta correttamente errori e risultati di SUBTOTALE e altre funzioni AGGREGA incorporate all'interno della riga.


tip

La funzione è disponibile da LibreOffice 4.4.


Sintassi

AGGREGA(Funzione; Opzione; Numero 1[; Numero 2][; ... ;[Numero 253]])

o

AGGREGA(Funzione; Opzione; Matrice[; k])

Funzione – argomento obbligatorio. Un indice funzioni o un riferimento a una cella con valore da 1 a 19, in conformità alla tabella riportata di seguito.

Indice funzioni

Funzione applicata

1

MEDIA

2

CONTA.NUMERI

3

CONTA.VALORI

4

MAX

5

MIN

6

PRODOTTO

7

DEV.ST.C

8

DEV.ST.P

9

SOMMA

10

VAR.S

11

VAR.P

12

MEDIANA

13

MODA.SNGL

14

GRANDE

15

PICCOLO

16

INC.PERCENTILE

17

INC.QUARTILE

18

ESC.PERCENTILE

19

ESC.QUARTILE


Opzione – argomento obbligatorio. Un indice opzioni o un riferimento a una cella con valore da 0 a 7 determina cosa ignorare, per la funzione, all'interno dell'area di celle.

Indice opzioni

Opzione applicata

0

Ignora solo funzioni SUBTOTALE e AGGREGA annidate

1

Ignora solo righe nascoste, funzioni SUBTOTALE e AGGREGA annidate

2

Ignora solo errori, funzioni SUBTOTALE e AGGREGA annidate

3

Ignora righe nascoste, ,errori, funzioni SUBTOTALE e AGGREGA annidate

4

Ignora nulla

5

Ignora solo righe nascoste

6

Ignora solo errori

7

Ignora solo righe nascoste ed errori


Number1: argomento richiesto. Il primo argomento numerico (se l'area è impostata da un elenco di valori all'interno della funzione) o un riferimento a una cella che lo contiene.

Numero2, 3, ...: facoltativo. Un argomento numerico o un riferimento a una cella (fino a 253 argomenti), per il quale è necessario il valore aggregato.

Matrice: argomento richiesto. La matrice può essere specificata tramite i limiti dell'intervallo, il nome dell'intervallo in questione o l'etichetta della colonna.

Icona di nota

Per utilizzare le diciture di colonna dovete attivare la funzione “Trova automaticamente diciture righe/colonne”.


k – argomento richiesto per le seguenti funzioni: GRANDE, PICCOLO, INC.PERCENTILE, INC.QUARTILE, ESC.PERCENTILE, ESC.QUARTILE. È un argomento numerico, che deve corrispondere al secondo argomento di queste funzioni.

Esempio

A

B

C

1

ColonnaUno

ColonnaDue

ColonnaTre

2

34

11

12

3

10

56

35

4

#DIV/0!

5

3

5

20

8

1

6

0

8

9

7

#VALORE!

20

21

8

5

7

8

9

14

0

5


=AGGREGA(4;2;A2:A9)
Restituisce il valore massimo per l'intervallo A2:A9 = 34, laddove =MAX(A2:A9) restituisce l'errore Err:511.

=AGGREGA(9;5;A5:C5)
Restituisce la somma per l'intervallo A5:C5 = 29, anche se alcune colonne sono nascoste.

=AGGREGA(9;5;B2:B9)
Restituisce la somma della colonna B = 115. Se una riga qualsiasi viene nascosta, la funzione omette il suo valore: per esempio, se fosse nascosta la settima riga, la funzione restituirebbe 95.

Questo esempio mostra come applicare la funzione a un intervallo 3D.

=AGGREGA(13;3;Foglio1.B2:B9:Foglio3.B2:B9)
La funzione restituisce il modo dei valori delle seconde colonne per i fogli 1:3 (che contengono gli stessi dati) = 8.

Potete usare un riferimento a una cella o a un intervallo di celle per ciascun argomento presente nella formula. L'esempio seguente mostra il suo funzionamento. Mostra, inoltre, l'uso delle diciture di colonna per specificare una matrice.

=AGGREGA(E3;E5;'ColonnaUno')
Se E3 = 13 e E5 = 5, la funzione restituisce il modo della prima colonna = 10.

Sosteneteci!