Fonctions de texte
Cette section décrit les fonctions de texte.
Utiliser des guillemets doubles dans les formules
Pour inclure une chaîne de texte dans une formule, placez la chaîne de texte entre deux guillemets doubles ("") et Calc prend les caractères de la chaîne sans tenter de les interpréter. Par exemple, la formule ="Hello le monde !" affiche la chaîne de texte Hello le monde ! dans la cellule, sans guillemets doubles environnants.
La formule plus complexe =CONCATENER("La vie est vraiment simple,";"mais nous insistons pour la rendre compliquée";"(Confucius).") concatène trois chaînes individuelles entre guillemets doubles, produisant La vie est vraiment simple, mais nous insistons pour la rendre compliquée (Confucius).
Pour placer un guillemet double littéral dans une chaîne à l'intérieur d'une formule, deux méthodes peuvent être utilisées :
-
Vous pouvez "échapper" le guillemet double avec un guillemet double supplémentaire, et Calc traite le guillemet double échappé comme une valeur littérale. Par exemple, la formule ="Mon nom est""John Doe""." renvoie la chaîne Mon nom est "John Doe". Un autre exemple simple est la formule =UNICODE("""") qui renvoie 34, la valeur décimale du caractère guillemet Unicode (U+0022) — ici les premier et quatrième guillemets doubles indiquent le début et la fin de la chaîne, tandis que le deuxième guillemet double échappe au troisième.
-
Vous pouvez utiliser la fonction CAR ou la fonction UNICAR pour insérer un guillemet double. Par exemple, la formule =UNICAR(34) & "The Catcher in the Rye" & UNICAR(34) & " est un livre célèbre de JD Salinger." affiche la chaîne "The Catcher in the Rye" est un livre célèbre de JD Salinger.
Sachez que la fonction AutoCorrect de Calc peut modifier les guillemets doubles. La correction automatique ne doit pas modifier les guillemets doubles dans les cellules de formule, mais peut modifier ceux utilisés dans les cellules sans formule contenant du texte. Par exemple, si vous copiez une chaîne entourée d'une autre forme de guillemets doubles typographiques, comme le guillemet double gauche (U+201C) et le guillemet double droit (U+201D), puis la collez dans un cellule de formule, une erreur peut se produire. Ouvrez la zone Guillemets doubles de la boîte de dialogue pour définir les caractères utilisés pour corriger automatiquement les guillemets doubles typographiques de début et de fin. Décochez le bouton bascule pour désactiver la fonctionnalité.
BAHTTEXT
Convertit un numéro en texte thaï, y compris les noms de devises thaïs.
BAHTTEXT(nombre)
nombre correspond à un nombre quelconque. "Baht" est ajouté à la partie entière du nombre et "Satang" à sa partie décimale.
=BAHTTEXT(12,65) renvoie une chaîne en caractères Thaï avec la signification de "Douze Baht et soixante-cinq Satang".
COM.MICROSOFT.BAHTTEXT
BASE
Convertit un entier positif en une base spécifiée en un texte à partir du système de numérotation. Les chiffres 0-9 et les lettres AZ sont utilisés.
BASE(nombre; racine[;longueur_minimum])
nombre est le nombre entier positif à convertir.
racine indique la base du système de nombre. Cela peut être n'importe quel nombre entier positif entre 2 et 36.
longueur_minimum (facultatif) détermine la longueur minimum de la séquence de caractères qui a été créée. Si le texte est plus court que la longueur minimum indiquée, des zéros sont ajoutés à la gauche de la chaîne.
=BASE(17;10;4) renvoie 0017 dans le système décimal.
=BASE(17;2) renvoie 10001 dans le système binaire.
=BASE(255;16;4) renvoie 00FF dans le système hexadécimal.
CAR
Convertit un nombre en caractère en fonction du tableau de code actif. Il peut s'agir d'un nombre entier à deux ou trois chiffres.
CAR(nombre)
nombre est un nombre entre 1 et 255 représentant la valeur de code du caractère.
=CAR(100) renvoie le caractère d.
="abc" & CAR(10) & "def" insère un caractère de saut de ligne dans une chaîne.
CHERCHE
Renvoie l'emplacement d'un segment de texte dans une chaîne de caractères. Vous pouvez facultativement définir le point de départ de la recherche. Le texte recherché peut être un nombre ou toute autre séquence de caractères. La recherche ne respecte pas la casse. Si le texte n'est pas trouvé, l'erreur 519 (#VALEUR) est renvoyée.
La recherche prend en charge les caractères génériques ou les expressions régulières. Lorsque les expressions régulières sont activées, vous pouvez entrer "tout.*", par exemple pour trouver le premier emplacement de "tout" suivi de n'importe quel caractère. Si vous souhaitez rechercher un texte qui est également une expression régulière, vous devez soit faire précéder chaque métacaractère ou opérateur d'expression régulière d'un caractère "\", soit placer le texte entre \Q...\E. Vous pouvez activer et désactiver l'évaluation automatique des caractères génériques ou des expressions régulières dans .
Lorsque vous utilisez des fonctions où un ou plusieurs arguments sont des chaînes de critères de recherche qui représentent une expression régulière, la première tentative consiste à convertir les critères de chaîne en nombres. Par exemple, ".0" se convertira en 0.0 et ainsi de suite. En cas de succès, la correspondance ne sera pas une correspondance d'expression régulière mais une correspondance numérique. Cependant, lorsque vous passez à un environnement local où le séparateur décimal n'est pas le point, la conversion d'expression régulière fonctionne. Pour forcer l'évaluation de l'expression régulière au lieu d'une expression numérique, utilisez une expression qui ne peut pas être mal interprétée comme numérique, telle que ". [0]" ou ".\0" ou "(?I) .0".
CHERCHE("texte_cherché";"texte"[;position])
Texte_cherché est le texte à rechercher.
Texte est le texte où la recherche va prendre place.
position (facultatif) est la position où la recherche doit commencer dans le texte.
=CHERCHE(54;998877665544) renvoie 10.
CODE
Renvoie le numéro de code du premier caractère du texte.
CODE("Texte")
Texte représente le texte dont vous voulez obtenir le code du premier caractère.
=CODE("Hieronymus") renvoie 72, =CODE("hieroglyphique") renvoie 104.
Le code utilisé à ce niveau n'est pas le code ASCII, mais le code de la table de codes active.
CONCATENER
Combine plusieurs chaînes de texte pour n'en former qu'une.
CONCATENER(chaîne1[;chaîne2[;...[;chaîne255]]])
chaîne1[;chaîne2][;...;[chaîne255]] sont des chaînes ou références à des cellules contenant des chaînes.
=CONCATENER("Bonne ";"journée ";"Mme ";"Sanou") renvoie : Bonne journée Mme Sanou.
CTXT
Renvoie un nombre en tant que texte avec un nombre défini de décimales et des séparateurs de milliers facultatifs.
CTXT(nombre;[décimales[;pas_de_séparateurs_de_milliers=FAUX]])
nombre est arrondi à Décimales (après le séparateur décimal) et le résultat est formaté sous forme de texte, en utilisant les paramètres spécifiques aux paramètres régionaux.
Décimales (facultatif) fait référence au nombre de décimales à afficher. Si Décimales est négatif, nombre est arrondi à ABS(Décimales) placé à gauche de la virgule décimale. Si Décimales est une fraction, elle est tronquée en ignorant en fait quel est l'entier le plus proche.
pas de séparateur de milliers (facultatif) détermine si le séparateur des milliers est utilisé. S'il est VRAI ou différent de zéro, les séparateurs de groupe sont omis de la chaîne résultante. Si le paramètre est égal à 0 ou s'il est totalement absent, les séparateurs de milliers des paramètres régionaux actuels sont affichés.
=CTXT(1234567,89;3) renvoie 1 234 567,890 comme chaîne de texte.
=CTXT(123456,789;;VRAI) renvoie 123456,79 comme chaîne de texte.
=CTXT(12345,6789;-2) renvoie 12 300 comme chaîne de texte.
=CTXT(1234567,89;-3;1) renvoie 12135000 comme chaîne de texte.
=CTXT(12345,789;3/4) renvoie 12 346 comme chaîne de texte.
=CTXT(12345,789;8/5) renvoie 12 345,8 comme chaîne de texte.
DECIMAL
Convertit le texte qui représente un nombre dans un système numérique avec la base donnée en un entier positif. La base doit être comprise entre 2 et 36. Les espaces et les tabulations sont ignorés. Le champ Texte n'est pas sensible à la casse.
Si la racine est 16, un x ou X de début, un 0x ou 0X de début ou un h ou H de fin sont ignorés. Si la racine est 2, un b ou un B de fin est ignoré. Les caractères ne faisant pas partie du système de numération génèrent une erreur.
DECIMAL("Texte";racine)
Texte est le texte à convertir.
racine indique la base du système de nombre. Cela peut être n'importe quel nombre entier positif entre 2 et 36.
=DECIMAL("17";10) renvoie 17.
=DECIMAL("FACE";16) renvoie 64206.
=DECIMAL("0101";2) renvoie 5.
DROITE
Renvoie le ou les derniers caractères d'un texte.
DROITE("Texte"[;nombre])
Texte est le texte dont la partie droite doit être déterminée.
nombre (facultatif) indique le nombre de caractères du texte de départ. Si ce paramètre n'est pas défini, un seul caractère est renvoyé.
=DROITE("Son";2) renvoie on.
DROITEB
Renvoie le ou les derniers caractères d'un texte en ensembles de doubles octets de caractères (DBCS).
DROITEB("Texte"[;nombre_octets])
Texte est le texte dont la partie droite doit être déterminée.
nombre_octets (facultatif) indique le nombre de caractères qui doivent être extraits par DROITEB, basé sur les octets. Si ce paramètre n'est pas défini, un octet est renvoyé.
DROITEB("中国";1) renvoie " " (1 octet est seulement la moitié d'un caractère DBCS et un caractère d'espace est renvoyé à la place).
DROITEB("中国";2) renvoie "国" (2 octets constituent un caractère DBCS complet).
DROITEB("中国";3) renvoie " 国" (3 octets constituent un demi caractère DBCS et un caractère DBCS complet ; un espace est renvoyé pour la première moitié).
DROITEB("中国";4) renvoie "中国" (4 octets constituent deux caractère DBCS complets).
DROITEB("bureau";3) renvoie "eau" (3 caractère non-DBCS, chacun constitué de 1 octet).
EPURAGE
Tous les caractères non imprimables sont supprimés de la chaîne.
EPURAGE("Texte")
Texte réfère au texte duquel doit être retiré tous caractères non imprimables.
=NBCAR(EPURAGE(CAR(7) & "LibreOffice Calc" & CAR(8))) renvoie 16, montrant que la fonction EPURAGE supprime les caractères Unicode non imprimables U+0007 ("BEL") et U+0008 ("BS") au début et à la fin de l'argument de chaîne. EPURAGE ne supprime pas les espaces.
EXACT
Compare deux chaînes de texte et renvoie la valeur VRAI si elles sont identiques. Cette fonction est sensible à la casse.
EXACT("Texte_1"; "Texte_2")
Texte_1 réfère au premier texte à comparer.
Texte_2 est le second texte à comparer.
=EXACT("microsystems";"Microsystems") renvoie FAUX.
FRANC
Convertit un nombre en une chaîne représentant le montant au format monétaire, arrondi à une décimale spécifiée, en utilisant le séparateur décimal qui correspond au paramètres régionaux actuels. Dans le champ Valeur saisissez le nombre à convertir. Facultativement, vous pouvez saisir le nombre de décimales dans le champ Décimales. Si aucune valeur n'est spécifiée, tous les nombres au format monétaire seront affichés avec deux décimales.
Vous pouvez définir le format monétaire dans les paramètres du système.
FRANC(valeur[;décimales])
valeur est un nombre, une référence à une cellule contenant un nombre ou une formule qui renvoie un nombre.
décimalesest le nombre facultatif de décimales.
=FRANC(255) renvoie $255.00 pour la locale Anglais (USA) et la monnaie USD (dollar) ; ￥255.00 pour la locale japonaise et la monnaie JPY (yen) ; 255,00 € pour la locale allemande (Allemagne) et la monnaie EUR (euro).
=DOLLAR(367.456;2) renvoie $367.46.
GAUCHE
Renvoie le ou les premiers caractères d'un texte.
GAUCHE("Texte"[;nombre])
Texte est le texte duquel les mots initiaux partiels doivent être déterminés.
nombre (facultatif) indique le nombre de caractères du texte de départ. Si ce paramètre n'est pas défini, un seul caractère est renvoyé.
=GAUCHE("sortie";3) renvoie “sor”.
GAUCHEB
Renvoie le premier caractère d'un texte DBCS (Double Byte Character Set).
GAUCHEB("Texte"[;nombre_octets])
Texte est le texte duquel les mots initiaux partiels doivent être déterminés.
nombre_octets (facultatif) indique le nombre de caractères qui doivent être extraits par GAUCHEB, basé sur les octets. Si ce paramètre n'est pas défini, un caractère est renvoyé.
=GAUCHEB("中国";1) renvoie " " (1 octet est seulement la moitié d'un caractère DBCS et un caractère d'espace est renvoyé à la place).
=GAUCHEB("中国";2) renvoie "中" (2 octets constituent un caractère DBCS complet).
=GAUCHEB("中国";3) renvoie "中 " (3 octets constituent un caractère DBCS et demi ; le dernier caractère renvoyé est alors un caractère d'espace.)
=GAUCHEB("中国";4) renvoie "中国" (4 octets constituent deux caractères DBCS complets).
=GAUCHEB("bureau";3) renvoie "bur" (3 caractères non-DBCS chacun consistant en 1 byte).
MAJUSCULE
Convertit en majuscules la chaîne indiquée dans le champ texte.
MAJUSCULE("Texte")
Texte réfère aux lettres en minuscules à convertir en majuscules.
=MAJUSCULE("Bonne journée") renvoie BONNE JOURNÉE.
MINUSCULE
Convertit toutes les majuscules d'une chaîne de caractères en minuscules.
MINUSCULE("Texte")
Texte réfère au texte à convertir.
=MINUSCULE("Son") renvoie son.
NBCAR
Renvoie la longueur d'une chaîne en incluant les espaces.
NBCAR("Texte")
Texte est le texte dont vous voulez déterminer la longueur.
=NBCAR("Bon après-midi") renvoie 14.
=NBCAR(12345,67) renvoie 8.
NBCARB
Pour les langues à ensembles de caractères sur deux octets (DBCS), renvoie le nombre d'octets utilisés pour représentes les caractères dans une chaîne de texte.
NBCARB("Texte")
Texte est le texte dont vous voulez déterminer la longueur.
NBCARB("中") renvoie 2 (1 caractère DBCS constitué de 2 octets).
NBCARB("中国") renvoie 4 (2 caractères DBCS chacun constitué de 2 octets).
GAUCHEB("bureau") renvoie 6 (6 caractère non-DBCS chacun constitué d'1 octet).
=NBCARB("Bon après-midi") renvoie 14.
=NBCARB(12345.67) renvoie 8.
NOMPROPRE
Met la première lettre de tous les mots d'une chaîne en majuscules.
NOMPROPRE("Texte")
Texte réfère au texte à convertir.
=NOMPROPRE("the document foundation" renvoie The Document Foundation.
REPLACE
Remplace une partie de la chaîne de texte par une chaîne de texte différente. Cette fonction sert à remplacer les caractères et les nombres, qui sont automatiquement convertis en texte. Le résultat de cette fonction s'affiche toujours en tant que texte. Si vous souhaitez effectuer d'autres calculs avec un nombre qui a été remplacé par du texte, vous devrez le reconvertir en nombre en utilisant la fonction CNUM.
Tout texte contenant des nombres doit être saisi entre guillemets, faute de quoi il est interprété comme un nombre et automatiquement converti en texte.
REMPLACER("Texte";position;longueur;"Nouveau_texte")
Texte réfère au texte dont une partie doit être remplacée.
position réfère à la position où le remplacement va débuter dans le texte.
longueur est le nombre de caractères à remplacer dans le texte.
Nouveau_texte réfère au texte qui remplace le Texte.
=REMPLACER("1234567";1;1;"444") renvoie "444234567". Un caractère à la position 1 est remplacé par le Nouveau_texte complet.
REPT
Répète une chaîne de caractères selon le nombre de fois spécifié.
REPT("Texte";nombre)
Texte est le texte à répéter.
nombre est le nombre à tester.
=REPT("Bonne journée";2) renvoie Bonne journéeBonne journée.
Référez-vous à la page de wiki REPT pour des détails complémentaires sur cette fonction.
STXT
Renvoie une chaîne d'un texte. Les paramètres indiquent le point de départ et le nombre de caractères.
STXT("Texte";début;nombre)
Texte est le texte contenant les caractères à extraire.
début est la position du premier caractère dans le texte à extraire.
nombre spécifie le nombre de caractères dans la partie de texte.
=STXT("office";2;2) renvoie ff.
STXTB
Renvoie une chaîne de texte d'un texte DBCS. Les paramètres indiquent la position de départ et le nombre de caractères.
STXTB("Texte";début;nombre_octets)
Texte est le texte contenant les caractères à extraire.
début est la position du premier caractère dans le texte à extraire.
nombre_octets indique le nombre de caractère que STXTB renvoie à partir du texte, en octets.
=STXTB("中国";1;0) renvoie "" (0 octet est toujours une chaîne vide).
=STXTB("中国";1;1) renvoie " " (1 octet est seulement la moitié d'un caractère DBCS et donc le résultat est un caractère d'espace).
=STXTB("中国";1;2) renvoie "中" (2 octets constituent un caractère DBCS complet).
=STXTB("中国";1;3) renvoie "中 " (3 octets constituent un caractère DBCS et demi, le dernier octet résulte en un caractère d'espace).
=STXTB("中国";1;4) renvoie "中国" (4 octets constituent deux caractères DBCS complets).
=STXTB("中国";2;1) renvoie " " (la position 2 de l'octet n'est pas au début d'un caractère dans une chaîne DBCS ; 1 caractère d'espace est renvoyé).
=STXTB("中国";2;2) renvoie " " (la position 2 de l'octet pointe la dernière moitié du premier caractère dans la chaîne DBCS ; les 2 octets demandés pour constituer la dernière moitié du premier caractère et la première moitié du deuxième caractère dans la chaîne ; 2 caractères d'espace sont donc renvoyés).
=STXTB("中国";2;3) renvoie " 国" (l'octet en position 2 n'est pas au début d'un caractère dans une chaîne DBCS ; un caractère d'espace est renvoyé pour l'octet en position 2).
=STXTB("中国";3;1) renvoie " " (l'octet en position 3 est au début d'un caractère dans une chaîne DBCS, mais 1 octet correspond seulement à la moitié d'un caractère DBCS et un caractère d'espace est donc renvoyé à la place).
=STXTB("中国";3;2) renvoie "国" (l'octet en position 3 est au début d'un caractère dans une chaîne DBCS, et 2 octets constituent un caractère DBCS).
=STXTB("bureau";2;3) renvoie "ure" (l'octet à la position 2 est au début d'un caractère dans une chaîne non-DBCS, et 3 octets d'une chaîne non-DBCS constituent 3 caractères).
SUBSTITUE
Remplace l'ancien texte par le nouveau texte dans une chaîne.
SUBSTITUE("texte";"texte_cherché";"nouveau_texte"[;occurrence])
Texte est le texte dans lequel le segment de texte doit être échangé.
Texte_cherché est le segment de texte qui doit être remplacé (un certain nombre de fois).
Nouveau_texte est le texte qui doit remplacer le segment de texte.
occurrence (facultatif) indique quelle occurrence du texte recherché doit être remplacée. Si ce paramètre est manquant, le texte recherché est remplacé partout.
=SUBSTITUE("123123123";"3";"abc") renvoie 12abc12abc12abc.
=SUBSTITUE("123123123";"3";"abc";2) renvoie 12312abc123.
SUPPRESPACE
Supprime les espaces d'une chaîne, les mots sont alors séparés par un seul caractère d'espacement.
SUPRESPACE("Texte")
Texte désigne le texte dans lequel les espaces sont supprimés.
=SUPRESPACE(" coucou le monde ") renvoie coucou le monde sans les espaces avant ou après et avec un seul espace entre les mots.
T
Cette fonction renvoie le texte cible ou une chaîne vide si la cible n'est pas du texte.
T(valeur)
Si valeur est une chaîne de texte ou réfère à une chaîne de texte, T renvoie cette chaîne de texte, sinon elle renvoie une chaîne de texte vide.
=T(12345) renvoie une chaîne vide.
=T("12345") renvoie la chaîne 12345.
TEXTE
Convertit un nombre en texte selon un format spécifié.
TEXTE(valeur;format)
valeur est la valeur (numérique ou textuelle) à convertir.
format est le texte définissant le format. Utilisez les décimales et les séparateurs de milliers correspondant à la langue définie dans le format de cellule.
=TEXTE(12,34567;"###,##") renvoie le texte 12,35
=TEXTE(12,34567;"000,00") renvoie le texte 012,35
=TEXTE("xyz";"=== @ ===") renvoie le texte === xyz ===
Voir également Codes de format de nombre : codes de format personnalisé définis par l'utilisateur.
TROUVE
Renvoie la position d'une chaîne de texte dans une autre chaîne. Vous pouvez également définir l'endroit à partir duquel la recherche doit être lancée. Le terme recherché peut être un nombre ou une chaîne de caractères. La recherche respecte la casse.
TROUVE("Texte_à_trouver";"Texte"[;position])
Texte_à_trouver réfère au texte à trouver.
Texte est le texte dans lequel la recherche prend place.
position (facultatif) est la position dans le texte à partir de laquelle la recherche commence.
=TROUVE(76;998877665544) renvoie 6.
UNICAR
Convertit un numéro de code en un caractère ou une lettre Unicode.
UNICAR(nombre)
=UNICAR(169) renvoie le caractère de copyright ©.
Voir également la fonction UNICODE().
UNICODE
Renvoie le numéro de code du premier caractère Unicode d'une chaîne de texte.
UNICODE("Texte")
=UNICODE("©") renvoie le numéro Unicode 169 du caractère de copyright.
Voir également la fonction UNICAR().