Sistema eragilea identifikatzea

Sistema eragilea Python zein Basic lengoaiekin identifikatu daiteke.

note

ComputerName propietatea Windowserako soilik dago erabilgarri. LibreOffice Basic lengoaiaren mugak gainditzeko, Python makroak deitu daitezke Basic-etik.


Python klase bat erabilita:


        import os, platform
        class Platform():
            @property
            def ComputerName(self): return platform.node()
            @property
            def DirSeparator(self): return os.sep
            @property
            def isLinux(self): return (self.OSName=='Linux')
            @property
            def isMacOSX(self): return (self.OSName=='Darwin')
            @property
            def isWindows(self): return (self.OSName=='Windows')
            @property
            def OSName(self): return platform.system()
            @property
            def PathDelimiter(self): return os.pathsep
    

Basic klase-modulu bat erabilita:

tip

LibreOffice Basic lengoaiak ez du jatorrizko MacOS X ezagutza. Plataformaren identifikazioa LibreOffice APIa erabilita egin daiteke.



        Option Compatible
        Option ClassModule
        Option Explicit
        
        Public Property Get ComputerName As String
            If isWindows Then ComputerName = Environ("ComputerName")
        End Property ' Platform.ComputerName
        
        Public Property Get DirSeparator As String
            DirSeparator = GetPathSeparator()
        End Property ' Platform.DirSeparator
        
        Public Property Get IsLinux As Boolean
            isLinux = ( GetGUIType()=4 ) ' Applies to macOS as well 
        End Property ' Platform.isLinux
        
        Public Property Get IsMacOSX As Boolean
            isMacOSX = ( OSName="MAC" )
        End Property ' Platform.isMacOSX
        
        Public Property Get IsWindows As Boolean
            isWindows = ( GetGUIType()=1 )
        End Property ' Platform.isWindows
        
        Public Property Get OSName As String
            ' Itzuli plataformaren izena honela: "MAC", "UNIX", "WIN"
            ' "Tools.UCB.ShowHelperDialog" funtziotik ondorioztatua
            With GlobalScope.Basiclibraries
                If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
            End With
            Dim keyNode As Object ' com.sun.star.configuration.ConfigurationAccess
            keyNode = Tools.Misc.GetRegistryKeyContent("org.openoffice.Office.Common/Help")
            OSName = keyNode.GetByName("System")
        End Property ' Platform.OSName
        
        Public Property Get PathDelimiter As String
            Select Case OSName
                Case "MAC", "UNIX" : PathDelimiter = ":"
                Case "WIN" : PathDelimiter = ";"
             End Select
        End Property ' Platform.PathDelimiter
    

Adibideak:

Pythonekin

>>> from <the_module> import Platform

>>> print(Platform().isMacOSX) # objektu-propietatea

True

>>> input(Platform().OSName) # objektu-propietatea

Darwin

Tresnak - Makroak - Exekutatu makroa... menutik.


        from <the_module> import Platform
        import screen_io as ui
        p = Platform()
        ui.MsgBox(''.join(['isMacOS: ',str(p.isMacOSX)]),0,p.OSName)
    

LibreOffice Basic lengoaiarekin


        Sub Platform_example()
            Dim p As New Platform ' Platform klasearen instantzia
            MsgBox p.isLinux ' objektu-propietatea
            Print p.isWindows, p.OSName ' objektu-propietateak
        End Sub ' Platform_example
    

Emaguzu laguntza!