Resume instrukzioa

Errore-informazioa berrezartzen du eta ondoren zer exekutatuko den adierazten du.

     Resume [ [0] | label | Next ]
   

0: Errore-informazioa berrezartzen du eta errorea eragin duen instrukzioa berriro exekutatzen du. 0 aukerakoa da.

label: Errore-informazioa berrezartzen du eta exekuzioa berrabiarazten du uneko azpierrutinan zehaztutako etiketan.

Next: Errore-informazioa berrezartzen du eta instrukzioa exekutatzen du errorea eragin duen instrukzioaren ondoren.

Errore-informazioa Erl, Err eta Error$ funtzioekin eraikitzen da.

• Erl: Errorea gertatu den lerro-zenbakia moduluan.

• Err: Errore-zenbakia.

• Error[$]: Errorearen deskribapena.

Resume erabiltzen bada errore-informazioa berrezartzeko, maneiatutako baldintza deitutako errutinetara hedatzea eragozten da.

Adibideak:

Errorea maneiatzeko errutina erabilienak honakoak dira: erabiltzaileari abisu bat bidaltzea, errorea konpontzea, errore-informazioa egunkarian gordetzea eta errorea konpontzeko azalpenak ematen dituzten errore pertsonalizatuak sortzea. Erabili Resume label mekanismo horiek beharrezkotzat jotzen direnean.

      Sub Error_Handling
      try: On Error GoTo catch
          ' errutinaren kodea hemen doa
          Error 91 ' adibideko errorea
      finally:
          ' errutina garbitzeko kodea hemen doa
          Exit Sub
      catch:
          Print Erl, Err, Error$
          Resume finally
      End Sub ' Error_Handling
    

Erabili Resume Next, adibidez, eten behar ez den iterazio-prozesu batean aurkitutako anormaltasunak jakinarazteko. Kasu horretan, beharbada errutina anitz maneiatu behar da.

      Sub Iteration
          planets = Array("☿","♀","♁","♂","♃","♄","⛢","♆")
      try:
          On Error GoTo ReportAndProcessNext
          For ndx = -3 To 11 Step 1
              MsgBox planets(ndx)
          Next
          On Error GoTo 0 ' Stop error catching
      finally:
          Exit Sub
      ReportAndProcessNext:
          Print "Error "& Err &" at line "& Erl &" - "& Error$
          Resume Next
      End Sub ' Iteration
    

Zenbait egoeratan egokia izan daiteke Resume parametrorik gabe erabiltzea akastuna de instrukzioa berriro exekutatzea. Hala ere, horrek amaierarik gabeko begizta bat sortu dezake.