CreateUnoServiceWithArguments funtzioa

UNO zerbitzu baten instantzia sortzen du ProcessServiceManager bidez, aukerako argumentu gehigarriak barne.

Sintaxia:


    CreateUnoServiceWithArguments(ServiceName As String, Arguments() As Variant) As Object

CreateUnoServiceWithArguments funtzioarekin erabili daitezkeen UNO zerbitzuak createInstanceWith.. edo createWith.. izen-eredua jarraitzen duten metodo-izenen bidez identifikatzen dira.

Return type:

Object

Zerbitzu erabilgarriak ezagutzeko, begiratu com::sun::star Module erreferentzia-orria.

Parametroak:

Name	Type	Description
ServiceName	String	The UNO service name to be created.
Arguments	Variant	One to many arguments that specify the instance of the service. Arguments are stored as a one dimensional array, according to their positions in the constructor method definition.

Adibidea:

The com.sun.star.ui.dialogs.FilePicker example below displays a built-in LibreOffice Save As dialog with two extra controls: a listbox and a checkbox.


    Sub FileSaveAsDialog()
       td = com.sun.star.ui.dialogs.TemplateDescription
       options = td.FILESAVE_AUTOEXTENSION_TEMPLATE
       dlg = CreateUnoServiceWithArguments( _
          "com.sun.star.ui.dialogs.FilePicker", _
          Array(options))
       dlg.execute()
    End Sub ' FileSaveAsDialog

Fitxategien elkarrizketa-koadroak, adibidez Irekia, Gorde honela eta parekoak, bi modutara erabili daitezke:

Sistema eragilearen leiho-kudeatzaileak fitxategiak aukeratzeko dituen jatorrizko elkarrizketa-koadro gisa.
LibreOffice aplikazioak fitxategiak aukeratzeko eskaintzen dituen elkarrizketa-koadro gisa.

Erabili - LibreOffice - Orokorra aukera bata edo bestea erabiltzeko.

UNO zerbitzuek lineako dokumentazio zabala dute api.libreoffice.org webgunean. Bisitatu FilePicker zerbitzua erreferentziako orria goiko adibidean erabili den zerbitzuak eskaintzen dituen metodoei buruz gehiago jakiteko.

Adibidea:

Hurrengo kodeak com.sun.star.security.DocumentDigitalSignatures zerbitzua darabil uneko dokumentua sinatzeko:


Sub  SignCurrentDocDialog
   Dim pv(0) as new com.sun.star.beans.PropertyValue
   pv(0).Name  = "StorageFormat"
   pv(0).Value = "ZipFormat"
   mode = com.sun.star.embed.ElementModes
   sf = CreateUnoService("com.sun.star.embed.StorageFactory")
   storage = sf.createInstanceWithArguments(Array(ThisComponent.URL, mode.WRITE, pv))
   dds = CreateUnoServiceWithArguments( _
      "com.sun.star.security.DocumentDigitalSignatures", _
      Array("1.2", True)) 
   dds.signDocumentContent(storage, Null)
End Sub ' SignCurrentDocDialog

com.sun.star.security.DocumentDigitalSignatures UNO zerbitzuaren CreateWithVersion eta createWithVersionAndValidSignature eraikitzaile-metodoek CreateUnoServiceWithArguments funtzioarekin zerbitzu horren instantzia bat sortzeko bi modu desberdin adierazten dituzte.

CreateUnoService funtzioa

UNO objektuak, funtzioak eta zerbitzuak

Calc funtzioak makroetan erabiltzea