MkDir lause

MkDir Statement diagram

Loob andmekandjale uue kataloogi.

Süntaks:


MkDir path

Parameetrid:

path: Any string expression that specifies the name and path of the directory to be created. You can also use URL notation.

Kui asukohta pole määratud, siis luuakse uus kataloog aktiivsesse kataloogi.

Veakoodid:

5 Vigane protseduuri väljakutse

76 Asukohta ei leitud

Näide:


Sub ExampleFileIO
' Failide korraldamise funktsioonide näide
Const sFile1 As String = "file://c|/autoexec.bat"
Const sDir1 As String = "file://c|/Temp"
Const sSubDir1 as String ="Test"
Const sFile2 as String = "Copied.tmp"
Const sFile3 as String = "Renamed.tmp"
Dim sFile As String
    sFile = sDir1 + "/" + sSubDir1
    ChDir( sDir1 )
    If Dir(sSubDir1,16)="" then ' Kas kataloog on olemas?
        MkDir sSubDir1
        MsgBox sFile,0,"Loo kataloog"
    End If
    sFile = sFile + "/" + sFile2
    FileCopy sFile1 , sFile
    MsgBox fSysURL(CurDir()),0,"Aktiivne kataloog"
    MsgBox sFile & Chr(13) & FileDateTime( sFile ),0,"Loomise aeg"
    MsgBox sFile & Chr(13)& FileLen( sFile ),0,"Faili pikkus"
    MsgBox sFile & Chr(13)& GetAttr( sFile ),0,"Faili atribuudid"
    Name sFile As sDir1 + "/" + sSubDir1 + "/" + sFile3
    ' Muuda nime samas kataloogis
    sFile = sDir1 + "/" + sSubDir1 + "/" + sFile3
    SetAttr( sFile, 0 ) 'Delete all attributes
    MsgBox sFile & Chr(13) & GetAttr( sFile ),0,"Uued faili atribuudid"
    Kill sFile
    RmDir sDir1 + "/" + sSubDir1
End Sub
 
' Teisendab URL-is süsteemi tee
Function fSysURL( fSysFp As String ) As String
Dim iPos As String
    iPos = 1
    iPos = Instr(iPos,fSysFp, getPathSeparator())
    Do While iPos > 0
        Mid( fSysFp, iPos , 1,"/")
        iPos = Instr(iPos+1,fSysFp, getPathSeparator())
    Loop
    ' koolon DOS-iga
    iPos = Instr(1,fSysFp,":")
    If iPos > 0 Then Mid( fSysFp, iPos , 1,"|")
    fSysURL = "file://" & fSysFp
End Function