StrConv funtzioa

Bihurtu kate bat bihurketa mota batek zehaztutakoaren arabera.

Konstante, funtzio edo objektu hau Option VBASupport 1 instrukzioa programa-kode exekutagarriko modulu batean kokatuta gaitzen da.

Sintaxia:

StrConv(string As String, Conversion As Integer, [ LCID ])

Itzulera-balioa:

String

Parametroak:

string: Any valid string expression.

Bihurketa: Gauzatuko den bihurketa mota, beheko taulan definitutako moduan.

Bihurketa	Balioa	Deskribapena
vbUpperCase	1	Testua parametroko karaktereak maiuskulara bihurtzen ditu.
vbLowerCase	2	Testua parametroko karaktereak minuskulara bihurtzen ditu.
vbProperCase	3	Testua parametroko hitz bakoitzeko lehen letra maiuskulara bihurtzen du.
vbWide	4	Testua parametroko karaktere estuak (zabalera erdikoak) zabalera osoko karakterera (zabalera osoa) bihurtzen ditu.
vbNarrow	8	Testua parametroko karaktere zabalak (zabalera osoa) zabalera estuko karakterera (zabalera erdia) bihurtzen ditu.
vbKatakana	16	Testua parametroko hiragana karaktereak katakana karaktere bihurtzen ditu.
vbHiragana	32	Testua parametroko katakana karaktereak hiragana karaktere bihurtzen ditu.
vbUnicode	64	Testua parametroko karaktereak Unicode karaktere bihurtzen ditu sistemaren kode-orri lehenetsia erabilita.
vbFromUnicode	128	Testua parametroko karaktereak Unicodetik sistemaren kode-orri lehenetsira bihurtzen ditu.

LCID Aukerakoa. Hizkuntzaren IDa zenbaki dezimaletan. Parametro hau erabiltzen ez bada, sistemaren hizkuntzaren IDa erabiliko da. Begiratu msi-encodinglist.txt fitxategia LCID balio erabilgarriak ezagutzeko.

Adibidea:


Option VBASupport 1
Option Explicit
Sub Test_StrConv
    Print StrConv("abc EFG hij", vbUpperCase) '= "ABC EFG HIJ"
    Print StrConv("abc EFG hij", vbLowerCase) ' =  "abc efg hij"
    Print StrConv("abc EFG hij", vbProperCase) ' = "Abc Efg Hij"

    REM Kate bateko karaktere estuak (byte bakarrekoak) karaktere zabalera bihurtzen ditu
    Print StrConv("ABCDEVB¥ì¥¹¥¥å©", vbWide) ' = "ＡＢＣＤＥＶＢ￥ì￥¹￥￥å©"

    REM Kate bateko karaktere zabalak (byte bikoitzekoak) karaktere estura (byte bakarra) bihurtzen ditu
    Print StrConv("ＡＢＣＤ＠＄％２３＇？ＥＧ", vbNarrow) ' = "ABCD@$%23'?EG"

    REM Hiragana karaktereak katakana karaktere bihurtzen ditu
    Print StrConv("かたかな", vbKatakana) ' = "カタカナ"

    REM Katakana karaktereak hiragana karaktere bihurtzen ditu
    Print StrConv("カタカナ", vbHiragana) '= "かたかな"

    REM Unitate-probetan erabilitako en-US hizkuntzari lotutako CP-1252 kodeketa onartzen du.
    Dim x() As Byte
    x = StrConv("ÉÏº£ÊÐABC", vbFromUnicode)
    Print UBound(x) ' 8 karaktere
    Print x(2) ' = 186
    Print StrConv(x, vbUnicode)' = "ÉÏº£ÊÐABC"
End Sub

VBA funtzio eta instrukzio esklusiboak