Fonction MOYENNE.SI

Renvoie la moyenne arithmétique de toutes les cellules d'une plage qui satisfait à une condition donnée. La fonction MOYENNE.SI additionne tous les résultats qui correspondent au test logique et divise cette somme par la quantité de valeurs sélectionnées.

tip

Cette fonction est disponible depuis la version 4.0 de LibreOffice.


Syntaxe

MOYENNE.SI(plage;critère[;plage_moyenne])

plage - argument requis. Une matrice, un nom d'une plage nommée ou une étiquette de colonne ou de ligne contenant les nombres pour la moyenne ou des nombres ou du texte pour la condition.

Critère : un critère est une référence, un nombre ou un texte à une seule cellule. Il est utilisé dans les comparaisons avec le contenu des cellules.

Une référence à une cellule vide est interprétée comme la valeur numérique 0.

Une expression correspondante peut être :

La recherche prend en charge les caractères génériques ou les expressions régulières . Lorsque les expressions régulières sont activées, vous pouvez saisir "tous. *", Par exemple pour trouver le premier emplacement de "tous" suivi de n'importe quel caractère. Si vous souhaitez rechercher un texte qui est également une expression régulière, vous devez soit précéder chaque caractère d'un caractère "\", soit placer le texte dans \Q ...\E. Vous pouvez activer ou désactiver l'évaluation automatique des caractères génériques ou des expressions régulières dans - LibreOffice Calc - Calculer .

warning

Lorsque vous utilisez des fonctions où un ou plusieurs arguments sont des chaînes de critères de recherche qui représentent une expression régulière, la première tentative consiste à convertir les critères de chaîne en nombres. Par exemple, ".0" se convertira en 0.0 et ainsi de suite. En cas de succès, la correspondance ne sera pas une correspondance d'expression régulière mais une correspondance numérique. Cependant, lorsque vous passez à un environnement local où le séparateur décimal n'est pas le point, la conversion d'expression régulière fonctionne. Pour forcer l'évaluation de l'expression régulière au lieu d'une expression numérique, utilisez une expression qui ne peut pas être mal interprétée comme numérique, telle que ". [0]" ou ".\0" ou "(?I) .0".


plage_moyenne - facultatif. C'est une plage de valeurs pour calculer la moyenne.

note

Si plage_moyenne n'est pas indiqué, plage est utilisé pour les deux, le calcul de la moyenne et la recherche en fonction de la condition. Si plage_moyenne est indiqué, plage est utilisé uniquement pour le test de condition, alors que plage_moyenne est utilisé pour le calcul de la moyenne.


note

Cette fonction fait partie du standard Open Document Format for Office Applications (Open Document) Version 1.2 (ISO/IEC 26300:2-2015)


warning

Si une cellule dans une plage de données pour calculer la moyenne est vide ou contient du texte, la fonction MOYENNE.SI ignore cette cellule.
Si la plage entière est vide, contient uniquement du texte ou toutes les valeurs de la plage ne satisfont pas la condition (ou n'importe quelle combinaison de celles-ci), la fonction renvoie l'erreur #DIV/0!


Exemple

Examinez le tableau suivant

A

B

C

1

Nom du produit

Ventes

Chiffre d'affaires

2

crayon

20

65

3

stylo

35

85

4

bloc-notes

20

190

5

livre

17

180

6

trousse

non

non


warning

Dans tous les exemples ci-dessous, les plages de calcul contiennent la ligne #6, qui est ignorée parce qu'elle contient du texte.


Usage simple

=MOYENNE.SI(B2:B6;"<35")

Calcule la moyenne pour les valeurs de la plage B2:B6 qui sont inférieures à 35. Renvoie 19 parce que la seconde ligne ne participe pas au calcul.

=MOYENNE.SI(B2:B6;"<"&MAX(B2:B6))

Calcule la moyenne pour les valeurs de la même plage qui sont inférieure à la valeur maximum de cette plage. Renvoie 19 parce que la valeur la plus grande (la seconde ligne) ne participe pas au calcul.

=MOYENNE.SI(B2:B6;">"&PETITE.VALEUR(B2:B6;1))

Calcule la moyenne pour les valeurs de la même plage qui sont supérieures à la première plus petite valeur de cette plage. Renvoie 25 parce que la première plus petite valeur (la quatrième ligne) ne participe pas au calcul.

Utilisation de plage_moyenne

=MOYENNE.SI(B2:B6;"<35";C2:C6)

Cette fonction recherche quelles valeurs sont inférieures à 35 dans la plage B2:B6 et calcule la moyenne des valeurs correspondantes à partir de la plage C2:C6. Renvoie 145 parce que la seconde ligne ne participe pas au calcul.

=MOYENNE.SI(B2:B6;">"&MIN(B2:B6);C2:C6)

La fonction cherche quelles valeurs de la plage B2:B6 sont supérieurs à la plus petite valeur dans la plage B2:B6 et calcul la moyenne des valeurs correspondantes dans la plage C2:C6. Renvoie 113,3 parce que la quatrième ligne (dans laquelle est la plus petite valeur dans la plage B2:B6) ne participe pas au calcul.

=MOYENNE.SI(B2:B6;"<"&LARGE(B2:B6;2);C2:C6)

La fonction recherche quelles valeurs de la plage B2:B6 sont inférieures à la seconde valeur la plus grand dans la plage B2:B6 et calcul la moyenne des valeurs correspondantes dans la plage C2:C6. Renvoie 180 parce qu'uniquement la quatrième ligne participe au calcul.

Utilisation des expressions régulières

=MOYENNE.SI(A2:A6;"crayon";B2:B6)

Cette fonction recherche quelles cellules de la plage A2:A6 contiennent uniquement le mot “crayon” et calcule la moyenne des valeurs correspondantes à partir de la plage B2:B6. Renvoie 35 parce que uniquement la seconde ligne participe au calcul. La recherche est exécutée dans la plage A2:A6 mais les valeurs sont renvoyées à partir de la plage B2:B6.

=MOYENNE.SI(A2:A6;"crayon.*";B2:B6)

Cette fonction recherche quelles cellules de la plage A2:A6 commence par “crayon” et se finissant avec n'importe quelle quantité d'autres caractères et calcule la moyenne des valeurs correspondantes à partir de la plage B2:B6. Renvoie 27,5 parce que maintenant “crayonner” satisfait aussi la condition et aussi bien la première que la seconde ligne participent au calcul.

=MOYENNE.SI(A2:A6;".*livre.*";B2:B6)

Cette fonction recherche quelles cellules de la plage A2:A6 contiennent “livre” commençant et finissant avec n'importe quelle quantité d'autres caractères et calcule la moyenne des valeurs correspondantes à partir de la plage B2:B6. Renvoie 18,5 parce qu'uniquement les troisièmes et quatrièmes rangs participent au calcul.

Référence à une cellule comme critère

Si vous avez besoin de modifier facilement un critère, vous le spécifiez dans une cellule séparée et utilisez une référence à cette cellule dans la condition de la fonction MOYENNE.SI.

=MOYENNE.SI(A2:A6;".*"&E2&".*";B2:B6)

Cette fonction recherche quelles cellules de la plage A2:A6 contiennent une combinaison de caractères spécifiés dans E2 commençant et finissant par n'importe quelle quantité d'autres caractères et calcule la moyenne des valeurs correspondantes à partir de la plage B2:B6. Si E2=livre, la fonction renvoie 18,5.

=MOYENNE.SI(B2:B6;"<"&E2;C2:C6)

Cette fonction recherche quelles cellules de la plage B2:B6 sont inférieures à la valeur spécifiée dans E2 et calcule la moyenne des valeurs correspondantes à partir de la plage C2:C6. Si E2=35, cette fonction renvoie 145.

Aidez-nous !