Συναρτήσεις υπολογιστικών φύλλων

Αυτή η ενότητα περιέχει περιγραφές των συναρτήσεων υπολογιστικού φύλλουμαζί με ένα παράδειγμα.

Για να έχετε πρόσβαση σε αυτήν τη λειτουργία...

Εισαγωγή - Συνάρτηση - Κατηγορία Υπολογιστικό φύλλο


ERROR.TYPE

Επιστρέφει έναν αριθμό που παριστάνει έναν ειδικό τύπο σφάλματος, ή την τιμή σφάλματος #N/A, αν δεν υπάρχει σφάλμα.

HYPERLINK

Όταν πατάτε σε ένα κελί που περιέχει τη συνάρτηση HYPERLINK, τότε ανοίγει ο υπερσύνδεσμος.

Αν χρησιμοποιήσετε την προαιρετική παράμετρο κείμενο κελιού, ο τύπος προσδιορίζει την ιστοσελίδα, και ύστερα εμφανίζει το κείμενο.

tip

Για να ανοίξετε ένα κελί που περιέχει μια υπερσύνδεση με το πληκτρολόγιο, επιλέξτε το κελί, πιέστε το πλήκτρο F2 για να εισάγετε τη λειτουργία Επεξεργασία, μετακινήστε το δρομέα μπροστά από την υπερσύνδεση, πιέστε το συνδυασμό πλήκτρων Shift+F10, και τέλος επιλέξτε Άνοιγμα υπερσύνδεσης.


Σύνταξη

HYPERLINK("URL" [; "ΚείμενοΚελιού"])

Το URL καθορίζει τον προορισμό του συνδέσμου. Η προαιρετική παράμετρος Κείμενο-κελιού είναι το κείμενο που εμφανίζεται στο κελί και το αποτέλεσμα της συνάρτησης. Αν η παράμετρος Κείμενο-κελιού δεν καθοριστεί, η URL εμφανίζεται στο κείμενο του κελιού και στο αποτέλεσμα της συνάρτησης.

Ο αριθμός 0 επιστρέφεται για κενά κελιά και στοιχεία πινάκων.

Παράδειγμα

Η συνάρτηση =HYPERLINK("http://www.example.org") εμφανίζει το κείμενο "http://www.example.org" στο κελί και εκτελεί την υπερσύνδεση http://www.example.org αν πατήσετε σε αυτό.

Η συνάρτηση =HYPERLINK("http://www.example.org";"Πατήστε εδώ") εμφανίζει το κείμενο "Πατήστε εδώ" στο κελί και εκτελεί τον υπερσύνδεσμο http://www.example.org όταν πατάτε σε αυτό.

=HYPERLINK("http://www.example.org";12345) εμφανίζει τον αριθμό 12345 και εκτελεί τον υπερσύνδεσμο http://www.example.org όταν πατηθεί.

=HYPERLINK($B4) όπου το κελί B4 περιέχει το http://www.example.org. Η συνάρτηση προσθέτει το http://www.example.org στο URL του υπερσυνδέσμου του κελιού και επιστρέφει το ίδιο κείμενο που χρησιμοποιήθηκε ως αποτέλεσμα συνάρτησης.

Η συνάρτηση =HYPERLINK("http://www.";"Πάτημα ") & "example.org" εμφανίζει το κείμενο Πατήστε στο example.org στο κελί και εκτελεί τον υπερσύνδεσμο http://www.example.org όταν πατάτε σε αυτό.

Το =HYPERLINK("#Sheet1.A1";"Μετάβαση στην κορυφή") εμφανίζει το κείμενο Μετάβαση στην κορυφή και μεταπηδά στο κελί Α1 στο Φύλλο1 σε αυτό το έγγραφο.

Το =HYPERLINK("file:///C:/writer.odt#Specification";"Μετάβαση στον σελιδοδείκτη του Writer") εμφανίζει το κείμενο "Μετάβαση στον σελιδοδείκτη του Writer", φορτώνει το καθορισμένο έγγραφο κειμένου και μεταβαίνει στον σελιδοδείκτη "Προδιαγραφή".

HLOOKUP

Επιστρέφει για μια τιμή και αναφορά στα κελιά κάτω από την επιλεγμένη περιοχή. Αυτή η συνάρτηση επαληθεύει αν η πρώτη γραμμή ενός πίνακα περιέχει μια συγκεκριμένη τιμή. Η συνάρτηση επιστρέφει τότε την τιμή σε μια γραμμή του πίνακα, που ονομάζεται στο Ευρετήριο, στην ίδια στήλη.

Η αναζήτηση υποστηρίζει σύμβολα υποκατάστασης ή κανονικές εκφράσεις. Με ενεργές τις κανονικές εκφράσεις, μπορείτε να εισάγετε "all.*", παραδείγματος χάρη για να βρείτε την πρώτη θέση του "all" ακολουθούμενου από οποιουσδήποτε χαρακτήρες. Εάν θέλετε να αναζητήσετε κείμενο που είναι επίσης κανονική έκφραση, πρέπει είναι να προηγείται σε κάθε χαρακτήρα ένας χαρακτήρας "\", ή να περιέχεται το κείμενο σε \Q...\E. Μπορείτε να ενεργοποιήσετε ή να απενεργοποιήσετε την αυτόματη αξιολόγηση των συμβόλων υποκατάστασης ή κανονικών εκφράσεων στο - LibreOffice Calc - Υπολογισμός.

warning

Όταν χρησιμοποιείτε συναρτήσεις όπου ένα ή περισσότερα ορίσματα είναι συμβολοσειρές κριτηρίων αναζήτησης που αντιπροσωπεύουν κανονική έκφραση, η πρώτη προσπάθεια είναι η μετατροπή των κριτηρίων συμβολοσειρών σε αριθμούς. Παραδείγματος χάρη, το ".0" θα μετατραπεί σε 0.0 κ.ο.κ. Εάν είναι πετυχημένο, η συμφωνία δεν θα είναι συμφωνία κανονικής έκφρασης, αλλά αριθμητική συμφωνία. Όμως, όταν αλλάζετε στις τοπικές ρυθμίσεις όπου ο δεκαδικός διαχωριστής δεν είναι η τελεία, η μετατροπή της κανονικής έκφρασης λειτουργεί. Για να εξαναγκάσετε την αξιολόγηση της κανονικής έκφρασης αντί για την αριθμητική έκφραση, χρησιμοποιήστε κάποια έκφραση που δεν μπορεί να παρανοηθεί ως αριθμητική, όπως ".[0]", ή ".\0", ή "(?i).0".


Σύνταξη

HLOOKUP(ΚριτήριοΑναζήτησης; Πίνακας; Δείκτης [; ΑναζήτησηΤαξινομημένηςΠεριοχής])

Για εξήγηση των παραμέτρων, δείτε: VLOOKUP (οι στήλες και οι γραμμές έχουν ανταλλαχθεί)

Διαχείριση κενών κελιών

ADDRESS

Επιστρέφει μια διεύθυνση κελιού (παραπομπή) ως κείμενο, σύμφωνα με τους καθορισμένους αριθμούς γραμμής και στήλης. Μπορείτε να καθορίσετε εάν η διεύθυνση θα εκφρασθεί ως απόλυτη (π.χ. $Α$1) ή ως σχετική (ως A1) ή σε μικτή μορφή (Α$1 ή $A1). Μπορείτε επίσης να καθορίσετε το όνομα του φύλλου.

Για καλύτερη λειτουργία ανάμεσα τους, οι συναρτήσεις ADDRESS και INDIRECT υποστηρίζουν μια προαιρετική παράμετρο για τον καθορισμό του αν θα γίνεται χρήση της σημείωσης διεύθυνσης R1C1 αντί για τη συνήθη σημείωση A1.

Στην ADDRESS, η παράμετρος εισάγεται ως η τέταρτη παράμετρος και μετακινεί τη προαιρετική παράμετρο ονόματος φύλλου στην πέμπτη θέση.

Στην INDIRECT, η παράμετρος προστίθεται ως δεύτερη παράμετρος.

Και στις δυο συναρτήσεις αν εισαχθεί όρισμα με τιμή 0, τότε χρησιμοποιείται η σημείωση R1C1. Αν δεν έχει εισαχθεί όρισμα ή έχει τιμή μεγαλύτερη του 0, τότε χρησιμοποιείται η σημείωση A1.

Στην περίπτωση της σημείωσης R1C1, η ADDRESS επιστρέφει αλφαριθμητικά διεύθυνσης χρησιμοποιώντας το θαυμαστικό '!' ως διαχωριστικό ονόματος φύλλων, και η INDIRECT αναμένει ότι το θαυμαστικό θα είναι διαχωριστικό ονόματος φύλλων. Και οι δύο συναρτήσεις χρησιμοποιούν την τελεία '.' ως διαχωριστικό ονομάτων φύλλων αν χρησιμοποιηθεί η σημείωση A1.

Κατά το άνοιγμα εγγράφων μορφής ODF 1.0/1.1, οι συναρτήσεις ADDRESS που δείχνουν όνομα του φύλλου ως την τέταρτη παράμετρο θα μετακινήσουν αυτό το όνομα φύλλου ώστε να γίνει η πέμπτη παράμετρος. Μια νέα τέταρτη παράμετρος με την τιμή 1 θα εισαχθεί.

Κατά την αποθήκευση εγγράφων σε μορφή ODF 1.0/1.1, αν οι συναρτήσεις ADDRESS έχουν μια τέταρτη παράμετρο, αυτή η παράμετρος θα απομακρυνθεί.

note

Μην αποθηκεύετε ένα λογιστικό φύλλο με την παλιά μορφή ODF 1.0/1.1 αν η νέα τέταρτη παράμετρος της συνάρτησης ADDRESS έχει τιμή 0.


note

Η συνάρτηση INDIRECT αποθηκεύεται χωρίς μετατροπή σε μορφή αρχείου ODF 1.0/1.1 Αν η δεύτερη παράμετρος είναι παρούσα, μια παλαιότερη έκδοση του Calc θα επιστρέψει σφάλμα για αυτή την συνάρτηση.


Σύνταξη

ADDRESS(Γραμμή; Στήλη [; Abs [; A1 [; "Φύλλο"]]])

Το Γραμμή αναπαριστά τον αριθμό γραμμής για την αναφορά κελιού.

Το Στήλη αναπαριστά τον αριθμό στήλης για την αναφορά κελιού (τον αριθμό, όχι το γράμμα)

Το Abs καθορίζει τον τύπο αναφοράς:

1: απόλυτη ($A$1)

2: αναφορά γραμμής απόλυτη, αναφορά στήλης σχετική (A$1)

3: γραμμή (σχετική); στήλη (απόλυτη) ($A1)

4: σχετική (A1)

A1 (προαιρετικό) - Αν ορισθεί σε 0, χρησιμοποιείται η σημείωση R1C1. Αν αυτή η παράμετρος είναι απούσα ή έχει άλλη τιμή εκτός από 0, τότε χρησιμοποιείται η σημείωση A1 notation.

Το Φύλλο αντιπροσωπεύει το όνομα του φύλλου. Πρέπει να τοποθετείται σε διπλά εισαγωγικά.

Παράδειγμα:

Η συνάρτηση =ADDRESS(1;1;2;"Φύλλο2") επιστρέφει τα εξής: Φύλλο2.A$1

Εάν ο επάνω τύπος είναι στο κελί Β2 του τρέχοντος φύλλου και το το κελί Α1 στο φύλλο 2 περιέχει την τιμή -6, μπορείτε να αναφερθείτε έμμεσα στο κελί παραπομπής χρησιμοποιώντας μια συνάρτηση στο B2 εισάγοντας =ABS(INDIRECT(B2)). Το αποτέλεσμα είναι η απόλυτη τιμή της αναφοράς κελιού που έχει καθοριστεί στο κελί B2, η οποία σε αυτήν την περίπτωση είναι το 6.

LOOKUP

Επιστρέφει τα περιεχόμενα ενός κελιού από μια περιοχή μιας γραμμής ή μιας στήλης. Προαιρετικά, η αντιστοιχισμένη τιμή (του ίδιου δείκτη) επιστρέφεται σε διαφορετική στήλη και γραμμή. Σε αντίθεση με τις συναρτήσεις VLOOKUP και HLOOKUP, τα διανύσματα αναζήτησης και αποτελέσματος μπορεί να βρίσκονται σε διαφορετικές θέσεις. Δεν χρειάζεται να είναι συνεχόμενα. Επιπλέον, το διάνυσμα αναζήτησης για τη συνάρτηση LOOKUP πρέπει να είναι ταξινομημένο αυξητικά, διαφορετικά η αναζήτηση δεν θα επιστρέψει χρησιμοποιήσιμα αποτελέσματα.

note

Αν η LOOKUP δεν μπορεί να βρει ακριβώς το κριτήριο αναζήτησης, ταιριάζει τη μεγαλύτερη τιμή στο εύρος αναζήτησης που είναι μικρότερη ή ίση με το κριτήριο αναζήτησης.


Η αναζήτηση υποστηρίζει σύμβολα υποκατάστασης ή κανονικές εκφράσεις. Με ενεργές τις κανονικές εκφράσεις, μπορείτε να εισάγετε "all.*", παραδείγματος χάρη για να βρείτε την πρώτη θέση του "all" ακολουθούμενου από οποιουσδήποτε χαρακτήρες. Εάν θέλετε να αναζητήσετε κείμενο που είναι επίσης κανονική έκφραση, πρέπει είναι να προηγείται σε κάθε χαρακτήρα ένας χαρακτήρας "\", ή να περιέχεται το κείμενο σε \Q...\E. Μπορείτε να ενεργοποιήσετε ή να απενεργοποιήσετε την αυτόματη αξιολόγηση των συμβόλων υποκατάστασης ή κανονικών εκφράσεων στο - LibreOffice Calc - Υπολογισμός.

warning

Όταν χρησιμοποιείτε συναρτήσεις όπου ένα ή περισσότερα ορίσματα είναι συμβολοσειρές κριτηρίων αναζήτησης που αντιπροσωπεύουν κανονική έκφραση, η πρώτη προσπάθεια είναι η μετατροπή των κριτηρίων συμβολοσειρών σε αριθμούς. Παραδείγματος χάρη, το ".0" θα μετατραπεί σε 0.0 κ.ο.κ. Εάν είναι πετυχημένο, η συμφωνία δεν θα είναι συμφωνία κανονικής έκφρασης, αλλά αριθμητική συμφωνία. Όμως, όταν αλλάζετε στις τοπικές ρυθμίσεις όπου ο δεκαδικός διαχωριστής δεν είναι η τελεία, η μετατροπή της κανονικής έκφρασης λειτουργεί. Για να εξαναγκάσετε την αξιολόγηση της κανονικής έκφρασης αντί για την αριθμητική έκφραση, χρησιμοποιήστε κάποια έκφραση που δεν μπορεί να παρανοηθεί ως αριθμητική, όπως ".[0]", ή ".\0", ή "(?i).0".


Σύνταξη

LOOKUP(ΚριτήριοΑναζήτησης; ΔιάνυσμαΑναζήτησης [; ΔιάνυσμαΑποτελέσματος])

Το Κριτήριο είναι η τιμή που θα αναζητηθεί, είτε εισαχθεί απευθείας είτε ως παραπομπή.

Το Διάνυσμα-αναζήτησης είναι η περιοχή μίας γραμμής ή μίας στήλης όπου θα διενεργηθεί η αναζήτηση.

Το Διάνυσμα-αποτελέσματος είναι μια άλλη περιοχή μίας γραμμής ή μίας στήλης από την οποία λαμβάνεται το αποτέλεσμα της συνάρτησης. Το αποτέλεσμα είναι το κελί του διανύσματος αποτελέσματος με τον ίδιο δείκτη όπως στην εμφάνιση που βρέθηκε στο διάνυσμα αναζήτησης.

Διαχείριση κενών κελιών

Παράδειγμα

Το =LOOKUP(A1;D1:D100;F1:F100) αναζητά το αντίστοιχο κελί στην περιοχή D1:D100 για τον αριθμό που εισάγατε στο Α1. Για την εύρεση, καθορίζεται ο αριθμός, π.χ. το 12ο κελί στην περιοχή. Μετά, το περιεχόμενο του 12ου κελιού επιστρέφεται ως τιμή της συνάρτησης (στο διάνυσμα αποτελέσματος).

MATCH

Επιστρέφει τη σχετική θέση ενός στοιχείου σε έναν πίνακα που ταιριάζει με μια καθορισμένη τιμή. Η συνάρτηση επιστρέφει τη θέση της τιμής που βρέθηκε ως αριθμός στον πίνακα-αναζήτησης.

Σύνταξη

MATCH(ΚριτήριοΑναζήτησης; ΠίνακαςΑναζήτησης [; Τύπος])

Το Κριτήριο-αναζήτησης είναι η τιμή που θα αναζητηθεί στον πίνακα μίας γραμμής ή μίας στήλης.

ΠίνακαςΑναζήτησης είναι η παραπομπή που αναζητείται. Ένας πίνακας αναζήτησης μπορεί να είναι μία μόνο γραμμή ή στήλη, ή τμήμα μίας γραμμής ή στήλης.

Ο Τύπος μπορεί να έχει τις τιμές 1, 0 ή -1. Εάν Τύπος = 1 ή εάν αυτή η προαιρετική παράμετρος δεν έχει καθοριστεί, θεωρείται ότι η πρώτη στήλη του πίνακα αναζήτησης ταξινομείται σε αύξουσα σειρά. Εάν Τύπος = -1 θεωρείται ότι η στήλη ταξινομείται σε φθίνουσα σειρά. Αντιστοιχεί στη συμπεριφορά της ίδιας συνάρτησης στο Microsoft Excel.

Εάν Τύπος = 0, εντοπίζονται μόνο ακριβείς περιπτώσεις συμφωνίας. Εάν το κριτήριο αναζήτησης βρεθεί πάνω από μία φορά, η συνάρτηση επιστρέφει τον δείκτη της πρώτης τιμής που ταιριάζει. Μόνο εάν Τύπος = 0, μπορείτε να αναζητήσετε κανονικές εκφράσεις (εάν είναι ενεργοποιημένο στις επιλογές υπολογισμού) ή σύμβολα υποκατάστασης (εάν είναι ενεργοποιημένο στις επιλογές υπολογισμού).

Εάν Τύπος = 1 ή λείπει η τρίτη παράμετρος, επιστρέφεται η τελευταία παράμετρος που είναι μικρότερη ή ίση με το κριτήριο αναζήτησης. Αυτό ισχύει ακόμα και όταν ο πίνακας αναζήτησης δεν έχει ταξινομηθεί. Εάν Τύπος = -1, επιστρέφεται η πρώτη τιμή που είναι μεγαλύτερη ή ίση.

Η αναζήτηση υποστηρίζει σύμβολα υποκατάστασης ή κανονικές εκφράσεις. Με ενεργές τις κανονικές εκφράσεις, μπορείτε να εισάγετε "all.*", παραδείγματος χάρη για να βρείτε την πρώτη θέση του "all" ακολουθούμενου από οποιουσδήποτε χαρακτήρες. Εάν θέλετε να αναζητήσετε κείμενο που είναι επίσης κανονική έκφραση, πρέπει είναι να προηγείται σε κάθε χαρακτήρα ένας χαρακτήρας "\", ή να περιέχεται το κείμενο σε \Q...\E. Μπορείτε να ενεργοποιήσετε ή να απενεργοποιήσετε την αυτόματη αξιολόγηση των συμβόλων υποκατάστασης ή κανονικών εκφράσεων στο - LibreOffice Calc - Υπολογισμός.

warning

Όταν χρησιμοποιείτε συναρτήσεις όπου ένα ή περισσότερα ορίσματα είναι συμβολοσειρές κριτηρίων αναζήτησης που αντιπροσωπεύουν κανονική έκφραση, η πρώτη προσπάθεια είναι η μετατροπή των κριτηρίων συμβολοσειρών σε αριθμούς. Παραδείγματος χάρη, το ".0" θα μετατραπεί σε 0.0 κ.ο.κ. Εάν είναι πετυχημένο, η συμφωνία δεν θα είναι συμφωνία κανονικής έκφρασης, αλλά αριθμητική συμφωνία. Όμως, όταν αλλάζετε στις τοπικές ρυθμίσεις όπου ο δεκαδικός διαχωριστής δεν είναι η τελεία, η μετατροπή της κανονικής έκφρασης λειτουργεί. Για να εξαναγκάσετε την αξιολόγηση της κανονικής έκφρασης αντί για την αριθμητική έκφραση, χρησιμοποιήστε κάποια έκφραση που δεν μπορεί να παρανοηθεί ως αριθμητική, όπως ".[0]", ή ".\0", ή "(?i).0".


Παράδειγμα

Το =MATCH(200;D1:D100) αναζητεί την περιοχή D1:D100, η οποία ταξινομείται κατά τη στήλη D, για την τιμή 200. Μόλις βρεθεί η τιμή αυτή, επιστρέφεται ο αριθμός της σειράς στην οποία βρέθηκε. Αν βρεθεί μεγαλύτερη τιμή κατά την αναζήτηση στη στήλη, επιστρέφεται ο αριθμός της προηγούμενης γραμμής.

INDIRECT

Επιστρέφει την παραπομπή που καθορίζεται από ένα κείμενο. Αυτή η συνάρτηση μπορεί επίσης να χρησιμοποιηθεί για να επιστραφεί η περιοχή μιας αντίστοιχης συμβολοσειράς.

Για καλύτερη λειτουργία ανάμεσα τους, οι συναρτήσεις ADDRESS και INDIRECT υποστηρίζουν μια προαιρετική παράμετρο για τον καθορισμό του αν θα γίνεται χρήση της σημείωσης διεύθυνσης R1C1 αντί για τη συνήθη σημείωση A1.

Στην ADDRESS, η παράμετρος εισάγεται ως η τέταρτη παράμετρος και μετακινεί τη προαιρετική παράμετρο ονόματος φύλλου στην πέμπτη θέση.

Στην INDIRECT, η παράμετρος προστίθεται ως δεύτερη παράμετρος.

Και στις δυο συναρτήσεις αν εισαχθεί όρισμα με τιμή 0, τότε χρησιμοποιείται η σημείωση R1C1. Αν δεν έχει εισαχθεί όρισμα ή έχει τιμή μεγαλύτερη του 0, τότε χρησιμοποιείται η σημείωση A1.

Στην περίπτωση της σημείωσης R1C1, η ADDRESS επιστρέφει αλφαριθμητικά διεύθυνσης χρησιμοποιώντας το θαυμαστικό '!' ως διαχωριστικό ονόματος φύλλων, και η INDIRECT αναμένει ότι το θαυμαστικό θα είναι διαχωριστικό ονόματος φύλλων. Και οι δύο συναρτήσεις χρησιμοποιούν την τελεία '.' ως διαχωριστικό ονομάτων φύλλων αν χρησιμοποιηθεί η σημείωση A1.

Κατά το άνοιγμα εγγράφων μορφής ODF 1.0/1.1, οι συναρτήσεις ADDRESS που δείχνουν όνομα του φύλλου ως την τέταρτη παράμετρο θα μετακινήσουν αυτό το όνομα φύλλου ώστε να γίνει η πέμπτη παράμετρος. Μια νέα τέταρτη παράμετρος με την τιμή 1 θα εισαχθεί.

Κατά την αποθήκευση εγγράφων σε μορφή ODF 1.0/1.1, αν οι συναρτήσεις ADDRESS έχουν μια τέταρτη παράμετρο, αυτή η παράμετρος θα απομακρυνθεί.

note

Μην αποθηκεύετε ένα λογιστικό φύλλο με την παλιά μορφή ODF 1.0/1.1 αν η νέα τέταρτη παράμετρος της συνάρτησης ADDRESS έχει τιμή 0.


note

Η συνάρτηση INDIRECT αποθηκεύεται χωρίς μετατροπή σε μορφή αρχείου ODF 1.0/1.1 Αν η δεύτερη παράμετρος είναι παρούσα, μια παλαιότερη έκδοση του Calc θα επιστρέψει σφάλμα για αυτή την συνάρτηση.


Σύνταξη

INDIRECT(Αναφ [; A1])

Το Ref αναπαριστά μια παραπομπή σε ένα κελί ή μια περιοχή (σε μορφή κειμένου) της οποίας τα περιεχόμενα θα επιστραφούν.

A1 (προαιρετικό) - Αν ορισθεί σε 0, χρησιμοποιείται η σημείωση R1C1. Αν αυτή η παράμετρος είναι απούσα ή έχει άλλη τιμή εκτός από 0, τότε χρησιμοποιείται η σημείωση A1 notation.

note

Εάν ανοίξετε ένα υπολογιστικό φύλλο του Excel που χρησιμοποιεί έμμεσες διευθύνσεις που υπολογίζονται από αλφαριθμητικές συναρτήσεις, οι διευθύνσεις του φύλλου δεν θα μεταφρασθούν αυτόματα. Π.χ., η διεύθυνση του Excel στο INDIRECT("[filename]sheetname!"&B1) δεν μετατρέπεται στη διεύθυνση του Calc στο INDIRECT("filename#sheetname."&B1).


Παράδειγμα

Το =INDIRECT(A1) ισούται με 100 αν το Α1 περιέχει το C108 ως αναφορά και το κελί C108 περιέχει την τιμή 100.

Το =SUM(INDIRECT("a1:" & ADDRESS(1;3))) αθροίζει τα κελιά στην περιοχή Α1 έως το κελί με τη διεύθυνση που ορίζεται από τη γραμμή 1 και στήλη 3. Αυτό σημαίνει ότι αθροίζεται η περιοχή A1:C1.

OFFSET

Επιστρέφει την τιμή ενός κελιού μετατοπισμένο κατά ορισμένο αριθμό γραμμών και στηλών από ένα δεδομένο σημείο αναφοράς.

Σύνταξη

OFFSET(Αναφορά; Γραμμές; Στήλες [; Ύψος [; Πλάτος]])

Η Παραπομπή είναι η αναφορά από την οποία η συνάρτηση αναζητά τη νέα παραπομπή.

Γραμμές είναι ο αριθμός των γραμμών από τις οποίες η αναφορά διορθώθηκε προς τα πάνω (αρνητική τιμή) ή προς τα κάτω. Χρησιμοποιήστε 0 για να παραμείνει στην ίδια γραμμή.

Στήλες είναι ο αριθμός των στηλών κατά τον οποίο η αναφορά διορθώθηκε στα αριστερά (αρνητική τιμή) ή στα δεξιά. Χρησιμοποιήστε το 0 για να παραμείνετε στην ίδια στήλη.

Το Ύψος (προαιρετικό) είναι το κατακόρυφο ύψος για μία περιοχή που ξεκινά από τη θέση της νέας παραπομπής.

Το Πλάτος (προαιρετικό) είναι το οριζόντιο πλάτος για μια περιοχή που ξεκινά στη θέση της νέας παραπομπής.

Τα ορίσματα Γραμμές και Στήλες δεν πρέπει να οδηγούν σε μηδενική ή αρνητική εκκίνηση γραμμής ή στήλης.

Τα ορίσματα Ύψος και Πλάτος δεν πρέπει να οδηγούν σε μηδενικό ή αρνητικό πλήθος γραμμών ή στηλών.

Στις συναρτήσεις του LibreOffice Calc, οι παράμετροι που σημειώνονται ως "προαιρετικές" μπορούν να παραληφθούν μόνο όταν δεν ακολουθεί καμιά παράμετρος. Παραδείγματος χάρη, σε μια συνάρτηση με τέσσερις παραμέτρους, όπου οι δύο τελευταίες παράμετροι είναι σημειωμένες ως "προαιρετικές", μπορείτε να αφήσετε έξω την παράμετρο 4 ή τις παραμέτρους 3 και 4, αλλά δεν μπορείτε να παραλείψετε μόνο την παράμετρο 3.

Παράδειγμα

Η συνάρτηση =OFFSET(A1;2;2) επιστρέφει την τιμή στο κελί C3 (το Α1 μετακινήθηκε δύο γραμμές και δύο στήλες κάτω). Αν το κελί C3 περιέχει την τιμή 100, η συνάρτηση αυτή επιστρέφει την τιμή 100.

Το =OFFSET(B2:C3;1;1) επιστρέφει μια αναφορά στη B2:C3 μετατοπισμένη προς τα κάτω κατά μία σειρά και μία στήλη προς τα δεξιά (C3:D4).

Το =OFFSET(B2:C3;-1;-1) επιστρέφει μια αναφορά στη B2:C3 μετατοπισμένη κατά μία σειρά επάνω και κατά μία στήλη αριστερά (A1:B2).

Το =OFFSET(B2:C3;0;0;3;4) επιστρέφει μια αναφορά στη B2:C3 με αλλαγή μεγέθους σε 3 σειρές και 4 στήλες (B2:E4).

Το =OFFSET(B2:C3;1;0;3;4) επιστρέφει μια αναφορά στη B2:C3 μετατοπισμένη κατά μία σειρά κάτω με αλλαγή μεγέθους σε 3 σειρές και 4 στήλες (B3:E5).

Η συνάρτηση =SUM(OFFSET(A1;2;2;5;6)) καθορίζει το σύνολο της περιοχής που ξεκινά από το κελί C3 και έχει ύψος 5 γραμμές και πλάτος 6 στήλες (περιοχή=C3:H7).

note

Εάν δίνονται το Πλάτος ή το Ύψος, η συνάρτηση OFFSET επιστρέφει μια αναφορά περιοχής κελιών. Εάν η Αναφορά είναι αναφορά μοναδικού κελιού και το Πλάτος και το Ύψος παραλείπονται, επιστρέφεται αναφορά μοναδικού κελιού.


DDE

Επιστρέφει το αποτέλεσμα μιας σύνδεσης DDE. Αν τα περιεχόμενα της συνδεδεμένης περιοχής ή ενότητας αλλάξουν, η τιμή που επιστρέφεται θα αλλάξει επίσης. Πρέπει να ξαναφορτώσετε το υπολογιστικό φύλλο ή να επιλέξετε Επεξεργασία - Σύνδεσμοι για να δείτε τους ανανεωμένους συνδέσμους. Δεν επιτρέπονται συνδέσεις μεταξύ διαφορετικών πλατφορμών, π.χ. από εγκατάσταση του LibreOffice σε Windows σε έγγραφο δημιουργημένο σε εγκατάσταση σε Λίνουξ.

Σύνταξη

DDE("Διακομιστής"; "Αρχείο"; "Περιοχή" [; Κατάσταση])

Διακομιστής είναι το όνομα μιας εφαρμογής στον διακομιστή. Οι εφαρμογές του LibreOffice έχουν το όνομα διακομιστή "soffice".

Αρχείο είναι ολόκληρο το όνομα αρχείου, συμπεριλαμβανομένης της διαδρομής.

Περιοχή είναι η περιοχή που περιέχει τα δεδομένα που θα αξιολογηθούν.

Κατάσταση είναι μια προαιρετική παράμετρος που ελέγχει τη μέθοδο με την οποία ο διακομιστής DDE μετατρέπει τα δεδομένα του σε αριθμούς.

Λειτουργία

Αποτέλεσμα

0 ή ελλιπής

Μορφή αριθμού από την τεχνοτροπία κελιού "Προεπιλογή"

1

Τα δεδομένα ερμηνεύονται πάντα με την προεπιλεγμένη μορφή για Αγγλικά ΗΠΑ

2

Τα δεδομένα ανακτώνται ως κείμενο και δεν μετατρέπονται σε αριθμούς


Παράδειγμα

Η =DDE("soffice";"c:\office\document\data1.ods";"φύλλο1.A1") διαβάζει τα περιεχόμενα του κελιού Α1 στο φύλλο1 του υπολογιστικού φύλλου data1.ods του LibreOffice Calc.

Το =DDE("soffice";"c:\office\document\motto.odt";"Today's motto (Σημερινό Απόφθεγμα)") επιστρέφει ένα απόφθεγμα στο κελί που περιέχει αυτό τον τύπο. Πρώτα, πρέπει να εισάγετε για γραμμή στο έγγραφο motto.odt που περιέχει το κείμενο του αποφθέγματος και να την καθορίσετε ως πρώτη γραμμή μιας ενότητας με το όνομα Today's Motto (Σημερινό Απόφθεγμα) (στο LibreOffice Writer στο Εισαγωγή - Ενότητα). Αν το απόφθεγμα τροποποιηθεί (και αποθηκευθεί) στο έγγραφο του LibreOffice Writer, το απόφθεγμα ενημερώνεται σε όλα τα κελιά του LibreOffice Calc στα οποία έχει καθορισθεί αυτή η σύνδεση DDE.

ROWS

Επιστρέφει το πλήθος των γραμμών σε μια παραπομπή ή σειρά δεδομένων.

Σύνταξη

ROWS(Πίνακας)

Ο Πίνακας είναι η παραπομπή ή η καθορισμένη περιοχή της οποίας ο συνολικός αριθμός γραμμών θα καθοριστεί.

Παράδειγμα

Η συνάρτηση =Rows(B5) επιστρέφει την τιμή 1 επειδή ένα κελί μόνο περιέχει μία γραμμή.

Η συνάρτηση =ROWS(A10:B12) επιστρέφει αποτέλεσμα 3.

Η συνάρτηση =ROWS(Rabbit) επιστρέφει την τιμή 3 αν το "Κουνέλι" είναι το όνομα της περιοχής (C1:D3).

ROW

Επιστρέφει τον αριθμό γραμμής μίας παραπομπής κελιών. Εάν η παραπομπή είναι ένα κελί, επιστρέφει τον αριθμό γραμμής του κελιού. Εάν η παραπομπή είναι μια περιοχή κελιών, επιστρέφει τους αντίστοιχους αριθμούς γραμμών σε έναν μονής στήλης,Πίνακα εφόσον ο τύπος έχει εισαχθεί ως τύπος πίνακα. Αν η συνάρτηση ROW με μία παραπομπής περιοχής δεν χρησιμοποιείται σε έναν τύπο πίνακα, μόνο ο αριθμός γραμμής της πρώτης περιοχής θα επιστραφεί.

Σύνταξη

ROW([Αναφορά])

Η Παραπομπή είναι ένα κελί, μια περιοχή ή το όνομα μιας περιοχής.

Εάν δεν ορίσετε μια παραπομπή, θα βρεθεί ο αριθμός γραμμής του κελιού στο οποίο έχει εισαχθεί ο τύπος. Το LibreOffice Calc ορίζει αυτόματα την παραπομπή στο τρέχον κελί.

Παράδειγμα

Η συνάρτηση =ROW(B3) επιστρέφει την τιμή 3 επειδή η παραπομπή αναφέρεται στην τρίτη γραμμή του πίνακα.

Η συνάρτηση {=ROW(D5:D8)} επιστρέφει τη σειρά δεδομένων μίας στήλης (5, 6, 7, 8) γιατί η καθορισμένη παραπομπή περιέχει τις γραμμές 5 έως 8.

Η συνάρτηση =ROW(D5:D8) επιστρέφει την τιμή 5 γιατί η συνάρτηση ROW δεν χρησιμοποιείται σαν τύπος σειράς δεδομένων και μόνο ο αριθμός της πρώτης γραμμή της παραπομπής επιστρέφεται.

Οι συναρτήσεις {=ROW(A1:E1)} και =ROW(A1:E1) επιστρέφουν την τιμή 1 γιατί η παραπομπή περιέχει μόνο τη γραμμή 1, ως πρώτη στήλη του πίνακα. (Καθώς οι περιοχές μίας γραμμής έχουν μόνο έναν αριθμό γραμμής, δεν έχει σημασία εάν ο τύπος χρησιμοποιείται ως τύπος σειράς δεδομένων.)

Η συνάρτηση =ROW() επιστρέφει την τιμή 3 αν ο τύπος εισήχθηκε στη γραμμή 3.

Η συνάρτηση {=ROW(Κουνέλι)} επιστρέφει τη σειρά δεδομένων μίας γραμμής (1, 2, 3) εάν η περιοχή (C1:D3) ονομάζεται "Κουνέλι".

ERRORTYPE

Επιστρέφει τον αριθμό που αντιστοιχεί σε μια τιμή σφάλματος που εμφανίζεται σε διαφορετικό κελί. Με τη βοήθεια αυτού του αριθμού, μπορείτε να δημιουργήσετε ένα κείμενο σφάλματος.

Αν συμβεί κάποιο λάθος, η συνάρτηση επιστρέφει μια λογική ή αριθμητική τιμή.

note

Η γραμμή κατάστασης έχει τον προκαθορισμένο κωδικό σφάλματος από το LibreOffice, αν πατήσετε στο κελί που περιέχει το σφάλμα.


Σύνταξη

ERRORTYPE(Παραπομπή)

Η Παραπομπή περιέχει τη διεύθυνση του κελιού στο οποίο παρουσιάζεται στο σφάλμα.

Παράδειγμα

Εάν το κελί A1 εμφανίζει την τιμή Err:518, η συνάρτηση =ERRORTYPE(A1) θα επιστρέψει τον αριθμό 518.

COLUMN

Επιστρέφει τον αριθμό στήλης μιας παραπομπής κελιού. Εάν η παραπομπή είναι ένα κελί, επιστρέφεται ο αριθμός στήλης του κελιού. Εάν η παράμετρος είναι μια περιοχή κελιών, οι αντίστοιχοι αριθμοί στήλης επιστρέφονται σε έναν πίνακα μονής γραμμής, εφόσον ο τύπος έχει εισαχθεί ως τύπος πίνακα. Εάν η συνάρτηση COLUMN με παράμετρο παραπομπής σε περιοχή δεν χρησιμοποιείται για τύπο πίνακα, καθορίζεται μόνο ο αριθμός στήλης του πρώτου κελιού μέσα στην περιοχή.

Σύνταξη

COLUMN([Αναφορά])

Η Παραπομπή είναι η παραπομπή σε κελί ή περιοχή κελιών της οποίας ο αριθμός της πρώτης στήλης θα εντοπιστεί.

Εάν δεν έχει εισαχθεί παραπομπή, εντοπίζεται ο αριθμός στήλης του κελιού στο οποίο έχει εισαχθεί ο τύπος. Το LibreOffice Calc ορίζει αυτόματα την παραπομπή στο τρέχον κελί.

Παράδειγμα

Η συνάρτηση =COLUMN(A1) ισούται με 1. Η στήλη Α είναι η πρώτη στήλη του πίνακα.

Η συνάρτηση =COLUMN(C3:E3) ισούται με 3. Η στήλη C είναι η τρίτη στήλη του πίνακα.

Η συνάρτηση =COLUMN(D3:G10) επιστρέφει ως αποτέλεσμα 4 επειδή η στήλη D είναι η τέταρτη στήλη του πίνακα και η συνάρτηση COLUMN δεν χρησιμοποιείται σαν συνάρτηση πίνακα. (Σε αυτήν την περίπτωση, η πρώτη τιμή του πίνακα χρησιμοποιείται πάντα ως αποτέλεσμα.)

Οι συναρτήσεις {=COLUMN(B2:B7)} και =COLUMN(B2:B7) επιστρέφουν και οι δύο τον αριθμό 2 γιατί η παραπομπή περιέχει μόνο τη στήλη B ως τη δεύτερη στήλη του πίνακα. Επειδή οι περιοχές με μία μόνο στήλη έχουν μόνο έναν αριθμό στήλης, δεν έχει σημασία εάν ο τύπος χρησιμοποιείται ως τύπος πίνακα.

Η συνάρτηση =COLUMN() επιστρέφει ως αποτέλεσμα 3 αν ο τύπος έχει εισαχθεί στη στήλη C.

Η συνάρτηση {=COLUMN(Rabbit)} επιστρέφει τον πίνακα μίας σειράς (3, 4), εάν το "Κουνέλι" είναι η καθορισμένη περιοχή (C1:D3).

SHEET

Επιστρέφει τον αριθμό του φύλλου της παραπομπής ή του αλφαριθμητικού που αντιπροσωπεύει ένα όνομα φύλλου. Εάν δεν εισαγάγετε παραμέτρους, το αποτέλεσμα είναι ο αριθμός φύλλου που περιέχει τον τύπο.

Σύνταξη

SHEET([Αναφορά])

Η Παραπομπή είναι προαιρετική και είναι η παραπομπή σε ένα κελί, μια περιοχή ή μια ακολουθία χαρακτήρων ονόματος πίνακα.

Παράδειγμα

Η συνάρτηση =SHEET(Sheet2.A1) επιστρέφεις την τιμή 2 αν το Φύλλο2 είναι το δεύτερο φύλλο στο έγγραφο του υπολογιστικού φύλλου.

AREAS

Επιστρέφει τον αριθμό των μεμονωμένων περιοχών που ανήκουν σε μια πολλαπλή περιοχή. Μια περιοχή μπορεί να αποτελείται από συνεχόμενα κελιά ή από ένα μόνο κελί.

Η συνάρτηση αναμένει μια παράμετρο. Αν δηλώσετε πολλαπλές περιοχές, θα πρέπει να τις περικλείσετε μέσα σε επιπρόσθετες παρενθέσεις. Οι πολλαπλές περιοχές μπορούν να εισαχθούν με τη χρήση του ερωτηματικού (;) ως διαχωριστικό, το οποίο θα μετατραπεί αυτόματα σε περισπωμένη (~). Η περισπωμένη χρησιμοποιείται για την συνένωση περιοχών.

Σύνταξη

AREAS(Παραπομπή)

Η παραπομπή απεικονίζει την αναφορά σε ένα κελί ή μία περιοχή κελιών.

Παράδειγμα

Το =ΠΕΡΙΟΧΕΣ(A1:B3;F2;G1) επιστρέφει 3, καθώς αναφέρεται σε τρία κελιά και/ή περιοχές. Μετά την καταχώριση αυτό μετατρέπεται σε =ΠΕΡΙΟΧΕΣ((A1:B3~F2~G1)).

Το =AREAS(Όλα) επιστρέφει 1 αν έχετε ορίσει μια περιοχή με το όνομα Όλα στο Δεδομένα - Ορισμός Περιοχής.

COLUMNS

Επιστρέφει τον αριθμό των στηλών στη δοθείσα παραπομπή.

Σύνταξη

COLUMNS(Πίνακας)

Ο Πίνακας είναι η παραπομπή σε μια περιοχή κελιών, της οποίας ο συνολικός αριθμός στηλών θα εντοπιστεί. Το όρισμα μπορεί επίσης να είναι ένα μόνο κελί.

Παράδειγμα

Η συνάρτηση =COLUMNS(B5) επιστρέφει ως αποτέλεσμα 1 επειδή ένα κελί μόνο του περιέχει μία στήλη.

Η συνάρτηση =COLUMNS(A1:C5) ισούται με 3. Η παραπομπή συγκρίνει τρεις στήλες.

Η συνάρτηση =COLUMNS(Κουνέλι) επιστρέφει ως αποτέλεσμα 2 αν το Κουνέλι είναι η καθορισμένη περιοχή (C1:D3).

STYLE

Εφαρμόζει μια τεχνοτροπία στο κελί που περιέχει τον τύπο. Μετά από ένα καθορισμένο χρονικό διάστημα, μπορεί να εφαρμοστεί μια άλλη τεχνοτροπία. Αυτή η συνάρτηση επιστρέφει πάντα την τιμή 0 και σας επιτρέπει να την προσθέσετε σε μια άλλη συνάρτηση χωρίς να αλλάξετε την τιμή. Μαζί με τη συνάρτηση CURRENT μπορείτε να εφαρμόσετε ένα χρώμα σε ένα κελί ανεξάρτητα από την τιμή. Π.χ.: =...+STYLE(IF(CURRENT()>3;"κόκκινο";"πράσινο")) εφαρμόζει την τεχνοτροπία "κόκκινο" στο κελί εάν η τιμή είναι μεγαλύτερη του 3, αλλιώς εφαρμόζεται η τεχνοτροπία "πράσινο". Και οι δύο μορφές κελιού, "κόκκινο" και "πράσινο" πρέπει να έχουν καθορισθεί από πριν.

Σύνταξη

STYLE("Τεχνοτροπία" [; Χρόνος [; "Τεχνοτροπία2"]])

Το Τεχνοτροπία είναι το όνομα μιας τεχνοτροπίας κελιού που έχει αντιστοιχηθεί στο κελί. Τα ονόματα των τεχνοτροπιών πρέπει να τοποθετούνται σε εισαγωγικά.

Η Ώρα είναι η προαιρετική περιοχή ώρας σε δευτερόλεπτα. Αν στην παράμετρο αυτή λείπει η τεχνοτροπία, δεν θα αλλάξει μετά το πέρας ενός συγκεκριμένου χρονικού διαστήματος.

Το Τεχνοτροπία2 είναι το προαιρετικό όνομα μιας τεχνοτροπίας κελιού που έχει αντιστοιχηθεί στο κελί μετά το πέρας ενός συγκεκριμένου χρονικού διαστήματος. Εάν αυτή η παράμετρος λείπει, εισάγεται η τιμή "Προεπιλογή".

Στις συναρτήσεις του LibreOffice Calc, οι παράμετροι που σημειώνονται ως "προαιρετικές" μπορούν να παραληφθούν μόνο όταν δεν ακολουθεί καμιά παράμετρος. Παραδείγματος χάρη, σε μια συνάρτηση με τέσσερις παραμέτρους, όπου οι δύο τελευταίες παράμετροι είναι σημειωμένες ως "προαιρετικές", μπορείτε να αφήσετε έξω την παράμετρο 4 ή τις παραμέτρους 3 και 4, αλλά δεν μπορείτε να παραλείψετε μόνο την παράμετρο 3.

Παράδειγμα

Η συνάρτηση =STYLE("Invisible";60;"Default") μορφοποιεί το κελί σε διαφανή μορφοποίηση για 60 δευτερόλεπτα ύστερα από τον επανυπολογισμό ή τη φόρτωση του εγγράφου, ύστερα ανατίθεται η μορφή Προεπιλογή. Και οι δύο μορφές κελιών πρέπει να καθοριστεί νωρίτερα.

Επειδή η STYLE() έχει μία αριθμητική τιμή επιστροφής μηδέν, αυτή η επιστρεφόμενη τιμή προστίθεται σε ένα αλφαριθμητικό. Αυτό μπορεί να εμποδιστεί χρησιμοποιώντας τη T() όπως στο ακόλουθο παράδειγμα:

="Κείμενο"&T(STYLE("myStyle"))

Δείτε επίσης τη συνάρτηση CURRENT() για ένα άλλο παράδειγμα.

GETPIVOTDATA

Η συνάρτηση GETPIVOTDATA επιστρέφει αποτέλεσμα από ένα συγκεντρωτικό πίνακα. Η τιμή διευθυνσιοδοτείται με χρήση ονομάτων πεδίων και στοιχείων, έτσι παραμένει έγκυρη εάν η διάταξη του συγκεντρωτικού πίνακα αλλάξει.

Σύνταξη

Μπορούν να χρησιμοποιηθούν δύο διαφορετικοί ορισμοί σύνταξης:

GETPIVOTDATA(ΠεδίοΠροορισμού; συγκεντρωτικός πίνακας[; Πεδίο 1; Στοιχείο 1][; ... [Πεδίο 126; Στοιχείο 126]])

ή

GETPIVOTDATA(συγκεντρωτικός πίνακας; περιορισμοί)

Ο δεύτερος τρόπος σύνταξης υιοθετείται αν δίνονται ακριβώς δύο παράμετροι εκ των οποίων η πρώτη είναι ένα κελί ή μια αναφορά περιοχής κελιών. Ο πρώτος τρόπος χρησιμοποιείται σε όλες τις άλλες περιπτώσεις. Ο Οδηγός συνάρτησης δείχνει τον πρώτο τρόπο.

Πρώτη σύνταξη

Το πεδίο στόχου είναι ένα αλφαριθμητικό που επιλέγει ένα από πεδία δεδομένων του συγκεντρωτικού πίνακα. Το αλφαριθμητικό μπορεί να είναι το όνομα της στήλης προέλευσης ή το όνομα του πεδίου δεδομένων όπως φαίνεται στον πίνακα (όπως "Άθροισμα - Πωλήσεις").

Ο Συγκεντρωτικός πίνακας είναι μια αναφορά σε ένα κελί ή περιοχή κελιών που είναι τοποθετημένο σε ένα συγκεντρωτικό πίνακα ή περιέχει ένα συγκεντρωτικό πίνακα. Αν η περιοχή κελιών περιλαμβάνει πολλούς συγκεντρωτικούς πίνακες, χρησιμοποιείται ο πίνακας που δημιουργήθηκε τελευταίος.

Αν δεν δίνονται τα ζευγάρια Πεδίο n / Στοιχείο n, επιστρέφεται το συνολικό άθροισμα. Αλλιώς κάθε ζεύγος προσθέτει έναν περιορισμό τον οποίο πρέπει να ικανοποιεί το αποτέλεσμα. Το Πεδίο n είναι το όνομα ενός πεδίου από τον συγκεντρωτικό πίνακα. Το Στοιχείο n είναι το όνομα ενός στοιχείου από αυτό το πεδίο.

Αν ο συγκεντρωτικός πίνακας περιέχει μόνο μία τιμή αποτελέσματος που ικανοποιεί όλους τους περιορισμούς, ή ένα υποσύνολο που συνοψίζει όλες τις τιμές που ταιριάζουν, επιστρέφεται αυτό το αποτέλεσμα. Αν δεν υπάρχει κανένα κατάλληλο αποτέλεσμα ή υπάρχουν πολλά χωρίς υποσύνολο για αυτά, επιστρέφεται μήνυμα λάθους. Αυτές οι συνθήκες ισχύουν για αποτελέσματα που συμπεριλαμβάνονται στον συγκεντρωτικό πίνακα.

Αν τα δεδομένα προέλευσης περιέχουν καταχωρήσεις που αποκρύπτονται από ρυθμίσεις του συγκεντρωτικού πίνακα, αυτές αγνοούνται. Η σειρά των ζευγών Πεδίο/Στοιχείο δεν παίζει ρόλο. Τα ονόματα πεδίων και στοιχείων δεν διακρίνουν πεζά-κεφαλαία.

Αν δεν δίνεται περιορισμός για ένα πεδίο σελίδας, χρησιμοποιείται υπονοούμενα η επιλεγμένη τιμή του πεδίου. Αν δίνεται περιορισμός για πεδίο σελίδας, πρέπει να ταιριάζει την επιλεγμένη τιμή του πεδίου, αλλιώς επιστρέφεται σφάλμα. Τα πεδία σελίδας είναι πεδία στην κορυφή αριστερά ενός συγκεντρωτικού πίνακα, που ορίζονται από την περιοχή "Πεδία Σελίδας" του διαλόγου διάταξης συγκεντρωτικού πίνακα. Από κάθε πεδίο σελίδας, μπορεί να επιλεγεί ένα στοιχείο (τιμή), το οποίο σημαίνει ότι μόνο αυτό το στοιχείο περιλαμβάνεται στον υπολογισμό.

Τιμές υποαθροισμάτων από τον συγκεντρωτικό πίνακα χρησιμοποιούνται μόνο αν χρησιμοποιούν τη λειτουργία "auto" (εκτός όταν καθορίζεται στον περιορισμό, βλέπε Δεύτερη σύνταξη παρακάτω).

Δεύτερη σύνταξη

Ο συγκεντρωτικός πίνακας έχει την ίδια έννοια όπως η πρώτη σύνταξη.

Το Περιορισμοί είναι ένας κατάλογος διαχωρισμένος με κενά. Οι καταχωρίσεις μπορούν να έχουν εισαγωγικά (μονά). Ολόκληρο το αλφαριθμητικό πρέπει να περιλαμβάνεται σε εισαγωγικά (διπλά) εκτός και αν παραπέμπεται το αλφαριθμητικό από άλλο κελί.

Μία από τις καταχωρίσεις μπορεί να είναι το όνομα του πεδίου δεδομένων. Το όνομα του πεδίου τιμών μπορεί να μην συμπεριληφθεί αν ο συγκεντρωτικός πίνακας περιλαμβάνει μόνο ένα πεδίο δεδομένων, αλλιώς πρέπει να υπάρχει.

Κάθε μία από τις άλλες καταχωρίσεις καθορίζει ένα περιορισμό της μορφής Πεδίο[Στοιχείο] (με τους τυπογραφικούς χαρακτήρες [ και ]) ή μόνο Στοιχείο αν το όνομα του στοιχείου είναι μοναδικό σε όλα τα πεδία που χρησιμοποιούνται στον συγκεντρωτικό πίνακα.

Μπορεί να προστεθεί ένα όνομα συνάρτησης με τη μορφή Πεδίο[Αντικείμενο;Συνάρτηση], το οποίο θα οδηγήσει τον περιορισμό να ταιριάξει μόνο όσες τιμές υποσυνόλων χρησιμοποιούν αυτή τη συνάρτηση. Τα δυνατά ονόματα συναρτήσεων είναι Sum, Count, Average, Max, Min, Product, Count (Αριθμοί μόνο), StDev (Δείγμα), StDevP (Πληθυσμός), Var (Δείγμα), και VarP (Πληθυσμός), με ταίριασμα πεζών-κεφαλαίων.

INDEX

Η συνάρτηση INDEX επιστρέφει μια υπο-περιοχή, που καθορίζεται με τον αριθμό γραμμής και στήλης ή με ένα προαιρετικό όνομα περιοχής. Ανάλογα με το περιεχόμενο, η INDEX επιστρέφει μια παραππμπή ή περιεχόμενο.

Σύνταξη

INDEX(Αναφορά [; Γραμμή [; Στήλη [; Περιοχή]]])

Παραπομπή είναι μια παραπομπή σε κελί, που έχει εισαχθεί είτε απευθείας είτε καθορίζοντας ένα όνομα περιοχής. Εάν η παραπομπή αποτελείται από πολλαπλές περιοχές, πρέπει να τοποθετήσετε την παραπομπή ή το όνομα της περιοχής σε παρενθέσεις.

Γραμμή (προαιρετική) αναπαριστά τον αριθμό γραμμής της περιοχής παραπομπής, για την οποία θα επιστραφεί τιμή. Στην περίπτωση του μηδέν (καμία συγκεκριμένη γραμμή) επιστρέφονται όλες οι γραμμές της παραπομπής.

Στήλη (προαιρετική) αναπαριστά τον αριθμό στήλης της περιοχής παραπομπής, για την οποία θα επιστραφεί τιμή. Στην περίπτωση του μηδέν (καμία συγκεκριμένη γραμμή) επιστρέφονται όλες οι στήλες της παραπομπής.

Περιοχή (προαιρετική) αντιπροσωπεύει τον αριθμό της υποπεριοχής αν αναφερόμαστε σε πολλαπλή περιοχή.

Παράδειγμα

Το =INDEX(Prices;4;1) επιστρέφει την τιμή από τη γραμμή 4 και τη στήλη 1 της περιοχής βάσης δεδομένων που καθορίζεται στο Δεδομένα - Ορισμός περιοχής ως Τιμές.

Το =INDEX(SumX;4;1) επιστρέφει την τιμή από την περιοχή SumX στη γραμμή 4 και στήλη 1 όπως καθορίζεται στο Φύλλο - Επώνυμες περιοχές και παραστάσεις - Ορισμός.

Το =INDEX(A1:B6;1) επιστρέφει μια παραπομπή στην πρώτη σειρά της περιοχής A1:B6.

Το =INDEX(A1:B6;0;1) επιστρέφει μια παραπομπή στην πρώτη στήλη της περιοχής A1:B6.

Το =INDEX((multi);4;1) υποδεικνύει την τιμή που περιέχεται στη γραμμή 4 και στήλη 1 της (πολλαπλής) περιοχής, την οποία ονομάσατε με το Φύλλο - Επώνυμες περιοχές και παραστάσεις - Ορισμός ως multi (πολλαπλές). Η πολλαπλή περιοχή μπορεί να αποτελείται από πολλές ορθογώνιες περιοχές, κάθε μία με γραμμή 4 και στήλη 1. Αν τώρα επιθυμείτε να καλέσετε το δεύτερο μπλοκ της πολλαπλής περιοχής εισάγετε τον αριθμό 2 ως την παράμετρο περιοχή.

Το =INDEX(A1:B6;1;1) υποδεικνύει την τιμή πάνω αριστερά της περιοχής A1:B6.

Το =INDEX((multi);0;0;2) επιστρέφει μια παραπομπή στη δεύτερη περιοχή της πολλαπλής περιοχής.

VLOOKUP

Κάθετη αναζήτηση ως προς τα διπλανά κελιά στα δεξιά. Αυτή η συνάρτηση ελέγχει αν μια συγκεκριμένη τιμή περιέχεται στην πρώτη στήλη μιας μήτρας. Η συνάρτηση μετά επιστρέφει την τιμή στην ίδια γραμμή της στήλη που ονομάζεται στο Index. Εάν η παράμετρος Sorted (ταξινομημένη) παραλείπεται ή ορίζεται ως TRUE (αληθής) ή ένα, υποτίθεται ότι τα δεδομένα ταξινομούνται κατά αύξουσα σειρά. Σε αυτήν την περίπτωση, αν το ακριβές SearchCriterion (Κριτήριο-Αναζήτησης) δεν βρεθεί, θα επιστραφεί η τελευταία τιμή που είναι μικρότερη από το κριτήριο. Εάν η παράμετρος Sorted (ταξινομημένη) ορισθεί ως FALSE (ψευδής) ή μηδέν, πρέπει να βρεθεί ακριβής συμφωνία, αλλιώς εμφανίζεται το σφάλμα Error: Value Not Available (Σφάλμα: Η τιμή δεν είναι διαθέσιμη). Συνεπώς, με μια τιμή μηδέν τα δεδομένα δεν χρειάζεται να είναι ταξινομημένα κατά αύξουσα σειρά.

Η αναζήτηση υποστηρίζει σύμβολα υποκατάστασης ή κανονικές εκφράσεις. Με ενεργές τις κανονικές εκφράσεις, μπορείτε να εισάγετε "all.*", παραδείγματος χάρη για να βρείτε την πρώτη θέση του "all" ακολουθούμενου από οποιουσδήποτε χαρακτήρες. Εάν θέλετε να αναζητήσετε κείμενο που είναι επίσης κανονική έκφραση, πρέπει είναι να προηγείται σε κάθε χαρακτήρα ένας χαρακτήρας "\", ή να περιέχεται το κείμενο σε \Q...\E. Μπορείτε να ενεργοποιήσετε ή να απενεργοποιήσετε την αυτόματη αξιολόγηση των συμβόλων υποκατάστασης ή κανονικών εκφράσεων στο - LibreOffice Calc - Υπολογισμός.

warning

Όταν χρησιμοποιείτε συναρτήσεις όπου ένα ή περισσότερα ορίσματα είναι συμβολοσειρές κριτηρίων αναζήτησης που αντιπροσωπεύουν κανονική έκφραση, η πρώτη προσπάθεια είναι η μετατροπή των κριτηρίων συμβολοσειρών σε αριθμούς. Παραδείγματος χάρη, το ".0" θα μετατραπεί σε 0.0 κ.ο.κ. Εάν είναι πετυχημένο, η συμφωνία δεν θα είναι συμφωνία κανονικής έκφρασης, αλλά αριθμητική συμφωνία. Όμως, όταν αλλάζετε στις τοπικές ρυθμίσεις όπου ο δεκαδικός διαχωριστής δεν είναι η τελεία, η μετατροπή της κανονικής έκφρασης λειτουργεί. Για να εξαναγκάσετε την αξιολόγηση της κανονικής έκφρασης αντί για την αριθμητική έκφραση, χρησιμοποιήστε κάποια έκφραση που δεν μπορεί να παρανοηθεί ως αριθμητική, όπως ".[0]", ή ".\0", ή "(?i).0".


Σύνταξη

=VLOOKUP(ΚριτήριοΑναζήτησης; Πίνακας; Δείκτης [; ΑναζήτησηΤαξονομημένηςΠεριοχής])

Το Κριτήριο-αναζήτησης είναι η τιμή που αναζητείται στην πρώτη στήλη της σειράς δεδομένων.

Πίνακας είναι η αναφορά, που πρέπει να αποτελείται τουλάχιστον από τόσες στήλες όσες και ο αριθμός που περάστηκε στο όρισμα του δείκτη.

Ο Δείκτης είναι ο αριθμός της στήλης στον πίνακα που περιέχει την τιμή που θα επιστραφεί ως αποτέλεσμα. Η πρώτη στήλη έχει τον αριθμό 1.

ΑναζήτησηΤαξινομημένηςΠεριοχής είναι μια προαιρετική παράμετρος που δείχνει εάν η πρώτη στήλη στον πίνακα περιέχει όρια περιοχών αντί για απλές τιμές. Σε αυτήν την κατηγορία, η αναζήτηση επιστρέφει την τιμή της γραμμής με την πρώτη στήλη να έχει τιμή ίση με ή μικρότερη από το ΚριτήριοΑναζήτησης. Π.χ., μπορεί να περιέχει ημερομηνίες όταν κάποια τιμή φόρου έχει αλλαχθεί και έτσι οι τιμές αναπαριστούν ημερομηνίες έναρξης περιόδου με συγκεκριμένη τιμή φόρου εν ισχύ. Συνεπώς, η αναζητά ημερομηνία που λείπει στην πρώτη στήλη του πίνακα, αλλά υπάρχει μεταξύ υφιστάμενων οριακών ημερομηνιών, θα δώσει την μικρότερη από αυτές, επιτρέποντας την αναζήτηση της εν ισχύ ημερομηνίας στην αναζητούμενη ημερομηνία. Εισάγετε την τιμή Μπουλ FALSE ή μηδέν, εάν η πρώτη στήλη δεν είναι κατάλογος ορίων περιοχής. Όταν αυτή η παράμετρος είναι TRUE ή δεν δίνεται, η πρώτη στήλη στον πίνακα πρέπει να ταξινομηθεί σε αύξουσα σειρά. Ταξινομημένες στήλες μπορούν να αναζητηθούν πολύ πιο γρήγορα και η συνάρτηση επιστρέφει πάντα μια τιμή, ακόμα κι αν η τιμή αναζήτησης δεν συμφωνεί ακριβώς, εάν είναι μεγαλύτερη από τη μικρότερη τιμή του ταξινομημένου καταλόγου. Σε αταξινόμητους καταλόγους, η τιμή αναζήτησης πρέπει να συμφωνεί ακριβώς. Αλλιώς η συνάρτηση θα επιστρέψει #Δ/Υ με μήνυμα: Σφάλμα: Μη διαθέσιμη τιμή.

Διαχείριση κενών κελιών

Παράδειγμα

Θέλετε να εισάγετε τον αριθμό ενός πιάτου στο μενού στο κελί A1 και το όνομα του πιάτου θα εμφανιστεί ως κείμενο στο γειτονικό κελί (B1) αμέσως. Η αντιστοίχηση αριθμός-σε-όνομα περιέχεται στον πίνακα D1:E100. Το κελί D1 περιέχει την τιμή 100, το κελί E1 περιέχει το όνομα Vegetable Soup (Σούπα χορτοφάγων), κ.ο.κ., για 100 αντικείμενα του μενού. Οι αριθμοί στην στήλη D ταξινομούνται σε αύξουσα σειρά. Συνεπώς, η προαιρετική παράμετρος Ταξινομημένο δεν είναι απαραίτητη.

Εισάγετε τον ακόλουθο τύπο στο κελί B1:

=VLOOKUP(A1;D1:E100;2)

Μόλις εισάγετε έναν αριθμό στο κελί A1, στο B1 θα εμφανίζει το αντίστοιχο κείμενο που περιέχεται στη δεύτερη στήλη παραπομπής D1:E100. Εισάγοντας έναν αριθμό που δεν υπάρχει, εμφανίζεται το κείμενο του επόμενου αριθμού από κάτω. Για να το αποφύγετε, εισαγάγετε την τιμή FALSE ως την τελευταία παράμετρο στον τύπο, ώστε να εμφανίζεται ένα μήνυμα σφάλματος, όταν εισάγεται ένας ανύπαρκτος αριθμός.

SHEETS

Καθορίζει τον αριθμό των φύλλων σε μια αναφορά. Εάν δεν εισαγάγετε παραμέτρους, επιστρέφει τον αριθμό των φύλλων στο τρέχον έγγραφο.

Σύνταξη

SHEETS([Αναφορά])

Η Παραπομπή είναι η παραπομπή σε έναν πίνακα ή μια περιοχή. Αυτή η παράμετρος είναι προαιρετική.

Παράδειγμα

Η συνάρτηση =SHEETS(Sheet1.A1:Sheet3.G12) επιστρέφει ως αποτέλεσμα 3 αν τα φύλλα Φύλλο1, Φύλλο2 και Φύλλο3 υπάρχουν με την σειρά που υποδεικνύονται.

CHOOSE

Χρησιμοποιεί ένα ευρετήριο για να επιστρέψει μια τιμή από έναν κατάλογο μέχρι 30 τιμές.

Σύνταξη

CHOOSE(Δείκτης; Τιμή1 [; Τιμή2 [; ... [; Τιμή254]]])

Δείκτης είναι μια αναφορά ή αριθμός μεταξύ 1 και 254 που δείχνει ποια τιμή θα παρθεί από τον κατάλογο.

Τιμή1, Τιμή2, …, Τιμή 254 είναι ο κατάλογος τιμών που εισήχθησαν ως αναφορά σε κελί ή ως μεμονωμένες τιμές.

Παράδειγμα

=CHOOSE(A1;B1;B2;B3;"Σήμερα";"Χθες";"Αύριο"), π.χ., επιστρέφει τα περιεχόμενα του κελιού Β2 για Α1=2. Για Α1=4, η συνάρτηση επιστρέφει το κείμενο "Σήμερα".

Παρακαλούμε, υποστηρίξτε μας!