Matrize-funtzioak

Kategoria honetan matrizeen funtzioak aurkituko dituzu.

Zer da matrize bat?

Kalkulu-orrietan balioak dituzten gelaxken barruti estekatuak dira matrizeak. 3 errenkada eta 3 zutabeko barruti karratua 3 x 3 matrizea da:

A

B

C

1

7

31

33

2

95

17

2

3

5

10

50


Dagoen matrizerik txikiena 1 x 2 edo 2 x 1 da, hau da, bi gelaxkakoa.

Zer da matrize-formula bat?

Formula batean gelaxka-barruti bateko balio indibidualak ebaluatzen direnean matrize-formula esaten zaio. Matrize-formulen eta gainerako formulen arteko desberdintasuna zera da: matrize-formulak aldi berean hainbat balio prozesatzen dituela eta ez bat bakarrik.

Hainbat balio prozesatzeaz gain, matrize-formula batek hainbat balio eman ditzake. Matrize-formula baten emaitza ere matrize bat izaten da.

Goiko matrizean gelaxka indibidualetako balioak 10ekin biderkatzeko ez da beharrezkoa gelaxka edo balio indibidual bakoitzari formula bat aplikatzea. Nahikoa duzu matrize-formula bakar bat erabiltzea. Hautatu 3 x 3 gelaxkako barruti bat kalkulu-orriko beste zati batean, sartu =10*A1:C3 formula eta berretsi sarrera + Shift + Enter tekla-konbinazioarekin. Emaitza 3 x 3 gelaxkako matrizea izango da eta gelaxka-barrutiko (A1:C3) balio indibidualak 10 faktorearekin biderkatuko dira.

Biderkatzeaz gain, bestelako eragiketak ere aplika ditzakezu erreferentzia-barrutian (matrizean). LibreOffice Calc-ek eragile asko eskaintzen dizkizu: batuketa (+), kenketa (-), biderketa (*), zatiketa (/), esponentea(^), berretzailea(&) eta konparazioa (=, <>, <, >, <=, >=). Eragileak gelaxka-barrutiko balio indibidual bakoitzari aplika dakizkioke, eta, matrize-formula sartu bada, matrize-formula gisa emango du emaitza.

Matrize-formuletan konparazio-eragileak aldatzean, gelaxka hutsek konparazio bakunen arau berdinak izango dituzte, hau da, 0 edo kate hutsaren bidez irudika daitezke. Hortaz, {=A1:A2=""} eta {=A1:A2=0} matrize-formulek TRUE emango dute A1 eta A2 gelaxkak hutsak daudenean.

Noiz erabiltzen dira matrize-formulak?

Behin eta berriz kalkulu berdina egin behar denean balio desberdinekin. Gero kalkulua egiteko metodoa aldatu nahi baduzu, nahikoa izango duzu matrize-formula eguneratzea. Matrize-formula bat gehitzeko, hautatu matrize-barruti osoa eta egin dagokion aldaketa matrize-formulan.

Matrize-formulei esker, gainera, leku asko aurreztu ahal izango duzu balio desberdinak kalkulatu behar dituzunean. Matrizeek memoria gutxi hartzen dute. Bestalde, matrizeak oinarrizko tresna dira kalkulu konplexuak egiteko. Izan ere, kalkuluetan hainbat gelaxka-barruti erabiltzeko aukera ematen dute. LibreOffice suiteak hainbat funtzio matematiko eskaintzen ditu matrizeetarako; adibidez, matrizeak biderkatzeko balio duen MMULT funtzioa, edo bi matrizeren biderkadura eskalarrak kalkulatzeko balio duen SUMPRODUCT funtzioa.

LibreOffice Calc-en matrize-formulak erabiltzea

Formula "normal" bat ere sor dezakezu, formula horretako erreferentzia-barrutiaren bidez (parametroen bidez, adibidez) matrize-formula bat adieraziz. Erreferentzia-barrutia eta errenkada edo zutabeen arteko ebakidura oinarri hartuta kalkulatuko da emaitza. Ebakidurarik ez badago edo intersekzioaren barrutiak errenkada edo zutabe guztiak hartzen baditu, #BALIOA! errore-mezua agertuko da. Hori ondorengo adibidean erakusten da:

Matrize-formulak sortzea

Funtzioen morroia erabiliz matrize-formula bat sortzen baduzu, Matrizea kontrol-laukia markatu behar duzu aldi bakoitzean, emaitzak matrize batean emateko. Bestela, kalkulatzen ari den matrizearen goiko ezker-gelaxkako balioa bakarrik emango du.

Matrize-formula zuzenean sartzen baduzu gelaxkan, ⇧+ + ⏎ tekla-konbinazioa erabili behar duzu, teklaren ordez. Formula orduan bihurtuko da matrize-formula.

note

Matrize-formulak giltzen artean agertzen dira LibreOffice Calc-en. Matrize-formulak ezin dira sortu eskuz giltzak sartuz.


warning

Emaitza-matrize bateko gelaxkak automatikoki babesten dira aldaketen aurka. Nolanahi ere, matrize-formula edita edo kopia dezakezu matrizearen gelaxka-barruti osoa hautatuz.


Barneko matrize-konstanteak erabiltzea formuletan

Calc-ek barneko matrize-konstanteak onartzen ditu formuletan. Barneko matrize bat '{' eta '}' giltzen artean agertzen da. Elementu bakoitza zenbakia (negatiboak barne), konstante logikoa (TRUE, FALSE), edo karaktere-kate literala izan daiteke. Konstanteak ez diren adierazpenak ez dira onartzen. Matrizeak errenkada batekoak edo gehiagokoak, eta zutabe batekoak edo gehiagokoak izan daitezke. Errenkada guztiek elementu kopuru bera izan behar dute, eta zutabe guztiek elementu kopuru bera izan behar dute.

Zutabe-bereizlea (errenkada bateko elementuak bereizten dituena) eta errenkada-bereizlea hizkuntzaren eta eskualdearen araberakoak dira. Hala ere, laguntza-eduki honetan ';' puntu eta koma eta '|' barra bertikala erabili dira zutabe- eta errenkada-bereizleak adierazteko, hurrenez hurren. Adibidez, ingelesez ',' koma erabiltzen da zutabe-bereizle modura, eta ';' errenkada-bereizle modura.

tip

Errenkaden eta zutabeen bereizlea ikusi eta aldatu daiteke - Calc - Formula - Bereizleak aukeran.


Matrizeak ezin diran habiaratuta egon.

Adibideak:

={1;2;3}

Hiru zenbakiko (1, 2 eta 3) errenkada bat duen matrize bat.

Matrize-konstante hau sartzeko, hautatu errenkada bateko hiru gelaxka, sartu ={1;2;3} formula giltzak eta puntu eta komak erabiliz, eta ondoren sakatu + ⇧ + ↵.

={1;2;3|4;5;6}

Bi errenkada eta errenkada bakoitzean hiru balio dituen matrizea.

={0;1;2|FALSE;TRUE;"bi"}

Nahasitako datuen matrizea.

=SIN(1;2;3})

Matrize-formula gisa sartuta, 1, 2 eta 3 argumentuko hiru SIN kalkuluren emaitza ematen du.

Matrize-formulak editatzea

  1. Hautatu matrize-formula duen gelaxka-barrutia edo -matrizea. Matrize osoa hautatzeko, kokatu gelaxka-kurtsorea matrize-barrutiaren barruan, eta ondoren sakatu + /, non / zenbakien teklatuko Zatiketa tekla den.

  2. Sakatu F2 edo jarri kurtsorea sarrera-lerroan. Bi modu horietan formula edita dezakezu.

  3. Aldaketak egin ondoren, sakatu + ⇧ + ↵.

tip

Matrizearen zatiak banaka formatea ditzakezu. Esate baterako, letra-kolorea alda dezakezu. Hautatu gelaxka-barruti bat, eta ondoren aldatu zeuk nahi duzun atributua.


Matrize-formulak kopiatzea

  1. Hautatu matrize-formula duen matrizea edo gelaxka-barrutia.

  2. Sakatu F2, edo jarri kurtsorea sarrera-lerroan.

  3. Kopiatu formula sarrera-lerroan, horretarako sakatu + C.

  4. Hautatu matrize-formula txertatu nahi duzun gelaxka-barrutia, eta sakatu F2 edo jarri kurtsorea sarrerako lerroan.

  5. Formula itsasteko, sakatu + V hautatutako gunean eta baieztatu + ⇧ + ↵ sakatuta. Horrela, hautatutako barrutiak matrize-formula izango du.

Matrize-barruti bat doitzea

Irteerako matrizea editatu nahi baduzu, egin hau:

  1. Hautatu matrize-formula duen matrizea edo gelaxka-barrutia.

  2. Hautapenaren behealdean, eskuinean, ikono txiki bat ikusiko duzu. Ikono horren bidez, barrutia handitu edo txikitu ahal izango duzu saguarekin.

note

Matrize-barrutia doitzen duzunean, matrize-formula ez da automatikoki doituko. Emaitza erakutsiko duen barrutia bakarrik ari zara aldatzen.


Sakatuta eusten badiozu teklari, matrize-formularen kopia bat sortu dezakezu emandako barrutian.

Baldintzapeko matrize-kalkuluak

IF() edo CHOOSE() funtzio bat daukan matrize-formula da baldintzapeko matrize-kalkulua. Gelaxka-barruti bat edo matrize-emaitza bat izaten da formulako baldintza-argumentua.

Ondorengo adibidean, {=IF(A1:A3>0;"yes";"no")} formularen >0 proba aplikatzen zaio A1:A3 barrutiko gelaxka bakoitzari, eta emaitza dagokion gelaxkan kopiatzen da.

A

B (formula)

B (emaitza)

1

1

{=IF(A1:A3>0;"yes";"no")}

bai

2

0

{=IF(A1:A3>0;"yes";"no")}

ez

3

1

{=IF(A1:A3>0;"yes";"no")}

bai


Matrize behartuen tratamendua eragiten dute funtzio hauek: CORREL, COVAR, FORECAST, FTEST, INTERCEPT, MDETERM, MINVERSE, MMULT, MODE, PEARSON, PROB, RSQ, SLOPE, STEYX, SUMPRODUCT, SUMX2MY2, SUMX2PY2, SUMXMY2, TTEST. Argumentu gisa barruti-erreferentziak erabiltzen badituzu funtzio horietako bati dei egitean, funtzioek matrize-funtzio gisa funtzionatuko dute. Matrize behartuen tratamenduaren adibide bat ikus daiteke ondorengo taulan:

A

B (formula)

B (emaitza)

C (matrize behartuaren formula)

C (emaitza)

1

1

=A1:A2+1

2

=SUMPRODUCT(A1:A2+1)

5

2

2

=A1:A2+1

3

=SUMPRODUCT(A1:A2+1)

5

3

=A1:A2+1

#BALIOA!

=SUMPRODUCT(A1:A2+1)

5


SUMX2MY2

Bi matrizeren karratuen arteko kenduren batuketa egiten du.

Sintaxia

SUMXMY2(X matrizea; Y matrizea)

X matrizea: argumentuen karratuak batzeko lehen matrizea.

Y matrizea: argumentuen karratuak kentzeko bigarren matrizea.

Azalpen gehiago orriaren goialdean.

SUMX2PY2

Bi matrizeren karratuen batura kalkulatzen du.

Sintaxia

SUMX2PY2(X matrizea; Y matrizea)

X matrizea argumentuen karratuak batzeko lehen matrizea adierazten du.

Y matrizea bigarren matrizea da; matrize horren elementuak karratu bihurtu eta gehitu behar dira.

Azalpen gehiago orriaren goialdean.

SUMXMY2

Bi matrizeren karratuen kenduren batuketa egiten du.

Sintaxia

SUMXMY2(X matrizea; Y matrizea)

X matrizea argumentuen karratuak kentzeko lehen matrizea adierazten du.

Y matrizea argumentuen karratuak kentzeko bigarren matrizea adierazten du.

Azalpen gehiago orriaren goialdean.

MMULT

Bi matrizeren matrize-biderketa kalkulatzen du. 1. matrizearen zutabe kopuruak bat etorri behar du 2. matrizeko errenkada kopuruarekin. Matrize karratuak errenkada eta zutabeen kopuru bera edukiko du.

Sintaxia

MMULT(1. matrizea; 2. matrizea)

1. matrizea: matrize-biderketan erabiliko den lehen matrizea da.

2. matrizea: bigarren matrizea da, errenkada kopuru bera duena.

note

Azalpen gehiago orriaren goialdean.


Adibidea

Hautatu barruti karratu bat. Aukeratu MMULT funtzioa. Hautatu 1. matrizea, ondoren hautatu 2. matrizea. Funtzioen morroia erabilita, markatu Matrizea kontrol-laukia. Egin klik Ados aukeran. Irteerako matrizea hautatutako lehen barrutian agertuko da.

LINEST

Datu multzo bati ondoen egokitzen zaion lerro zuzen baten estatistika-taula bat ematen du.

Sintaxia

LINEST(data_Y [; data_X [; linearType [; stats]]])

datuak_Y: errenkada edo zutabe bakarreko barruti bat da, datu-puntuen multzo baten y koordenatuak zehazten dituena.

datuak_X: errenkada edo zutabe bakarreko barruti bat da, x koordenatuak zehazten dituena. datuak_X zehazten ez bada, balio lehenetsia 1, 2, 3, ..., n izango da. Aldagai multzo bat baino gehiago badago, errenkada edo zutabe anizkoitzak dagozkion barruti bat izango da datuak_X beharbada.

LINEST funtzioak datuen arabera ondoen egokitzen den lerro zuzen bat y = a + bx kalkulatzen du, erregresio lineala erabiliz ("karratu txikienen" metodoa). Aldagai multzo bat baino gehiago badaude, lerro zuzenak forma hau izango du: y = a + b1x1 + b2x2 ... + bnxn.

linealMota FALSE bada, lerro zuzena jatorritik pasatzera behartuko da (a konstantea zero da; y = bx). Zehazten ez bada, lineal_mota TRUE izango da balio lehenetsia (lerroa ez da jatorritik pasatzera behartuko).

estatistika zehazten ez bada edo FALSE bada, estatistika-taularen goiko lerroa bakarrik emango da. TRUE bada, taula osoa emango da.

LINEST funtzioak estatistikako taula (matrize) bat ematen du, eta matrize-formula gisa sartu behar da (adibidez + ⇧ + ↵ erabiliz, soilik erabili beharrean).

LibreOffice Calc-eko funtzioetan, "aukerakoa" marka daukaten parametroak alde batera utz daitezke ondoren parametrorik ez dagoenean soilik. Adibidez, lau parametro dituen funtzio batean, funtzio horietako azken biek "aukerakoa" marka badaukate, 4. parametroa edo 3. eta 4. parametroa alde batera utz ditzakezu, baina ezin duzu alde batera utzi 3. parametroa bakarrik.

Azalpen gehiago orriaren goialdean.

Adibidea

Funtzio honek matrize bat ematen du, eta beste matrize-funtzioak bezala maneiatzen da. Hautatu erantzunetarako barruti bat, eta funtzioa. Hautatu Y_datuak. Nahi izanez gero, beste parametro batzuk sar ditzakezu. Hautatu Matrizea eta egin klik Ados botoian.

Sistemak ematen dituen emaitzek (estatistika = 0 bada), gutxienez erregresio-lerroaren malda eta Y ardatzarekiko ebakidura erakusten dituzte. Estatistika ez bada 0, beste emaitza batzuk bistaratuko dira.

LINEST funtzioaren beste emaitza batzuk:

Azter itzazu ondorengo adibideak:

A

B

C

D

E

F

G

1

x1

x2

y

LINEST balioa

2

4

7

100

4,17

-3,48

82,33

3

5

9

105

5,46

10,96

9,35

4

6

11

104

0,87

5,06

#E/E

5

7

12

108

13,21

4

#E/E

6

8

15

111

675,45

102,26

#E/E

7

9

17

120

8

10

19

133


A zutabeak hainbat X1 balio ditu, B zutabeak hainbat X2 balio eta C zutabeak Y balioak. Balio horiek dagoeneko sartuta dituzu kalkulu-orrian. E2:G6 definitu da kalkulu-orrian, eta Funtzioen morroia aktibatu duzu. LINEST funtzioak eragina izan dezan, Matrizea kontrol-laukia hautatuta eduki behar duzu Funtzioen morroian. Ondoren, hautatu balio hauek kalkulu-orrian (edo sartu teklatuarekin):

datuak_Y C2:C8 da

datuak_X A2:B8 da

lineal_mota eta estatistika, biak, 1 gisa ezartzen dira.

Ados botoian klik egin bezain laster, LibreOffice Calc-ek LINEST balioekin beteko du goiko adibidea, adibidean erakusten den bezala.

Formula barrako formula bat dator LINEST matrizeko gelaxka bakoitzarekin. LINEST matrizea: {=LINEST(C2:C8;A2:B8;1;1)}

Horrela irudikatzen dira kalkulatutako LINEST balioak:

E2 eta F2: x1 eta x2 balioen y=b+m*x erregresio-lerroaren m malda. Balioak alderantzizko ordenan ematen dira, hau da, x2 eta E2ren malda eta x2 eta F2ren malda.

G2: Y ardatzarekiko b ebakidura.

E3 eta F3: malda-balioaren errore estandarra.

G3: ebakiduraren errore estandarra

E4: RSQ

F4: Y baliori dagokionez kalkulatutako erregresioaren errore estandarra.

E5: Bariantza-kalkuluko F balioa.

F5: Bariantza-kalkuluko askatasun graduak.

E6: Batez besteko linealeko Y balio estimatuen desbideratze karratuen batura.

F6: Adierazitako Y balioetatik estimatutako Y balioaren desbideratze karratuen batura.

Azalpen gehiago orriaren goialdean.

GROWTH

Erregresio-funtzio esponentzialeko puntuak kalkulatzen ditu.

Sintaxia

GROWTH(DataY [; DataX [; NewDataX [; FunctionType]]])

Datuak_Y: Y datuen matrizea.

Datuak_X (aukerakoa): X datuen matrizea.

Datu_berriak_X (aukerakoa): X datu-matrizea, balioak birkalkulatzen dituena.

Funtzio_mota (aukerakoa). Funtzio_mota = 0 bada, y = m^x formako funtzioak kalkulatuko dira. Bestela, y = b*m^x formako funtzioak kalkulatuko dira.

LibreOffice Calc-eko funtzioetan, "aukerakoa" marka daukaten parametroak alde batera utz daitezke ondoren parametrorik ez dagoenean soilik. Adibidez, lau parametro dituen funtzio batean, funtzio horietako azken biek "aukerakoa" marka badaukate, 4. parametroa edo 3. eta 4. parametroa alde batera utz ditzakezu, baina ezin duzu alde batera utzi 3. parametroa bakarrik.

Azalpen gehiago orriaren goialdean.

Adibidea

Funtzio honek matrize bat ematen du, eta beste funtzioak bezala maneiatzen da. Hautatu erantzunak erakusteko erabili nahi duzun barrutia, eta hautatu funtzioa. Hautatu Datuak_Y. Sartu beste parametroak, markatu Matrizea eta egin klik Ados botoian.

LOGEST

Erregresio-kurba esponentzialaren parametroak (y=b*m^x) kalkulatzen ditu matrize gisa.

Sintaxia

LOGEST(DataY [; DataX [; FunctionType [; Stats]]])

Datuak_Y Y datuen matrizea adierazten du.

Datuak_X (aukerakoa) X datuen matrizea adierazten du.

Funtzio_mota (aukerakoa). Funtzio_mota = 0 bada, y = m^x formako funtzioak kalkulatuko dira. Bestela, y = b*m^x formako funtzioak kalkulatuko dira.

Estatistika (aukerakoa). Estatistika=0 bada, erregresio koefizientea bakarrik kalkulatuko da.

LibreOffice Calc-eko funtzioetan, "aukerakoa" marka daukaten parametroak alde batera utz daitezke ondoren parametrorik ez dagoenean soilik. Adibidez, lau parametro dituen funtzio batean, funtzio horietako azken biek "aukerakoa" marka badaukate, 4. parametroa edo 3. eta 4. parametroa alde batera utz ditzakezu, baina ezin duzu alde batera utzi 3. parametroa bakarrik.

Azalpen gehiago orriaren goialdean.

Adibidea

Ikus LINEST. Edonola ere, ez da karratuen baturarik emango.

TREND

Erregresio-marra bateko puntuak kalkulatzen ditu.

Sintaxia

TREND(DataY [; DataX [; NewDataX [; LinearType]]])

Datuak_Y Y datuen matrizea adierazten du.

Datuak_X (aukerakoa) X datuen matrizea adierazten du.

Datu berriak_X (aukerakoa) balioak birkalkulatzeko erabiltzen diren X datuen matrizea adierazten du.

Lineal_mota (aukerakoa). Lineal_mota = 0 bada, marrak zero puntuaren bidez kalkulatuko dira. Bestela, zuzenketa-marrak ere kalkulatu egingo dira. Lehenespenez, Lineal_mota <> 0.

LibreOffice Calc-eko funtzioetan, "aukerakoa" marka daukaten parametroak alde batera utz daitezke ondoren parametrorik ez dagoenean soilik. Adibidez, lau parametro dituen funtzio batean, funtzio horietako azken biek "aukerakoa" marka badaukate, 4. parametroa edo 3. eta 4. parametroa alde batera utz ditzakezu, baina ezin duzu alde batera utzi 3. parametroa bakarrik.

Azalpen gehiago orriaren goialdean.

Adibidea

Hautatu kalkulu-orriko barruti bat erregresio-lerroak bistaratzeko. Hautatu funtzioa. Sartu hasiera-datuak edo hautatu saguarekin. Hautatu Matrizea eremua, eta egin klik Ados botoian. Hasierako datuekin kalkulatutako erregresio-datuak bistaratuko dira.

TRANSPOSE

Matrize bateko errenkadak eta zutabeak trukatzen ditu.

Sintaxia

TRANSPOSE(matrizea)

Matrizea: trukatu beharreko matrizea.

note

Matrize-funtzioei buruzko sarrera orokor bat aurki dezakezu orri honen goialdean.


Adibidea

Kalkulu-orrian, hautatu trukatu beharreko matrizea izango duen barrutia. Jatorrizko matrizeak n errenkada eta m zutabe baditu, zuk hautatutako barrutiak gutxienez m errenkada eta n zutabe izan behar ditu. Orduan sartu formula zuzenean, hautatu jatorrizko matrizea eta sakatu . Edo, Funtzioen morroia erabiltzen ari bazara, hautatu Matrizea kontrol-laukia. Trukatutako matrizea hautatutako helburuko barrutian agertuko da, eta automatikoki babestuta egongo da aldaketen aurka.

A

B

C

D

1

2

3

4

5

2

6

7

8

9


Goiko taulak 2 errenkada eta 4 zutabe ditu. Haiek trukatzeko, 4 errenkada eta 2 zutabe hautatu behar dira. Goiko taula A7:B10 (4 errenkada, 2 zutabe) barrutira trukatu nahi izanez gero, barruti osoa hautatu eta honakoa sartu behar da:

TRANSPOSE(A1:D2)

Ondoren, ziurtatu matrize-formula gisa sartzen dela erabilita. Emaitza honakoa izango da:

A

B

7

2

6

8

3

7

9

4

8

10

5

9


MINVERSE

Matrizearen alderantzizkoa ematen du.

Sintaxia

MINVERSE(matrizea)

Matrizea: alderantzikatu beharreko matrize karratua.

Azalpen gehiago orriaren goialdean.

Adibidea

Hautatu barruti karratu bat eta hautatu MINVERSE. Hautatu emaitza-matrizea, hautatu Matrizea eremua eta egin klik Ados botoian.

MDETERM

Matrizearen determinantea ematen du. Funtzio honek balio bat ematen du uneko gelaxkan; ez da beharrezkoa emaitzentzako barruti bat definitzea.

Sintaxia

MDETERM(matrizea)

Matrizea: determinanteak definitzen dituen matrize-karratua.

note

Matrize-funtzioei buruzko sarrera orokor bat aurki dezakezu orri honen goialdean.


Azalpen gehiago orriaren goialdean.

SUMPRODUCT

Matrizeko argumentuen biderketaren batura ematen du.

Sintaxia

SUMPRODUCT(1. matrizea[; 2. matrizea;][...;[255. matrizea]])

1. matrizea[; 2. matrizea;][...;[255. matrizea]] biderkatuko diren elementuak dituzten matrizeak dira.

Gutxienez matrize batek izan behar du argumentu-zerrendaren parte. Matrize bakar bat ematen bada, matrizeko elementu guztiak batuko dira. Matrize bat baino gehiago ematen bada, tamaina berekoek izan behar dute.

Adibidea

A

B

C

D

1

2

3

4

5

2

6

7

8

9

3

10

11

12

13


=SUMPRODUCT(A1:B3;C1:D3) funtzioak 397 ematen du.

Kalkulua: A1*C1 + B1*D1 + A2*C2 + B2*D2 + A3*C3 + B3*D3

SUMPRODUCT erabil dezakezu bi bektoreren biderkadura eskalarra kalkulatzeko.

note

SUMPRODUCT funtzioak zenbaki bakar bat ematen du; ez daukazu funtzioa matrize-funtzio gisa sartu beharrik.


Azalpen gehiago orriaren goialdean.

MUNIT

Tamaina jakin bateko matrize unitario karratua ematen du. Matrize unitarioa matrize karratu bat da, diagonal nagusiko elementuak berdin 1 dituena eta beste matrize-elementu guztiak berdin 0.

Sintaxia

MUNIT(Neurriak)

Neurriak: matrize unitarioaren neurria.

note

Matrize-funtzioei buruzko sarrera orokor bat aurki dezakezu orri honen goialdean.


Adibidea

Hautatu kalkulu-orriko barruti karratu bat; adib. A1etik A5era.

Barrutia desautatu gabe, hautatu MUNIT funtzioa. Hautatu Matrizea kontrol-laukia. Sartu matrize unitarioaren neurriak, kasu honetan 5, eta egin klik Ados botoian.

=MUNIT(5) formula hautatutako barrutiaren azken gelaxkan (E5) ere sar daiteke, eta ondoren sakatu.

Orain A1:E5 barrutia duen matrize unitarioa ikusiko duzu.

Azalpen gehiago orriaren goialdean.

FREQUENCY

Zutabe bakarreko matrize gisa kalkulatzen du maiztasunaren banaketa. Klaseak matrizeak emandako balioen barruan dauden Datuak matrizeetako balioen kopurua zenbatzen du.

Sintaxia

FREQUENCY(Datuak; Klaseak)

Datuak: kontatzeko balioen erreferentzia.

Klaseak: muga-balioen matrizea.

note

Matrize-funtzioei buruzko sarrera orokor bat aurki dezakezu orri honen goialdean.


Adibidea

Ondorengo taulan, ordenatu gabeko neurri-balioak daude A zutabean. Klaseentzako sartu duzun A zutabeko datu-banaketarako goi-muga izango du B zutabeak. B1 gelaxkan sartutako mugaren arabera, 5 baino txikiagoa edo berdina den balio neurtuen (datuak) kopurua emango du FREQUENCY funtzioak. B2 gelaxkako muga 10 denez, FREQUENCY funtzioak bigarren emaitza gisa eman behar lituzke 5 baino handiagoak edo 10en berdinak diren balio neurtuak. B6 gelaxkan sartutako testuak, ">25", erreferentzia-xedeetarako bakarrik balio du.

A

B

C

1

12

5

1

2

8

10

3

3

24

15

2

4

11

20

3

5

5

25

1

6

20

>25

1

7

16

8

9

9

7

10

16

11

33


Hautatu zutabe bateko barruti bat maiztasuna sartzeko goi klase-mugaren gainetik dauden balioentzako. Klaseen goi-muga baino eremu bat altuagoa hautatu behar duzu. Adibide honetan, hautatu C1:C6 barrutia. Aktibatu FREQUENCY funtzioa Funtzioen morroian. Hautatu (A1:A11) tarteko datu-barrutia, eta ondoren klase-mugak sartutako Klaseak barrutia (B1:B6). Hautatu Matrizea kontrol-laukia, eta egin klik Ados botoian. Maiztasunaren kalkulua ikusiko duzu C1:C6 barrutian.

Azalpen gehiago orriaren goialdean.

Emaguzu laguntza!