ScriptForge.Dictionary service

A dictionary is a collection of key-item pairs

• The key is a case-insensitive string

• Items may be of any type

Keys and items can be retrieved, counted, updated, and much more.

A Szótár szolgáltatás hasonló a beépített LibreOffice Basic Collection objektumhoz, azonban több funkcióval rendelkezik. Például a Collection objektumok nem támogatják a kulcsok lekérdezését. Ezen túlmenően a szótárak olyan további képességekkel rendelkeznek, mint a kulcsok cseréje, annak vizsgálata, hogy egy adott kulcs már létezik-e, valamint a szótár átalakítása tömbobjektummá vagy JSON-stringgé.

A szolgáltatás igénybevétele

The following example creates myDict as an empty dictionary.

    GlobalScope.BasicLibraries.loadLibrary("ScriptForge")
    Dim myDict As Variant
    myDict = CreateScriptService("Dictionary")
  

It is recommended to free resources after use:

     Set myDict = myDict.Dispose()
  

The example below creates an empty instance of the Dictionary service and uses the Python native update method to populate it with the contents of a Python dict object.

    dico = dict('A' = 1, 'B' = 2, 'C' = 3)
    # Initialize myDict as an empty dict object
    myDict = CreateScriptService('Dictionary')
    # Load the values of dico into myDict
    myDict.update(dico)
    myDict['D'] = 4
    print(myDict)   # {'A': 1, 'B': 2, 'C': 3, 'D': 4}
    propval = myDict.ConvertToPropertyValues()
  

It is possible to create an instance of the Dictionary service using a Python dict object as argument as shown in the following example.

    dico = dict('A' = 1, 'B' = 2, 'C' = 3)
    # Initialize myDict with the content of dico
    myDict = CreateScriptService('Dictionary', dico)
    myDict['D'] = 4
    print(myDict) # {'A': 1, 'B': 2, 'C': 3, 'D': 4}
    propval = myDict.ConvertToPropertyValues()
  

Mivel a Python beépített szótár-támogatással rendelkezik, a Dictionary szolgáltatás legtöbb metódusa csak Basic parancsfájlok számára érhető el. Kivételt képez a ConvertToPropertyValues és a ImportFromPropertyValues, amelyek Basic és Python nyelven is támogatottak.

Tulajdonságok

The Keys and Items properties return their respective contents, using an identical ordering. The order is unrelated to the creation sequence.

The following example uses the Keys property to iterate over all keys in the dictionary myDict.

    Dim a As Variant, b As String
    a = myDict.Keys
    For Each b In a
        MsgBox(myDict.Item(b))
    Next b
    

Add

Adds a new key-item pair into the dictionary. Returns True if successful.

dict.Add(key: str, item: any): bool

key: String value used to identify the Item. The key is not case-sensitive.

item: Any value, including an array, a Basic object, a UNO object, a dictionary, etc.

      Dim NewValue As Variant
      myDict.Add("NewKey", NewValue)
    

Minden kulcsnak egyedinek kell lennie ugyanabban a szótárban. Ha a kulcs már létezik a szótárban, a rendszer DUPLICATEKEYERROR hibaüzenetet küld. A szóköz karakterekből álló kulcsok INVALIDKEYERROR hibát okoznak.

ConvertToArray

Stores the contents of the dictionary in a two-columns zero-based array. The keys are stored in the first column and the items are stored in the second column.

If the dictionary is empty, this method will return an empty Array.

dict.ConvertToArray(): any[0..*, 0..1]

      Dim myDict as Variant
      myDict = CreateScriptService("Dictionary")
      myDict.Add("a", 1)
      myDict.Add("b", 2)
      myDict.Add("c", 3)
      Dim arr as Variant
      arr = myDict.ConvertToArray()
      '(("a", 1), ("b", 2), ("c", 3))
    

ConvertToJson

Converts the contents of a dictionary to JSON (JavaScript Object Notation) text.

Korlátozások

Ez a módszer a következő adattípusokat támogatja: String, Boolean, számok, Null és Empty. Az ilyen típusú elemeket tartalmazó tömbök is megengedettek, függetlenül azok méretétől. A dátumok karakterláncokká konvertálódnak, azonban nem használhatók tömbökön belül. Az egyéb adattípusok az SF_SF_String.Represent szolgáltatás segítségével karakterlánc megfelelőjükbe konvertálódnak át.

dict.ConvertToJson(indent: str = ""): str

behúzás: Ha a indent egy pozitív szám vagy egy szöveg, a JSON tömbelemek és objektumtagok pretty-printelve lesznek ezzel a behúzási szinttel. A negatív indent érték új sorokat ad be nem húzással. Az alapértelmezett érték egy üres karakterlánc "", amely a legtömörebb ábrázolást választja. A indent pozitív egész számmal történő használata ennyi szóközzel vonja be a sort szintenként. Ha a indent egy karakterlánc, például Chr(9) vagy Tab(1), akkor a Tab karaktert használja az egyes szintek behúzására.

      myDict.Add("p0", 12.5)
      myDict.Add("p1", "a string àé""ê")
      myDict.Add("p2", DateSerial(2020,9,28))
      myDict.Add("p3", True)
      myDict.Add("p4", Array(1,2,3))
      MsgBox myDict.ConvertToJson()    
      '{"p0": 12.5, "p1": "a string \u00e0\u00e9\"\u00ea", "p2": "2020-09-28", "p3": true, "p4": [1, 2, 3]}
    

ConvertToPropertyValues

Stores the contents of the dictionary into an array of PropertyValues.

Each entry in the array is a com.sun.star.beans.PropertyValue. The key is stored in Name, the item is stored in Value.

Ha az egyik elem Date típusú, akkor az egy com.sun.star.util.DateTime struktúrává konvertálódik. Ha az egyik elem üres tömb, akkor Null értékűvé konvertálódik. Az eredményül kapott tömb üres, ha a szótár üres.

dict.ConvertToPropertyValues(): obj[0..*]

    Dim myDict as Variant
    myDict = CreateScriptService("Dictionary")
    'Adds some properties to the dictionary
    myDict.Add("Color", "Blue")
    myDict.Add("Width", 20)
    'Converts to an Array of PropertyValue objects
    Dim prop as Variant
    prop = myDict.ConvertToPropertyValues()
  

Note in the example below that a Python dictionary needs to be passed as the second argument of the CreateScriptService method.

    myDict = dict()
    myDict["Color"] = "Blue"
    myDict["Width"] = 30
    sfDic = CreateScriptService("Dictionary", myDict)
    prop = sfDic.ConvertToPropertyValues()
  

Many services and methods in the UNO library take in parameters represented using the PropertyValue struct, which is part of the LibreOffice API.

Exists

Determines if a key exists in the dictionary.

dict.Exists(key: str): bool

key: The key to be looked up in the dictionary.

    Dim myDict as Variant
    myDict = CreateScriptService("Dictionary")
    'Adds some properties to the dictionary
    myDict.Add("Color", "Blue")
    myDict.Add("Width", 20)
    '(...)
    If Not myDict.Exists("Size") Then
       MsgBox "You have to provide a Size value"
    End If
  

ImportFromJson

Adds the content of a JSON (JavaScript Object Notation) string into the current dictionary. Returns True if successful.

Korlátozások

The JSON string may contain numbers, text, booleans, null values and arrays containing those types. It must not contain JSON objects namely sub-dictionaries.

An attempt is made to convert text to date if the item matches one of these patterns: YYYY-MM-DD, HH:MM:SS or YYYY-MM-DD HH:MM:SS.

dict.ImportFromJson(inputstr: str, overwrite: bool = False): bool

inputstr: The string to import.

overwrite: Ha True, akkor a szótárban létezhetnek azonos nevű bejegyzések, és azok értékei felülíródnak. Ha False (alapértelmezett), az ismétlődő kulcsok hibát fognak okozni. Figyeljünk arra, hogy a szótár kulcsai nem nagy- és kisbetű-érzékenyek, míg a JSON karakterláncokban a nevek nagy- és kisbetű-érzékenyek.

    Dim s As String
    s = "{'firstName': 'John','lastName': 'Smith','isAlive': true,'age': 66, 'birth':  '1954-09-28 20:15:00'" _
        & ",'address': {'streetAddress': '21 2nd Street','city': 'New York','state': 'NY','postalCode': '10021-3100'}" _
        & ",'phoneNumbers': [{'type': 'home','number': '212 555-1234'},{'type': 'office','number': '646 555-4567'}]" _
        & ",'children': ['Q','M','G','T'],'spouse': null}"
    s = Replace(s, "'", """")
    myDict.ImportFromJson(s, OverWrite := True)
    'The (sub)-dictionaries "address" and "phoneNumbers" (0) and (1) are imported as Empty values.
  

ImportFromPropertyValues

A PropertyValue objektumok tömbjének tartalmát beilleszti az aktuális szótárba. A PropertyValue nevek a szótárban Kulcsként szerepelnek, míg az Értékek a megfelelő értékeket tartalmazzák. Siker esetén True értéket ad vissza.

dict.ImportFromPropertyValues(propertyvalues: obj[0..*], overwrite: bool = False): bool

propertyvalues: A zero-based 1-dimensional array containing com.sun.star.beans.PropertyValue objects. This parameter may also be a single PropertyValue object not contained in an Array.

overwrite: Ha True, akkor a szótárban létezhetnek azonos nevű bejegyzések, és azok értékei felülíródnak. Ha False (alapértelmezett), az ismétlődő kulcsok hibát fognak okozni. Vegyük figyelembe, hogy a szótárkulcsok esetében a Basicben a nagy- és kisbetűk nem érzékenyek, míg a tulajdonságértékek halmazaiban és a Python szótárakban a nevek nagy- és kisbetűk érzékenyek.

The examples below first create an array with two PropertyValue objects and then convert it to a dictionary.

    Dim vProp As New com.sun.star.beans.PropertyValue
    Dim arrProp : arrProp = Array()
    vProp.Name = "Color"
    vProp.Value = "Blue"
    arrProp = SF_Array.Append(arrProp, vProp)
    vProp.Name = "Date"
    vProp.Value = CDateToUnoDateTime(Now)
    arrProp = SF_Array.Append(arrProp, vProp)
    myDict = CreateScriptService("Dictionary")
    myDict.ImportFromPropertyValues(arrProp, Overwrite := True)
    Dim keys : keys = myDict.Keys
    For Each k In keys
        MsgBox k & " - " & myDict.Item(k)
    Next k
  

    from scriptforge import CreateScriptService
    from datetime import datetime
    import uno
    bas = CreateScriptService("Basic")
    arrProp = list()
    vProp = uno.createUnoStruct("com.sun.star.beans.PropertyValue")
    vProp.Name = "Color"
    vProp.Value = "Blue"
    arrProp.append(vProp)
    vProp = uno.createUnoStruct("com.sun.star.beans.PropertyValue")
    vProp.Name = "Date"
    vProp.Value = bas.CDateToUnoDateTime(datetime.now())
    arrProp.append(vProp)
    myDict = CreateScriptService("Dictionary")
    myDict.ImportFromPropertyValues(arrProp, overwrite=True)
    for k in myDict.keys():
        bas.MsgBox("{} - {}".format(k, myDict[k]))
  

Item

Retrieves an existing dictionary entry based on its key. Returns the value of the item if successful, otherwise returns Empty.

dict.Item(key: str): any

key: Not case-sensitive. If it does not exist, Empty value is returned.

The following example iterates over all keys in the dictionary and uses the Item method to access their values.

    Dim myDict as Variant, k as Variant, allKeys as Variant
    myDict = CreateScriptService("Dictionary")
    myDict.Add("key1", 100)
    myDict.Add("key2", 200)
    myDict.Add("key3", 300)
    allKeys = myDict.Keys
    For Each k in allKeys
       MsgBox(myDict.Item(k))
    Next k
  

Remove

Removes an existing dictionary entry based on its key. Returns True if successful.

dict.Remove(key: str): bool

key: Not case-sensitive. Must exist in the dictionary, otherwise an UNKNOWNKEYERROR error is raised.

    myDict.Add("key1", 100)
    myDict.Add("key2", 200)
    myDict.Add("key3", 300)
    MsgBox(myDict.Count) ' 3
    myDict.Remove("key2")
    MsgBox(myDict.Count) ' 2
  

RemoveAll

Removes all the entries from the dictionary. Returns True if successful.

dict.RemoveAll(): bool

    myDict.Add("key1", 100)
    myDict.Add("key2", 200)
    myDict.Add("key3", 300)
    MsgBox(myDict.Count) ' 3
    myDict.RemoveAll()
    MsgBox(myDict.Count) ' 0
  

ReplaceItem

Replaces an existing item value based on its key. Returns True if successful.

dict.ReplaceItem(key: str, value: any): bool

key: String value representing the key whose value will be replaced. Not case-sensitive. If the key does not exist in the dictionary, an UNKNOWNKEYERROR error is raised.

value: The new value of the item referred to with the key parameter.

    myDict.Add("a", 1)
    MsgBox(myDict.Item("a")) ' 1
    myDict.ReplaceItem("a", 100)
    MsgBox(myDict.Item("a")) ' 100
  

ReplaceKey

Replaces an existing key in the dictionary by a new key. The item value is left unchanged. Returns True if successful.

dict.ReplaceKey(key: str, value: str): bool

key: String value representing the key to be replaced. Not case-sensitive. If the key does not exist in the dictionary, a UNKNOWNKEYERROR error is raised.

value: String value for the new key. Not case-sensitive. If the new key already exists in the dictionary, an DUPLICATEKEYERROR error is raised.

    myDict.Add("oldKey", 100)
    MsgBox(myDict.Item("oldKey")) ' 100
    myDict.ReplaceKey("oldKey", "newKey")
    MsgBox(myDict.Item("newKey")) ' 100
  

All ScriptForge Basic routines or identifiers that are prefixed with an underscore character "_" are reserved for internal use. They are not meant be used in Basic macros or Python scripts.