Muuttujien käyttö

LibreOffice Basicin muuttujien perusteet kuvaillaan oheisena.

Muuttujien tunnusten nimeämissäännöt

Muuttujan nimi voi koostua enintään 255 merkistä. Muuttujanimen ensimmäisen merkin pitää olla joku kirjaimista A-Z tai a-z. Numeroitakin voi käyttää muuttujien nimissä, mutta skandinaaviset kirjaimet (ääkköset), välimerkit ja erikoismerkit eivät ole sallittuja. Poikkeuksen tekee alaviivamerkki ("_"). LibreOffice Basicin muuttujien tunnuksissa kirjainkokoa ei erotella. Muuttujan nimessä voi esiintyä välilyönti, mutta silloin nimeä on käytettävä hakasulkeissa.

Esimerkkejä muuttujien tunnuksista:


    MyNumber=5      'Correct'
    MyNumber5=15    'Correct'
    MyNumber_5=20   'Correct'
    My Number=20    'Not valid, variable with space must be enclosed in square brackets'
    [My Number]=12  'Correct'
    DéjàVu=25       'Not valid, special characters are not allowed'
    5MyNumber=12    'Not valid, variable may not begin with a number'
    Number,Mine=12  'Not valid, punctuation marks are not allowed'

Muuttujien määrittely

LibreOffice Basicissa ei ole muuttujien esittely- eli määrittelypakkoa. Muuttujan määrittely voidaan tehdä Dim-lauseella. Useamman muuttujan määrittelylauseessa muuttuja erotellaan pilkuilla. Muuttujan tyyppi määritetään joko tyypin määräävällä loppumerkillä tai käyttämällä määrittelevää avainsanaa.

Esimerkkejä muuttujien määrittelyistä:


    Dim a$               'Declares the variable "a" as a String'
    Dim a As String      'Declares the variable "a" as a String'
    Dim a$, b As Integer 'Declares one variable as a String and one as an Integer'
    Dim c As Boolean     'Declares c as a Boolean variable that can be TRUE or FALSE'
warning

Kun muuttujalle on määritelty tietty tietotyyppi, samannimistä muuttujaa ei voi enää tyyppimääritellä toisen tyyppiseksi!


When you declare multiple variables in a single line of code you need to specify the type of each variable. If the type of a variable is not explicitly specified, then Basic will assume that the variable is of the Variant type.


  ' Both variables "a" and "b" are of the Integer type
  Dim a As Integer, b As Integer
  ' Variable "c" is a Variant and "d" is an Integer
  Dim c, d As Integer
  ' A variable can also be explicitly declared as a Variant
  Dim e As Variant, f As Double
note

The Variant type is a special data type that can store any kind of value. To learn more, refer to the section The Variant type below.


Pakollinen muuttujien määrittely

Muuttujien määrittelyn voi tehdä pakolliseksi käyttämällä seuraavaa käskyä:


Option Explicit

Option Explicit -lauseen on oltava moduulin ensimmäisenä rivinä, ennen ensimmäistä SUB-riviä. Yleisesti ottaen, vain taulukot tarvitsevat nimenomaisen määrittelyn. Muut muuttujat tulevat määritellyiksi tyypin määräävällä merkillä tai, sen puuttuessa, oletuksena Single-tyyppisiksi (perusliukuluvuiksi).

Muuttujien tietotyypit

LibreOffice Basic tukee neljää muuttujaluokkaa:

Kokonaislukumuuttujat

Kokonaislukumuuttujien (Integer) arvoalue on -32768 ... 32767. Jos liukulukuarvo sijoitetaan kokonaislukumuuttujaan, desimaalit pyöristetään lähimpään kokonaislukuun. Kokonaislukumuuttujien laskenta on nopeaa ja ne sopivat silmukoiden laskureiksi. Kokonaislukumuuttuja vie vain kaksi tavua muistissa. Tietotyypin määräysmerkkinä on "%".


Dim Variable%
Dim Variable As Integer

Pitkät kokonaislukumuuttujat

Pitkien kokonaislukumuuttujien (Long) arvoalue on -2147483648 ... 2147483647. Jos liukulukuarvo sijoitetaan pitkän kokonaisluvun muuttujaan, desimaalit pyöristetään lähimpään kokonaislukuun. Pitkien kokonaislukumuuttujien laskenta on nopeaa ja ne sopivat silmukoiden laskureiksi, kun arvot ovat suuria. Pitkä kokonaislukumuuttuja vie neljä tavua muistissa. Tyypin määräysmerkkinä on "&".


Dim Variable&
Dim Variable As Long

Desimaalilukumuuttujat

Desimaalilukumuuttujat voivat esittää negatiivisia ja positiivisia lukuja tai arvon nolla. Tarkkuus on jopa 19 numeroa.

Plusmerkkiä (+) ja miinusmerkkiä (-) voi käyttää desimaaliluvun edessä (välilyönnin kanssa tai ilman).

Jos desimaaliluku (liukuluku) sijoitetaan kokonaislukumuuttujaan, LibreOffice Basic pyöristää lukua ylös- tai alaspäin.

Perustarkkuuden liukulukumuuttujat

Single variables can take positive or negative values ranging from 3.402823 x 10E38 to 1.401298 x 10E-45. Single variables are floating-point variables, in which the decimal precision decreases as the non-decimal part of the number increases. Single variables are suitable for mathematical calculations of average precision. Calculations require more time than for Integer variables, but are faster than calculations with Double variables. A Single variable requires 4 bytes of memory. The type-declaration character is "!".


Dim Variable!
Dim Variable As Single

Kaksinkertaisen tarkkuuden liukulukumuuttujat

Double variables can take positive or negative values ranging from 1.79769313486232 x 10E308 to 4.94065645841247 x 10E-324. Double variables are floating-point variables, in which the decimal precision decreases as the non-decimal part of the number increases. Double variables are suitable for precise calculations. Calculations require more time than for Single variables. A Double variable requires 8 bytes of memory. The type-declaration character is "#".


Dim Variable#
Dim Variable As Double

Valuuttamuuttujat

Valuuttamuuttujat (Currency) tallennetaan sisäisesti 64-bittisinä lukuina (8 tavua) ja esitetään kiinteän pilkun desimaalilukuna 15 kokonaisluku- 4 desimaaliosan numerolla. Arvoalue on -922337203685477.5808 ... +922337203685477.5807. Currency-muuttujia käytetään laskettaessa suuren tarkkuuden vaativia valuuttalaskuja. Tietotyypin määräysmerkkinä on "@".


Dim Variable@
Dim Variable As Currency

Literals for integers

Numbers can be encoded using octal and hexadecimal forms.


  xi = &o13 '    8 + 3
  ci = &h65 ' 6*16 + 5
  MAX_Integer =  &o77777 '  32767 = &h7FFF
  MIN_Integer = &o100000 ' -32768 = &h8000
  MAX_Long = &h7fffffff '  2147483647 = &o17777777777
  MIN_Long = &h80000000 ' -2147483648 = &o20000000000

Merkkijonomuuttujat

String variables can hold character strings with up to 2,147,483,648 characters. Each character is stored as the corresponding Unicode value. String variables are suitable for word processing within programs and for temporary storage of any non-printable character up to a maximum length of 2 Gbytes. The memory required for storing string variables depends on the number of characters in the variable. The type-declaration character is "$".

tip

In BASIC String functions, the first character of the string has index 1.



Dim Variable$
Dim Variable As String

Boolen muuttujat

Boolen muuttujilla on vain kaksi (totuus)arvoa: TRUE (tosi) tai FALSE (epätosi). Numero 0 tulkitaan arvoksi FALSE, kaikki muut arvot tulkitaan arvoksi TRUE.


Dim Variable As Boolean

Päivämäärämuuttujat

Päivämäärämuuttujissa (Date) voi olla vain päivämäärä- tai aika-arvoja, jotka on tallennettu sisäiseen erityismuotoon. Arvot, jotka sijoitetaan Date-muuttujiin funktiolla Dateserial, Datevalue, Timeserial ja Timevalue, muuntuvat sisäiseen erityismuotoon. Päivämäärämuuttujat muutetaan tavanomaisiksi luvuiksi käyttämällä funktioita Day, Month ja Year tai Hour, Minute ja Second. Sisäinen muoto tekee mahdolliseksi vertailla päivämäärä- ja aika-arvoja laskemalla kahden luvun erotus. Nämä muuttujat voidaan esitellä eli määritellä vain avainsanalla Date.


Dim Variable As Date

Literals for Dates

Date literals allow to specify unambiguous date variables that are independent from the current language. Literals are enclosed between hash signs #. Possible formats are:


  zeroDay = #12/30/1899#
  dob = #2010-09-28#

The Variant type

Variables declared as Variant can handle any data type. This means that the actual data type is defined during runtime as a value is assigned to the variable.

There are three main ways to create a Variant variable, as shown below:


  Dim varA            ' The type is not specified, hence the variable is a Variant
  Dim varB as Variant ' The variable is explicitly declared as a Variant
  varC = "abc"        ' Previously undeclared variables are treated as Variants

The example below uses the TypeName function to show how the type of a Variant variable changes upon assignment.


  Dim myVar As Variant
  MsgBox TypeName(myVar) ' Empty
  myVar = "Hello!"
  MsgBox TypeName(myVar) ' String
  myVar = 10
  MsgBox TypeName(myVar) ' Integer
note

A Variant variable is initialized with the Empty special data type. You can use the IsEmpty function to test if a variable is an Empty Variant.


You can also use the keyword Any to declare a variable as a Variant. However, Any is deprecated and is available for backward compatibility.

warning

Arguments with type Variant or Any passed in function calls are not checked for their types.



  Dim myVar As Any ' Variable "myVar" is a Variant

Muuttujien alkuarvot

Heti kun muuttuja on määritelty, sen arvo alustetaan samalla "Null"-arvoksi. Katso seuraavia sääntöjä:

Numeeriset muuttujat alustetaan arvoon "0" määriteltäessä.

Päivämäärämuuttujat saavat sisäisen 0-arvon; se vastaa arvon "0" antamista muuttujalle funktiolla Day, Month ja Year tai Hour, Minute ja Second.

Merkkijonomuuttujat alustetaan tyhjällä merkkijonolla ("") määriteltäessä.

Taulukot

LibreOffice Basic tuntee yksi- ja moniulotteiset taulukot, jotka määritellään tietyn tietotyypin mukaan. Taulukot soveltuvat luetteloiden ja taulukoiden muokkaamiseen ohjelmassa. Taulukon yksittäiset alkiot ovat osoitettavissa käyttäen taulukon nimeä ja alkion indeksinumeroa.

Taulukot pitää määritellä Dim-lauseella. Taulukon indeksointi on toteutettavissa useilla erilaisilla tavoilla:


    Dim Text$(20)       '21 elements numbered from 0 to 20'
    Dim Text$(5,4)      '30 elements (a matrix of 6 x 5 elements)'
    Dim Text$(5 To 25)  '21 elements numbered from 5 to 25'
    Dim Text$(-15 To 5) '21 elements (including 0), numbered from -15 to 5'

Indeksiväli voi kattaa niin positiivisia kuin negatiivisiakin lukuja.

Vakiot

Vakioilla on muuttumaton arvo. Ne määritellään vain kerran ohjelmassa eikä niitä voi määritellä myöhemmin uudestaan:


Const ConstName=Expression

Please support us!