Kalkulu-orrietako funtzioak

Kalkulu-orria funtzioen deskribapenak eta adibideak aurkituko dituzu atal honetan.

ERROR.TYPE

Errore mota espezifiko bat ordezkatzen duen zenbaki bat ematen du, edo #E/E errore-balioa, errorerik ez badago.

STYLE

Applies a style to the cell containing the formula.

ADDRESS

Gelaxkaren erreferentzia ematen du testu moduan, zehaztutako errenkada- eta zutabe-zenbakien arabera. Nahi izanez gero, erreferentzia nola interpretatuko den defini dezakezu: helbide absolutu gisa (adib. $A$1), helbide erlatibo gisa (A1), edo modu mistoan (A$1 edo $A1). Orriaren izena ere zehatz dezakezu.

Elkarrerabilgarriak izan daitezen, ADDRESS eta INDIRECT funtzioek parametro gehigarri bat onartzen dute, ohiko A1 notazioaren ordez R1C1 helbide-notazioa erabiliko den edo ez zehazteko.

ADDRESS funtzioan, parametroa laugarren parametro gisa sartzen da, aukerako orri-izenaren parametroa bosgarren lekura eramanez.

INDIRECT funtzioan, parametroa bigarren parametro gisa txertatzen da.

Bi funtzioetan, argumentua 0 balioarekin txertatzen bada, orduan R1C1 notazioa erabiliko da. Argumentua ez bada zehazten edo 0 ez den balio bat badauka, orduan A1 notazioa erabiliko da.

R1C1 notazioaren kasuan, ADDRESS funtzioak '!' orri-izenen bereizle gisa erabiliz ematen ditu helbide-kateak, eta INDIRECT funtzioak harridura-marka erabiltzea espero du orri-izenen bereizle gisa. Bi funtzioek puntua ('.') erabiltzen dute orri-izenen bereizle gisa A1 notazioarekin.

ODF 1.0/1.1 formatuko dokumentuak irekitzean, orri-izena laugarren parametro gisa erakusten duten ADDRESS funtzioek orri-izen hori bosgarren parametro izateko mugituko dute. 1 balioa daukan laugarren parametro bat txertatuko da.

Dokumentu bat ODF 1.0/1.1 formatuan gordetzean, ADDRESS funtzioak laugarren parametro bat badauka, parametro hori kendu egingo da.

ADDRESS(Errenkada; Zutabea [; Abs [; A1 [; "Orria"]]])

Errenkada: gelaxka-erreferentziaren errenkada-zenbakia

Zutabea: gelaxka-erreferentziaren zutabe-zenbakia (letra ez)

Abs argumentuak erreferentzia mota zehazten du:

1: absolutua ($A$1)

2: errenkada-erreferentziaren mota absolutua da; zutabe-erreferentzia, aldiz, erlatiboa (A$1)

3: errenkada (erlatiboa); zutabea (absolutua) ($A1)

4: erlatiboa (A1)

A1 (aukerakoa) - 0 ezartzen bada, R1C1 notazioa erabiliko da. Parametro hori ez bada agertzen edo 0 ez den beste balio bat ezarri bazaio, A1 notazioa erabiliko da.

Orria: orriaren izena adierazten du. Komatxo bikoitzen artean ipini behar da.

Adibidea:

=ADDRESS(1;1;2;;"Orria2") formulak hau ematen du: Orria2.A$1

Goiko formula uneko orriaren B2 gelaxkan badago, eta 2. orriko A1 gelaxkak -6 balioa badu, gelaxka horri zeharkako erreferentzia egin diezaiokezu B2 gelaxkan funtzio bat ipinita, =ABS(INDIRECT(B2)) sartuta. Emaitza izango da B2 gelaxkan zehaztutako gelaxka-erreferentziaren balio absolutua; kasu honetan, 6.

AREAS

Barruti anizkoitz batean zenbat barruti dauden ematen du.. Barruti bat elkarren ondoko gelaxken barrutia edo gelaxka bakarra izan daiteke.

Funtzio honek argumentu bakar bat espero du. Hainbat barruti zehazten badituzu, parentesi gehigarrien artean jarri behar dituzu. Hainbat barruti sar ditzakezu puntu eta koma (;) bereizle gisa erabiliz, baina hori automatikoki bihurtzen da tilet (~) eragile. Tiletak barrutiak elkartzeko erabiltzen dira.

AREAS(Erreferentzia)

Erreferentzia: gelaxka baten edo gelaxka-barruti baten erreferentzia.

=AREAS((A1:B3;F2;G1)): 3 ematen du, hiru gelaxkaren/barrutiaren erreferentzia baita. Ondoren, sarrera honen arabera bihurtuko da: =AREAS((A1:B3~F2~G1)).

=AREAS(All) funtzioak 1 emango du, aurretik Datuak - Definitu barrutia aukeran area bat definitu baduzu.

CHOOSE

Balio bat aukeratzen du gehienez 30 balio-argumentu dituen zerrenda batetik.

CHOOSE(Indizea; Balioa 1 [; Balioa 2 [; ... [; Balioa 30]]])

Indizea: 1 eta 30 bitarteko erreferentzia edo zenbaki bat da, zerrendatik zein balio hartu behar duen adierazten duena.

Balioa 1, Balioa 2, ..., Balioa 30 gelaxka baten erreferentzia gisa edo banakako balio gisa sartutako balioen zerrenda da.

=CHOOSE(A1;B1;B2;B3;"Gaur";"Bihar";"Bihar") formulak, adibidez, B2 gelaxkaren balioa itzuliko du 'A1 = 2'rentzat; 'A1 = 4'rentzat, aldiz, funtzioak "Gaur" testua emango du.

COLUMN

Gelaxka-erreferentzia baten zutabe-zenbakia itzultzen du. Erreferentzia gelaxka bat bada, gelaxka horrek zutabe-zenbakia itzuliko da; parametroa gelaxka-area bat bada, hari dagozkion zutabe-zenbakiak itzuliko dira errenkada bakarreko matrize gisa formula matrize-formula gisa sartzen bada. Area-erreferentziako parametro bat duen COLUMN funtzioa ez bada erabiltzen matrize-formula baterako, areako lehen gelaxkaren zutabe-zenbakia soilik zehaztuko da.

COLUMN([Erreferentzia])

Erreferentzia: lehen zutabearen zenbakia zehaztu behar zaion gelaxkaren erreferentzia.

Erreferentziarik sartzen ez bada, formula sartutako gelaxkaren zutabe-zenbakia aurkituko du. LibreOffice Calc-ek automatikoki ezartzen dio erreferentzia uneko gelaxkari.

=COLUMN(A1) berdin 1. A zutabea da taulako lehen zutabea.

=COLUMN(C3:E3) berdin 3. C zutabea da taulako hirugarren zutabea.

=COLUMN(D3:G10) funtzioak 4 ematen du; izan ere, D zutabea taulako laugarren zutabea da eta COLUMN funtzioa ez da erabiltzen matrize-formula gisa. (Horrelakoetan, beti matrizearen lehen balioa erabiltzen da emaitza gisa).

{=COLUMN(B2:B7)} eta =COLUMN(B2:B7) biek 2 itzultzen dute, erreferentziak soilik B zutabea daukalako taulako bigarren zutabe gisa. Zutabe bakarreko areek soilik zutabearen zenbaki bakarra dutenez, berdin dio formula formula-matrize gisa erabiltzen den edo ez.

=COLUMN(): 3 ematen du, formula C zutabean sartu bada.

{=COLUMN(Untxia)}: errenkada bakarreko matrizea (3, 4) ematen du, "Untxia" bada barruti izenduna (C1:D3).

COLUMNS

Erreferentziaren zutabe kopurua ematen du.

COLUMNS(matrizea)

Matrizea: zutabe kopuru totala kalkulatu behar zaion gelaxka-barrutiaren erreferentzia. Argumentua gelaxka bakarra ere izan daiteke.

=COLUMNS(B5): 1 ematen du, gelaxka batek zutabe bakarra baitu.

=COLUMNS(A1:C5) 3 ematen du. Erreferentziak hiru zutabe ditu.

=COLUMNS(Untxia): 2 ematen du Untxia bada barruti izenduna (C1:D3).

DDE

DDE esteka baten emaitza ematen du. Estekatutako barrutiko edo ataleko edukia aldatzen bada, emaitzaren balioa ere aldatu egingo da. Eguneratutako estekak ikusteko, berriro kargatu behar duzu kalkulu-orria, edo Editatu - Estekak aukeratu. Plataformen arteko estekak ez dira onartzen; adibidez, Windows makina batean exekutatzen ari den LibreOffice instalazio batetik Linux makina batean sortutako dokumentu batera.

DDE("Zerbitzaria"; "Fitxategia"; "Barrutia" [; Modua])

Zerbitzaria: zerbitzari-aplikazioaren aukera da. LibreOfficeaplikazioek "soffice" zerbitzari-izena izaten dute.

Fitxategia: fitxategi-izen osoa, bide-izena zehaztuta.

Barrutia: ebaluatu beharreko datuen barrutia.

Modua: DDE zerbitzariak datuak zenbaki nola bihurtzen dituen kontrolatzeko aukerako parametroa.

Mode	Effect
0 edo ezer ez	Zenbaki-formatua gelaxka-estilo "lehenetsitik"
1	Datuak beti interpretatzen dira AEBetako ingelesaren formatu estandarrean
2	Datuak testu gisa maneiatzen dira; ez dira zenbaki-formatura bihurtzen

=DDE("soffice";"c:\office\document\data1.ods";"Orria1.A1") funtzioak LibreOffice Calc-en data1.ods kalkulu-orriko Orria1 orriko A1 gelaxkako edukia irakurtzen du.

=DDE("soffice";"c:\office\document\motto.odt";"Today's motto") funtzioak lema bat ematen du formula honen gelaxkan. Lehendabizi, motto.odt dokumentuan lerro bat sartu behar duzu lemaren testua duena; ondoren, Today’s Motto (Gaurko Lema) izeneko sekzioko lehen lerro gisa definitu behar da (LibreOffice Writerren, Txertatu - Sekzioa aukeran). Lema aldatzen (eta gordetzen) bada LibreOffice Writer dokumentuan, lema hori eguneratu egingo da DDE esteka hori definituta duten LibreOffice Calc fitxategiaren gelaxka guztietan.

ERRORTYPE

Gelaxka batean gertatutako errore bati dagokion errore-balioa ematen du. Zenbaki horren laguntzarekin, errore-mezuaren testua sor dezakezu.

ERRORTYPE(Erreferentzia)

Erreferentzia: errorea gertatzen den gelaxkaren helbidea.

A1 gelaxkak Err:518 bistaratzen badu, =ERRORTYPE(A1) funtzioak 518 zenbakia ematen du.

ORG.OPENOFFICE.ERRORTYPE

GETPIVOTDATA

GETPIVOTDATA funtzioak taula dinamiko baten emaitza-balioa itzultzen du. Balioa eremuen eta elementuen izenen bidez adierazten da, beraz baliozkoa da taula dinamikoaren diseinua aldatzen bada ere.

Bi sintaxi-definizio desberdin erabil daitezke:

GETPIVOTDATA(HelburukoEremua; TaulaDinamikoa[; 1. eremua; 1. eremua][; ... [126. eremua; 126. elementua]])

edo

GETPIVOTDATA(TaulaDinamikoa; Murriztapenak)

Bigarren sintaxia erabiliko da, bi parametro berdin ematen badira, eta horietatik lehen parametroa gelaxka edo gelaxka-barruti baten erreferentzia bada. Lehen sintaxia erabiliko da beste kasu guztietan. Funtzioen morroiak lehen sintaxia erakutsiko du.

Lehen sintaxia

HelburuEremua taula dinamikoko datu-eremu bat hautatzen duen kate bat da. Katea iturburu-zutabearen izena izan daiteke, edo taulan erakusten den datu-eremuaren izena (esaterako "Batuketa - Salmentak").

TaulaDinamikoa taula dinamiko batean kokatuta dagoen edo taula dinamiko bat duen gelaxka baten edo gelaxka-barruti baten erreferentzia da. Gelaxka-barrutiak taula dinamiko bat baino gehiago badu, sortutako azken taula erabiliko da.

n. eremua / n. elementua bikoterik ematen ez bada, total orokorra itzuliko da. Bestela, bikote bakoitzak emaitzak bete behar duen murriztapen bat gehituko du. n. eremua taula dinamikoko eremu baten izena da. n. elementua eremu horretako elementu baten izena da.

Taula dinamikoak murriztapen guztiak betetzen dituen emaitza bakarra badu, edo bat datozen balio guztiak laburbiltzen dituen emaitza subtotal bat badu, emaitza hori itzuliko da. Bat datorren emaitzarik ez badago, edo subtotala duten hainbat badaude, errore bat itzuliko da. Baldintza horiek taula dinamikoan sartuta dauden emaitzei aplikatzen zaizkie.

Iturburu-datuek taula dinamikoaren ezarpenen bidez ezkutatutako sarrerak badituzte, horiek ez ikusi egingo dira. Eremua/elementua bikotearen ordena ez da esanguratsua. Eremuen eta elementuen izenetan ez dira maiuskulak eta minuskulak bereizten.

Iragazki baterako murriztapenik ematen ez bada, eremuan hautatutako balioa erabiliko da. Iragazki baterako murriztapen bat ematen bada, eremuan hautatutako balioarekin bat etorri behar du, bestela errorea itzuliko da. Iragazkiak taula dinamikoaren goian ezkerrean dauden eremuak dira, taula dinamikoaren diseinu-koadroko "Iragazkiak" area erabilita betetzen direnak. Iragazki bakoitzerako, elementu (balio) bat hautatu daiteke, alegia, elementu hori besterik ez da sartuko kalkuluan.

Taula dinamikoko balio subtotalak "auto" funtzioa badarabilte soilik erabiliko dira (murriztapenean adierazita dagoenean salbu, ikusi Bigarren sintaxia behean).

Bigarren sintaxia

TaulaDinamikoa balioak lehen sintaxian duen esanahi bera du.

Murriztapenak: zuriunez bereizitako zerrenda bat da. Sarrerak komatxo (komatxo bakun) artean jar daitezke. Karaktere-kate osoa komatxoen (komatxo bikoitzen) artean jarri behar da, beste gelaxka bateko karaktere-katea erreferentziatzen ez baduzu.

Sarreretako bat datu-eremuaren izena izan daiteke. Datu-eremuaren izena kanpoan utzi daiteke taula dinamikoak datu-eremu bakarra badu, bestela presente egon behar du.

Gainerako sarreretako bakoitzak murriztapen bat zehazten du, Eremua[Elementua] forman ([ eta ] karaktere literalekin), edo soilik Elementua, elementu-izena bakarra bada taula dinamikoak darabiltzan eremu guztien artean.

Funtzio-izen bat Eremua[Elementua;Funtzioa] gisa gehi daiteke, eta horrek funtzio hori erabiltzen duten subtotal-balioekin bakarrik bat etortzera behartuko du murriztapena. Funtzio-izen posibleak: Sum, Count, Average, Max, Min, Product, Count (zenbakiak soilik), StDev (lagina), StDevP (populazioa), Var (lagina) eta VarP (populazioa), maiuskulak/minuskulak bereizi gabe.

HLOOKUP

Balio bat bilatzen du eta hautatutako barrutiaren azpiko gelaxkei erreferentzia egiten die. Matrize baten lehen errenkadak balio jakin bat duen egiaztatzen du funtzio honek. Orduan funtzioak matrizearen errenkada batean ematen du balioa. Indizea aukerak esleitzen du errenkada, matrizearen zutabe berean.

HLOOKUP(Kontsulta; Matrizea; Indizea [; BarrutiOrdenatuarenKontsulta])

Parametroen azalpena ezagutzeko, ikus: VLOOKUP (zutabeak eta errenkadak trukatuta daude)

Demagun datu-base txiki bat eraiki dugula A1:DO4 gelaxka-barrutian, eta datu-base horrek 118 elementu kimikori buruzko informazioa duela. Lehen zutabeak 'Elementua', 'Ikurra', 'Zenbaki atomikoa' eta 'Masa atomiko erlatiboa' errenkada-izenburuak ditu. Gainerako zutabeek elementu bakoitzaren informazioa dute, eta elementuak ezkerretik eskuinera ordenatuta daude zenbaki atomikoaren arabera. Adibidez, B1:B4 gelaxkek 'Hidrogenoa', 'H', '1' eta '1.008' balioak dituzte, eta DPO1:DO4 gelazkek 'Oganesona', 'Og', '118' eta '294' balioak dituzte.

	A	B	C	D	...	DO
1	Elementua	Hidrogenoa	Helioa	Litioa	...	Oganesona
2	Ikurra	H	He	Li	...	Og
3	Zenbaki atomikoa	1	2	3	...	118
4	Masa atomiko erlatiboa	1.008	4.0026	6.94	...	294

=HLOOKUP("Beruna"; $A$1:$DO$4; 2; 0) funtzioak berunaren ikurra den 'Pb' itzultzen du.

=HLOOKUP("Urrea"; $A$1:$DO$4; 3; 0) funtzioak urrearen zenbaki atomikoa den 79 itzultzen du.

=HLOOKUP("Karbonoa"; $A$1:$DO$4; 4; 0) funtzioak karbonoaren masa atomiko erlatiboa den 12.011 itzultzen du.

HYPERLINK

HYPERLINK funtzioa daukan gelaxka batean klik egitean, hiperesteka ireki egingo da.

Aukerako GelaxkaBalioa parametroa erabiltzen bada, formulak URLa aurkitzen du eta testua edo zenbakia erakusten du.

HYPERLINK("URLa" [; GelaxkaBalioa])

URLa parametroak estekaren helburua zehazten du. Aukerako GelaxkaBalioa parametroa gelaxkan bistaratuko den testua edo zenbakia da eta emaitza gisa itzuliko da. Ez bada GelaxkaBalioa zehazten, URLa bistaratzen da gelaxka-testuan eta emaitza gisa hori itzultzen da.

0 zenbakia emango da gelaxka hutsei eta matrize-elementuei dagokienez.

=HYPERLINK("http://www.adibidea.org") funtzioak "http://www.adibidea.org" testua erakusten du gelaxkan eta http://www.adibidea.org hiperesteka exekutatzen du gainean klik egiten denean.

=HYPERLINK("http://www.adibidea.org";"Egin klik hemen") funtzioak "Egin klik hemen" testua erakusten du gelaxkan eta http://www.adibidea.org hiperesteka exekutatzen du gainean klik egiten denean.

=HYPERLINK("http://www.adibidea.org";12345) funtzioak 12345 zenbakia erakusten du eta http://www.adibidea.org hiperesteka exekutatzen du gainean klik egiten deneean.

=HYPERLINK($B4) non B4 gelaxkak http://www.example.org katea duen. Funtzioak http://www.example.org gehitzen dio hiperesteka-gelaxkaren URLari eta testu bera itzultzen du, formularen emaitza gisa erabiliko dena.

=HYPERLINK("http://www.";"Sakatu ") & "example.org" funtzioak 'Sakatu example.org' bistaratzen du gelaxkan eta 'http://www.example.org' hiperesteka exekutatzen du sakatzen denean.

=HYPERLINK("#Orria1.A1";"Joan gora") funtzioak 'Joan gora' testua bistaratzen du eta dokumentuko Orria1.A1 gelaxkara jauzi egiten du.

=HYPERLINK("file:///C:/writer.odt#Markatzailea";"Joan Writer laster-markara") funtzioak 'Joan Writer laster-markara' bistaratzen du, zehaztutako testu-dokumentua kargatzen du eta 'Markatzailea' laster-markara jauzi egiten du.

=HYPERLINK("file:///C:/Documents/";"ireki Documents karpeta") funtzioak 'Ireki Documents karpeta' testua bistaratzen du eta karpetaren edukiak erakusten ditu sistema eragilearen fitxategi-kudeatzailea erabiliz.

INDEX

INDEX returns a reference, a value or an array of values from a reference range, specified by row and column index number or array of row and array of columns index numbers, and an optional range index.

INDEX() returns a reference if the argument is one or more references. When used in a cell in the form =INDEX(), the reference is resolved and the values displayed. When INDEX() is used in arguments of other functions, =FUNCTION(INDEX()...), the function gets the reference passed that was returned by INDEX(). Returning a reference is different from returning an array of values for functions that handles them differently.

INDEX(Reference [; [Row] [; [Column] [; Range]]])

Reference is a reference, entered either directly or by specifying a range name. If the reference consists of multiple ranges, you must enclose the list of references or range names in parentheses, or either use the tilde (~) range concatenation operator or define a named range with multiple areas.

Row (optional) represents the row or the array of row indexes of the reference range, for which to return a value. In case of zero or omitted (no specific row) all referenced rows are returned.

Column (optional) represents the column or array of column indexes of the reference range, for which to return a value. In case of zero or omitted (no specific column) all referenced columns are returned.

Range (optional) represents the index of the subrange if referring to a multiple range, default is 1.

{=INDEX({1,3,5;7,9,10},{2;1},1)} return a 2 row array containing 7 and 1. The row index {2;1} pick row 2 then row 1. The columns index 1 picks the first column.

{=INDEX(D3:G12,{1;2;3;4},{3,1})} return a 4 rows by 2 columns array. The row index array {1;2;3;4} picks rows 3 to 6 and {3;1} picks the third (F) and first column (D). Columns 1 and 3 of the source reference are swapped in the resulting array.

=INDEX(Prezioak;4;1): Datuak - Definitu aukeran Prezio gisa zehaztutako datu-baseko barrutiko 4. errenkadako eta 1. zutabeko balioa ematen du.

=INDEX(SumX;4;1): 4. errenkadako eta 1. zutabeko SumX barrutiko balioa ematen du, Orria - Izendun barrutiak eta adierazpenak - Definitu aukeran zehaztuta bezala.

{=INDEX(A1:B6;1)} returns the values of the first row of A1:B6. Enter the formula as an array formula.

{=INDEX(A1:B6;0;1)} returns the values of the first column of A1:B6. Enter the formula as an array formula.

=INDEX(A1:B6;1;1): A1:B6 barrutiko goi-ezkerraldeko gelaxkako balioa adierazten du.

{=INDEX((A1:B6;C1:D6);0;0;2)} returns the values of the second range C1:D6 of the multiple range. Enter the formula as an array formula.

INDIRECT

Testu-kate batek zehaztutako erreferentzia ematen du. Kate baten barrutia emateko ere erabil daiteke funtzio hau.

INDIRECT(Erref [; A1])

Erref: gelaxka edo barruti baten erreferentzia (testu-formakoa).

A1 (aukerakoa) - 0 ezartzen bada, R1C1 notazioa erabiliko da. Parametro hori ez bada agertzen edo 0 ez den beste balio bat ezarri bazaio, A1 notazioa erabiliko da.

=INDIRECT(A1) berdin izango da, A1 gelaxkak C108 badauka erreferentzia gisa, eta C108 gelaxkak 100 balioa badauka.

Errenkada 1 eta zutabea 3 elementuen bidez definitutako gelaxkatik A1 gelaxkarainoko barrutiko gelaxka guztiak batzen ditu =SUM(INDIRECT("a1:" & ADDRESS(1;3))) funtzioak. Beraz, A1:C1 barrutia batzen da.

LOOKUP

Gelaxka baten edukia ematen du errenkada bateko nahiz zutabe bateko barruti batetik edo matrize batetik. Nahi izanez gero, esleitutako balioa (indize berekoa) beste errenkada eta zutabe baten emango da. VLOOKUP eta HLOOKUP funtzioetan ez bezala, bilaketa eta emaitza bektoreak kokagune desberdinetan egon daitezke; ez dute zertan elkarren ondokoak izan. Gainera, LOOKUP funtzioaren bilaketa-bektoreak ordenatuta egon behar du, bestela bilaketak ez baitu emaitza erabilgarririk emango.

LOOKUP(Kontsulta; BilaketaBektorea [; EmaitzaBektorea])

Kontsulta: Bilatuko den edozein motatako balio bat, bai zuzenean bai erreferentzia gisa sartuta.

Bilaketa-Bektorea: Errenkada- edo zutabe-bakunaren bilatzeko barrutia.

EmaitzaBektorea: Zutabe edo errenkada bakarreko beste barruti bat; hortik hartzen da, hain zuzen, funtzioaren emaitza. Bilaketa-bektorean aurkitutako elementuaren indize bera duen emaitza-bektorearen gelaxka da emaitza.

=LOOKUP(A1;D1:D100;F1:F100): A1 gelaxkan sartu duzun zenbakiari D1:D100 barrutian dagokion gelaxka bilatzen du. Bilatutako balioari dagokionez, indizea zehazten da. Adib.: gelaxka honetako 12. gelaxka. Orduan, 12. gelaxkaren edukia emango du funtzioaren balio gisa (emaitzen bektorean).

MATCH

Balioak konparatu ondoren, matrizean zenbatgarren kokagunea duen adierazten du. Bilaketan aurkitutako balioaren kokagunea ematen du funtzioak.

MATCH(Bilaketa; KontsultaMatrizea [; Mota])

Bilaketa: Errenkada edo zutabe bakarreko matrizean bilatu beharreko balioa.

KontsultaMatrizea: Bilatutako erreferentzia. Bilaketa-matrizea errenkada edo zutabe bakarreko matrizea izan daiteke, edo errenkada edo zutabe bakarreko zati bat.

Mota: 1, 0, edo –1 balioa izan dezake. Mota = 1 bada edo aukerako parametro hau ez bada agertzen, orduan ulertuko da bilaketa-matrizeko lehen zutabea goranzko ordenan ordenatuta dagoela. Mota= -1 bada, zutabeak beheranzko ordena duela ulertuko da. Microsoft Exceleko funtzio berari dagokio.

Mota = 0 bada, zehatz-mehatz bat datozen balioak bakarrik aurkituko ditu. Bilaketa-irizpidea behin baino gehiagotan bilatzen bada, aurrena bilatutakoa emango du funtzioak. Mota = 0 bada bakarrik bilatu ahal izango dituzu adierazpen erregularrak.

Mota = 1 bada edo hirugarren parametrorik ez badago, bilaketa-irizpidearen berdina edo txikiagoa den azken balioaren indizea emango du. Mota = -1 denean, handiagoa edo berdina den lehen balioaren indizea emango du.

=MATCH(200;D1:D100): 200 balioa bilatzen du D1:D100 barrutian, zeina D zutabearen arabera ordenatuta baitago. Balio hori bilatu orduko, balioaren errenkada-zenbakia ematen du. Zutabean bilaketa egitean balio handiago bat aurkitzen bada, aurreko errenkadaren zenbakia ematen du.

OFFSET

Abiapuntutik lerratutako gelaxkaren erreferentzia ematen du.

OFFSET(Erreferentzia; Errenkadak; Zutabeak [; Altuera [; Zabalera]])

Erreferentzia: erreferentzia horretatik abiatuta bilatzen du funtzioak erreferentzia berria.

Errenkadak: erreferentzia gorantz (balio negatiboa) edo beherantz zuzendu beharreko errenkada kopurua.

Zutabeak: erreferentzia ezkerrerantz (balio negatiboa) edo eskumarantz zuzendu beharreko zutabe kopurua. Erabili 0 zutabe berean geratzeko.

Altuera (aukerakoa): erreferentzia-kokagune berrian hasten den barruti baten aukerako altuera bertikala.

Zabalera (aukerakoa): erreferentzia-kokagune berrian hasten den barruti baten aukerako zabalera horizontala.

Errenkadak eta Zutabeak argumentuek ez dute errenkada edo zutabeen kopuru negatibo edo zero kopurura eraman behar.

Altuera eta Zabalera argumentuek ez dute errenkada edo zutabeen kopuru negatibo edo zero kopurura eraman behar.

LibreOffice Calc-eko funtzioetan, "aukerakoa" marka daukaten parametroak alde batera utz daitezke ondoren parametrorik ez dagoenean soilik. Adibidez, lau parametro dituen funtzio batean, funtzio horietako azken biek "aukerakoa" marka badaukate, 4. parametroa edo 3. eta 4. parametroa alde batera utz ditzakezu, baina ezin duzu alde batera utzi 3. parametroa bakarrik.

=OFFSET(A1;2;2): C3 gelaxkako balioa ematen du (A1 gelaxka bi errenkada eta bi zutabe beherantz mugituta). C3 gelaxkak 100 balioa badauka, funtzio honek 100 balioa ematen du.

=OFFSET(B2:C3;1;1): B2:C3 barrutia errenkada bat beherago eta zutabe bat eskuinerago (C3:D4).

=OFFSET(B2:C3;-1;-1): B2:C3 barrutia errenkada bat gorago eta zutabe bat ezkerrerago (B2:D4).

=OFFSET(B2:C3;0;0;3;4): B2:C3 barrutiaren erreferentzia bat ematen du, baina tamaina aldatuta 3 errenkada eta 4 zutabe izan ditzan (B2:E4).

=OFFSET(B2:C3;1;0;3;4): B2:C3 barrutiaren erreferentzia bat ematen du, baina errenkada bat beherago, tamaina aldatuta 3 errenkada eta 4 zutabe izan ditzan (B3:E5).

=SUM(OFFSET(A1;2;2;5;6)): C3 gelaxkan hasten den eta 5 errenkadako altuera eta 6 zutabeko zabalera dituen barruti osoa zehazten du, hau da, C3:H7 barrutia.

ROW

Gelaxka-erreferentzia baten errenkada-zenbakia itzultzen du. Erreferentzia gelaxka bat bada, gelaxka horrek errenkada-zenbakia itzuliko da; parametroa gelaxka-barruti bat bada, hari dagozkion errenkada-zenbakiak itzuliko dira zutabe bakarreko matrize gisa formula matrize-formula gisa sartzen bada. Barruti-erreferentziako parametro bat duen ROW funtzioa ez bada erabiltzen matrize-formula batean, barrutiko lehen gelaxkaren errenkada-zenbakia soilik itzuliko da.

ROW([Erreferentzia])

Erreferentzia: gelaxka, barrutia, edo barruti-izena da.

Erreferentzia bat adierazten ez baduzu, formula sartutako gelaxkaren errenkada-zenbakia emango du. LibreOffice Calc-ek automatikoki ezartzen dio erreferentzia uneko gelaxkari.

=ROW(B3): 3 ematen du, erreferentziak taulako hirugarren errenkadari egiten baitio erreferentzia.

{=ROW(D5:D8)}: zutabe bakarreko matrizea ematen du (5, 6, 7, 8), zehaztutako erreferentziak 5 eta 8 arteko errenkadak baititu.

=ROW(D5:D8): 5 ematen du, ROW funtzioa ez baita erabili matrize-formula gisa, eta erreferentziaren lehen errenkadaren zenbakia bakarrik ematen du.

{=ROW(A1:E1)} eta =ROW(A1:E1) funtzioek 1 ematen dute, erreferentziak errenkada1 bakarrik baitu taulako lehen errenkada gisa. (Errenkada bakarreko areek errenkada-zenbaki bakarra izaten dutenez, berdin da formula matrize-formula gisa sartu ala ez).

=ROW(): 3 ematen du, formula 3. errenkadan sartu bada.

{=ROW(Untxia)}: zutabe bakarreko matrizea (1, 2, 3) ematen du, "Untxia" bada barruti izenduna (C1:D3).

ROWS

Matrize edo erreferentzia batek zenbat errenkada dituen ematen du.

ROWS(matrizea)

Matrizea: errenkada kopuru totala kalkulatu behar zaion barruti izenduna edo erreferentzia.

=Rows(B5): 1 ematen du, gelaxka batek errenkada bakarra baitu.

=ROWS(A10:B12): 3 ematen du.

=ROWS(Untxia): 3 ematen du, "Untxia" bada barruti izenduna (C1:D3).

SHEET

Erreferentzia baten orri-zenbakia edo orri-izena ordezkatzen duen kate bat itzultzen du. Ez bada parametrorik sartzen, formula duen kalkulu-orriaren orri-zenbakia izango da emaitza.

SHEET([Erreferentzia])

Erreferentzia: gelaxka baten, barruti baten edo orri-izen baten karaktere-katearen erreferentzia. Aukerakoa da.

=SHEET(Orria2.A1): 2 itzuliko du, 'Orria2' kalkulu-orriko bigarren orria bada.

=SHEET("Orria3"): 3 itzuliko du 'Orria3' kalkulu-orriko hirugarren orria bada.

SHEETS

Erreferentzia bateko orri kopurua zehazten du. Ez baduzu parametrorik sartzen, uneko dokumentuko orri kopurua emango du.

SHEETS([Erreferentzia])

Erreferentzia: orri edo barruti baten erreferentzia da. Parametro hau aukerakoa da.

=SHEETS(Orria1.A1:Orria3.G12): 3 ematen du, Orria1, Orria2 eta Orria3 badaude adierazitako sekuentzian.

VLOOKUP

Bilaketa bertikala eskuineko elkarren ondoko gelaxken erreferentziarekin. Balio jakin bat matrizearen lehen zutabean badagoen begiratzen du funtzio honek. Orduan funtzioak balioa itzultzen du indizeak izendatutako zutabeko errenkada berean. Ordenatua parametroa ez bada zehazten edo TRUE (egiazkoa) ezartzen bada, datuak goranzko ordenan ordenatu behar direla ulertzen da. Kasu horretan, Kontsulta ez bada aurkitzen, hurrengo balioa itzuliko da. Ordenatua FALSE (faltsua) edo zero bada, zehatz-mehatz bat datorrena aurkitu behar da, eta bestela honako errorea emango du: Errorea: balioa ez dago eskuragarri. Hortaz, zero balioarekin ez dago datuak gorantz ordenatu beharrik.

=VLOOKUP(Kontsulta; Matrizea; Indizea [; BarrutiOrdenatuarenKontsulta])

Kontsulta: Matrizearen lehen zutabean bilatu den edozein motatako balioa da.

Matrizea erreferentzia da, Indize argumentuan pasatu den zenbakiak bezain besteko zutabe gutxienez hartzen dituena.

Indizea: bilatzen ari den balioa duen matrizeko zutabearen zenbakia. Lehen zutabearen zenbakia 1 da.

BarrutiOrdenatuarenKontsulta aukerako parametro bat da, matrizearen lehen zutabeak barruti-mugak dituen (balio soilik izan ordez) adierazten duena. Modu horretan, kontsultak itzultzen du Kontsulta balioaren berdina edo txikiagoa duen lehen zutabea duen errenkadako balioa. Adibidez, parametro horrek zerga-balioren bat aldatu deneko datak eduki ditzake, eta kasu horretan, zerga-balio bat indarrean sartu zeneko denbora-tarte baten hasiera-datak ordezkatzen dituzte balioek. Beraz, matrizearen lehen zutabean ez dagoen data bat bilatzen bada, data hori ez badago data-muga batzuen artean, haietako baxuena emango luke, bilatutako datan indarrean sartzen den data bilatzea ahalbidetuz. Sartu FALSE (gezurra) balio boolearra edo zero lehen zutabea ez bada barruti-mugen zerrenda bat. Parametro hau TRUE (egia) bada edo ematen ez bada, matrizeko lehen zutabea gorantz ordenatu behar da. Ordenatutako zutabeak azkarrago arakatzen dira eta funtzioak beti itzultzen du baio bat, baita bilaketa-balioa zehatz-mehatz bat ez badator ere, ordenatutako zerrendako baliorik baxuena baino altuagoa bada. Ordenatu gabeko zerrendetan, bilaketa-balioarekin zehaztasunez egin behar da bat; bestela, funtzioak #E/E itzuliko du eta honako mezua emango du: Errorea: Balioa ez dago eskuragarri.

Demagun menuko plater baten zenbakia sartu nahi duzula A1 gelaxkan, eta plateraren izena testu gisa bistaratu nahi duzula ondoko gelaxkan (B1). Kode eta izenaren arteko korrespondentzia D1:E100 matrizean esleitzen da. D1 gelaxkak 100 balioa dauka, E1 gelaxkak Arrain-zopa plater-izena, eta abar. 100 plater daude guztira. D zutabeko zenbakiak goranzko ordenan daude; hortaz, Ordenatua aukerako parametroa ez da beharrezkoa.

Sartu formula hau B1 gelaxkan:

=VLOOKUP(A1;D1:E100;2)

A1 gelaxkan zenbaki bat sartzen duzun bezain laster, D1:E100 erreferentziaren bigarren zutabeko testua erakutsiko du B1 gelaxkak. Lehendik ez dagoen zenbaki bat sartzen baduzu, (behera) hurrengo zenbakia duen testua bistaratuko du. Hori gerta ez dadin, formulan sartu FALSE (faltsua) azken parametro gisa, eta horrela errore-mezua emango du lehendik ez dagoen zenbakia sartutakoan.