Programowanske přikłady za wodźenske elementy w dialogowym editorje

Slědowace přikłady su nowy dialog z mjenom "Dialog1". Wužiwajće nastroje w symbolowej lajsće nastrojow w dialogowym editorje, zo byšće dialog wutworił a slědowace wodźenske elementy přidał: kontrolny kašćik z mjenom "Kontrolny kašćik 1", popisowe polo z mjenom "Popisowe polo 1", Tłóčatko z mjenom "Tłóčatko 1" a lisćinowe polo z mjenom "Lisćinowe polo 1".

Dźiwajće přeco na wulkopisanje a małopisanje, hdyž objektowej wariabli wodźenski element připokazujeće.

Globalna funkcija za začitanje dialogow


Function LoadDialog(Libname as String, DialogName as String, Optional oLibContainer)
Dim oLib as Object ' com.sun.star.script.XLibraryContainer
Dim oLibDialog as Object
Dim oRuntimeDialog as Object
    If IsMissing(oLibContainer) Then
        oLibContainer = DialogLibraries
    End If
    oLibContainer.LoadLibrary(LibName)
    oLib = oLibContainer.GetByName(Libname)
    oLibDialog = oLib.GetByName(DialogName)
    oRuntimeDialog = CreateUnoDialog(oLibDialog)
    LoadDialog() = oRuntimeDialog
End Function

Funkcija LoadDialog so w Tools.ModuleControls składuje, kotryž je w Nałoženske makra a dialogi k dispoziciji.

Dialog pokazać


REM globalna definicija wariblow
Dim oDialog1 AS Object
Sub StartDialog1
    With GlobalScope.BasicLibraries
       If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
    End With
    oDialog1 = Tools.ModuleControls.LoadDialog("Standard", "Dialog1")
    oDialog1.Execute()
End Sub

Kajkosće wodźenskich elementow w programje čitać abo wobdźěłać


Sub Sample1
    With GlobalScope.Basiclibraries
       If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
    End With
    oDialog1 = Tools.LoadDialog("Standard", "Dialog1")
    REM Model dialoga wobstarać
    oDialog1Model = oDialog1.Model
    REM tekst pola Popisowe polo 1 pokazać
    oLabel1 = oDialog1.GetControl("Label1")
    MsgBox oLabel1.Text
    REM nowy tekst za wodźenski element Popisowe polo 1 nastajić
    oLabel1.Text = "Nowe dataje"
    REM modelowe kajkosće za wodźenski element Kontrolny kašćik 1 pokazać
    oCheckBox1Model = oDialog1Model.CheckBox1
    MsgBox oCheckBox1Model.Dbg_Properties
    REM nowy status za Kontrolny kašćik 1 za model wodźenskeho elementa nastajić
    oCheckBox1Model.State = 1
    REM modelowe kajkosće za wodźenski element Tłóčatko 1 pokazać
    oCMD1Model = oDialog1Model.CommandButton1
    MsgBox oCMD1Model.Dbg_Properties
    REM kajkosće wodźenskeho elementa Tłóčatko 1 pokazać
    oCMD1 = oDialog1.GetControl("CommandButton1")
    MsgBox oCMD1.Dbg_Properties
    REM dialog wuwjesć
    oDialog1.Execute()
End Sub

Lisćinowemu polu zapisk přidać


Sub AddEntry
    With GlobalScope.Basiclibraries
       If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
    End With
    oDialog1 = ModuleControls.LoadDialog("Standard", "Dialog1")
    REM přidawa lisćinowemu polu nowy zapisk
    oDialog1Model = oDialog1.Model
    oListBox = oDialog1.GetControl("ListBox1")
    Dim iCount as integer
    iCount = oListbox.ItemCount
    oListbox.additem("New Item" & iCount,0)
End Sub

Zapisk z lisćinoweho pola wotstronić


Sub RemoveEntry
    With GlobalScope.Basiclibraries
       If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
    End With
    oDialog1 = Tools.ModuleControls.LoadDialogLoadDialog("Standard", "Dialog1")
    REM prěni zapisk z lisćinoweho pola wotstronić
    oDialog1Model = oDialog1.Model
    oListBox = oDialog1.GetControl("ListBox1")
    oListbox.removeitems(0,1)
End Sub

Kajkosće wodźenskich elementow w dialogowym editorje změnić

Dialog Basic wutworić

Wodźenske elementy w dialogowym editorje wutworić

Dialog z Basic wočinić