ScriptForge.Array zerbitzua

Dimentsio bakarreko matrizeak (bektoreak) eta bi dimentsiotakoak manipulatzeko eta transformatzeko metodoen bilduma bat eskaintzen du. Besteak beste, ezartze-eragiketak, ordenatzea, testu-fitxategiak inportatzea eta esportatzea ahalbidetzen du.

Bi dimentsio baino gehiago dituzten matrizeak ezin dira erabili zerbitzu honetako metodoekin. Salbuespen bakarra CountDims metodoa da, horrek edozein dimentsio kopuru duten matrizeak onartzen baititu.

Matrize-elementuek edozein motatako balioak eduki ditzakete, baita azpimatrizeak ere.

Zerbitzuari deitzea

Array zerbitzua erabili baino lehen, ScriptForge liburutegia kargatu behar da honakoa erabilita:


    GlobalScope.BasicLibraries.loadLibrary("ScriptForge")
  

Liburutegia kargatzean SF_Array objektua sortuko da, era horren bidez Array zerbitzuko metodoak deitu ahal izango dira.

Hurrengo kode-zatiek Array zerbitzuko metodoak deitzeko modu desberdinak erakusten dituzte (adibide gisa Append metodoa erabili da):


    Dim arr : arr = Array(1, 2, 3)
    arr = SF_Array.Append(arr, 4)
  

    Dim arr : arr = Array(1, 2, 3)
    Dim svc : svc = SF_Array
    arr = svc.Append(arr, 4)
  

    Dim arr : arr = Array(1, 2, 3)
    Dim svc : svc = CreateScriptService("Array")
    arr = svc.Append(arr, 4)
  
warning

Python lengoaiak zerrenden eta tuplen euskarria daukanez, Array zerbitzuaren metodo gehienak Basic scriptetarako soilik daude erabilgarri. Salbuespen bakarra ImportFromCSVFile da, hori Basic zein Python lengoaietan baitago onartuta.


Array zerbitzuaren metodoen zerrenda

Append
AppendColumn
AppendRow
Contains
ConvertToDictionary
Copy
CountDims
Difference
ExportToTextFile
ExtractColumn
ExtractRow

Flatten
ImportFromCSVFile
IndexOf
Insert
InsertSorted
Intersection
Join2D
Prepend
PrependColumn
PrependRow
RangeInit

Reverse
Shuffle
Slice
Sort
SortColumns
SortRows
Transpose
TrimArray
Union
Unique


tip

Metodo askoren lehen argumentua erabiliko den matrize-objektua da. Beti erreferentzia gisa pasatuko da eta ez du aldaketarik izango. 'Append', 'Prepend' eta antzeko metodoek matrize-objektu berria itzuliko dute exekutatuak izan ondoren.


Append

Argumentu gisa zerrendatutako elementuak sarrerako matrizearen amaieran eransten ditu.

Sintaxia:

svc.Append(array_1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]

Parametroak:

array_1d : Lehendik dagoen matrizea, hutsik egon daiteke.

arg0, arg1, ...: array_1d matrizeari erantsiko zaizkion elementuak.

Adibidea:


    Dim a As Variant
    a = SF_Array.Append(Array(1, 2, 3), 4, 5)
        ' (1, 2, 3, 4, 5)
  

AppendColumn

Zutabe bat eransten du bi dimentsioko matrize baten eskuineko aldean. Emaitza modura sortuko den matrizeak hasierako bi dimentsioko matrizearen beheko muga berak izango ditu.

Sintaxia:

svc.AppendColumn(array_2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]

Parametroak:

array_2d: Lehendik dagoen matrize bat, hutsik egon daiteke. Matrizeak dimentsio bakarra badu, emaitza gisa lortuko den bi dimentsioko matrizearen lehen zutabetzat hartuko da.

column: Dimentsio bakarreko matrizea, array_2d matrizean dauden errenkada kopuruaren bezain beste elementu dituena.

Adibidea:


    Dim a As Variant, b As variant
    a = SF_Array.AppendColumn(Array(1, 2, 3), Array(4, 5, 6))
        ' ((1, 4), (2, 5), (3, 6))
    b = SF_Array.AppendColumn(a, Array(7, 8, 9))
        ' ((1, 4, 7), (2, 5, 8), (3, 6, 9))
    c = SF_Array.AppendColumn(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
  

AppendRow

Erantsi errenkada berria bi dimentsioko matrize baten beheko aldean. Emaitza modura sortuko den matrizeak hasierako bi dimentsioko matrizearen beheko muga berak izango ditu.

Sintaxia:

svc.AppendRow(array_2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*])

Parametroak:

array_2d: Lehendik dagoen matrize bat, hutsik egon daiteke. Matrizeak dimentsio bakarra badu, emaitza gisa lortuko den bi dimentsioko matrizearen lehen errenkadatzat hartuko da.

row: Dimentsio bakarreko matrizea, array_2d matrizean dauden zutabe kopuruaren bezain beste elementu dituena.

Adibidea:


    Dim a As Variant, b As variant
    a = SF_Array.AppendRow(Array(1, 2, 3), Array(4, 5, 6))
        '  ((1, 2, 3), (4, 5, 6))
    b = SF_Array..AppendRow(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
  

Contains

Egiaztatu dimentsio bakarreko matrize batek zenbaki, testu edo data jakin bat duen. Testu-konparazioak maiuskulak/minuskulak kontuan hartu ditzake edo ez.
Sarrerako matrize ordenatuak modu homogeneoan bete behar dira, alegia, elementu guztiek mota bereko eskalarrak izan behar dute (Empty eta Null elementuak debekatuta daude).
Metodoaren emaitza aurresanezina da matrizea ordenatua dela iragartzen bada eta halakoa ez bada.
Bilaketa bitarra egiten da matrizea ordenatzen denean; bestela, goitik behera eskaneatu besterik ez da egiten eta Empty eta Null elementuei ez ikusiarena egiten zaie.

Sintaxia:

svc.Contains(array_1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ""): bool

Parametroak:

array_1d: Eskaneatuko den matrizea.

tofind: Bilatuko den zenbaki, data edo kate bat.

casesensitive: Kateak konparatzeko soilik (Balio lehenetsia = False).

sortorder: "ASC", "DESC" edo "" (ordenatu gabea) izan daiteke. Balio lehenetsia "" da.

Adibidea:


    Dim a As Variant
    a = SF_Array.Contains(Array("A","B","c","D"), "C", SortOrder := "ASC") ' True
    SF_Array.Contains(Array("A","B","c","D"), "C", CaseSensitive := True) ' False
  

ConvertToDictionary

Biltegiratu 2 zutabetako matrize baten edukia ScriptForge.Dictionary objektu batean.
Gakoa lehen zutabetik erauziko da, elementua bigarrenetik.

Sintaxia:

svc.ConvertToDictionary(array_2d: any[0..*, 0..1]): obj

Parametroak:

array_2d: ScriptForge.Dictionary objektu bihurtuko diren datuak.

Adibidea:


    Dim a As Variant, b As Variant
    a = SF_Array.AppendColumn(Array("a", "b", "c"), Array(1, 2, 3))
    b = SF_Array.ConvertToDictionary(a)
    MsgBox b.Item("c") ' 3
  

Copy

1D edo 2D matrize baten kopia bat sortzen du.

Sintaxia:

svc.Copy(array_nd: any[0..*]): any[0..*]

svc.Copy(array_nd: any[0..*, 0..*]): any[0..*, 0..*]

Parametroak:

array_nd: Kopiatuko den 1D edo 2D matrizea.

Adibidea:

Array objektu baten esleitze sinple batek bere erreferentzia kopiatuko du, objektuaren edukien kopia bat sortu ordez. Ikusi beheko adibidea:


    Dim a as Variant, b as Variant
    a = Array(1, 2, 3)
    ' Beheko esleipena erreferentzia bidez egin da
    b = a
    ' Hortaz, "b" balioa aldatzen bada "a" ere aldatuko da
    b(0) = 10
    MsgBox a(0) ' 10
  

Copy metodoa erabiltzen bada, Array objektuaren kopia oso bat egingo da. Beheko adibidean, a eta b objektu desberdinak dira eta b aldagaiko balioak aldatzen direnean, a aldagaiak ez du aldaketarik jasango.


    Dim a as Variant, b as Variant
    a = Array(1, 2, 3)
    ' "a" balioaren kopia bat sortzen du "Copy" metodoa erabilita
    b = SF_Array.Copy(a)
    b(0) = 10
    MsgBox a(0) ' 1
  

CountDims

Zenbatu matrize baten dimentsio kopurua. Emaitza bi baino handiagoa izan daiteke.
Argumentua matrize bat ez bada, -1 itzultzen du.
Matrizea hasieratu gabe badago, 0 itzultzen du.

Sintaxia:

svc.CountDims(array_nd: any): int

Parametroak:

array_nd: Aztertuko den matrizea.

Adibidea:


    Dim a(1 To 10, -3 To 12, 5)
    MsgBox SF_Array.CountDims(a) ' 3
  

Difference

Eraiki multzo bat, zeron oinarritutako matrize gisa, sarrerako bi matrizeei diferentzia eragilea aplikatuta. Emaitza gisa sortutako elementuak lehen matrizetik sortuko dira, ez bigarrenetik.
Emaitzako matrizea gorantz ordenatuta egongo da.
Sarrerako bi matrizeek modu homogeneoan beteta egon behar dute, alegia, beren elementuek mota bereko eskalarrak izan behar dute. Empty eta Null elementuak debekatuta daude.
Testu-konparazioak maiuskulak/minuskulak kontuan hartu ditzake edo ez.

Sintaxia:

svc.Difference(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

Parametroak:

array1_1d: Erreferentziako dimentsio bakarreko matrize bat. Matrize horretako elementuak aztertuko dira, zein kenduko den erabakitzeko.

array2_1d: Dimentsio bakarreko matrizea. Matrize horren elementuak sarrerako lehen matrizetik kenduko dira.

casesensitive: Argumentu hau aplikatu ahal izateko, matrizeak kateekin beteta egon behar dute (Balio lehenetsia = False).

Adibidea:


    Dim a As Variant
    a = SF_Array.Difference(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
        ' ("A", "B")
  

ExportToTextFile

Idatzi matrize bateko elementu guztiak modu sekuentzialean testu-fitxategi batean. Fitxategia lehendik badago, hura gainidatziko da abisurik gabe.

Sintaxia:

svc.ExportToTextFile(array_1d: any[0..*], filename: str, [encoding: str]): bool

Parametroak:

array_1d: Esportatuko den matrizea. Kateak soilik izan behar ditu.

filename: Datuak idazteko erabiliko den testu-fitxategiaren izena. Izena adierazteko, SF_FileSystem zerbitzuaren FileNaming propietateari egin behar zaio kasu.

Encoding: Erabiliko den karaktere-jokoa. Erabili IANA karaktere-jokoak atalean zerrendatutako izen bat. Kontuan izan LibreOffice aplikazioak ez dituela zertan existitzen diren karaktere-joko guztiak inplementatu. Balio lehenetsia "UTF-8" da.

Adibidea:


    SF_Array.ExportToTextFile(Array("A","B","C","D"), "C:\Temp\A short file.txt")
  

ExtractColumn

Erauzi zutabe zehatz bat bi dimentsiotako matrize batetik, matrize berria sortzeko.
Beheko LBound eta goiko UBound mugak sarrerako matrizearen lehen dimentsioak dituenen berdinak dira.

Sintaxia:

svc.ExtractColumn(array_2d: any[0..*, 0..*], columnindex: int): any[0..*, 0..*]

Parametroak:

array_2d: Erauzketa matrize honetatik egingo da.

columnindex: Erauziko den zutabearen zenbakia. [LBound, UBound] barrutian egon behar du.

Adibidea:


    '3x3 matrize bat sortzen du: |1, 2, 3|
    '                      |4, 5, 6|
    '                      |7, 8, 9|
    Dim mat as Variant, col as Variant
    mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
    mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
    mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
    'Hirugarren zutabea erauzten du: |3, 6, 9|
    col = SF_Array.ExtractColumn(mat, 2)
  

ExtractRow

Erauzi errenkada zehatz bat bi dimentsiotako matrize batetik, matrize berria sortzeko.
Beheko LBound eta goiko UBound mugak sarrerako matrizearen lehen dimentsioak dituenen berdinak dira.

Sintaxia:

svc.ExtractRow(array_2d: any[0..*, 0..*], rowindex: int): any[0..*, 0..*]

Parametroak:

array_2d: Erauzketa matrize honetatik egingo da.

rowindex: Erauziko den errenkadaren zenbakia. [LBound, UBound] barrutian egon behar du.

Adibidea:


    '3x3 matrize bat sortzen du: |1, 2, 3|
    '                      |4, 5, 6|
    '                      |7, 8, 9|
    Dim mat as Variant, row as Variant
    mat = SF_Array.AppendRow(Array(), Array(1, 2, 3))
    mat = SF_Array.AppendRow(mat, Array(4, 5, 6))
    mat = SF_Array.AppendRow(mat, Array(7, 8, 9))
    'Lehen errenkada erauzten du: |1, 2, 3|
    row = SF_Array.ExtractRow(mat, 0)
  

Flatten

Pilatu matrize berri batean, azpimatrizerik gabe, matrize bateko elementu bakarrak eta bere azpimatrizeetako elementu guztiak. Azpimatrize hutsei ez ikusiarena egingo zaie eta dimentsio bat baino gehiago ditzuten azpimatrizeak ez dira berdinduko.

Sintaxia:

svc.Flatten(array_1d: any[0..*]): any[0..*]

Parametroak:

array_1d: Lehendik dagoen matrizea, hutsik egon daiteke.

Adibidea:


    Dim a As Variant
    a = SF_Array.Flatten(Array(Array(1, 2, 3), 4, 5))
        ' (1, 2, 3, 4, 5)
  
tip

Flatten metodoa erabili daiteke, Append edo Prepend edo beste metodo batzuekin batera, 1D matrizeen multzo bat 1D matrize bakarrean kateatzeko.


Adibidea:

Hurrengo adibidean, Flatten eta Append metodoak hiru matrize kateatzeko nola erabili daitezkeen azaltzen da.


    'Hiru matrize sortzen ditu adibide honetarako
    Dim a as Variant, b as Variant, c as Variant
    a = Array(1, 2, 3)
    b = Array(4, 5)
    c = Array(6, 7, 8, 9)
    'Hiru matrize kateatzen ditu 1D matrize bakar batean
    Dim arr as Variant
    arr = SF_Array.Flatten(SF_Array.Append(a, b, c))
    '(1, 2, 3, 4, 5, 6, 7, 8, 9)
  

ImportFromCSVFile

Inportatu komaz banandutako balioen (CSV) fitxategi bateko datuak. Komaren ordez beste karaktere bat erabili daiteke.

CSV formatu aplikagarria IETF Common Format and MIME Type for CSV Files webgunean dago deskribatuta.

Fitxategiko lerro bakoitzak erregistro oso bat du (ez dago onartuta lerroak zatitzea).
Hala ere, \n, \t eta antzeko sekuentziak aldaketarik gabe uzten dira. Erabili SF_String.Unescape() metodoa haiek kudeatzeko.

Metodo honek bi dimentsiotako matrize bat itzultzen du. Matrizearen errenkada bakoitza fitxategian irakurritako erregistro bakar bati dagokio, eta zutabeak erregistroko zutabeei dagozkie. Ez da egiaztatzerik egiten eremu motek zutabez zutabe duten koherentzia ziurtatzeko. Estimazio bat egingo da zenbakizko motak eta datak diren motak identifikatzeko.

Lerroak fitxategiko lehen lerroak baino eremu gehiago edo gutxiago baditu, salbuespen bat sortuko da. Lerro hutsei ez ikusiarena egingo zaie. Fitxategiaren tamainak elementu kopuruaren muga gainditzen badu (ikusi kodea barruan), abisu bat sortuko da eta matrizea moztu egingo da.

Sintaxia:

svc.ImportFromCSVFile(filename: str, delimiter: str = ',', dateformat: str = ''): any[0..*]

Parametroak:

filename: Datuak dituen testu-fitxategiaren izena. Izena adierazteko, SF_FileSystem zerbitzuaren FileNaming propietatearen arabera egin behar da.

delimiter: Karaktere bakarra, normalean koma bat, puntu eta koma bat edo tabulazio-karaktere bat (Lehenetsia = ",").

dateformat : Mekanismo berezi batek maneiatzen ditu datak dateformat honakoetako bat bada: "UUUU-HH-EE", "EE-HH-UUUU" edo "HH-EE-UUUU". Marratxoaren (-) ordez puntu bat (.), barra bat (/) edo zuriune bat erabili daiteke. Beste data-formatu batzuei ez ikusiarena egingo zaie. Lehenespen modura, hutsik dagoen "" katea diren datak testu normaltzat hartzen dira.

Adibidea:

Har dezagun, adibidez, "myFile.csv" fitxategia, honako edukiak dituena:

Izena,JaiotzeData,Helbidea,Hiria

Anna,2002/03/31,"Aiztogile kalea, 21",Gasteiz

Asier,1998/05/04,"Judimendi kalea, 3",Gasteiz

Beheko adibideak, Basic eta Python lengoaietan, CSV fitxategi bateko edukiak irakurtzen ditu eta Array objektu batean jartzen ditu.

Basic lengoaian

    Dim arr As Variant
    arr = SF_Array.ImportFromCSVFile("C:\Temp\myFile.csv", DateFormat := "YYYY/MM/DD")
    MsgBox arr(0, 3) ' Hiria
    MsgBox arr(1, 2) ' Aiztogile kalea, 21
    MsgBox arr(1, 3) ' Gasteiz
  
Python lengoaian

    from scriptforge import CreateScriptService
    svc = CreateScriptService("Array")
    bas = CreateScriptService("Basic")
    arr = svc.ImportFromCSVFile(r"C:\Temp\myFile.csv", dateformat = "YYYY/MM/DD")
    bas.MsgBox(arr[0][3]) # Hiria
    bas.MsgBox(arr[1][2]) # Aiztogile kalea, 21
    bas.MsgBox(arr[1][3]) # Gasteiz
  

IndexOf

Bilatu dimentsio bakarreko matrize batean zenbaki, kate edo data bat. Testu-konparazioak maiuskulak/minuskulak kontuan hartu ditzake edo ez.
Matrizea ordenatuta badago, modu homogeneneoan bete behar da, alegia, elementu guztiek mota bereko eskalarrak izan behar dute (Empty eta Null elementuak debekatuta daude).
Metodoaren emaitza ezin da aurresan matrizea ordenatuta dagoela esaten bada baina ez badago.
Ordenatutako matrizeetan bilaketa bitarra exekutatzen da. Bestela, matrizeak goitik behera eskaneatzen dira eta Empty eta Null elementuei ez ikusiarena egiten zaie.

Metodoak LBound(sarrerako matrizea) - 1 itzultzen du bilaketak arrakastarik izan ez badu.

Sintaxia:

svc.IndexOf(array_1d: any[0..*], tofind: any, casesensitive: bool = False, sortorder: str = ''): int

Parametroak:

array_1d: Eskaneatuko den matrizea.

tofind: Bilatuko den zenbaki, data edo kate bat.

casesensitive: Kateak konparatzeko soilik (Balio lehenetsia = False).

sortorder: "ASC", "DESC" edo "" (ordenatu gabea) izan daiteke. Balio lehenetsia "" da.

Adibidea:


    MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", SortOrder := "ASC") ' 2
    MsgBox SF_Array.IndexOf(Array("A","B","c","D"), "C", CaseSensitive := True) ' -1
  

Insert

Sartu argumentu gisa zerrendatutako elementuak sarrerako matrizearen indize jakin baten aurrean.
Argumentuak itsuan txertatuko dira. Horietako bakoitza eskalar bar izan daiteke edo edozein motatako azpimatrize bat izan daiteke.

Sintaxia:

svc.Insert(array_1d: any[0..*], before: int, arg0: any, [arg1: any] ...): any[0..*]

Parametroak:

array_1d: Lehendik dagoen matrizea, hutsik egon daiteke.

before: Txertatzea indize honen aurrean gertatuko da; [LBound, UBound + 1] tartean egon behar du.

arg0, arg1, ...: array_1d matrizean txertatuko diren elementuak.

Adibidea:


    Dim a As Variant
    a = SF_Array.Insert(Array(1, 2, 3), 2, "a", "b")
        ' (1, 2, "a", "b", 3)
  

InsertSorted

Elementu berri bat bere tokian txertatzen du ordenatutako matrize batean.
Matrizeak modu homogeneoan egon behar du beteta, alegia, elementu guztiek mota bereko eskalarrak izan behar dute.
Empty eta Null elementuak debekatuta daude.

Sintaxia:

svc.InsertSorted(array_1d: any[0..*], item: any, sortorder: str = 'ASC', casesensitive: bool = False): any[0..*]

Parametroak:

array_1d: Balioa matrize honetan txertatuko da.

item : Txertatuko den eskalarra, matrizean lehendik dauden elementuen mota berekoa.

sortorder: "ASC" (balio lehenetsia) edo "DESC" izan daiteke.

casesensitive: Kateak konparatzeko soilik (Balio lehenetsia = False).

Adibidea:


    Dim a As Variant
    a = SF_Array.InsertSorted(Array("A", "C", "a", "b"), "B", CaseSensitive := True)
        ' ("A", "B", "C", "a", "b")
  

Intersection

Eraiki multzo bat, zeron oinarritutako matrize gisa, sarrerako bi matrizeen ebakidura-eragiketa aplikatuta. Emaitza gisa lortutako elementuak bi matrizeetan daudenak dira.
Emaitza gisa lortutako matrizea gorantz ordenatuta dago.
Sarrerako bi matrizeek modu homogeneoan beteta egon behar dute, alegia, elementu guztiek mota bereko eskalarrak izan behar dute. Empty eta Null elementuak debekatuta daude.
Testu-konparazioan maiuskulak/minuskulak kontuan hartu daitezke edo ez.

Sintaxia:

svc.Intersection(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

Parametroak:

array1_1d: Sarrerako lehen matrizea.

array2_1d: Sarrerako bigarren matrizea.

CaseSensitive: Matrizeak testu-elementuekin beteta badaude soilik (Balio lehenetsia = False).

Adibidea:


    Dim a As Variant
    a = SF_Array.Intersection(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
        ' ("C", "b")
  

Join2D

Elkartu bi dimentsioko matrize bat bi mugatzailerekin, bat zutabeentzat eta bestea errenkadentzat.

Sintaxia:

svc.Join2D(array_2d: any [0..*, 0..*], [columndelimiter: str], [rowdelimiter: str], [quote: str]): str

Parametroak:

array_2d: Elementu bakoitzak testu, zenbaki, data edo boolear izan behar du.
Datak UUU-HH-EE oo:mm:ss formatura bihurtuko dira.
Baliogabeko elementuak zero luzerako kateekin ordeztuko dira.

columndelimiter: Zutabe bakoitza mugatzen du (balio lehenetsia = Tab/Chr(9)).

rowdelimiter: Errenkada bakoitza mugatzen du (balio lehenetsia = LineFeed/Chr(10))

quote: True (egia) bada, babestu kateak komatxo bikoitzekin. Balio lehenetsia False (faltsua) da.

Adibidea:


    ' arr = | 1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5           |
    '       | 6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10 |
    Dim arr as Variant : arr = Array()
    arr = SF_Array.AppendRow(arr, Array(1, 2, "A", [2020-02-29], 51, 2, "A", [2020-02-29], 5))
    arr = SF_Array.AppendRow(arr, Array(6, 7, "this is a string", 9, 106, 7, "this is a string", 9, 10))
    Dim arrText as String
    arrText = SF_Array.Join2D(arr, ",", "/", False)
    ' 1,2,A,,51,2,A,,5/6,7,this is a string,9,106,7,this is a string,9,10
  

Prepend

Kokatu argumentu gisa zerrendatutako elementuak sarrerako matrizearen hasieran.

Sintaxia:

svc.Prepend(array_1d: any[0..*], arg0: any, [arg1: any] ...): any[0..*]

Parametroak:

array_1d: Lehendik dagoen matrizea, hutsik egon daiteke.

arg0, arg1, ...: array_1d matrizearen aurrean kokatuko diren elementuen zerrenda.

Adibidea:


    Dim a As Variant
    a = SF_Array.Prepend(Array(1, 2, 3), 4, 5)
        ' (4, 5, 1, 2, 3)
  

PrependColumn

Erantsi zutabe berri bat bi dimentsioko matrize baten ezkerreko aldean. Emaitza gisa sortutako matrizeak hasierako bi dimentsioko matrizearen beheko muga berak izango ditu.

Sintaxia:

svc.PrependColumn(array_2d: any[0..*, 0..*], column: any[0..*]): any[0..*, 0..*]

Parametroak:

array_2d: Lehendik dagoen matrizea, hutsik egon daiteke. Matrizeak dimentsio bakarra badu, sortuko den bi dimentsioko matrizearen azken zutabetzat hartuko da.

column: Dimentsio bakarreko matrizea, array_2d matrizean dauden errenkada kopuruaren bezain beste elementu dituena.

Adibidea:


    Dim a As Variant, b As variant
    a = SF_Array.PrependColumn(Array(1, 2, 3), Array(4, 5, 6))
        ' ((4, 1), (5, 2), (6, 3))
    b = SF_Array.PrependColumn(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(0, i) ≡ i
  

PrependRow

Erantsi errenkada berri bat bi dimentsioko matrize baten hasieran. Emaitza gisa sortutako matrizeak hasierako bi dimentsioko matrizearen beheko muga berak izango ditu.

Sintaxia:

svc.PrependRow(array_2d: any[0..*, 0..*], row: any[0..*]): any[0..*, 0..*]

Parametroak:

array_2d: Lehendik dagoen matrize bat, hutsik egon daiteke. Matrizeak dimentsio bakarra badu, emaitza gisa lortuko den bi dimentsioko matrizearen azken errenkadatzat hartuko da.

row: Dimentsio bakarreko matrizea, array_2d matrizean dauden zutabe kopuruaren bezain beste elementu dituena.

Adibidea:


    Dim a As Variant, b As variant
    a = SF_Array.PrependRow(Array(1, 2, 3), Array(4, 5, 6))
        ' ((4, 5, 6), (1, 2, 3))
    b = SF_Array.PrependRow(Array(), Array(1, 2, 3))
        ' ∀ i ∈ {0 ≤ i ≤ 2} : b(i, 0) ≡ i
  

RangeInit

Hasieratu zeron oinarritutako matrize berri bat zenbakizko balioekin.

Sintaxia:

svc.RangeInit(from: num, upto: num, [bystep: num]): num[0..*]

Parametroak:

from: Lehen elementuaren balioa.

upto: Azken elementuak ez du upto gainditu behar.

bystep : Elkarren ondoan dauden bi elementuen arteko diferentzia (balio lehenetsia = 1).

Adibidea:


    Dim a As Variant
    a = SF_Array.RangeInit(10, 1, -1)
        ' (10, 9, 8, 7, 6, 5, 4, 3, 2, 1)
  

Reverse

Itzuli dimentsio bakarreko matrize baten alderantzizkoa.

Sintaxia:

svc.Reverse(array_1d: any[0..*]): any[0..*]

Parametroak:

array_1d: Alderantzikatuko den matrizea.

Adibidea:


    Dim a As Variant
    a = SF_Array.Reverse(Array("a", 2, 3, 4))
        ' (4, 3, 2, "a")
  

Shuffle

Dimentsio bakarreko matrize baten ausazko permutazio bat itzultzen du.

Sintaxia:

svc.Shuffle(array_1d: any[0..*]): any[0..*]

Parametroak:

array_1d: Nahastuko den matrizea.

Adibidea:


    Dim a As Variant
    a = SF_Array.Shuffle(Array(1, 2, 3, 4))
        ' "a" matrizea orain ausazko ordenan dago, adibidez (2, 3, 1, 4)
  

Slice

Dimentsio bakarreko matrize baten azpimultzo bat itzultzen du.

Sintaxia:

svc.Slice(array_1d: any[0..*], from: int, [upto: int]): any[0..*]

Parametroak:

array_1d: Zatituko den matrizea.

from: Erauziko den azpimatrizearen indizerik baxuena (from barne) array_1d matrizean

upto: Erauziko den azpimatrizearen goiko indizea array_1d matrizean (upto barne). Balio lehenetsia array_1d matrizearen goiko muga da. upto < from bada, itzulitako matrizea hutsik egongo da.

Adibidea:


    Dim a As Variant
    a = SF_Array.Slice(Array(1, 2, 3, 4, 5), 1, 3) ' (2, 3, 4)
  

Sort

Ordenatu dimentsio bakarreko matrize bat gorantz edo beherantz. Testu-konparazioetan maiuskulak/minuskulak kontuan hartu daitezke edo ez.
Matrizeak modu homogeneoan beteta egon behar du, alegia, elementuek mota bereko eskalarrak izan behar dute.
Empty eta Null elementuak onartzen dira. Normalean, Empty < Null < beste edozein balio eskalar.

Sintaxia:

svc.Sort(array_1d: any[0..*], sortorder: str, casesensitive: bool = False): any[0..*]

Parametroak:

array_1d: Ordenatuko den matrizea.

sortorder: "ASC" (balio lehenetsia) edo "DESC" izan daiteke.

casesensitive: Kateak konparatzeko soilik (Balio lehenetsia = False).

Adibidea:


    Dim a As Variant
    a = SF_Array.Sort(Array("a", "A", "b", "B", "C"), CaseSensitive := True)
        ' ("A", "B", "C", "a", "b")
  

SortColumns

Itzuli bi dimentsioko matrize baten zutabeen permutazio bat, emandako errenkada baten balioen arabera ordenatuta.
Matrizeak modu homogeneoan beteta egon behar du, alegia, elementuek mota bereko eskalarrak izan behar dute.
Empty eta Null elementuak onartzen dira. Normalean, Empty < Null < beste edozein balio eskalar.

Sintaxia:

svc.SortColumns(array_2d: any[0..*, 0..*], rowindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]

Parametroak:

array_2d: Ordenatuko den bi dimentsiotako matrizea.

rowindex: Zutabeak ordenatzeko erreferentzia gisa erabiliko den errenkadaren indizea.

sortorder: "ASC" (balio lehenetsia) edo "DESC" izan daiteke.

casesensitive: Kateak konparatzeko soilik (Balio lehenetsia = False).

Adibidea:


    ' arr = | 5, 7, 3 |
    '       | 1, 9, 5 |
    '       | 6, 1, 8 |
    Dim arr as Variant : arr = Array(5, 7, 3)
    arr = SF_Array.AppendRow(arr, Array(1, 9, 5))
    arr = SF_Array.AppendRow(arr, Array(6, 1, 8))
    arr = SF_Array.SortColumns(arr, 2, "ASC")
    ' arr = | 7, 5, 3 |
    '       | 9, 1, 5 |
    '       | 1, 6, 8 |
  

SortRows

Itzuli bi dimentsioko matrize baten errenkaden permutazio bat, emandako zutabe baten balioen arabera ordenatuta.
Matrizeak modu homogeneoan beteta egon behar du, alegia, elementuek mota bereko eskalarrak izan behar dute.
Empty eta Null elementuak onartzen dira. Normalean, Empty < Null < beste edozein balio eskalar.

Sintaxia:

svc.SortRows(array_2d: any[0..*, 0..*], columnindex: int, sortorder: str, casesensitive: bool = False): any[0..*, 0..*]

Parametroak:

array_2d: Ordenatuko den matrizea.

columnindex: Errenkadak ordenatzeko erreferentzia gisa erabiliko den zutabearen indizea.

sortorder: "ASC" (balio lehenetsia) edo "DESC" izan daiteke.

casesensitive: Kateak konparatzeko soilik (Balio lehenetsia = False).

Adibidea:


    ' arr = | 5, 7, 3 |
    '       | 1, 9, 5 |
    '       | 6, 1, 8 |
    Dim arr as Variant : arr = Array(5, 7, 3)
    arr = SF_Array.AppendRow(arr, Array(1, 9, 5))
    arr = SF_Array.AppendRow(arr, Array(6, 1, 8))
    arr = SF_Array.SortRows(arr, 0, "ASC")
    ' arr = | 1, 9, 5 |
    '       | 5, 7, 3 |
    '       | 6, 1, 8 |
  

Transpose

Errenkadak eta zutabeak trukatzen ditu bi dimentsioko matrize batean.

Sintaxia:

svc.Transpose(array_2d: any[0..*, 0..*]): any[0..*, 0..*]

Parametroak:

array_2d: Trukatuko den bi dimentsiotako matrizea.

Adibidea:


    ' arr1 = | 1, 2 |
    '        | 3, 4 |
    '        | 5, 6 |
    arr1 = Array(1, 2)
    arr1 = SF_Array.AppendRow(arr1, Array(3, 4))
    arr1 = SF_Array.AppendRow(arr1, Array(5, 6))
    arr2 = SF_Array.Transpose(arr1)
    ' arr2 = | 1, 3, 5 |
    '        | 2, 4, 6 |
    MsgBox arr2(0, 2) ' 5
  

TrimArray

Dimentsio bakarreko matrize batean, kendu Null, Empty eta zero luzerako sarrerak.
Kate motako elementuak LibreOffice Basic Trim() funtzioarekin moztuko dira.

Sintaxia:

svc.TrimArray(array_1d: any[0..*]): any[0..*]

Parametroak:

array_1d: Moztuko den matrizea.

Adibidea:


    Dim a As Variant
    a = SF_Array.TrimArray(Array("A", "B", Null, " D "))
        ' ("A", "B", "D")
  

Union

Eraiki multzo bat, zeron oinarritutako matrize gisa, sarrerako bi matrizeen batuketa-eragiketa aplikatuta. Emaitza gisa lortutako elementuak bi matrizeetan daudenak dira.
Emaitza gisa lortutako matrizea gorantz ordenatuta egongo dira.
Sarrerako bi matrizeek modu homogeneoan beteta egon behar dute, alegia, elementu guztiek mota bereko eskalarrak izan behar dute. Empty eta Null elementuak debekatuta daude.
Testu-konparazioan maiuskulak/minuskulak kontuan hartu daitezke edo ez.

Sintaxia:

svc.Union(array1_1d: any[0..*], array2_1d: any[0..*], casesensitive: bool = False): any[0..*]

Parametroak:

array1_1d: Sarrerako lehen matrizea.

array2_1d: Sarrerako bigarren matrizea.

casesensitive: Matrizeak kateekin beteta badaude soilik aplikatuko da (Balio lehenetsia = False).

Adibidea:


    Dim a As Variant
    a = SF_Array.Union(Array("A", "C", "A", "b", "B"), Array("C", "Z", "b"), True)
        ' ("A", "B", "C", "Z", "b")
  

Unique

Eraiki balio bakarren multzo bat sarrerako matrize batetik eratorrita.
Sarrerako matrizeak modu homogeneoan beteta egon behar du, alegia, elementu guztiek mota bereko eskalarrak izan behar dute. Empty eta Null elementuak debekatuta daude.
Testu-konparazioan maiuskulak/minuskulak kontuan hartu daitezke edo ez.

Sintaxia:

svc.Unique(array_1d: any[0..*], casesensitive: bool = False): any[0..*]

Parametroak:

array_1d: Sarrerako matrizea.

casesensitive: Matrizeak kateekin beteta badaude soilik aplikatuko da (Balio lehenetsia = False).

Adibidea:


    Dim a As Variant
    a = SF_Array.Unique(Array("A", "C", "A", "b", "B"), CaseSensitive := True)
        '  ("A", "B", "C", "b")
  
warning

Azpimarraren karaktere bat, "_", aurrizki gisa duten ScriptForge Basic errutina edo identifikatzaile guztiak barneko erabilerarako erreserbatuta daude. Ez dira Basic makroetan edo Python scriptetan erabili behar.


Emaguzu laguntza!