Στατιστικές συναρτήσεις - Μέρος πρώτο

COUNTIFS

Επιστρέφει τον αριθμό των κελιών που ικανοποιούν τα κριτήρια σε πολλαπλές περιοχές.

B

Επιστρέφει την πιθανότητα ενός δείγματος από τη διωνυμική κατανομή.

Σύνταξη

B(Δοκιμές; SP; T1 [; T2])

Οι Δοκιμές είναι ο αριθμός των ανεξάρτητων δοκιμών.

Η Pεπιτυχία είναι η πιθανότητα επιτυχίας για κάθε δοκιμή.

Το T1 ορίζει το κατώτατο όριο του αριθμού δοκιμών.

Το T2 (προαιρετικό) ορίζει το ανώτατο όριο του αριθμού δοκιμών.

Παράδειγμα

Ποια είναι η πιθανότητα να πετύχετε ακριβώς δύο φορές έξι σε δέκα ρίψεις του ζαριού; Η πιθανότητα να πετύχετε έξι (ή οποιονδήποτε άλλο αριθμό) είναι 1/6. Ο ακόλουθος τύπος συνδυάζει αυτούς τους παράγοντες:

Η συνάρτηση =B(10;1/6;2) επιστρέφει ως αποτέλεσμα την πιθανότητα 29%.

BETA.DIST

Επιστρέφει τη συνάρτηση βήτα.

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.2.

Σύνταξη

BETA.DIST(Αριθμός; Άλφα; Βήτα; Αθροιστική [; Έναρξη [; Τέλος]])

Ο Αριθμός (απαιτείται) είναι η τιμή μεταξύ του Αρχή και του Τέλος στην οποία εκτιμάται η συνάρτηση.

Η Άλφα (απαιτείται) είναι μια παράμετρος στην κατανομή.

Η Βήτα (απαιτείται) είναι μια παράμετρος στην κατανομή.

Αθροιστική (απαιτείται) μπορεί να είναι 0 ή ψευδής για να υπολογιστεί η συνάρτηση πυκνότητας πιθανότητας. Μπορεί να είναι οποιαδήποτε άλλη τιμή ή αληθής για να υπολογιστεί η συνάρτηση αθροιστικής κατανομής.

Αρχή (προαιρετικό) είναι το χαμηλότερο όριο για τον Αριθμό.

Τέλος (προαιρετικό) είναι το υψηλότερο όριο για τον Αριθμό.

Στις συναρτήσεις του LibreOffice Calc, οι παράμετροι που σημειώνονται ως "προαιρετικές" μπορούν να παραληφθούν μόνο όταν δεν ακολουθεί καμιά παράμετρος. Παραδείγματος χάρη, σε μια συνάρτηση με τέσσερις παραμέτρους, όπου οι δύο τελευταίες παράμετροι είναι σημειωμένες ως "προαιρετικές", μπορείτε να αφήσετε έξω την παράμετρο 4 ή τις παραμέτρους 3 και 4, αλλά δεν μπορείτε να παραλείψετε μόνο την παράμετρο 3.

Παράδειγμα

Το =BETA.DIST(2;8;10;1;1;3) επιστρέφει την τιμή 0,6854706

Το =BETA.DIST(2;8;10;0;1;3) επιστρέφει την τιμή 1,4837646

Τεχνικές πληροφορίες

Αυτή η συνάρτηση δεν αποτελεί μέρος του προτύπου Open Document Format for Office Applications (OpenDocument) Έκδοση 1.3. Μέρος 4: Μορφή επανυπολογισμένου τύπου (OpenFormula). Ο χώρος του ονόματος είναι

COM.MICROSOFT.BETA.DIST

BETA.INV

Επιστρέφει το αντίστροφο της συνάρτησης αθροιστικής πυκνότητας πιθανότητας βήτα.

Σύνταξη

BETA.INV(Αριθμός; Άλφα; Βήτα [; Έναρξη [; Τέλος]])

Ο Αριθμός είναι η πιθανότητα που σχετίζεται με την κατανομή βήτα για τα δεδομένα ορίσματα άλφα (Alpha) και βήτα (Beta).

Το άλφα (Alpha) είναι μια αυστηρά θετική παράμετρος την κατανομή βήτα.

Το βήτα (Beta) είναι μια αυστηρά θετική παράμετρος της κατανομής βήτα.

Έναρξη (Start) (προαιρετικό) είναι το κάτω όριο της περιοχής εξόδου της συνάρτησης. Εάν παραλειφθεί, η προεπιλεγμένη τιμή είναι 0.

Τέλος (End) (προαιρετικό) είναι το άνω όριο της περιοχής εξόδου της συνάρτησης. Εάν παραλειφθεί, η προεπιλεγμένη τιμή είναι 1.

Παράδειγμα

Το =BETA.INV(0,5;5;10) επιστρέφει την τιμή 0,3257511553.

Σελίδα βίκι του BETA.INV

Τεχνικές πληροφορίες

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.2.

COM.MICROSOFT.BETA.INV

BETADIST

Επιστρέφει την συνάρτηση βήτα.

Σύνταξη

BETADIST(Αριθμός; Άλφα; Βήτα [; Έναρξη [; Τέλος [; Αθροιστική]]])

Ο Αριθμός είναι η τιμή μεταξύ της Αρχή και της Τέλος στην οποία εκτιμάται η συνάρτηση.

Alpha είναι μια παράμετρος στην κατανομή.

Beta είναι μια παράμετρος στην κατανομή.

Start (προαιρετικό) είναι το χαμηλότερο όριο για το Number.

End (προαιρετικό) είναι το υψηλότερο όριο για το Number.

Αθροιστική (προαιρετικό) μπορεί να είναι 0 ή ψευδής για να υπολογιστεί η συνάρτηση πυκνότητας πιθανότητας. Μπορεί να είναι οποιαδήποτε άλλη τιμή ή αληθής ή παραλειπόμενη για να υπολογιστεί η συνάρτηση αθροιστικής κατανομής.

Παράδειγμα

Το =BETADIST(0,75;3;4) επιστρέφει την τιμή 0,96.

BETAINV

Επιστρέφει το αντίστροφο της αθροιστικής συνάρτησης πυκνότητας πιθανότητας Βήτα (Beta).

Σύνταξη

BETAINV(Αριθμός; Άλφα; Βήτα [; Έναρξη [; Τέλος]])

Το άλφα (Alpha) είναι μια αυστηρά θετική παράμετρος την κατανομή βήτα.

Το βήτα (Beta) είναι μια αυστηρά θετική παράμετρος της κατανομής βήτα.

Παράδειγμα

Το =BETAINV(0,5;5;10) επιστρέφει την τιμή 0,3257511553.

Σελίδα βίκι του BETAINV

BINOM.DIST

Επιστρέφει τη διωνυμική κατανομή πιθανότητας του μεμονωμένου όρου.

Σύνταξη

BINOM.DIST(X; Δοκιμές;SP; C)

Το X είναι ο αριθμός των επιτυχιών για ένα σύνολο δοκιμών.

Οι Δοκιμές είναι ο αριθμός των ανεξάρτητων δοκιμών.

Η Pεπιτυχία είναι η πιθανότητα επιτυχίας για κάθε δοκιμή.

C = 0 υπολογίζει την πιθανότητα ενός μοναδικού γεγονότος και C = 1 υπολογίζει την αθροιστική πιθανότητα.

Παράδειγμα

Η συνάρτηση =BINOM.DIST(A1;12;0.5;0) εμφανίζει (αν οι τιμές 0 μέχρι 12 εισάγονται στο A1) τις πιθανότητες για 12 ρίψεις νομίσματος που οι Κεφαλές θα επιστρέψουν ακριβώς τον αριθμό των φορών που εισάγονται στο Α1.

Η συνάρτηση =BINOM.DIST(A1;12;0.5;1) εμφανίζει τις αθροιστικές συναρτήσεις για τις ίδιες σειρές. Για παράδειγμα, αν A1 = 4, είναι η αθροιστική πιθανότητα της σειράς 0, 1, 2, 3, ή 4 φορές να έρθουν Κεφαλές (μη αποκλειστικό OR).

Τεχνικές πληροφορίες

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.2.

COM.MICROSOFT.BINOM.DIST

BINOM.INV

Επιστρέφει τη μικρότερη τιμή για την οποία η αθροιστική διωνυμική κατανομή είναι μεγαλύτερη ή ίση με μια τιμή κριτηρίου.

Σύνταξη

BINOM.INV(Δοκιμές; SP; Άλφα)

Οι Δοκιμές είναι ο συνολικός αριθμός δοκιμών.

Η Pεπιτυχία είναι η πιθανότητα επιτυχίας για κάθε δοκιμή.

Άλφα είναι η συνοριακή πιθανότητα που θα επιτευχθεί ή θα ξεπεραστεί.

Παράδειγμα

=BINOM.INV(8;0.6;0.9) επιστρέφει 7, την ελάχιστη τιμή για την οποία η αθροιστική διωνυμική κατανομή είναι μεγαλύτερη ή ίση με τη τιμή ενός κριτηρίου.

Τεχνικές πληροφορίες

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.2.

COM.MICROSOFT.BINOM.INV

BINOMDIST

Επιστρέφει τη διωνυμική κατανομή πιθανότητας του μεμονωμένου όρου.

Σύνταξη

BINOMDIST(X, Δοκιμές, Pεπιτυχία, C)

Το X είναι ο αριθμός των επιτυχιών για ένα σύνολο δοκιμών.

Οι Δοκιμές είναι ο αριθμός των ανεξάρτητων δοκιμών.

Η Pεπιτυχία είναι η πιθανότητα επιτυχίας για κάθε δοκιμή.

C = 0 υπολογίζει την πιθανότητα ενός μοναδικού γεγονότος και C = 1 υπολογίζει την αθροιστική πιθανότητα.

Παράδειγμα

Η συνάρτηση =BINOMDIST(A1;12;0.5;0) εμφανίζει (αν οι τιμές 0 ως 12 εισάγονται στο A1) τις πιθανότητες για 12 ρίψεις νομίσματος που οι Κεφαλές θα επιστραφούν ακριβώς τον αριθμό των φορών που εισάγονται στο Α1.

Η συνάρτηση =BINOMDIST(A1;12;0.5;1) εμφανίζει τις αθροιστικές συναρτήσεις για τις ίδιες σειρές. Για παράδειγμα, αν A1 = 4, είναι η αθροιστική πιθανότητα των σειρών 0, 1, 2, 3, ή 4 φορές να έρθουν Κεφαλές (όχι αποκλειστικά το OR).

CHIDIST

Επιστρέφει την τιμή της πιθανότητας από την αναφερόμενη Χ-τετράγωνο κατανομή ότι οι υποθέσεις εφαρμόζονται. Η συνάρτηση CHIDIST συγκρίνει την τιμή Χ-τετράγωνο που δόθηκε από ένα τυχαίο δείγμα που υπολογίζεται από το άθροισμα (παρατηρούμενη τιμή-αναμενόμενη τιμή)^2/αναμενόμενη τιμή για όλες τις τιμές, με την θεωρητική Χ-τετράγωνο κατανομή και καθορίζει με αυτόν τον τρόπο την πιθανότητα σφάλματος κάτω από τις υποθέσεις του ελέγχου.

Η πιθανότητα που καθορίστηκε από τη συνάρτηση CHIDIST μπορεί να καθοριστεί επίσης και από τη συνάρτηση CHITEST.

Σύνταξη

CHIDIST(Αριθμός; ΒαθμοίΕλευθερίας)

Ο Αριθμός είναι η Χ-τετράγωνο τιμή του τυχαίου δείγματος που χρησιμοποιήθηκε για τον καθορισμό της πιθανότητας σφάλματος.

Οι Βαθμοί-ελευθερίας είναι οι βαθμοί ελευθερίας του πειράματος.

Παράδειγμα

Η συνάρτηση =CHIDIST(13.27; 5) ισούται με 0.02.

Αν η τιμή της Χ-τετράγωνο του τυχαίου δείγματος είναι 13,27 και αν το πείραμα έχει 5 βαθμούς ελευθερίας, τότε οι υποθέσεις ικανοποιούνται με πιθανότητα σφάλματος 2%.

CHIINV

Επιστρέφει την αντίστροφη της μονόπλευρης κατανομής πιθανότητας Χ τετράγωνο.

Σύνταξη

CHIINV(Αριθμός; ΒαθμοίΕλευθερίας)

Ο Αριθμός είναι η τιμή της πιθανότητας σφάλματος.

Οι ΒαθμοίΕλευθερίας είναι οι βαθμοί ελευθερίας για το πείραμα.

Παράδειγμα

Ρίχνετε ένα ζάρι 1020 φορές. Οι αριθμοί του ζαριού 1 έως 6 εμφανίζονται 195, 151, 148, 189, 183 και 154 φορές (παρατηρούμενες τιμές). Πρόκειται να ελεγχθεί η υπόθεση ότι το ζάρι δεν είναι πειραγμένο.

Η Χ τετράγωνο κατανομή του τυχαίου δείγματος καθορίζεται από τον τύπο που δίδεται παραπάνω. Αφού η αναμενόμενη τιμή για ένα δεδομένο αριθμό του ζαριού μετά από n ρίψεις είναι n φορές επί 1/6, συνεπώς 1020/6 = 170, ο τύπος επιστρέφει την Χ τετράγωνο τιμή ίση του 13.27.

Αν το (παρατηρούμενο) Χ τετράγωνο είναι μεγαλύτερο ή ίσο με το (θεωρητικό) Χ τετράγωνο της συνάρτησης CHIINV, η υπόθεση θα απορριφθεί, αφού η απόκλιση μεταξύ θεωρίας και πειράματος είναι πολύ μεγάλη. Αν το παρατηρούμενο Χ τετράγωνο είναι μικρότερο από αυτό της CHIINV, η υπόθεση επιβεβαιώνεται με μια υποδεικνυόμενη πιθανότητα σφάλματος.

Το =CHIINV(0.05;5) επιστρέφει 11.07.

Το =CHIINV(0.02;5) επιστρέφει 13.39.

Αν η πιθανότητα σφάλματος είναι 5%, το ζάρι δεν είναι κανονικό. Αν η πιθανότητα σφάλματος είναι 2%, δεν υπάρχει λόγος υποψίας ότι το ζάρι είναι πειραγμένο.

CHISQ.DIST

Επιστρέφει τη συνάρτηση πυκνότητας πιθανότητας ή την αθροιστική συνάρτηση κατανομής για την κατανομή χ-τετράγωνο.

Σύνταξη

CHISQ.DIST(Αριθμός; ΒαθμοίEλευθερίας; Αθροιστικό)

ΒαθμοίΕλευθερίας είναι οι βαθμοί ελευθερίας του πειράματος.

Αθροιστική μπορεί να είναι 0 ή ψευδής για να υπολογιστεί η συνάρτηση πυκνότητας πιθανότητας. Μπορεί να είναι οποιαδήποτε άλλη τιμή ή αληθής για να υπολογιστεί η συνάρτηση αθροιστικής κατανομής.

Παράδειγμα

=CHISQ.DIST(3; 2; 0) ισούται με 0,1115650801, τη συνάρτηση πυκνότητας πιθανότητας με 2 βαθμούς ελευθερίας, στο x = 3.

=CHISQ.DIST(3; 2; 1) ισούται με 0,7768698399, την αθροιστική κατανομή x τετράγωνο με 2 βαθμούς ελευθερίας, στην τιμή x=3.

Τεχνικές πληροφορίες

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.2.

COM.MICROSOFT.CHISQ.DIST

CHISQ.DIST.RT

Επιστρέφει την τιμή της πιθανότητας από την αναφερόμενη Χ-τετράγωνο για να επιβεβαιωθεί η υπόθεση. Η CHISQ.DIST.RT συγκρίνει την τιμή Χ-τετράγωνο που δόθηκε από ένα τυχαίο δείγμα που υπολογίζεται από το άθροισμα (παρατηρούμενη τιμή-αναμενόμενη τιμή)^2/αναμενόμενη τιμή για όλες τις τιμές, με την θεωρητική κατανομή Χ-τετράγωνο και καθορίζει από αυτήν την πιθανότητα σφάλματος για την υπόθεση που θα ελεγχθεί.

Η πιθανότητα που καθορίστηκε από την CHISQ.DIST.RT μπορεί επίσης να καθοριστεί από την CHITEST.

Σύνταξη

CHISQ.DIST.RT(Αριθμός; ΒαθμοίΕλευθερίας)

Αριθμός είναι η Χ-τετράγωνο τιμή του τυχαίου δείγματος που χρησιμοποιήθηκε για τον καθορισμό της πιθανότητας σφάλματος.

ΒαθμοίΕλευθερίας είναι οι βαθμοί ελευθερίας του πειράματος.

Παράδειγμα

Η συνάρτηση =CHISQ.DIST.RT=(13.27; 5) ισούται με 0,0209757694.

Αν η τιμή της Χ-τετράγωνο του τυχαίου δείγματος είναι 13,27 και αν το πείραμα έχει 5 βαθμούς ελευθερίας, τότε η υπόθεση ικανοποιείται με πιθανότητα σφάλματος 2%.

Τεχνικές πληροφορίες

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.2.

COM.MICROSOFT.CHISQ.DIST.RT

CHISQ.INV

Επιστρέφει την αντίστροφη της αριστερής ουράς κατανομής πιθανότητας Χ τετράγωνο.

Σύνταξη

CHISQ.INV(Πιθανότητα; ΒαθμοίΕλευθερίας)

Η Πιθανότητα είναι η τιμή της πιθανότητας για την οποία πρόκειται να υπολογισθεί η αντίστροφη της κατανομής χ τετράγωνο.

Οι ΒαθμοίΕλευθερίας είναι οι βαθμοί ελευθερίας για την συνάρτηση χ τετράγωνο.

Παράδειγμα

Το =CHISQ.INV(0,5;1) επιστρέφει 0,4549364231.

Τεχνικές πληροφορίες

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.2.

COM.MICROSOFT.CHISQ.INV

CHISQ.INV.RT

Επιστρέφει την αντίστροφη της μονόπλευρης πιθανότητας της κατανομής Χ τετράγωνο.

Σύνταξη

CHISQ.INV.RT(Αριθμός; ΒαθμοίΕλευθερίας)

Ο Αριθμός είναι η τιμή της πιθανότητας σφάλματος.

ΒαθμοίΕλευθερίας είναι οι βαθμοί ελευθερίας του πειράματος.

Παράδειγμα

Το =CHISQ.INV.RT(0.05;5) επιστρέφει 11,0704976935.

Το =CHISQ.INV.RT(0.02;5) επιστρέφει 13,388222599 .

Τεχνικές πληροφορίες

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.2.

COM.MICROSOFT.CHISQ.INV.RT

CHISQ.TEST

Επιστρέφει την πιθανότητα απόκλισης από μια τυχαία κατανομή δύο σειρών ελέγχων βάσει ενός ελέγχου x τετράγωνο για ανεξαρτησία. Η συνάρτηση CHITEST επιστρέφει την x τετράγωνο κατανομή των δεδομένων.

Η πιθανότητα που καθορίζεται από τη συνάρτηση CHISQ.TEST μπορεί να καθοριστεί επίσης με τη συνάρτηση CHISQ.DIST. Σε αυτήν την περίπτωση, το x τετράγωνο του τυχαίου δείγματος θα πρέπει να μεταβιβαστεί ως παράμετρος αντί ως γραμμή δεδομένων.

Σύνταξη

CHI.TEST(ΔεδομέναΒ; ΔεδομέναΕ)

Τα ΔεδομέναΒ είναι η σειρά δεδομένων των παρατηρήσεων.

Τα ΔεδομέναE είναι το εύρος των αναμενόμενων τιμών.

Παράδειγμα

	ΔεδομέναΒ (παρατηρούμενα)	ΔεδομέναΕ (αναμενόμενα)
1	195	170
2	151	170
3	148	170
4	189	170
5	183	170
6	154	170

Το =CHISQ.TEST(A1:A6;B1:B6) ισούται με 0,0209708029. Αυτή είναι η πιθανότητα που επαρκεί για τα παρατηρούμενα δεδομένα της θεωρητικής κατανομής Χ-τετράγωνο.

Τεχνικές πληροφορίες

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.2.

COM.MICROSOFT.CHISQ.TEST

CHISQDIST

Επιστρέφει τη συνάρτηση πυκνότητας ή την αθροιστική της κανονικής κατανομής για την κατανομή chi-square.

Σύνταξη

CHISQDIST(Αριθμός; Βαθμοί_ελευθερίας [; Αθροιστική])

Ο Αριθμός είναι η τιμή για την οποία πρόκειται να υπολογισθεί ο φυσικός λογάριθμος της Γάμμα συνάρτησης.

Οι ΒαθμοίΕλευθερίας είναι ο αριθμός των βαθμών ελευθερίας για την Τ κατανομή.

Αθροιστική (προαιρετικό): 0 ή ψευδής υπολογίζει τη συνάρτηση πυκνότητας πιθανότητας. Οι άλλες τιμές ή αληθής ή παραλειπόμενη υπολογίζει τη συνάρτηση αθροιστικής κατανομής.

CHISQINV

Επιστρέφει το αντίστροφο της CHISQDIST .

Σύνταξη

CHISQINV(Πιθανότητα; Βαθμοί ελευθερίας)

Ο Αριθμός είναι η τιμή της πιθανότητας για την οποία πρόκειται να υπολογισθεί η αντίστροφη Γάμμα κατανομή.

Οι Βαθμοί-ελευθερίας είναι ο αριθμός των βαθμών ελευθερίας για την Τ κατανομή.

CHITEST

Επιστρέφει την πιθανότητα απόκλισης από μια τυχαία κατανομή δύο σειρών ελέγχων βάσει ενός ελέγχου Χ τετράγωνο για ανεξαρτησία. Η συνάρτηση CHITEST επιστρέφει την Χ τετράγωνο κατανομή των δεδομένων.

Η πιθανότητα που καθορίζεται από τη συνάρτηση CHITEST μπορεί να καθοριστεί επίσης με τη συνάρτηση CHIDIST. Σε αυτήν την περίπτωση, το Χ τετράγωνο του τυχαίου δείγματος θα πρέπει να μεταβιβαστεί ως παράμετρος αντί ως γραμμή δεδομένων.

Σύνταξη

CHITEST(ΔεδομέναΒ, ΔεδομέναΕ)

Τα ΔεδομέναΒ είναι η σειρά δεδομένων των παρατηρήσεων.

Τα ΔεδομέναE είναι το εύρος των αναμενόμενων τιμών.

Παράδειγμα

	ΔεδομέναΒ (παρατηρούμενα)	ΔεδομέναΕ (αναμενόμενα)
1	195	170
2	151	170
3	148	170
4	189	170
5	183	170
6	154	170

Το =CHITEST(A1:A6;B1:B6) ισούται με 0.02. Αυτή είναι η πιθανότητα που επαρκεί για τα παρατηρούμενα δεδομένα της θεωρητικής Χ-τετράγωνο κατανομής.

COUNT

Μετρά πόσοι αριθμοί υπάρχουν στον κατάλογο των ορισμάτων. Παραβλέπονται οι καταχωρήσεις κειμένου.

Σύνταξη

COUNT(Αριθμός 1 [; Αριθμός 2 [; … [; Αριθμός 255]]])

Αριθμός 1, Αριθμός 2, … , Αριθμός 255 είναι αριθμοί, αναφορές σε κελιά ή περιοχές κελιών αριθμών.

Αυτή η συνάρτηση αγνοεί οποιοδήποτε κείμενο ή κενό κελί στην περιοχή των δεδομένων. Εάν υποψιάζεστε εσφαλμένα αποτελέσματα από αυτήν τη συνάρτηση, ψάξτε για κείμενο στις περιοχές δεδομένων. Για να επισημάνετε περιεχόμενα κειμένου σε περιοχή δεδομένων, χρησιμοποιήστε το γνώρισμα Επισήμανση τιμής.

Παράδειγμα

Θα καταμετρηθούν οι καταχωρήσεις 2, 4, 6 και οκτώ στα πεδία Τιμή 1-4.

=COUNT(2;4;6;"eight") = 3. Επομένως, ο η καταμέτρηση των αριθμών είναι 3.

COUNTA

Καταμετρά πόσες τιμές βρίσκονται στον κατάλογο ορισμάτων. Οι καταχωρήσεις κειμένου επίσης καταμετρούνται, ακόμη και όταν περιέχουν κενό αλφαριθμητικό ή μήκος 0. Αν ένα όρισμα είναι μία σειρά δεδομένων ή μία παραπομπή, τα κενά κελιά εντός της σειράς δεδομένων ή της παραπομπής παραβλέπονται.

Σύνταξη

COUNTA(Αριθμός 1 [; Αριθμός 2 [; … [; Αριθμός 255]]])

Αριθμός 1, Αριθμός 2, … , Αριθμός 255 είναι αριθμοί, αναφορές σε κελιά ή περιοχές κελιών αριθμών.

Παράδειγμα

Θα καταμετρηθούν οι καταχωρήσεις 2, 4, 6 και οκτώ στα πεδία Τιμή 1-4.

=COUNTA(2;4;6;"eight") = 4. Επομένως, η καταμέτρηση των τιμών είναι 4.

COUNTBLANK

Επιστρέφει το πλήθος των κενών κελιών.

Σύνταξη

COUNTBLANK(Περιοχή)

Επιστρέφει τον αριθμό των κενών κελιών στην περιοχή κελιών Περιοχή.

Παράδειγμα

Η =COUNTBLANK(A1:B2) επιστρέφει 4 αν τα κελιά Α1, Α2, Β1, Β2 είναι όλα κενά.

COUNTIF

Επιστρέφει τον αριθμό των κελιών που ταιριάζουν με συγκεκριμένα κριτήρια εντός μιας περιοχής κελιών.

Σύνταξη

COUNTIF(Περιοχή; Κριτήριο)

Περιοχή είναι η περιοχή στην οποία θα εφαρμοσθούν τα κριτήρια.

Κριτήριο: Κριτήριο είναι μια μοναδική αναφορά κελιού, αριθμού, ή κειμένου. Χρησιμοποιείται σε συγκρίσεις με περιεχόμενα κελιού.

Μια αναφορά σε κενό κελί ερμηνεύεται ως η αριθμητική τιμή 0.

Μια σύμφωνη έκφραση μπορεί να είναι:

Μια αριθμητική ή λογική τιμή. Ένα σύμφωνο περιεχόμενο κελιού ισούται με τον αριθμό ή τη λογική τιμή.
Μια τιμή που ξεκινά με έναν συγκριτή (<, <=, =, >, >=, <>).

Για =, εάν η τιμή είναι κενή συμφωνεί με κενά κελιά.

Για <>, εάν η τιμή είναι κενή συμφωνεί με μη κενά κελιά.

Για <>, εάν η τιμή δεν είναι κενή, συμφωνεί με οποιοδήποτε περιεχόμενο κελιού εκτός από την τιμή, συμπεριλαμβανομένων των κενών κελιών.

Σημείωση: "=0" δεν συμφωνεί με κενά κελιά.

Για = και <>, εάν η τιμή δεν είναι κενή και δεν μπορεί να ερμηνευτεί ως τύπος αριθμού ή ένας από τους υποτύπους του και η ιδιότητα Τα κριτήρια αναζήτησης = και <> πρέπει να εφαρμόζονται σε ολόκληρα κελιά είναι σημειωμένη, η σύγκριση είναι ως προς ολόκληρα τα περιεχόμενα του κελιού· εάν ξεσημειωθεί, η σύγκριση είναι ως προς οποιοδήποτε τμήμα του πεδίου που ταιριάζει με τα κριτήρια. Για = και <>, εάν η τιμή δεν είναι κενή και δεν μπορεί να ερμηνευθεί ως τύπος αριθμού, εφαρμόζεται ένας από τους υποτύπους του.
Άλλη τιμή κειμένου. Εάν η ιδιότητα Search criteria = and <> must apply to whole cells (Τα κριτήρια αναζήτησης = και <> πρέπει να εφαρμοστούν σε ολόκληρα κελιά) είναι αληθής, η σύγκριση είναι ως προς τα περιεχόμενα ολόκληρου του κελιού, εάν είναι ψευδής η σύγκριση είναι ως προς οποιοδήποτε υποτμήμα του πεδίου που ταιριάζει με τα κριτήρια. Η έκφραση μπορεί να περιέχει κείμενο, αριθμούς, κανονικές εκφράσεις ή σύμβολα υποκατάστασης (Εάν είναι ενεργοποιημένα στις επιλογές υπολογισμού).

Η αναζήτηση υποστηρίζει χαρακτήρες Υποκατάστασης (μπαλαντέρ) ή κανονικές εκφράσεις. Με ενεργοποιημένες τις κανονικές εκφράσεις, μπορείτε να εισαγάγετε "all.*", για παράδειγμα, για να βρείτε την πρώτη θέση του "all" ακολουθούμενη από οποιουσδήποτε χαρακτήρες. Εάν θέλετε να αναζητήσετε ένα κείμενο που είναι επίσης κανονική έκφραση, πρέπει είτε να προηγηθεί κάθε μεταχαρακτήρα ή τελεστή κανονικής έκφρασης με έναν χαρακτήρα "\" ή να περικλείσετε το κείμενο στο \Q...\E. Μπορείτε να ενεργοποιήσετε και να απενεργοποιήσετε την αυτόματη αξιολόγηση χαρακτήρων υποκατάστασης ή κανονικής έκφρασης στο - LibreOffice Υπολογισμός - Υπολογισμός .

Όταν χρησιμοποιείτε συναρτήσεις όπου ένα ή περισσότερα ορίσματα είναι συμβολοσειρές κριτηρίων αναζήτησης που αντιπροσωπεύουν κανονική έκφραση, η πρώτη προσπάθεια είναι η μετατροπή των κριτηρίων συμβολοσειρών σε αριθμούς. Παραδείγματος χάρη, το ".0" θα μετατραπεί σε 0.0 κ.ο.κ. Εάν είναι πετυχημένο, η συμφωνία δεν θα είναι συμφωνία κανονικής έκφρασης, αλλά αριθμητική συμφωνία. Όμως, όταν αλλάζετε στις τοπικές ρυθμίσεις όπου ο δεκαδικός διαχωριστής δεν είναι η τελεία, η μετατροπή της κανονικής έκφρασης λειτουργεί. Για να εξαναγκάσετε την αξιολόγηση της κανονικής έκφρασης αντί για την αριθμητική έκφραση, χρησιμοποιήστε κάποια έκφραση που δεν μπορεί να παρανοηθεί ως αριθμητική, όπως ".[0]", ή ".\0", ή "(?i).0".

Παράδειγμα

Το A1:A10 είνια μια περιοχή κελιών που περιέχει τους αριθμούς 2000 έως 2009. Το κελί B1 περιέχει τον αριθμό 2006. Στο κελί Β2, εισάγετε έναν τύπο:

=COUNTIF(A1:A10;2006) - αυτό επιστρέφει 1.

=COUNTIF(A1:A10;B1) - αυτό επιστρέφει 1.

=COUNTIF(A1:A10;">=2006") - αυτό επιστρέφει 4.

=COUNTIF(A1:A10;"<"&B1) - όταν το Β1 περιέχει 2006, αυτό επιστρέφει 6.

Το =COUNTIF(A1:A10;C2) όπου το κελί C2 περιέχει το κείμενο >2006 καταμετρά το πλήθος των κελιών της περιοχής A1:A10 τα οποία είναι >2006.

Για μέτρηση μόνο των αρνητικών αριθμών: =COUNTIF(A1:A10;"<0")

EXPON.DIST

Επιστρέφει την εκθετική κατανομή.

Σύνταξη

EXPON.DIST(Αριθμός; Λάμδα; C)

Ο Αριθμός είναι η τιμή της συνάρτησης.

Το Λάμδα είναι η τιμή της παραμέτρου.

C είναι μία λογική τιμή που καθορίζει τη μορφή της συνάρτησης. Για C = 0 υπολογίζεται η συνάρτηση πυκνότητας και για C = 1 υπολογίζεται η κατανομή.

Παράδειγμα

Η συνάρτηση =EXPON.DIST(3;0.5;1) επιστρέφει 0,7768698399.

Τεχνικές πληροφορίες

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.2.

COM.MICROSOFT.EXPON.DIST

EXPONDIST

Επιστρέφει την εκθετική κατανομή.

Σύνταξη

EXPONDIST(Αριθμός, Λάμδα, C)

Ο Αριθμός είναι η τιμή της συνάρτησης.

Το Λάμδα είναι η τιμή της παραμέτρου.

Η C είναι μία λογική τιμή που καθορίζει τη μορφή της συνάρτησης. Για C = 0 υπολογίζεται η συνάρτηση κατανομής, και για C = 1 υπολογίζεται η κατανομή.

Παράδειγμα

Η συνάρτηση =EXPONDIST(3;0.5;1) επιστρέφει ως αποτέλεσμα 0.78.

INTERCEPT

Υπολογίζει το σημείο όπου μια γραμμή τέμνει τον άξονα Y χρησιμοποιώντας υπάρχουσες τιμές X και τιμές Y.

Σύνταξη

INTERCEPT(ΔεδομέναY, ΔεδομέναX)

Τα ΔεδομέναY είναι το εξαρτημένο σύνολο παρατηρήσεων ή δεδομένων.

Τα ΔεδομέναX είναι το ανεξάρτητο σύνολο παρατηρήσεων ή δεδομένων.

Εδώ πρέπει να χρησιμοποιηθούν ονόματα, σειρές δεδομένων ή παραπομπές που περιέχουν αριθμούς. Φυσικά, μπορείτε να εισάγετε απευθείας αριθμούς.

Παράδειγμα

Για να υπολογίσετε το σημείο τομής, χρησιμοποιείστε τα κελιά D3:D9 ως την τιμή Y και C3:C9 ως την τιμή X από το δείγμα υπολογιστικού φύλλου. Η είσοδος των δεδομένων θα είναι ως ακολούθως:

=INTERCEPT(D3:D9;C3:C9) = 2,15.

RSQ

Επιστρέφει το τετράγωνο του συντελεστή συσχέτισης κατά Pearson που βασίζεται στις δοθείσες τιμές. Η συνάρτηση RSQ (που ονομάζεται επίσης συντελεστής προσδιορισμού) είναι μία μέτρηση για την ακρίβεια μίας προσαρμογής και μπορεί να χρησιμοποιηθεί για την εφαρμογή της ανάλυσης παλινδρόμησης.

Σύνταξη

RSQ(ΔεδομέναY, ΔεδομέναX)

Τα ΔεδομέναY είναι μία σειρά δεδομένα ή περιοχή από σημεία δεδομένων.

Τα ΔεδομέναX είναι μία σειρά δεδομένα ή περιοχή από σημεία δεδομένων.

Παράδειγμα

Η συνάρτηση =RSQ(A1:A20;B1:B20) υπολογίζει το συντελεστή συσχέτισης για τα δύο σύνολα δεδομένων στις στήλες Α και Β.

Συναρτήσεις ανά κατηγορία