SUMIFS

Mengembalikan jumlah nilai sel dalam rentang yang memenuhi beberapa kriteria dalam beberapa rentang.

Fungsi ini tersedia sejak LibreOffice 4.0.

Sintaksis

SUMIFS(Func_Range; Range1; Criterion1[; Range2; Criterion2][; … ; [Range127; Criterion127]])

Func_Range – memerlukan argumen. Ini merupakan rentang sel, nama sebuah rentang yang dinamai atau label sebah kolom atau baris berisi nila untuk dihitung jumlahnya.

Range1 – required argument. It is a range of cells, a name of a named range, or a label of a column or a row, to which the corresponding criterion is to be applied.

Criterion1: A criterion is a text expression computed from a single cell Reference, Formula, Number or Text. It is used in comparisons with cell contents.

A reference to an empty cell is interpreted as the numeric value 0.

A matching expression can be:

A number or logical value. A matching cell content equals the number or logical value.
A value beginning with a comparator (<, <=, =, >, >=, <>).

For =, if the value is empty it matches empty cells.

For <>, if the value is empty it matches non-empty cells.

For <>, if the value is not empty it matches any cell content except the value, including empty cells.

Note: "=0" does not match empty cells.

For = and <>, if the value is not empty and can not be interpreted as a number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.
Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Range2 - Opsional. Range2 dan semua yang berikut memiliki arti yang sama dengan Range1.

Criterion2 – Optional. Criterion2 and all the following mean the same as Criterion.

Pencarian mendukung wildcard atau ekspresi reguler. Dengan memfungsikan ekspresi reguler, Anda dapat memasukkan "all.*", misalnya untuk menemukan lokasi pertama "all" diikuti oleh karakter apa pun. Jika Anda ingin mencari teks yang juga merupakan ekspresi reguler, Anda harus mengawali setiap karakter meta atau operator ekspresi reguler dengan karakter "\", atau mengapit teks di dalam \Q...\E. Anda dapat mengaktifkan dan menonaktifkan evaluasi otomatis karakter pengganti atau ekspresi reguler di - LibreOffice Calc - Hitung.

Saat menggunakan fungsi yang satu atau lebih argumennya berupa string kriteria pencarian yang merepresentasikan ekspresi reguler, upaya pertama adalah mengonversi kriteria string tersebut menjadi angka. Misalnya, ".0" akan dikonversi menjadi 0.0, dan seterusnya. Jika berhasil, kecocokannya bukan kecocokan ekspresi reguler, melainkan kecocokan numerik. Namun, ketika beralih ke lokal di mana pemisah desimalnya bukan titik, konversi ekspresi reguler akan berfungsi. Untuk memaksa evaluasi ekspresi reguler, alih-alih ekspresi numerik, gunakan ekspresi yang tidak dapat salah dibaca sebagai numerik, seperti ".[0]" atau ".\0", atau "(?i).0".

Func_Range dan Range1, Range2 ... harus memiliki ukuran yang sama, jika tidak fungsi mengembalikan err: 502 - Argumen tidak valid.

Hubungan logis antara kriteria dapat didefinisikan sebagai logika AND (kata hubung). Dengan kata lain, jika dan hanya jika semua kriteria yang diberikan terpenuhi, nilai dari sel yang sesuai dari Func_Range yang diberikan diperhitungkan.

Fungsi ini dapat memiliki hingga 255 argumen, artinya Anda dapat menentukan 127 rentang kriteria dan kriteria untuknya.

Jika sel berisi TRUE, itu diperlakukan sebagai 1, jika sel berisi FALSE - sebagai 0 (nol).

Fungsi ini adalah bagian dari Open Document Format untuk Aplikasi Perkantoran (OpenDocument) Versi 1.2. (ISO/IEC 26300:2-2015)

Contoh

Pertimbangkan tabel berikut

	A	B	C
1	Nama Produk	Sales	Revenue
2	pensil	20	65
3	pena	35	85
4	buku catatan	20	190
5	buku	17	180
6	pencil-case	not	not

Dalam semua contoh di bawah ini, rentang untuk perhitungan mengandung baris #6, yang diabaikan karena mengandung teks.

Penggunaan sederhana

-10000

Menghitung jumlah nilai dari rentang B2:B6 yang lebih besar dari atau sama dengan 20. Mengembalikan 75, karena baris kelima tidak memenuhi kriteria.

-10000

Menghitung jumlah nilai dari rentang C2:C6 yang lebih besar dari 70 dan sesuai dengan rentang sel B2:B6 dengan nilai lebih besar dari atau sama dengan 20. Mengembalikan 275, karena baris kedua dan kelima tidak memenuhi setidaknya satu kriteria.

Menggunakan ekspresi reguler dan fungsi bersarang

=SUMIFS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Menghitung jumlah nilai dari rentang C2:C6 yang sesuai pada semua nilai pada rentang B2:B6 kecuali nilai minimum dan maksimulnya. Mengembalikan 255, kecuali baris ketiga dan keempat tidak cocok setidaknya satu kriteria.

=SUMIFS(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Menghitung jumlah nilai rentang C2: C6 yang sesuai dengan semua sel rentang A2: A6 yang dimulai dengan "pena" dan ke semua sel rentang B2: B6 kecuali maksimumnya. Mengembalikan 65, karena hanya baris kedua yang memenuhi semua kriteria.

Referensi ke sel sebagai kriteria

Jika Anda perlu mengubah kriteria dengan mudah, Anda mungkin ingin menentukannya di sel yang terpisah dan menggunakan referensi ke sel ini dalam kondisi fungsi SUMIFS. Misalnya, fungsi di atas dapat ditulis ulang sebagai berikut:

=SUMIFS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Jika E2 = pena, fungsi mengembalikan 65, karena tautan ke sel diganti dengan kontennya.

Buka berkas dengan contoh:

SUMIFS wiki page.

SUM, SUMIF

COUNTIFS, MINIFS, fungsi MAXIFS, AVERAGEIFS, SUMIFS

Daftar Ekspresi Reguler