WORKDAY.INTL

Returns the date calculated from a start date with a specific number of work days, before or after the start date. The calculation can include week-ends and holidays as non-working days.

Sintaxe

WORKDAY.INTL(StartDate; Days [; Weekend [; Holidays]])

StartDate: is the date from when the calculation is carried out.

Days is the number of workdays. Positive value for a result after the start date, negative value for a result before the start date.

FinDeSemana é un parámetro opcional - un número ou cadea empregado para especificar os días da semana que son do fin de semana e non se consideran días laborábeis. FinDeSemana é un número ou cadea que indica cando caen os fins de semana. O seu valor indica os días de fin de semana seguintes:

De 1 a 7 para fins de semana de dous días e 11 a 17 para fins de semana de un día.

Número	Fin de semana
1 ou omitido	Sábado e domingo
2	Domingo e luns
3	Luns e martes
4	Martes e mércores
5	Mércores e xoves
6	Xoves e venres
7	Venres e sábado
11	Só domingo
12	Só luns
13	Só martes
14	Só mércores
15	Só xoves
16	Só venres
17	Só sábado

A cadea FinDeSemana fornece outro medio de definir os días non laborábeis da semana. Debe ter sete (7) caracteres - ceros (0) para días laborábeis e uns (1) para días non laborábeis. Cada carácter representa un día da semana, comezando no luns. Só son válidos 1 e 0. «1111111» non é unha cadea válida e non debería empregarse. Por exemplo, a cadea «0000011» define sábado e domingo como días non laborábeis.

Vacacións é unha lista opcional de datas que hai que contar como días non laborábeis. A lista pode darse como intervalo de celas.

Ao inserir datas como partes de fórmulas, as barras ou guións empregados como separadores de datas interprétanse como operadores aritméticos. Polo tanto, as datas introducidas neste formato non se recoñecen como datas e producen cálculos erróneos. Para que as datas sexan interpretadas como parte das fórmulas hai que empregar a función DATA, por exemplo, DATA(1954;7;20) ou colocar a data entre aspas e empregar a notación ISO 8601, por exemplo, «1954-07-20». Evite empregar formatos de data dependentes de formatos rexionais, como «07/20/54» porque o cálculo pode producir erros se o documento se carga cunha configuración local diferente.

É posíbel unha conversión sen ambigüidades para as datas e horas en ISO 8601 nos seus formatos estendidos con separadores. Se se produce un erro #VALUE!, desmarque Xerar erro #VALUE! en - Calc do LibreOffice - Fórmula, botón Detalles... na sección «Configuración detallada para cálculos», na caixa de lista Conversión de texto en número.

Exemplos

What date comes 20 workdays after December 13, 2016? Enter the start date in C3 and the number of workdays in D3.

The weekend parameter (number) may be left blank or defined as 1 for default weekend (non-working days) – Saturday and Sunday.

Cells F3 to J3 contain five (5) holidays for Christmas and New Year in date format: December 24, 2016; December 25, 2016; December 26, 2016; December 31, 2016; and January 1, 2017.

=WORKDAY.INTL(C3;D3;;F3:J3) returns January 11, 2017 in the result cell, say D6 (use date format for the cell).

To define Friday and Saturday as weekend days, use the weekend parameter 7.

=WORKDAY.INTL(C3;D3;7;F3:J3) returns January 15, 2017 with weekend parameter 7.

To define Sunday only the weekend day, use the weekend parameter 11.

=WORKDAY.INTL(C3;D3;11;F3:J3) returns January 9, 2017.

Alternatively, use the weekend string "0000001" for Sunday only weekend.

=WORKDAY.INTL(C3;D3;"0000001";F3:J3) returns January 9, 2017.

The function can be used without the two optional parameters – Weekday and Holidays – by leaving them out:

=WORKDAY.INTL(C3;D3) gives the result: January 10, 2017.

Información técnica

Esta función está dispoñíbel desde a versión 4.3 do LibreOffice.

Esta función NON é parte do estándar Formato Open Document para Aplicacións de Ofimática (OpenDocument), versión 1.3. Parte 4: Fórmula recalculada (OpenFormula). O espazo de nomes é

COM.MICROSOFT.WORKDAY.INTL

WORKDAY.INTL wiki page.

Funcións de data e hora