COUNTIFS

Returns the count of cells that meet criteria in multiple ranges.

Tuta funkcija je wot LibreOffice 4.0 k dispoziciji.

Syntax

COUNTIFS(Range; Criterion[; Range2; Criterion2][; ... ; [Range127; Criterion127]])

Range1 – required argument. It is a range of cells, a name of a named range, or a label of a column or a row, to which the corresponding criterion is to be applied.

Criterion: A criterion is a single cell Reference, Number or Text. It is used in comparisons with cell contents.

A reference to an empty cell is interpreted as the numeric value 0.

A matching expression can be:

A Number or Logical value. A matching cell content equals the Number or Logical value.
A value beginning with a comparator (<, <=, =, >, >=, <>).

For =, if the value is empty it matches empty cells.

For <>, if the value is empty it matches non-empty cells.

For <>, if the value is not empty it matches any cell content except the value, including empty cells.

Note: "=0" does not match empty cells.

For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.
Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Range2 – Optional. Range2 and all the following mean the same as Range1.

Criterion2 – Optional. Criterion2 and all the following mean the same as Criterion.

Pytanje zastupowace symbole abo regularne wurazy podpěruje. Ze zmóžnjenymi regularnymi wurazami móžeće „all.*“ zapodać, zo byšće na přikład prěnje wustupowanje „all“, slědowane wot někajkich znamješkow, namakał. Jeli chceće tekst pytać, kotryž je tež regularny wuraz, dyrbiće pak před kóžde metaznamješko abo operator regularneho wuraza znamješko „\“ stajić pak tekst z \Q…\E wobdać. Móžeće awtomatiske wuhódnoćenje zastupowacych symbolow abo regularnych wurazow w – LibreOffice Calc – Wuličić zmóžnić abo znjemóžnić.

Hdyž funkcije wužiwaće, hdźež so jedyn argument wužiwa abo wjacore argumenty wužiwaja, kotrež su znamješkowe rjećazki pytanskich kriterijow, kotrež regularny wuraz reprezentuja, prěni pospyt je, kriterije znamješkoweho rjećazka do ličbow přetworić. „.0“ so na přikład do 0.0 přetworja a tak dale. Jeli to je wuspěšne, njebudźe wotpowědnik wotpowědnik regularneho wuraza, ale budźe numeriski wotpowědnik. Hdyž wšak narodnu šemu wužiwaće, hdźež decimalne dźělatko dypk njeje, budźe přetworjenje regularneho wuraza fungować. Zo byšće wuhódnoćenje regularneho wuraza město numeriskeho wuraza wunuzował, wužiwajće někajki wuraz, kotryž njeda so wopak jako numeriski rozumić, na přikład „.[0]“ abo „.\0“ abo „(?i).0.

Range, Range2, ... and Criterion, Criterion2, ... must have the same size, otherwise the function returns err:502 - Invalid argument.

The logical relation between criteria can be defined as logical AND (conjunction). In other words, if and only if all given criteria are met, a value from the corresponding cell of the given Func_Range is taken into calculation.

The function can have up to 255 arguments, meaning that you can specify 127 criteria ranges and criteria for them.

If a cell contains TRUE, it is treated as 1, if a cell contains FALSE – as 0 (zero).

This function is part of the Open Document Format for Office Applications (OpenDocument) standard Version 1.2. (ISO/IEC 26300:2-2015)

Example

Consider the following table

	A	B	C
1	Product Name	Sales	Revenue
2	pencil	20	65
3	pen	35	85
4	notebook	20	190
5	book	17	180
6	pencil-case	not	not

In all examples below, ranges for calculation contain the row #6, which is ignored because it contains text.

Simple usage

=COUNTIFS(B2:B6;">=20")

Counts the amount of rows of the range B2:B6 with values greater than or equal to 20. Returns 3, because the fifth and the sixth rows do not meet the criterion.

=COUNTIFS(B2:B6;">=20";C2:C6;">70")

Counts the amount of rows that contain simultaneously values greater than 70 in the C2:C6 range and values greater than or equal to 20 in the B2:B6 range. Returns 2, because the second, the fifth and the sixth rows do not meet at least one criterion.

Using regular expressions and nested functions

For these examples to work as described, make sure that Enable regular expressions in formulas is selected in - LibreOffice Calc - Calculate.

=COUNTIFS(B2:B6;"[:alpha:]*")

Counts the amount of rows of the B2:B6 range that contain only alphabet symbols. Returns 1, because only sixth row meets the criterion.

=COUNTIFS(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Counts the amount of rows of the B2:B6 range excluding rows with minimum and maximum values of this range. Returns 2, because the third, the fifth and the sixth rows do not meet at least one criterion.

=COUNTIFS(A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Counts the amount of rows that correspond to all cells of the A2:A6 range starting with "pen" and to all cells of the B2:B6 range with exception of its maximum. Returns 1, because only second row meets all criteria.

Reference to a cell as a criterion

If you need to change a criterion easily, you may want to specify it in a separate cell and use a reference to this cell in the condition of the COUNTIFS function. For example, the above function can be rewritten as follows:

=COUNTIFS(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

If E2 = pen, the function returns 1, because the link to the cell is substituted with its content and it works as a function above.

Dataju z přikładom wočinić:

COUNTIFS wiki page.

COUNT, COUNTIF, COUNTBLANK, COUNTA

COUNTIFS, MINIFS, MAXIFS, AVERAGEIFS, SUMIFS

List of Regular Expressions