Testu-funtzioak

Atal honek Testua funtzioen deskribapenak ditu.

Komando hau erabiltzeko...

Txertatu - Funtzioa - Testua kategoria


Komatxo bikoitzak erabiltzea formuletan

Formula batean testu-kate bat sartzeko, kokatu katea komatxo bikoitzen artean ("). Calc aplikazioak kateko karaktereak bere hartan hartuko ditu, interpretatzen saiatu gabe. Adibidez, ="Kaixo mundua!" formulak Kaixo mundua! testu-katea erakutsiko du gelaxkan, komatxo bikoitzik gabe.

=CONCATENATE("Bizitza sinplea da, "; "baina konplexu bihurtzen saiatzen gara "; "(Konfuzio).") formula konplexuenak komatxo bikoitza artean dauden hiru kate kateatzen ditu. Irteera honakoa izango da: Bizitza sinplea da, baina konplexu bihurtzen saiatzen gara (Konfuzio).

Formula bateko kate batean komatxo bikoitz literalak kokatzeko, bi metodo erabili daitezke:

  1. Komatxo bikoitzek "ihes egin dezaten", komatxo bikoitz gehigarri bat erabili daiteke. Calc aplikazioak balio literaltzat hartuko du ihes egindako komatxo bikoitza. Adibidez, ="Nire izena ""Jon Etxebarria"" da." formulak Nire izena "Jon Etxebarria" da. katea emango du. Beste adibide sinple bat =UNICODE("""") da: horrek 34 itzuliko du, komatxoaren Unicode karakterearen balio hamartarra (U+0022) alegia — adibide horretan lehen eta laugarren komatxo bikoitzek katearen hasiera eta amaiera adierazten dute, eta bigarren komatxo bikoitza hirugarrenak ihes egin dezan erabili da.

  2. CHAR funtzioa edo UNICHAR funtzioa erabili daiteke komatxo bikoitzak txertatzeko. Adibidez, =UNICHAR(34) & "Narrazioak" & UNICHAR(34) & " Joseba Sarrionandiaren liburu ezaguna da ." formulak "Narrazioak" Joseba Sarrionandiaren liburu ezaguna da. katea erakutsiko du.

Kontuan izan Calc aplikazioak funtzioak automatikoki zuzentzeko duen funtzionaltasunak komatxo bikoitiak aldatu ditzakeela. Autozuzenketak ez lituzke komatxo bikoitiak aldatu beharko formula-gelaxketan, baina testua duten eta formula ez dutenetan bai aldatu ditzakeela. Adibidez, komatxo bikoitien beste forma tipografikoren batez inguratuta dagoen kate bat kopiatzen bada eta formula-gelaxka batean itsasten bada, errore bat gertatu daiteke. Kasu horretakoak dira ezkerreko komatxo bikoitia (U+201C) eta eskuineko komatxo bikoitia (U+201D). Ireki Tresnak - Autozuzenketa-aukerak - Lokalizatutako aukerak elkarrizketa-koadroko Komatxo bikoitzak area eta ezarri hasierako eta amaierako komatxo bikoitz tipografikoak automatikoki zuzentzeko erabiliko diren karaktereak. Desaktibatu Ordeztu botoia eginbide hori desgaitzeko.

ARABIC

Testu gisa adierazita dagoen zenbaki erromatar bati dagokion zenbakizko balioa itzuliko du.

ASC

Byte bikoitzeko (zabalera osoko) karaktereak byte bakarreko (zabalera erdiko) ASCII eta katakana karaktere bihurtzen ditu.

JIS

Byte bakarreko (zabalera erdiko) ASCII edo katakana karaktereak byte bikoitzeko (zabalera osoko) karaktere bihurtzen ditu.

REGEX

Bat etortzeak eta erauzteak egiten ditu, edo aukeran ordezteak egiten ditu, adierazpen erregularrak erabilita.

ROMAN

Zenbaki bat zenbaki erromatar bihurtzen du. Balio-barrutia 0 eta 3999 artekoa da. Sinplifikazio-modu bat zehaztu daiteke 0 eta 4 arteko barrutian.

VALUE

Zenbaki baten kate-irudikapena bere zenbakizko formara bihurtzen du. Emandako katea baliozko data, ordu eta data-ordua bada, hari dagokion data-ordu serieko zenbakia itzuliko da.

WEBSERVICE

Web-edukia URI batetik eskuratzea.

FILTERXML

Aplikatu XPath adierazpen bat XML dokumentu bati.

ENCODEURL

URL kodetuko kate bat itzultzen du.

BAHTTEXT

Zenbaki bat Thailandierazko testura bihurtzen du, thailandiar moneta-izenak barne.

Sintaxia

BAHTTEXT(Zenbakia)

Zenbakia: edozein zenbaki da. "Baht" zenbakiaren osoko zatiari eransten zaio, eta "Satang", berriz, zenbakiaren dezimal zatiari.

Adibidea

=BAHTTEXT(12,65): Thailandierako karaktereekin idatzitako kate bat ematen du, hauxe esan nahi duena: "Hamabi Baht eta hirurogeita bost Satang".

Informazio teknikoa

Funtzio hau ez dago Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format estandarrean. Izen-espazioa honakoa da:

COM.MICROSOFT.BAHTTEXT

BASE

Osoko zenbaki bat zehaztutako oinarri batera bihurtzen du zenbakitze-sistema jakin bateko testu-forman. 0-9 digituak eta A-Z letrak erabiliko dira.

Sintaxia

BASE(Zenbakia; Erroa [; GutxienekoLuzera])

Zenbakia: bihurtu beharreko osoko zenbaki positiboa.

Erroa parametroak adierazten du zenbakizko sistemaren oinarria. 2 eta 36 arteko edozein osoko balio positibo izan daiteke.

GutxienekoLuzera (aukerakoa): sortutako karaktere-sekuentziaren gutxieneko luzera zehazten du. Testua ez bada adierazitako gutxieneko luzerara iristen, zeroak gehituko dira karaktere-katearen ezkerraldean.

Adibidea

=BASE(17;10;4): 0017 ematen du sistema hamartarrean.

=BASE(17;2): 10001 ematen du sistema bitarrean.

=BASE(255;16;4): 00FF ematen du sistema hamaseitarrean.

Ikusi, baita ere

DECIMAL

CHAR

Zenbaki bat karaktere bihurtzen du, uneko kode-taularen arabera. Zenbakia bi digituko nahiz hiru digituko osoko zenbakia izan daiteke.

127 kode baino gehiagokoak sistemaren karaktere-mapaketaren araberakoak izango dira (iso-8859-1, iso-8859-2, Windows-1252, Windows-1250 esate baterako), eta beraz baliteke eramangarria ez izatea.

Sintaxia

CHAR(zenbakia)

Zenbakia: karakterearen kode-balioa adierazten duen 1 eta 255 arteko zenbakia.

Adibidea

=CHAR(100): d karakterea ematen du.

="abc" & CHAR(10) & "def" funtzioak lerro-jauziaren karakterea sartzen du katean.

CLEAN

Inprimatzekoak ez diren karaktereak kendu egingo dira katetik.

Sintaxia

CLEAN(testua)

Testua: inprimatzekoak ez diren karaktereak kendu behar zaizkion testua.

Adibidea

=LEN(CLEAN(CHAR(7) & "LibreOffice Calc" & CHAR(8))) funtzioak 16 itzultzen du, CLEAN funtzioak inprimagarriak ez diren U+0007 ("BEL") eta U+0008 ("BS") Unicode karaktereak ezabatzen dituela kate-argumentuaren hasieran eta amaieran. CLEAN funtzioak ez ditu zuriuneak kentzen.

CODE

Testu-kate bateko lehen karakterearen zenbakizko kodea ematen du.

Sintaxia

CODE(Testua)

Testua: lehen karakterearen kodea zehaztu behar zaion testua da.

127 kode baino gehiagokoak sistemaren karaktere-mapaketaren araberakoak izango dira (iso-8859-1, iso-8859-2, Windows-1252, Windows-1250 esate baterako), eta beraz baliteke eramangarria ez izatea.

Adibidea

=CODE("Hieronymus") funtzioak 72 ematen du; =CODE("hieroglyphic") funtzioak 104 ematen du.

note

Hemen erabilitako kodea ez da ASCII, unean kargatutako kode-taula baizik.


CONCATENATE

Hainbat testu-kate konbinatzen ditu kate bakar batean.

Sintaxia

CONCATENATE(Katea 1 [; Katea 2 [; … [; Katea 255]]])

1. katea[; 2. katea][; … ;[255. katea]] kateak dira edo kateak dituzten gelaxken erreferentziak dira.

Adibidea

=CONCATENATE("Egun";"on";"Arregi. ";"andrea") funtzioak honako hau ematen du: Egun on Arregi andrea.

DECIMAL

Zenbaki bat adierazten duen testua osoko zenbaki positibo bihurtzen du emandako oinarri-erroa duen zenbakizko sistema batean. Erroak 2 eta 36 arteko barrutian egon behar du. Zuriuneei eta tabulazioei ez ikusiarena egiten zaie. Testua eremuak ez ditu maiuskulak/minuskulak kontuan hartzen.

Erroa 16 bada, ez dira kontuan hartuko aurretik dauden x edo X edo 0x edo 0X karaktereak, edo h edo H erantsiak. Erroa 2 bada, ez dira kontuan hartuko b edo B erantsiak. Zenbakizko sistemakoak ez diren beste karaktereek errorea sortzen dute.

Sintaxia

DECIMAL("Testua"; Erroa)

Testua: Bihurtuko den testua.

Erroa: Zenbakizko sistemaren oinarria edo erroa adierazten du. 2 eta 36 arteko osoko edozein zenbaki positibo izan daiteke.

Adibidea

=DECIMAL("17";10): 17 ematen du.

=DECIMAL("FACE";16): 64206 ematen du.

=DECIMAL("0101";2): 5 ematen du.

Ikusi, baita ere

BASE

DOLLAR

Zenbaki bat moneta-formatuko kantitate bat adierazten duen kate bihurtzen du, zehaztutako dezimal kopuruarekin eta uneko eskualde-ezarpenari dagokion dezimal-bereizlea erabiliz. Balioa eremuan, sartu bihurtuko den zenbakia. Aukeran, dezimal kopurua Dezimalak eremuan sartu daiteke. Ez bada baliorik zehazten, moneta-formatuko zenbaki guztiak bi dezimalekin bistaratuko dira.

Sistemaren ezarpenetan ezartzen da moneta-formatua.

Sintaxia

DOLLAR(Balioa [; Dezimalak])

Balioa: zenbaki bat da, zenbaki bat duen gelaxka baten erreferentzia edo zenbaki bat ematen duen formula.

Dezimalak leku dezimalen aukerako kopurua da.

Adibidea

=DOLLAR(255) funtzioak $255.00 itzultzen du ingeleseko (USA) eskualde-ezarpenarekin eta USD (dolar) monetarekin; ¥255.00 itzultzen du japonierako eskualde-ezarpenarekin eta JPY (yen) monetarekin; edo 255,00 € alemanierako (Alemania) eskualde-ezarpenarekin eta EUR (euro) monetarekin.

=DOLLAR(367.456;2) funtzioak $367.46 itzultzen du.

EXACT

Bi testu-kate konparatzen ditu, eta TRUE ematen du berdinak baldin badira. Funtzio honek maiuskulak eta minuskulak bereizten ditu.

Sintaxia

EXACT(testua_1;testua_2)

Testua1: konparatzeko lehen testua.

Testua2: konparatzeko bigarren testua.

Adibidea

=EXACT("microsystems";"Microsystems") FALSE itzultzen du.

FIND

Testu-kate batek beste kate baten barruan duen kokapena itzultzen du. Bilaketa non hasi ere defini dezakezu. Bilaketa-terminoa zenbaki bat edo edozein karaktere-kate izan daiteke. Bilaketak maiuskulak eta minuskulak bereizten ditu.

Sintaxia

FIND("BilaketaTestua"; "Testua" [; Kokagunea])

BilaketaTestua: bilatu nahi den testua.

Testua: bilaketa zein testutan egingo den zehazten du.

Kokagunea: (aukerakoa): testuko kokagune horretatik hasiko da bilaketa.

Adibidea

=FIND(76;998877665544): 6 ematen du.

FIXED

Zenbakia testu gisa itzultzen du dezimalen eta aukerako milako bereizleen kopuru jakin batekin.

Sintaxia

FIXED(Zenbakia; Dezimalak = 2 [; MilakoenBereizlerikEz = FALSE]])

Zenbakia biribildu egingo da Dezimalak tokiekin (dezimalen bereizlearen ondoren) eta emaitzari testuaren formatua emango zaio eskualde-ezarpenaren araberako ezarpenak erabilita.

Dezimalak (aukerakoa) parametroak bistaratuko den dezimal kopurua adierazten du. Dezimalak negatiboa bada, Zenbakia biribildu egingo da ABS(Dezimalak) tokietara dezimalen markatik ezkerrera. Dezimalak zatiki bat bada, moztu egingo da eta ez ikusiarena egingo zaio osoko zenbaki hurbilenari.

MilakoenBereizlerikEz (aukerakoa) parametroak milakoen bereizlea erabiliko den ala ez zehazten du. TRUE bada edo zero ez bada, talde-bereizleak ez dira erabiliko emaitza gisa sortuko den katean. Parametroa 0 bada edo ez bada eman, uneko hizkuntza-ezarpenaren milakoen bereizlea erabiliko da.

Adibidea

=FIXED(1234567,89;3) funtzioak 1.234.567,890 itzultzen du testu-kate gisa.

=FIXED(123456.789;;TRUE) funtzioak 123456.79 itzultzen du testu-kate gisa.

=FIXED(12345.6789;-2) funtzioak 12.300 itzultzen du testu-kate gisa.

=FIXED(12134567.89;-3;1) funtzioak 12135000 itzultzen du testu-kate gisa.

=FIXED(12345.789;3/4) funtzioak 12,346 itzultzen du testu-kate gisa.

=FIXED(12345.789;8/5) funtzioak 12.345,8 itzultzen du testu-kate gisa.

LEFT

Testu-kateko lehen karakterea edo karaktereak ematen ditu.

Sintaxia

LEFT("Testua" [; Zenbakia])

Testua: hasierako hitz partzialak zehazteko testua.

Zenbakia (aukerakoa): hasierako testuaren karaktere kopurua zehazten du. Parametro hau definitzen ez bada, karaktere bat emango du funtzioak.

Adibidea

=LEFT("irteera";3): “irt” ematen du.

LEFTB

DBCS testu-kateko lehen karakterea ematen ditu.

tip

Funtzio hau LibreOffice 4.2 bertsiotik dago erabilgarri.


Sintaxia

LEFTB("Testua" [; Byte_kopurua])

Testua: hasierako hitz partzialak zehazteko testua.

Byte_kopurua (aukerakoa): LEFTB funtzioak aterako dituen karaktere kopurua zehazten du. Parametro hau definitzen ez bada, karaktere bat emango du funtzioak.

Adibidea

=LEFTB("中国";1) funtzioak " " itzultzen du (byte 1 DBCS karaktere baten erdia da eta, hori dela eta, zuriune-karaktere bat itzultzen da).

=LEFTB("中国";2) funtzioak "中" itzultzen du (2 bytek DBCS karaktere oso bat osatzen dute).

=LEFTB("中国";3) funtzioak "中 " itzultzen du (3 bytek DBCS karaktere bat eta erdi osatzen dute; itzulitako azken karakterea zuriune bat izango da).

=LEFTB("中国";4) funtzioak "中国" itzultzen du (4 bytek bi DBCS karaktere oso egiten dute).

=LEFTB("office";3) funtzioak "off" itzultzen du (DBCS ez diren 3 karaktere, bakoitza 1 bytekoa).

LEN

Kate baten luzera ematen du, zuriuneak barne.

Sintaxia

LEN("testua")

Testua: luzera zehaztu beharreko testua da.

Adibidea

=LEN("Egun zoragarria"): 15 ematen du.

=LEN(12345,67): 8 ematen du.

LENB

Byte bikoitzeko karaktere multzoko (DBCS) hizkuntzetarako, karaktereak testu-kate batean ordezkatzeko erabiltzen den byte kopurua ematen du.

tip

Funtzio hau LibreOffice 4.2 bertsiotik dago erabilgarri.


Sintaxia

LENB("Testua")

Testua: luzera zehaztu beharreko testua da.

Adibidea

LENB("中"): 2 ematen du (2 byte dituen DBCS karaktere bat).

LENB("中国"): 4 ematen du (bakoitzak 2 byte dituen 2 DBCS karaktere).

LENB("office"): 6 ematen du (bakoitzak byte 1 duen eta DBCS ez diren 6 karaktere).

=LENB("Egun zoragarria"): 15 ematen du.

=LENB(12345,67): 8 ematen du.

LOWER

Testu-kateko letra maiuskula guztiak minuskula bihurtzen ditu.

Sintaxia

LOWER("testua")

Testua: bihurtu beharreko testua.

Adibidea

=LOWER("Eguzkia"): eguzkia ematen du.

MID

Testu baten testu-katea ematen du. Parametroek hasierako kokagunea eta karaktere kopurua adierazten dute.

Sintaxia

MID("testua"; hasiera; kopurua)

Testua: erauzi beharreko karaktereak dituen testua da.

Hasiera: karaktereak atera behar zaizkion testuan lehen karaktereak duen kokagunea.

Zenbakia (aukerakoa): testu zatiko karaktere kopurua zehazten du.

Adibidea

=MID("office";2;2): ff ematen du.

MIDB

DBCS testu baten testu-katea itzultzen du. Parametroek hasierako kokagunea eta karaktere kopurua adierazten dute.

tip

Funtzio hau LibreOffice 4.2 bertsiotik dago erabilgarri.


Sintaxia

MIDB("Testua"; Hasiera; Byte_kopurua)

Testua: erauzi beharreko karaktereak dituen testua da.

Hasiera: karaktereak atera behar zaizkion testuan lehen karaktereak duen kokagunea.

Byte_kopurua: MIDBk testutik emango duen karaktere kopurua, bytetan, zehazten du.

Adibidea

=MIDB("中国";1;0) funtzioak "" itzultzen du (0 byte hutsik dagoen katea da beti).

=MIDB("中国";1;1) funtzioak " " itzultzen du (byte 1 DBCS karaktere baten erdia da eta, hori dela eta, zuriune-karaktere bat itzultzen da).

=MIDB("中国";1;2) funtzioak "中" itzultzen du (2 bytek DBCS karaktere oso bat osatzen dute).

=MIDB("中国";1;3) funtzioak "中 " itzultzen du (3 byte DBCS karaktere bat eta erdi dira; azken byteak zuriune bat itzultzen du).

=MIDB("中国";1;4) funtzioak "中国" itzultzen du (4 bytek bi DBCS karaktere oso egiten dute).

=MIDB("中国";2;1) funtzioak " " itzultzen du (2 byte-kokagunea ez dago karaktere baten hasieran DBCS kate batean; zuriune bat itzultzen da).

=MIDB("中国";2;2) funtzioak " " itzultzen du (2 byte-kokaguneak DBCS kateko lehen karakterearen azken erdira apuntatzen du; eskatutako 2 byte-ak, beraz, lehen karakterearen azken erdia eta bigarren karakterearen lehen erdia dira; beraz, 2 zuriune-karaktere itzultzen dira).

=MIDB("中国";2;3) funtzioak " 国" itzultzen du (2 byte-kokagunea ez dago DBCS kate bateko karaktere baten hasieran; zuriune-karaktere bat itzuliko da 2 byte-kokagunerako).

=MIDB("中国";3;1) funtzioak " " itzultzen du (3 byte-kokagunea DBCS kate bateko karaktere baten hasieran dago, baina byte 1 DBCS karaktere baten erdia besterik ez da, eta beraz, zuriune-karaktere bat itzultzen da).

=MIDB("中国";3;2) funtzioak "国" itzultzen du (3 byte-kokagunea DBCS kate bateko karaktere baten hasieran dago, eta 2 byte-k DBCS karaktere bat osatzen dute).

=MIDB("office";2;3) funtzioak "ffi" itzultzen du (2 byte-kokagunea DBCS ez den kate bateko karaktere baten hasieran dago, eta 3 byte, DBCS ez den kate batean, 3 karaktere dira).

PROPER

Testu-kate bateko hitz guztietako lehen letra maiuskulaz ipintzen du.

Sintaxia

PROPER("testua")

Testua: bihurtu beharreko testua.

Adibidea

=PROPER("the document foundation") funtzioak 'The Document Foundation' itzultzen du.

REPLACE

Testu-kate baten zati bat ordezten du beste testu-kate batekin. Funtzio hau karaktereak nahiz zenbakiak ordezteko erabil daiteke (zenbakiak normalean testu bihurtzen dira). Funtzioaren emaitza testu gisa bistaratzen da beti. Gero kalkuluak egin nahi badituzu testu bihurtu den zenbaki batekin, berriro zenbaki bihurtu beharko duzu VALUE funtzioarekin.

Zenbakiak dituen edozein testu komatxoen artean idatzi behar da, ez baduzu nahi zenbaki gisa interpretatu eta automatikoki testu bihurtzea.

Sintaxia

REPLACE("Testua"; Kokagunea; Luzera; "TestuBerria")

Testua: zati bat ordeztuko zaion testua.

Kokagunea: testuaren barruan ordezpen-prozesua hasiko den tokia.

Luzera: Testua katean ordeztu beharreko karaktere kopurua.

Testu berria: Testua ordeztuko duen testua.

Adibidea

=REPLACE("1234567";1;1;"444"): "444234567" ematen du. 1 kokaguneko karaktere bat Testu berri osoak ordeztuko du.

REPT

Karaktere-kate bat zehaztutako kopia kopuruarekin errepikatuko du.

Sintaxia

REPT("testua"; kopurua)

Testua: errepikatu beharreko testua.

Kopurua: errepikapenen kopurua.

Adibidea

=REPT("Egun on";2): Egun onEgun on ematen du.

tip

Begiratu REPT wiki-orria funtzio horri buruzko xehetasun gehiago jasotzeko.


RIGHT

Testu baten azkenengo karakterea edo karaktereak itzultzen du.

Sintaxia

RIGHT("Testua" [; Zenbakia])

Testua: eskuineko zatia zehaztu behar zaion testua.

Zenbakia (aukerakoa): Testuak eskuineko aldean duen karaktere kopurua zehazten du. Parametro hau definitzen ez bada, karaktere bat emango du funtzioak.

Adibidea

=RIGHT("Eguzkia";2): ia ematen du.

RIGHTB

Byte bikoitzeko karaktere multzoak (DBCS) dituen testu bateko azken karakterea edo karaktereak ematen ditu.

tip

Funtzio hau LibreOffice 4.2 bertsiotik dago erabilgarri.


Sintaxia

RIGHTB("Testua" [; Byte_kopurua])

Testua: eskuineko zatia zehaztu behar zaion testua.

Byte_kopurua (aukerakoa): RIGHTB funtzioak aterako dituen karaktere kopurua, bytetan oinarrituta, zehazten du. Parametro hau definitzen ez bada, byte bat emango du funtzioak.

Adibidea

RIGHTB("中国";1) " " ematen du (byte 1 DBCS karaktere baten erdia da eta, hori dela eta, zuriune-karaktere bat itzultzen da).

RIGHTB("中国";2): "国" ematen du (2 byte-k DBCS karaktere oso bat osatzen dute).

RIGHTB("中国";3): " 国" ematen du (3 byte-k DBCS karaktere baten erdi bat eta DBCS karaktere oso bat osatzen dute; zuriune bat itzultzen da lehen erdirako).

RIGHTB("中国";4): "中国" ematen du (4 byte-k bi DBCS karaktere oso egiten dute).

RIGHTB("office";3): "ice" ematen du (DBCS ez diren 3 karaktere, bakoitza 1 byte-koa).

SEARCH

Testu-segmentu batek karaktere-kate batean duen kokagunea ematen du. Nahi izanez gero, bilaketa non hasiko den zehaztu dezakezu. Bilaketa-testua zenbaki bat edo edozein karaktere-sekuentzia izan daiteke. Bilaketak ez ditu maiuskulak eta minuskulak bereizten. Testua aurkitzen ez bada, 519 errorea (#VALUE) itzultzen du.

Bilaketan komodinak eta adierazpen erregularrak onartzen dira. Adierazpen erregularrak gaitzen badira, "egun.*" sartu daiteke, adibidez, hasieran "egun" duen lehen hitza aurkitzeko. Adierazpen erregularra den testu bat aurkitu nahi izanez gero, erabili "\" karaktere bat horietako edozeinen aurrean edo inguratu testua \Q...\E karaktereekin. Komodinen eta adierazpen erregularren ebaluazio automatikoa aktibatu edo desaktibatu daiteke - LibreOffice Calc - Kalkulatu aukeran.

warning

Adierazpen erregular bat ordezkatzen duten bilaketa-irizpideko kateak diren argumentu bat edo gehiago dituzten funtzioak erabiltzean, lehen aldian kate-irizpide horiek zenbaki bihurtzeko saialdia egingo da. Adibidez, ".0" katea 0.0 bihurtuko da, eta abar. Ongi bihurtzen bada, bat etortzea ez da izango adierazpen erregularreko bat etortzea, baizik eta zenbakizko bat etortzea. Hala ere, dezimalen bereizlea puntua ez den eskualde-ezarpen batean, adierazpen erregularraren bihurketak funtzionatu egingo du. Zenbakizko adierazpen bat sortu ordez adierazpen erregularraren ebaluazioa behartzeko, erabili zenbakitzat hartu ezin daitezkeen adierazpenak, adibidez ".[0]" edo ".\0" edo "(?i).0".


Sintaxia

SEARCH("BilaketaTestua"; "Testua" [; Kokagunea])

BilaketaTestua: bilatu beharreko testua.

Testua: bilaketa zein testutan egingo den zehazten du.

Kokagunea: (aukerakoa): testuko kokagune horretatik hasiko da bilaketa.

Adibidea

=SEARCH(54;998877665544): 10 ematen du.

SUBSTITUTE

Kate bateko testu zaharra testu berriarekin ordezten du.

Sintaxia

SUBSTITUTE("Testua"; "BilaketaTestua"; "TestuBerria" [; Agerraldia])

Testua: testu-segmentuak trukatu behar zaizkion testua.

Bilatutako_testua: (hainbat aldiz) ordeztu beharreko testu-segmentua.

Testu berria: testu-segmentua ordeztuko duen testua.

Agerraldia (aukerakoa): bilatutako testuaren zein agerraldi ordeztu behar den zehazten du. Parametro hau agertzen ez bada, agerraldi guztiak ordeztuko dira.

Adibidea

=SUBSTITUTE("123123123";"3";"abc"): 12abc12abc12abc ematen du.

=SUBSTITUTE("123123123";"3";"abc";2): 12312abc123 ematen du.

T

Funtzio honek helburuko testua itzultzen du, edo testu-kate huts bat, helburua testua ez bada.

Sintaxia

T(balioa)

Balioa testu-kate bat da, edo testu-kate bati egiten dio erreferentzia; T-k testu-atea itzultzen du, edo, bestela, testu-kate huts bat.

Adibidea

=T(12345): kate huts bat ematen du.

=T("12345"): 12345 ematen du.

TEXT

Balio bat testu bihurtzen du emandako formatu baten arabera.

Sintaxia

TEXT(Balioa; Formatua)

Balioa: Bihurtuko den balioa (zenbakizkoa edo testuzkoa) da.

Formatua: formatua definitzen duen testua. Gelaxka-formatuan ezarritako hizkuntzaren araberako dezimal eta milakoen bereizleak erabili.

Adibidea

=TEXT(12,34567;"###.##"): 12,35 testua ematen du

=TEXT(12,34567;"000,00"): 012,35 testua ematen du

=TEXT("xyz";"=== @ ===") funtzioak === xyz === testua itzultzen du

tip

Ikus baita ere Zenbakien formatu-kodeak: erabiltzaileak definitutako formatu-kode pertsonalizatuak.


TRIM

Kate bateko zuriuneak kentzen ditu, zuriune-karaktere bakar bat utziz hitzen artean.

Sintaxia

TRIM("Testua")

Testua zuriuneak kenduko zaizkion testua da.

Adibidea

=TRIM(" kaixo mundua "): 'kaixo mundua' ematen du, aurreko eta atzeko zuriuneak kenduta eta hitzen artean zuriune bakarrak utzita.

UNICHAR

Kode-zenbaki bat Unicode karaktere edota letra bihurtzen du.

Sintaxia

UNICHAR(zenbakia)

Adibidea

=UNICHAR(169): © copyright-karakterea ematen du.

tip

Ikus, baita ere, UNICODE() funtzioa.


UNICODE

Testu-kate bateko lehen Unicode karakterearen zenbakizko kodea ematen du.

Sintaxia

UNICODE("Testua")

Adibidea

=UNICODE("©"): copyright-karakterearen 169 Unicode zenbakia ematen du.

tip

Ikusi, baita ere, UNICHAR() funtzioa.


UPPER

Testua eremuan zehaztutako karaktere-katea maiuskuletara bihurtzen du.

Sintaxia

UPPER(testua)

Testua: maiuskuletara bihurtu nahi dituzun minuskulak.

Adibidea

=UPPER("Egun on"): EGUN ON ematen du.

Emaguzu laguntza!