COUNTIFS

Returns the count of cells that meet criteria in multiple ranges.

This function is available since LibreOffice 4.0.

Syntax

COUNTIFS(Range; Criterion[; Range2; Criterion2][; ... ; [Range127; Criterion127]])

Range1 – required argument. It is a range of cells, a name of a named range, or a label of a column or a row, to which the corresponding criterion is to be applied.

Criterion: A criterion is a single cell Reference, Number or Text. It is used in comparisons with cell contents.

A reference to an empty cell is interpreted as the numeric value 0.

A matching expression can be:

A Number or Logical value. A matching cell content equals the Number or Logical value.
A value beginning with a comparator (<, <=, =, >, >=, <>).

For =, if the value is empty it matches empty cells.

For <>, if the value is empty it matches non-empty cells.

For <>, if the value is not empty it matches any cell content except the value, including empty cells.

Note: "=0" does not match empty cells.

For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.
Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Range2 – Optional. Range2 and all the following mean the same as Range1.

Criterion2 – Optional. Criterion2 and all the following mean the same as Criterion.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

Range, Range2, ... and Criterion, Criterion2, ... must have the same size, otherwise the function returns err:502 - Invalid argument.

The logical relation between criteria can be defined as logical AND (conjunction). In other words, if and only if all given criteria are met, a value from the corresponding cell of the given Func_Range is taken into calculation.

The function can have up to 255 arguments, meaning that you can specify 127 criteria ranges and criteria for them.

If a cell contains TRUE, it is treated as 1, if a cell contains FALSE – as 0 (zero).

Ez a függvény az Open Document Format for Office Applications (OpenDocument) szabvány 1.2-es verziójának része. (ISO/IEC 26300:2-2015)

Example

Figyelje meg a következő táblázatot

	A	B	C
1	Termék neve	Eladások	Bevétel
2	tollbetét	20	65
3	toll	35	85
4	jegyzőkönyv	20	190
5	könyv	17	180
6	tolltartó	nem	nem

In all examples below, ranges for calculation contain the row #6, which is ignored because it contains text.

Egyszerű használat

=DARABHATÖBB(B2:B6;">=20")

Megszámolja a B2:B6 tartomány azon sorait, amelyek nagyobbak, vagy egyenlőek 20-szal. A visszaadott érték 3, mert az 5. és 6. sor nem teljesíti a feltételt.

=DARABHATÖBB(B2:B6;">=20";C2:C6;">70")

Megszámolja azon sorokat, amelyek a C2:C6 tartományban nagyobbak vagy egyelőek 70-nel, és a B2:B6 tartományban nagyobbak, vagy egyenlőek 20-szal. A visszaadott érték 2, mert a 2., 5. és 6. sorok nem teljesítik legalább az egyik feltételt.

Reguláris kifejezések és beágyazott függvények használata

For these examples to work as described, make sure that Enable regular expressions in formulas is selected in - LibreOffice Calc - Calculate.

=DARABHATÖBB(B2:B6;"[:alpha:]*")

Megszámolja a B2:B6 tartomány azon sorait, amelyek csak betűket tartalmaznak. A visszaadott érték 1, mert csak a 6. sor teljesíti a feltételt.

=DARABHATÖBB(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Megszámolja a B2:B6 tartomány azon sorait, amelyek nem a maximális vagy minimális értéket tartalmazzák. A visszaadott érték 2, mert a 3., 5. és 6. sor nem teljesíti legalább az egyik feltételt.

=DARABHATÖBB(A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Megszámolja azok sorok számát, amelyek megfelelnek az A2:A6 tartomány "toll" kezdetű celláinak, és a B2:B6 tartomány összes cellájának a maximum kivételével. A visszatérési értéke 1, mert csak a második sor teljesíti az összes feltételt.

Hivatkozás cellára feltételként

Ha egyszerűen szeretne feltételt módosítani, akkor érdemes egy külön cellában megadni, és erre a cellára mutató hivatkozást használni a DARABHATÖBB függvény feltételében. A fenti függvény például átírható a következőképpen:

=DARABHATÖBB(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

Ha E2 = toll, akkor a függvény az 1 értéket adja vissza, mert a cellahivatkozás az értékével lesz helyettesítve, és a fenti függvényként működik.

Open file with example:

COUNT, COUNTIF, COUNTBLANK, COUNTA

COUNTIFS, MINIFS, MAXIFS, ÁTLAGHATÖBB, SUMIFS

Reguláris kifejezések listája