SFDialogs.Dialog service

The Dialog service contributes to the management of dialogs created with the Basic Dialog Editor. Each instance of the current class represents a single dialog box displayed to the user.

tip

A dialog box can be displayed in modal or in non-modal modes.


In modal mode, the box is displayed and the execution of the macro process is suspended until one of the OK or Cancel buttons is pressed. In the meantime, user actions executed on the box can trigger specific actions.

In non-modal mode, the dialog box is "floating" on the user desktop and the execution of the macro process continues normally. A non-modal dialog closes when it is terminated with the Terminate() method or when the LibreOffice session ends. The window close button is inactive in non-modal dialogs.

A dialog box disappears from memory after its explicit termination.

tip

The SFDialogs.Dialog service is closely related to the SFDialogs.DialogControl service.


Service invocation and usage

The Dialog service is invoked through the CreateScriptService method. It requires three positional arguments to specify the dialog box to activate:

Container: "GlobalScope" for preinstalled libraries or a window name as defined by ScriptForge.UI service. Empty string "" default value stands for the current document.

Library: The case-sensitive name of a library contained in the container. Default value is "Standard".

DialogName: A case-sensitive string designating the dialog.

Below LibreOffice Basic and Python examples are displaying the dlgConsole dialog that belongs to ScriptForge shared library:


      Dim oDlg As Object, lButton As Long
      Dim Container As String, Library As String, DialogName As String
      Set oDlg = CreateScriptService("SFDialogs.Dialog", "GlobalScope", "ScriptForge", "dlgConsole")
      '... controls initialization goes here...
      lButton = oDlg.Execute()
      'Default mode = Modal
      If lButton = oDlg.OKBUTTON Then
      '... Process controls and do what is needed here
      End If
      oDlg.Terminate()
  

Or using Python:


    dlg = CreateScriptService('SFDialogs.Dialog', 'GlobalScope', 'ScriptForge', 'dlgConsole')
    # ... controls initialization goes here...
    rc = dlg.Execute()
    # Default mode is Modal
    if rc == dlg.OKBUTTON:
        # ... Process controls and do what is needed here
    dlg.Terminate()
  

Alternatively a Dialog instance can be retrieved via the SFDialogs.DialogEvent service, providing that the dialog was initiated with the Dialog service. DialogEvent returns the SFDialogs.Dialog service instance that triggered the event.


    Sub SomeEvent(ByRef poEvent As Object)
        Dim oDlg As Object
        Set oDlg = CreateScriptService("SFDialogs.DialogEvent", poEvent)
    End Sub
  

with Python:


    def some_event(event: uno):
        dlg = CreateScriptService("SFDialogs.DialogEvent", event)
  

Note that in previous examples, the prefix "SFDialogs." may be omitted when deemed appropriate.

Properties

Name

ReadOnly

Type

Description

OKBUTTON

Yes

Integer

Value = 1. An OK button was pressed.

CANCELBUTTON

Yes

Integer

Value = 0. A Cancel button was pressed.

Caption

No

String

Specify the title of the dialog.

Height

No

Long

Specify the height of the dialog box.

Modal

Yes

Boolean

Specifies if the dialog box is currently in execution in modal mode.

Name

Yes

String

The name of the dialog

Page

No

Integer

A dialog may have several pages that can be traversed by the user step by step. The Page property of the Dialog object defines which page of the dialog is active.

Visible

No

Boolean

Specify if the dialog box is visible on the desktop. By default it is not visible until the Execute() method is run and visible afterwards.

XDialogModel

Yes

UNO
object

The UNO object representing the dialog model. Refer to XControlModel and UnoControlDialogModel in Application Programming Interface (API) documentation for detailed information.

XDialogView

Yes

UNO
object

The UNO object representing the dialog view. Refer to XControl and UnoControlDialog in Application Programming Interface (API) documentation for detailed information.

Width

No

Long

Specify the width of the dialog box.


Event properties

note

These event properties are available from LibreOffice 7.2 onwards.


Returns a URI string with the reference to the script triggered by the event. Read its specification in the scripting framework URI specification.

Name

ReadOnly

Basic IDE Description

OnFocusGained

Yes

When receiving focus

OnFocusLost

Yes

When losing focus

OnKeyPressed

Yes

Key pressed

OnKeyReleased

Yes

Key released

OnMouseDragged

Yes

Mouse moved while key presses

OnMouseEntered

Yes

Mouse inside

OnMouseExited

Yes

Mouse outside

OnMouseMoved

Yes

Mouse moved

OnMousePressed

Yes

Mouse button pressed

OnMouseReleased

Yes

Mouse button released


Methods

Activate
Controls

EndExecute
Execute

Terminate


Activate

Set the focus on the current Dialog instance. Return True if focusing was successful.

This method is called from a dialog or control event, or when a dialog is displayed in non-modal mode.

SĂŒntaks:

svc.Activate(): bool

NĂ€ide:


      Dim oDlg As Object
      Set oDlg = CreateScriptService(,, "myDialog")
      oDlg.Execute()
      ' ...
      oDlg.Activate()
   

Python and LibreOffice Basic examples both assume that the dialog is stored in current document's Standard library.


     dlg = CreateScriptService(,,'myDialog')
     dlg.Execute()
     # ...
     dlg.Activate()
   

Controls

Return either:

SĂŒntaks:

svc.Controls(): str[0..*]

svc.Controls(controlname: str): svc

Parameetrid:

ControlName : A valid control name as a case-sensitive string. If absent, the list of control names is returned as a zero-based array.

NĂ€ide:


      Dim myDialog As Object, myList As Variant, myControl As Object
      Set myDialog = CreateScriptService("SFDialogs.Dialog", , "Standard", "Dialog1")
      myList = myDialog.Controls()
      Set myControl = myDialog.Controls("myTextBox")
   

     dlg = CreateScriptService('SFDialogs.Dialog','', 'Standard', 'Dialog1')
     ctrls = dlg.Controls()
     ctrl = dlg.Controls('myTextBox')
   

EndExecute

Ends the display of a modal dialog and gives back the argument as return value for the current Execute() running action.

EndExecute() is usually contained in the processing of a macro triggered by a dialog or control event.

SĂŒntaks:

svc.EndExecute(returnvalue: int)

Parameetrid:

returnvalue: The value passed to the running Execute() method.

NĂ€ide:

Using LibreOffice Basic:


      Sub OnEvent(poEvent As com.sun.star.lang.EventObject)
          Dim oDlg As Object
          Set oDlg = CreateScriptService("SFDialogs.DialogEvent", poEvent)
          oDlg.EndExecute(ReturnValue := 25)
      End Sub
   

Using Python:


     from com.sun.star.lang import EventObject
     def on_event(event: EventObject):
         dlg = CreateScriptService("SFDialogs.DialogEvent", event)
         dlg.EndExecute(25)
   
tip

Above com.sun.star.lang.EventObject mentions are optional. Such annotations help identify LibreOffice Application Programming Interface (API).


Execute

Display the dialog box and, when modal, wait for its termination by the user. The returned value is either:

For non-modal dialog boxes the method always returns 0 and the execution of the macro continues.

SĂŒntaks:

svc.Execute(modal: bool = True): int

Parameetrid:

modal: False when non-modal dialog. Default = True.

NĂ€ide:

In this Basic example myDialog dialog is stored in current document's Standard library.


      Dim oDlg As Object, lReturn As Long
      Set oDlg = CreateScriptService("SFDialogs.Dialog", , , "myDialog")
      lReturn = oDlg.Execute(Modal := False)
      Select Case lReturn
          ' ...
      End Select
   

This Python code displays DlgConvert modal dialog from Euro shared Basic library.


     dlg = CreateScriptService("SFDialogs.Dialog", 'GlobalScope', 'Euro', "DlgConvert")
     rc = dlg.Execute()
     if rc == dlg.CANCELBUTTON:
         # ...
   

Terminate

Terminate the Dialog service for the current instance. Return True if the termination was successful.

SĂŒntaks:

svc.Terminate(): bool

NĂ€ide:

Below Basic and Python examples open DlgConsole and dlgTrace non-modal dialogs. They are respectively stored in ScriptForge and Access2Base shared libraries. Dialog close buttons are disabled and explicit termination is performed at the end of a running process.

In this example a button in DlgConsole is substituting inhibited window closing:


     oDlg = CreateScriptService("SFDialogs.Dialog","GlobalScope","ScriptForge","DlgConsole")
     oDlg.Execute(modal:=False)
     Wait 5000
     oDlg.Terminate()
   

With Python:


     from time import sleep
     dlg = CreateScriptService('SFDialogs.Dialog',"GlobalScope",'Access2Base',"dlgTrace")
     dlg.Execute(modal=False)
     sleep 5
     dlg.Terminate()
   
warning

All ScriptForge Basic routines or identifiers that are prefixed with an underscore character "_" are reserved for internal use. They are not meant be used in Basic macros.


Palun toeta meid!