Servizio ScriptForge.Array

Fornisce una raccolta di metodi per manipolare e trasformare matrici a una dimensione (vettori) e a due dimensioni (matrici). Questi comprendono: operazioni di inserimento, ordinamento, importazione da ed esportazione in file di testo.

Le matrici con più di due dimensioni non possono essere usate con i metodi di questo servizio, con l'unica eccezione del metodo CountDims che accetta matrici con qualsiasi numero di dimensioni.

Gli elementi delle matrici possono contenere qualsiasi tipo di valore, comprese matrici nidificate.

Invocazione del servizio

Prima di usare il servizio Array è necessario caricare le librerie ScriptForge usando:

    GlobalScope.BasicLibraries.loadLibrary("ScriptForge")
  

Il caricamento della libreria creerà l'oggetto SF_Array che può essere usato per chiamare i metodi del servizio Array.

I seguenti frammenti di codice mostrano diversi modi per richiamare i metodi del servizio Array (il metodo Append è usato come esempio):

    Dim arr : arr = Array(1, 2, 3)
    arr = SF_Array.Append(arr, 4)
  

    Dim arr : arr = Array(1, 2, 3)
    Dim svc : svc = SF_Array
    arr = svc.Append(arr, 4)
  

    Dim arr : arr = Array(1, 2, 3)
    Dim svc : svc = CreateScriptService("Array")
    arr = svc.Append(arr, 4)
  

Dato che Python è dotato del supporto integrato delle liste e delle tuple, la maggior parte dei metodi del servizio Array è disponibile solamente per gli script in Basic. L'unica eccezione è ImportFromCSVFile che è supportato sia in Basic, sia in Python.

Il primo argomento della maggior parte dei metodi è l'oggetto matrice da considerare. Viene passato sempre per riferimento e rimane inalterato. I metodi come Append, Prepend, ecc. dopo la loro esecuzione restituiscono una nuova matrice.

Append

Aggiunge gli elementi elencati negli argomenti alla fine della matrice di partenza.

svc.Append(array_1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]

array_1d : la matrice preesistente, che può essere vuota.

arg0, arg1, ...: gli elementi che saranno aggiunti ad array_1d.

    Dim a As Variant
    a = SF_Array.Append(Array(1, 2, 3), 4, 5)
        ' (1, 2, 3, 4, 5)
  

AppendColumn

Aggiunge una nuova colonna alla destra di una matrice bidimensionale. La matrice che ne risulta ha gli stessi limiti inferiori della matrice bidimensionale iniziale.

svc.AppendColumn(array_2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]

array_2d: la matrice preesistente, che può essere vuota. Se la matrice ha una sola dimensione, viene considerata come prima colonna della matrice bidimensionale risultante.

column: una matrice unidimensionale con tanti elementi quante sono le righe in array_2d.

    Dim a As Variant, b As variant
    a = SF_Array.AppendColumn(Array(1, 2, 3), Array(4, 5, 6))
        ' ((1, 4), (2, 5), (3, 6))
    b = SF_Array.AppendColumn(a, Array(7, 8, 9))
        ' ((1, 4, 7), (2, 5, 8), (3, 6, 9))
    c = SF_Array.AppendColumn(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
  

AppendRow

Aggiunge un nuova riga in fondo a una matrice bidimensionale. La matrice che ne risulta ha gli stessi limiti inferiori della matrice bidimensionale iniziale.

svc.AppendRow(array_2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*])

array_2d: la matrice preesistente, che può essere vuota. Se la matrice è unidimensionale, viene considerata la prima riga della matrice bidimensionale risultante.

row: una matrice unidimensionale contenente tanti elementi quante sono le colonne in array_2d.

    Dim a As Variant, b As variant
    a = SF_Array.AppendRow(Array(1, 2, 3), Array(4, 5, 6))
        '  ((1, 2, 3), (4, 5, 6))
    b = SF_Array..AppendRow(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
  

Contains

Controlla se una matrice unidimensionale contiene un determinato numero, testo o data. La comparazione del testo può essere soggetta a distinzione tra maiuscole e minuscole oppure no.
Le matrici ordinate di partenza devono essere riempite in modo omogeneo, ciò significa che tutti gli elementi devono essere scalari dello stesso tipo (i valori Empty e Null sono vietati).
Il risultato del metodo non è prevedibile se una matrice viene passata come ordinata, ma in realtà non lo è.
Se la matrice è ordinata viene effettuata una ricerca di tipo binario, altrimenti viene semplicemente controllata da cima a fondo e i valori Empty e Null vengono ignorati.

svc.Contains(array_1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ""): bool

array_1d: la matrice da controllare.

tofind: un numero, una data o una stringa da cercare.

casesensitive: solo per il confronto di stringhe (predefinito = False).

sortorder: può essere una delle stringhe "ASC", "DESC" o "" (non ordinato). Il valore predefinito è "".

    Dim a As Variant
    a = SF_Array.Contains(Array("A","B","c","D"), "C", SortOrder := "ASC") ' True
    SF_Array.Contains(Array("A","B","c","D"), "C", CaseSensitive := True) ' False
  

ConvertToDictionary

Memorizza il contenuto di una matrice bidimensionale in un oggetto ScriptForge.Dictionary.
La chiave sarà estratta dalla prima colonna e l'elemento dalla seconda.

svc.ConvertToDictionary(array_2d: any[0..*, 0..1]): obj

array_2d: i dati da convertire in un oggetto ScriptForge.Dictionary.

• La prima colonna deve contenere esclusivamente stringhe con lunghezza maggiore di zero, in qualunque ordine. Nel dizionario questi valori saranno usati come etichette.

• La seconda colonna contiene i dati da associare all'etichetta corrispondente nel dizionario.

    Dim a As Variant, b As Variant
    a = SF_Array.AppendColumn(Array("a", "b", "c"), Array(1, 2, 3))
    b = SF_Array.ConvertToDictionary(a)
    MsgBox b.Item("c") ' 3
  

Copy

Crea la copia di una matrice 1D o 2D.

svc.Copy(array_nd: any[0..*]): any[0..*]

svc.Copy(array_nd: any[0..*, 0..*]): any[0..*, 0..*]

array_nd: la matrice 1D o 2D da copiare.

Una semplice assegnazione di un oggetto Array copierà il suo riferimento invece di creare una copia dei contenuti dell'oggetto. Osservate l'esempio seguente:

    Dim a as Variant, b as Variant
    a = Array(1, 2, 3)
    ' L'assegnazione sottostante è fatta per riferimento
    b = a
    ' Perciò modificando i valori in "b" si modificano anche in "a"
    b(0) = 10
    MsgBox a(0) ' 10
  

Usando il metodo Copy, viene effettuata la copia dell'intero oggetto Array. Nell'esempio seguente, a e b sono oggetti differenti e la modifica dei valori in b non ha effetto sui valori in a.

    Dim a as Variant, b as Variant
    a = Array(1, 2, 3)
    ' Crea una copia di "a" usando il metodo "Copy"
    b = SF_Array.Copy(a)
    b(0) = 10
    MsgBox a(0) ' 1
  

CountDims

Conta il numero di dimensioni di una matrice. Il risultato può essere maggiore di due.
Se l'argomento non è una matrice restituisce -1
Se la matrice non è inizializzata, restituisce 0.

svc.CountDims(array_nd: any): int

array_nd: la matrice da esaminare.

    Dim a(1 To 10, -3 To 12, 5)
    MsgBox SF_Array.CountDims(a) ' 3
  

Difference

Costruisce un insieme, in forma di matrice con indice iniziale zero, applicando l'operatore della differenza ai valori delle due matrici di partenza. Gli elementi risultanti derivano dalla prima matrice e non dalla seconda.
La matrice risultante è ordinata in modo crescente.
Entrambe le matrici di partenza devono essere riempite in modo omogeneo, i loro elementi devono essere scalari dello stesso tipo. Sono proibiti gli elementi Empty e Null.
Il confronto del testo può distinguere tra maiuscole e minuscole.

svc.Difference(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

array1_1d: una matrice unidimensionale di riferimento, i cui elementi sono esaminati per la rimozione.

array2_1d: una matrice unidimensionale, i cui elementi vengono rimossi dalla matrice passata come primo argomento.

casesensitive: questo argomento è applicabile solamente alle matrici popolate da stringhe (predefinito = False).

    Dim a As Variant
    a = SF_Array.Difference(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
        ' ("A", "B")
  

ExportToTextFile

Scrivete in sequenza tutti gli elementi della matrice in un file di testo. Se il file esiste già, viene sovrascritto senza alcun avvertimento.

svc.ExportToTextFile(array_1d: any[0..*], filename: str, [encoding: str]): bool

array_1d: la matrice da esportare. Deve contenere solamente stringhe.

filename: il nome del file di testo in cui scrivere i dati. Il nome deve essere espresso in conformità alla proprietà FileNaming corrente del servizio SF_FileSystem.

Encoding: il set di caratteri da usare. Usate uno dei nomi presente nell'elenco set di caratteri IANA. Fate attenzione che LibreOffice potrebbe non implementare tutti i set di caratteri esistenti (il predefinito è "UTF-8").

    SF_Array.ExportToTextFile(Array("A","B","C","D"), "C:\Temp\A short file.txt")
  

ExtractColumn

Estrae una determinata colonna da una matrice bidimensionale memorizzandola in una nuova matrice.
I suoi limiti inferiore LBound e superiore UBound sono identici a quelli della prima dimensione della matrice di partenza.

svc.ExtractColumn(array_2d: any[0..*, 0..*], columnindex: int): any[0..*, 0..*]

array_2d: la matrice da cui eseguire l'estrazione.

columnindex: il numero della colonna da estrarre - dev'essere compreso nell'intervallo [LBound, UBound].

    'Crea una matrice 3x3: |1, 2, 3|
    '                      |4, 5, 6|
    '                      |7, 8, 9|
    Dim mat as Variant, col as Variant
    mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
    mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
    mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
    'Estrae la terza colonna: |3, 6, 9|
    col = SF_Array.ExtractColumn(mat, 2)
  

ExtractRow

Estrae una determinata riga da una matrice bidimensionale memorizzandola in una nuova matrice.
I suoi limiti inferiore LBound e superiore UBound sono identici a quelli della seconda dimensione della matrice di partenza.

svc.ExtractRow(array_2d: any[0..*, 0..*], rowindex: int): any[0..*, 0..*]

array_2d: la matrice da cui eseguire l'estrazione.

rowindex: il numero della riga da estrarre - deve essere compreso nell'intervallo [LBound, UBound].

    'Crea una matrice 3x3: |1, 2, 3|
    '                      |4, 5, 6|
    '                      |7, 8, 9|
    Dim mat as Variant, row as Variant
    mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
    mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
    mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
    'Estrae la prima riga: |1, 2, 3|
    row = SF_Array.ExtractRow(mat, 0)
  

Flatten

Accoda tutti i singoli elementi di una matrice e tutti gli elementi delle matrici nidificate in un'unica nuova matrice priva di matrici nidificate. Le matrici nidificate vuote vengono ignorate, mentre quelle che hanno un numero di dimensioni maggiore di uno non vengono appiattite.

svc.Flatten(array_1d: any[0..*]): any[0..*]

array_1d: la matrice preesistente, che può essere vuota.

    Dim a As Variant
    a = SF_Array.Flatten(Array(Array(1, 2, 3), 4, 5))
        ' (1, 2, 3, 4, 5)
  

Potete usare il metodo Flatten assieme ad altri metodi come Append o Prepend in modo da concatenare un insieme di matrici 1D in una singola matrice 1D.

Quello che segue è un esempio di come i due metodi Flatten e Append possono essere combinati per concatenare tre matrici.

    'Crea le tre matrici usate in questo esempio
    Dim a as Variant, b as Variant, c as Variant
    a = Array(1, 2, 3)
    b = Array(4, 5)
    c = Array(6, 7, 8, 9)
    'Concatena le tre matrici in una singola matrice 1D
    Dim arr as Variant
    arr = SF_Array.Flatten(SF_Array.Append(a, b, c))
    '(1, 2, 3, 4, 5, 6, 7, 8, 9)
  

ImportFromCSVFile

Importa i dati contenuti in un file CSV (valori separati da virgole). La virgola può essere sostituita con qualsiasi altro carattere.

Il formato CSV utilizzabile è descritto in Formati comuni IETF e tipi MIME per i file CSV (in inglese).

Ciascuna riga del file contiene un record intero (non è ammessa l'interruzione delle righe).
In ogni caso sequenze come \n, \t, ... non vengono modificate. Per gestirle usate il metodo SF_String.Unescape().

Il metodo restituisce una matrice bidimensionale le cui righe corrispondono a un singolo record letto dal file e le cui colonne corrispondono a un campo del record. Non effettua controlli in merito alla coerenza dei tipi di campo nelle colonne. Una presunzione migliore verrà fatta nell'identificazione dei tipi numerici e delle date.

Se una riga contiene un numero minore o maggiore di campi rispetto alla prima riga del file, si genera un'eccezione. In ogni caso le righe vuote saranno semplicemente ignorate. Se la dimensione del file eccede il numero limite di elementi (vedete all'interno del codice), viene sollevata un'eccezione e la matrice viene troncata.

svc.ImportFromCSVFile(filename: str, delimiter: str = ',', dateformat: str = ''): any[0..*]

filename: il nome del file di testo contenente i dati. Il nome deve essere espresso in conformità alla proprietà FileNaming corrente del servizio SF_FileSystem.

delimiter: un singolo carattere, di solito una virgola, un punto e virgola o un carattere di tabulazione (predefinito = ",").

dateformat: un meccanismo speciale gestisce le date quando dateformat è in uno dei formati "AAAA-MM-GG", "GG-MM-AAAA" o "MM-GG-AAAA". Il trattino (-) può essere sostituito con un punto (.), una barra (/) o uno spazio. Gli altri formati di data saranno ignorati. Le date che per impostazione predefinita sono "" vengono considerate testo normale.

Considerate il file CSV "myFile.csv" con i seguenti contenuti:

Nome,DataDiNascita,Indirizzo,Città

Anna,31/03/2002,"Via della chiesa, 21",Tolosa

Fred,04/05/1998,"Via Albert Einstein, 113A",Carcassonne

L'esempio sottostante in Basic e Python legge il contenuto del file CSV e lo memorizza in un oggetto Array.

    Dim arr As Variant
    arr = SF_Array.ImportFromCSVFile("C:\Temp\myFile.csv", DateFormat := "DD/MM/YYYY")
    MsgBox arr(0, 3) ' Città
    MsgBox arr(1, 2) ' Via della chiesa, 21
    MsgBox arr(1, 3) ' Tolosa
  

    from scriptforge import CreateScriptService
    svc = CreateScriptService("Array")
    bas = CreateScriptService("Basic")
    arr = svc.ImportFromCSVFile(r"C:\Temp\myFile.csv", dateformat = "DD/MM/YYYY")
    bas.MsgBox(arr[0][3]) # Città
    bas.MsgBox(arr[1][2]) # Via della chiesa, 21
    bas.MsgBox(arr[1][3]) # Tolosa
  

IndexOf

Cerca un numero, una stringa o una data all'interno di una matrice unidimensionale. Il confronto del testo può distinguere tra maiuscole e minuscole.
Se la matrice è ordinata deve essere riempita in modo omogeneo, ciò significa che tutti gli elementi devono essere scalari dello stesso tipo (i valori Empty e Null non sono ammessi).
Il risultato del metodo non è prevedibile se una matrice viene passata come ordinata, ma in realtà non lo è.
Se la matrice è ordinata viene eseguita una ricerca di tipo binario, altrimenti viene semplicemente controllata da cima a fondo e i valori Empty e Null vengono ignorati.

Se la ricerca è stata infruttuosa, il metodo restituisce LBound(matrice di partenza) - 1.

svc.IndexOf(array_1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ''): int

array_1d: la matrice da controllare.

tofind: un numero, una data o una stringa da cercare.

casesensitive: solo per il confronto di stringhe (predefinito = False).

sortorder: può essere una delle stringhe "ASC", "DESC" o "" (non ordinato). Il valore predefinito è "".

    MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", SortOrder := "ASC") ' 2
    MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", CaseSensitive := True) ' -1
  

Insert

Inserisce, prima di un determinato indice della matrice di partenza, tutti gli elementi elencati negli argomenti.
Gli argomenti vengono inseriti alla cieca. Ciascuno di essi dev'essere uno scalare di qualsiasi tipo o una matrice da nidificare.

svc.Insert(array_1d: any[0..*], before: int, arg0: any, [arg1: any] ...): any[0..*]

array_1d: la matrice preesistente, che può essere vuota.

before: l'indice prima del quale deve avvenire l'inserimento; dev'essere compreso nell'intervallo [LBound, UBound + 1].

arg0, arg1, ...: gli elementi da inserire in array_1d.

    Dim a As Variant
    a = SF_Array.Insert(Array(1, 2, 3), 2, "a", "b")
        ' (1, 2, "a", "b", 3)
  

InsertSorted

Inserisce un nuovo elemento nel posto corretto di una matrice ordinata.
La matrice deve essere riempita in modo omogeneo, ciò significa che tutti gli elementi devono essere scalari dello stesso tipo.
Gli elementi Empty e Null non sono ammessi.

svc.InsertSorted(array_1d: any[0..*], item: any, sortorder: str = 'ASC', casesensitive: bool = False): any[0..*]

array_1d: la matrice in cui il valore deve essere inserito.

item: il valore scalare da inserire, dello stesso tipo degli elementi già presenti nella matrice.

sortorder: può essere uno tra "ASC" (predefinito) o "DESC".

casesensitive: solo per il confronto di stringhe (predefinito = False).

    Dim a As Variant
    a = SF_Array.InsertSorted(Array("A", "C", "a", "b"), "B", CaseSensitive := True)
        ' ("A", "B", "C", "a", "b")
  

Intersection

Costruisce un insieme, in forma di matrice con indice iniziale zero, applicando alle due matrici l'operatore di intersezione degli insiemi. Gli elementi risultanti sono quelli presenti in entrambe le matrici.
La matrice risultante è ordinata in modo crescente.
Entrambe le matrici di partenza devono essere riempite in modo omogeneo, in altre parole, tutti i loro elementi devono essere scalari dello stesso tipo. Sono proibiti gli elementi Empty e Null.
Il confronto del testo può distinguere tra maiuscole e minuscole.

svc.Intersection(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

array1_1d: la prima matrice di partenza.

array2_1d: la seconda matrice di partenza.

casesensitive: si applica alle matrici popolate da elementi di testo (valore predefinito = False).

    Dim a As Variant
    a = SF_Array.Intersection(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
        ' ("C", "b")
  

Join2D

Unisce una matrice bidimensionale con due delimitatori, uno per le colonne e uno per le righe.

svc.Join2D(array_2d: any [0..*, 0..*], [columndelimiter: str], [rowdelimiter: str], [quote: str]): str

array_2d: ogni elemento deve essere un testo, un numero, una data o un valore logico (booleano).
Le date sono convertite nel formato AAAA-MM-GG hh:mm:ss.
Gli elementi non validi sono sostituiti da stringhe vuote di lunghezza zero.

columndelimiter: delimita ciascuna colonna (predefinito = Tab/Chr(9)).

rowdelimiter: delimita ciascuna riga (predefinito = LineFeed/Chr(10))

quote: se True, protegge le stringhe racchiuse tra virgolette. Il valore predefinito è False.

    ' arr = | 1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5           |
    '       | 6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10 |
    Dim arr as Variant : arr = Array()
    arr = SF_Array.AppendRow(arr, Array(1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5))
    arr = SF_Array.AppendRow(arr, Array(6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10))
    Dim arrText as String
    arrText = SF_Array.Join2D(arr, ",", "/", False)
    ' 1,2,A,,51,2,A,,5/6,7,this is a string,9,106,7,this is a string,9,10
  

Prepend

Aggiunge, all'inizio della matrice di partenza, gli elementi elencati negli argomenti.

svc.Prepend(array_1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]

array_1d: la matrice preesistente, che può essere vuota.

arg0, arg1, ...: l'elenco degli elementi da aggiungere all'inizio di array_1d.

    Dim a As Variant
    a = SF_Array.Prepend(Array(1, 2, 3), 4, 5)
        ' (4, 5, 1, 2, 3)
  

PrependColumn

Inserisce una nuova colonna alla sinistra di una matrice bidimensionale. La matrice risultante ha gli stessi limiti inferiori della matrice bidimensionale di partenza.

svc.PrependColumn(array_2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]

array_2d: la matrice preesistente, che può essere vuota. Se la matrice ha una dimensione, viene considerata come ultima colonna della risultante matrice bidimensionale.

column: una matrice unidimensionale con tanti elementi quante sono le righe in array_2d.

    Dim a As Variant, b As variant
    a = SF_Array.PrependColumn(Array(1, 2, 3), Array(4, 5, 6))
        ' ((4, 1), (5, 2), (6, 3))
    b = SF_Array.PrependColumn(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
  

PrependRow

Inserisce una nuova riga all'inizio di una matrice bidimensionale. La matrice risultante ha gli stessi limiti inferiori della matrice bidimensionale di partenza.

svc.PrependRow(array_2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*]

array_2d: la matrice preesistente, che può essere vuota. Se la matrice ha una dimensione, viene considerata come ultima riga della risultante matrice bidimensionale.

row: una matrice unidimensionale contenente tanti elementi quante sono le colonne in array_2d.

    Dim a As Variant, b As variant
    a = SF_Array.PrependRow(Array(1, 2, 3), Array(4, 5, 6))
        ' ((4, 5, 6), (1, 2, 3))
    b = SF_Array.PrependRow(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
  

RangeInit

Inizializza con valori numerici una nuova matrice avente base zero.

svc.RangeInit(from: num, upto: num, [bystep: num]): num[0..*]

from: valore del primo elemento.

upto: l'ultimo elemento non può eccedere upto.

bystep: la differenza tra due elementi successivi (predefinito = 1).

    Dim a As Variant
    a = SF_Array.RangeInit(10, 1, -1)
        ' (10, 9, 8, 7, 6, 5, 4, 3, 2, 1)
  

Reverse

Restituisce la matrice unidimensionale invertita di quella iniziale.

svc.Reverse(array_1d: any[0..*]): any[0..*]

array_1d: la matrice da invertire.

    Dim a As Variant
    a = SF_Array.Reverse(Array("a", 2, 3, 4))
        ' (4, 3, 2, "a")
  

Shuffle

Restituisce una permutazione casuale di una matrice unidimensionale.

svc.Shuffle(array_1d: any[0..*]): any[0..*]

array_1d: la matrice da mescolare.

    Dim a As Variant
    a = SF_Array.Shuffle(Array(1, 2, 3, 4))
        ' ora la matrice "a" è in ordine casuale, ad es. (2, 3, 1, 4)
  

Slice

Restituisce un sottoinsieme di una matrice unidimensionale.

svc.Slice(array_1d: any[0..*], from: int, [upto: int]): any[0..*]

array_1d: la matrice da cui estrarre una parte.

from: l'indice più basso di array_1d da cui inizia la sottomatrice da estrarre (from compreso)

upto: l'indice più alto di array_1d in cui finisce la sottomatrice da estrarre (upto compreso). Il valore predefinito è il limite superiore di array_1d. Se upto < from allora la matrice restituita è vuota.

    Dim a As Variant
    a = SF_Array.Slice(Array(1, 2, 3, 4, 5), 1, 3) ' (2, 3, 4)
  

Sort

Ordina una matrice unidimensionale in modo ascendente o discendente. Il confronto di testi può distinguere tra maiuscole e minuscole.
La matrice deve essere riempita in modo omogeneo, ciò significa che gli elementi devono essere scalari dello stesso tipo.
Gli elementi Empty e Null sono ammessi. Convenzionalmente Empty < Null < qualunque altro valore scalare.

svc.Sort(array_1d: any[0..*], sortorder: str, casesensitive: bool = False): any[0..*]

array_1d: la matrice da ordinare.

sortorder: può essere uno tra "ASC" (predefinito) o "DESC".

casesensitive: solo per il confronto di stringhe (predefinito = False).

    Dim a As Variant
    a = SF_Array.Sort(Array("a", "A", "b", "B", "C"), CaseSensitive := True)
        ' ("A", "B", "C", "a", "b")
  

SortColumns

Restituisce la permutazione delle colonne di una matrice bidimensionale, ordinata in base ai valori di una determinata riga.
La riga dev'essere riempita in modo omogeneo, il che significa che tutti gli elementi devono essere scalari dello stesso tipo. Gli
Elementi Empty e Null sono ammessi. Convenzionalmente Empty < Null < qualunque altro valore scalare.

svc.SortColumns(array_2d: any[0..*, 0..*], rowindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]

array_2d: la matrice bidimensionale da ordinare.

rowindex: l'indice della riga che sarà usata come riferimento per ordinare le colonne.

sortorder: può essere uno tra "ASC" (predefinito) o "DESC".

casesensitive: solo per il confronto di stringhe (predefinito = False).

    ' arr = | 5, 7, 3 |
    '       | 1, 9, 5 |
    '       | 6, 1, 8 |
    Dim arr as Variant : arr = Array(5, 7, 3)
    arr = SF_Array.AppendRow(arr, Array(1, 9, 5))
    arr = SF_Array.AppendRow(arr, Array(6, 1, 8))
    arr = SF_Array.SortColumns(arr, 2, "ASC")
    ' arr = | 7, 5, 3 |
    '       | 9, 1, 5 |
    '       | 1, 6, 8 |
  

SortRows

Restituisce una permutazione delle righe di una matrice bidimensionale, ordinata in base ai valori di una determinata colonna.
La colonna deve essere riempita in modo omogeneo, perciò tutti gli elementi devono essere scalari dello stesso tipo. Gli
Elementi Empty e Null sono ammessi. Convenzionalmente Empty < Null < qualunque altro valore scalare.

svc.SortRows(array_2d: any[0..*, 0..*], columnindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]

array_2d: la matrice da ordinare.

columnindex: l'indice della colonna che sarà usata come riferimento per ordinare le righe.

sortorder: può essere uno tra "ASC" (predefinito) o "DESC".

casesensitive: solo per il confronto di stringhe (predefinito = False).

    ' arr = | 5, 7, 3 |
    '       | 1, 9, 5 |
    '       | 6, 1, 8 |
    Dim arr as Variant : arr = Array(5, 7, 3)
    arr = SF_Array.AppendRow(arr, Array(1, 9, 5))
    arr = SF_Array.AppendRow(arr, Array(6, 1, 8))
    arr = SF_Array.SortRows(arr, 0, "ASC")
    ' arr = | 1, 9, 5 |
    '       | 5, 7, 3 |
    '       | 6, 1, 8 |
  

Transpose

Inverte righe e colonne di una matrice bidimensionale.

svc.Transpose(array_2d: any[0..*, 0..*]): any[0..*, 0..*]

array_2d: la matrice bidimensionale da trasporre.

    ' arr1 = | 1, 2 |
    '        | 3, 4 |
    '        | 5, 6 |
    arr1 = Array(1, 2)
    arr1 = SF_Array.AppendRow(arr1, Array(3, 4))
    arr1 = SF_Array.AppendRow(arr1, Array(5, 6))
    arr2 = SF_Array.Transpose(arr1)
    ' arr2 = | 1, 3, 5 |
    '        | 2, 4, 6 |
    MsgBox arr2(0, 2) ' 5
  

TrimArray

Rimuove da una matrice unidimensionale tutti gli elementi Null, Empty e di lunghezza zero.
Agli elementi di tipo stringa vengono rimossi gli spazi con la funzione Trim() di LibreOffice Basic.

svc.TrimArray(array_1d: any[0..*]): any[0..*]

array_1d: la matrice da cui rimuovere gli spazi iniziali e finali.

    Dim a As Variant
    a = SF_Array.TrimArray(Array("A", "B", Null, " D "))
        ' ("A", "B", "D")
  

Union

Costruisce un insieme, in forma di matrice con indice iniziale zero, applicando alle due matrici iniziali l'operatore di unione degli insiemi. Gli elementi risultanti provengono da entrambe le matrici.
La matrice risultante è ordinata in modo crescente.
Entrambe le matrici di partenza devono essere riempite in modo omogeneo, i loro elementi devono essere scalari dello stesso tipo. Gli elementi Empty e Null non sono ammessi.
Il confronto del testo può distinguere o meno tra maiuscole e minuscole.

svc.Union(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

array1_1d: la prima matrice di partenza.

array2_1d: la seconda matrice di partenza.

casesensitive: applicabile solo alle matrici popolate da stringhe (predefinito = False).

    Dim a As Variant
    a = SF_Array.Union(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
        ' ("A", "B", "C", "Z", "b")
  

Unique

Costruisce un insieme di valori univoci derivati dalla matrice di partenza.
La matrice iniziale deve essere riempita in modo omogeneo, i suoi elementi devono essere scalari dello stesso tipo. Gli elementi Empty e Null non sono ammessi.
Il confronto del testo può distinguere tra maiuscole e minuscole.

svc.Unique(array_1d: any[0..*], casesensitive: bool = False): any[0..*]

array_1d: la matrice di partenza.

casesensitive: applicabile solo se la matrice è popolata da stringhe (predefinito = False).

    Dim a As Variant
    a = SF_Array.Unique(Array("A", "C", "A", "b", "B"), CaseSensitive := True)
        '  ("A", "B", "C", "b")
  

Tutte le routine e gli identificatori Basic di ScriptForge che iniziano con un carattere di sottolineatura "_" sono riservati per uso interno. Non è previsto il loro utilizzo nelle macro in Basic o negli script in Python.