Instruction For...Next

Répète les instructions situées dans le bloc For ... Next un nombre spécifié de fois.

Syntaxe :

Diagramme de l'instruction For


For counter=start To end [Step step]
    Bloc d'instructions
    [Exit For]
    Bloc d'instructions
Next [counter]

Diagramme de l'instruction For Each


  For Each item In list
      Bloc d'instructions
  [Exit For]
      Bloc d'instructions
  Next [item]

Variables :

compteur: de bouclecompteurinitialisé à la valeur à droite du signe égal(start). Seules les variables numériques sont valides. Le compteur de boucles augmente ou diminue en fonction de la variable pas jusqu'à ce que fin soit dépassé.

début: Variable numérique qui définit la valeur initiale au début de la boucle.

fin: Variable numérique définissant la valeur finale à la fin de la boucle.

pas: Définit la valeur par laquelle augmenter ou diminuer le compteur de boucles. Sipas n'est pas précisé, le compteur de boucles est augmenté de 1. dans ce cas, fin doit être supérieur à début. Si vous voulez diminuer lecompteur, fin doit être inférieur à début, et pas doit être défini à une valeur négative.

La boucle For...Next répète toutes les instructions comprises dans la boucle le nombre de fois spécifié par les paramètres.

Lorsque la variable compteur décroît, LibreOffice Basic vérifie si fin est atteint. Aussitôt que compteur franchit la valeurfin la boucle se termine automatiquement.

Il est possible d'imbriquer des instructions For...Next. Si aucune variable n'est spécifiée après l'instruction Next, Next se réfère automatiquement à l'instruction For la plus récente.

Si vous spécifiez un incrément de 0, les instructions comprises entre For et Next sont répétées en continu.

Lors de la décroissance de la variable de compteur, LibreOffice Basic vérifie le débordement. La boucle se termine quand le compteur dépassefin (valeur Pas positive) ou est inférieure à fin (valeur de Pas négative.).

Utilisez l'instruction Exit For pour sortir de la boucle sans condition. Cette instruction doit être insérée à l'intérieur d'une boucle For...Next. Pour évaluer la condition de sortie, utilisez l'instruction If...Then comme suit :


  For...
      Bloc d'instructions
      If condition = True Then Exit For
      Bloc d'instructions
  Next
note

En cas de boucles For...Nextimbriquées,si vous sortez de la boucle avec Exit For, une seule boucle se termine.


Exemples

L'exemple suivant utilise deux boucles imbriquées pour trier un tableau de chaînes avec 10 éléments (sEntry ()), qui est rempli de divers contenus:


Sub ExampleSort
Dim sEntry(9) As String
Dim iCount As Integer, iCount2 As Integer
Dim sTemp As String
    sEntry = Array("Jerry","Patty","Kurt","Thomas","Michael",_
                 "David","Cathy","Susie","Edward","Christine")
    For iCount = 0 To 9
        For iCount2 = iCount + 1 To 9
            If sEntry(iCount) > sEntry(iCount2) Then
                sTemp = sEntry(iCount)
                sEntry(iCount) = sEntry(iCount2)
                sEntry(iCount2) = sTemp
            End If
        Next iCount2
    Next iCount
    For iCount = 0 To 9
        Print sEntry(iCount)
    Next iCount
End Sub

Ceci explore le contenu d'un tableau pour afficher chaque élément qu'il contient.


  Sub list_iteration
      couverts= Array("fourchette", "couteau", "cuiller")
      For Each item in couverts
          Print item
      Next ' item
  End Sub

Aidez-nous !