AVERAGEIF funtzioa
Emandako irizpide bat betetzen dituen barruti bateko gelaxka guztien batezbesteko aritmetikoa ematen du. AVERAGEIF funtzioak proba logikoekin bat datozen emaitza guztiak batzen ditu eta batuketa hori hautatutako balioen kopuruarekin zatitzen du.
AVERAGEIF(Barrutia; Irizpidea [; BatezbestekoBarrutia ])
Barrutia (derrigorrezko argumentua). Matrize bat, izendun barruti baten izena edo zutabe edo errenkada baten etiketa, batezbestekoa egiteko erabiliko diren zenbakiak edo baldintzaren testua dituena.
Bilaketan komodinak eta adierazpen erregularrak onartzen dira. Adierazpen erregularrak gaitzen badira, "egun.*" sartu daiteke, adibidez, hasieran "egun" duen lehen hitza aurkitzeko. Adierazpen erregularra den testu bat aurkitu nahi izanez gero, erabili "\" karaktere bat horietako edozeinen aurrean edo inguratu testua \Q...\E karaktereekin. Komodinen eta adierazpen erregularren ebaluazio automatikoa aktibatu edo desaktibatu daiteke aukeran.
Adierazpen erregular bat ordezkatzen duten bilaketa-irizpideko kateak diren argumentu bat edo gehiago dituzten funtzioak erabiltzean, lehen aldian kate-irizpide horiek zenbaki bihurtzeko saialdia egingo da. Adibidez, ".0" katea 0.0 bihurtuko da, eta abar. Ongi bihurtzen bada, bat etortzea ez da izango adierazpen erregularreko bat etortzea, baizik eta zenbakizko bat etortzea. Hala ere, dezimalen bereizlea puntua ez den eskualde-ezarpen batean, adierazpen erregularraren bihurketak funtzionatu egingo du. Zenbakizko adierazpen bat sortu ordez adierazpen erregularraren ebaluazioa behartzeko, erabili zenbakitzat hartu ezin daitezkeen adierazpenak, adibidez ".[0]" edo ".\0" edo "(?i).0".
BatezbestekoBarrutia (aukerakoa). Batezbestekoa kalkulatzeko erabiliko diren balioen barrutia.
BatezbestekoBarrutia zehazten ez bada, Barrutia erabiliko da bietarako, batezbestekoaren kalkulurako eta baldintzaren araberako bilaketarako. BatezbestekoBarrutia zehazten bada, Barrutia baldintza-probarako soilik erabiliko da eta BatezbestekoBarrutia batezbestekoaren kalkulurako erabiliko da.
Funtzio hori Open Document Format for Office Applications (OpenDocument) estandarraren 1.2 bertsioan (ISO/IEC 26300:2-2015) dago onartuta.
Batezbestekoa kalkulatzeko balio-barrutiko gelaxka bat hutsik badago edo testua badu, AVERAGEIF funtzioak gelaxka hori ez ikusi egingo du.
Barruti osoa hutsik badago, testua soilik badu edo baldintza betetzen ez duten barruti-balioak baditu, funtzioak #DIV/0! errorea emango du.
Begiratu honako taula
|
A |
B |
C |
|
|---|---|---|---|
|
1 |
Produktuaren izena |
Salmentak |
Diru-sarrerak |
|
2 |
arkatza |
20 |
65 |
|
3 |
luma |
35 |
85 |
|
4 |
koadernoa |
20 |
190 |
|
5 |
liburua |
17 |
180 |
|
6 |
arkatz-kutxa |
ez |
ez |
Beheko adibide guztietan batuketa kalkulatzeko barrutiek #6 errenkada dute, baina hura ez ikusi egingo da testua duelako.
Erabilera sinplea
=AVERAGEIF(B2:B6;"<35")
B2:B6 barrutian 35 baino txikiagoak diren balioen batezbestekoa kalkulatzen du. 19 ematen du, bigarren errenkada ez baita kontuan hartzen kalkuluan.
=AVERAGEIF(B2:B6;"<"&MAX(B2:B6))
Barrutiko balio maximoa baino txikiagoak diren balioen batezbestekoa kalkulatzen du. 19 ematen du, baliorik handiena (bigarren errenkada) ez baita kontuan hartzen kalkuluan.
=AVERAGEIF(B2:B6;">"&SMALL(B2:B6;1))
Barrutiko lehen balio minimoa baino handiagoak diren balioen batezbestekoa kalkulatzen du. 25 ematen du, lehen baliorik txikiena (laugarren errenkada) ez baita kontuan hartzen kalkuluan.
BatezbestekoBarrutia erabiltzea
=AVERAGEIF(B2:B6;"<35";C2:C6)
Funtzioak bilatzen du zein balioak diren 35 baino gutxiago B2:B6 barrutian, eta C2:C6 barrutitik dagozkien balioen batezbestekoa kalkulatzen du. 145 itzultzen du, bigarren errenkadak ez duelako parte hartzen kalkuluan.
=AVERAGEIF(B2:B6;">"&MIN(B2:B6);C2:C6)
Funtzioak bilatzen du B2:B6 barrutiko zein balioak diren B2:B6 barrutiko baliorik txikiena baino handiagoak, eta C2:C6 barrutitik dagozkien balioen batezbestekoa kalkulatzen du. 113,3 itzultzen du, laugarren errenkadak (B2:B6 barrutiko baliorik txikiena duenak) ez duelako parte hartzen kalkuluan.
=AVERAGEIF(B2:B6;"<"&LARGE(B2:B6;2);C2:C6)
Funtzioak bilatzen du B2:B6 barrutiko zein balioak diren B2:B6 barrutiko bigarren baliorik handiena baino txikiagoak, eta C2:C6 barrutitik dagozkien balioen batezbestekoa kalkulatzen du. 180 itzultzen du, laugarren errenkadak soilik hartzen duelako parte kalkuluan.
Adierazpen erregularrak erabiltzea
=AVERAGEIF(A2:A6;"arkatz";B2:B6)
Funtzioak bilatzen du A2:A6 barrutiko zein gelaxkek duten "arkatz" hitza, eta barruti horri dagozkion B2:B6 barrutiko balioen batezbestekoa kalkulatzen du. Funtzioak 20 ematen du, lehen errenkadek soilik hartuko duelako parte kalkuluan. Bilaketa A2:A6 barrutian egingo da, baina balioak B2:B6 barrutitik itzuliko dira.
=AVERAGEIF(A2:A6;"arkatz.*";B2:B6)
Funtzioak bilatzen du A2:A6 barrutiko zein gelaxkek duten "arkatz" hitza, amaieran beste edozein karaktereren edozein kopuru izanda, eta barruti horri dagozkion B2:B6 barrutiko balioen batezbestekoa kalkulatzen du. Funtzioak 20 emango du, baina kontuan izan "arkatz-kutxa" kateak ere baldintza betetzen duelako, eta horregatik, lehen eta azken errenkadek hartuko dutela parte kalkuluan.
=AVERAGEIF(A2:A6;".*liburu.*";B2:B6)
Funtzioak bilatzen du A2:A6 barrutiko zein gelaxkek duten "liburu" hitza, hasieran eta amaieran beste edozein karaktereren edozein kopuru izanda, eta barruti horri dagozkion B2:B6 barrutiko balioen batezbestekoa kalkulatzen du. Funtzioak 17 ematen du, bosgarren errenkadak soilik hartuko baitu parte kalkuluan.
Irizpidetzat gelaxka baten erreferentzia erabiltzea
Irizpide bat erraz aldatu nahi baduzu, beste gelaxka batean zehaztu dezakezu eta gelaxka horren erreferentzia bat erabili AVERAGEIF funtzioaren baldintzan.
=AVERAGEIF(A2:A6;".*"&E2&".*";B2:B6)
Funtzioak bilatzen du A2:A6 barrutiko zein gelaxkek duten E2 gelaxkan zehaztutako karaktereen konbinazio bat, hasietan eta amaieran beste edozein karaktereren edozein kopuru izanda, eta barruti horri dagozkion B2:B6 barrutiko balioen batezbestekoa kalkulatzen du. E2 = liburu bada, funtzioak 17 ematen du.
=AVERAGEIF(B2:B6;"<"&E2;C2:C6)
Funtzioak bilatzen du B2:B6 barrutiko zein gelaxkak E2 gelaxkan zehaztutako balioa baino txikiagoa duten, eta barruti horri C2:C6 barrutian dagozkion balioen batezbestekoa kalkulatzen du. E2 = 35 bada, funtzioak 145 ematen du.