Πληροφοριακές συναρτήσεις

Αυτή η κατηγορία περιλαμβάνει τις συναρτήσεις Πληροφορίες.

Για να έχετε πρόσβαση σε αυτήν τη λειτουργία...

Εισαγωγή - Συνάρτηση- Κατηγορία Πληροφορίες


Τα δεδομένα στον ακόλουθο πίνακα εξυπηρετούν ως η βάση για μερικά από τα παραδείγματα στις περιγραφές των συναρτήσεων:

C

D

2

τιμή x

τιμή y

3

-5

-3

4

-2

0

5

-1

1

6

0

3

7

2

4

8

4

6

9

6

8


CELL

Επιστρέφει πληροφορίες για τη διεύθυνση, τη μορφοποίηση ή τα περιεχόμενα ενός κελιού.

Σύνταξη

CELL("ΤύποςΠληροφοριών" [; Αναφορά])

ΤύποςΠληροφορίας είναι η συμβολοσειρά χαρακτήρων που καθορίζει τον τύπο των πληροφοριών. Η συμβολοσειρά χαρακτήρων είναι πάντα στην αγγλική γλώσσα. Η χρήση πεζών ή κεφαλαίων γραμμάτων είναι προαιρετική.

ΤύποςΠληροφορίας

Σημαίνει

COL

Επιστρέφει τον αριθμό της στήλης παραπομπής.

Η =CELL("COL";D2) επιστρέφει 4.

ROW

Επιστρέφει τον αριθμό της γραμμής παραπομπής.

Η =CELL("ROW";D2) επιστρέφει 2.

SHEET

Επιστρέφει τον αριθμό του φύλλου παραπομπής.

Το =CELL("Sheet";Sheet3.D2) επιστρέφει 3.

ADDRESS

Επιστρέφει την απόλυτη διεύθυνση του κελιού της αναφοράς.

Το =CELL("ADDRESS";D2) επιστρέφει $D$2.

Η =CELL("ADDRESS";Sheet3.D2) επιστρέφει $Sheet3.$D$2.

=CELL("ADDRESS";'X:\dr\test.ods'#$Sheet1.D2) επιστρέφει 'file:///X:/dr/test.ods'#$Sheet1.$D$2.

FILENAME

Επιστρέφει το όνομα αρχείου και τον αριθμό φύλλου του κελιού της αναφοράς.

Το =CELL("FILENAME";D2) επιστρέφει 'file:///X:/dr/own.ods'#$Sheet1, αν ο τύπος στο τρέχον έγγραφο X:\dr\own.ods βρίσκεται στο Φύλλο1.

Το =CELL("FILENAME";'X:\dr\test.ods'#$Sheet1.D2) επιστρέφει 'file:///X:/dr/test.sxc'#$Sheet1.

COORD

Επιστρέφει την πλήρη διεύθυνση κελιού με συμβολισμό Lotus™.

Η =CELL("COORD"; D2) επιστρέφει $A:$D$2.

Η =CELL("COORD"; Sheet3.D2) επιστρέφει $C:$D$2.

CONTENTS

Επιστρέφει τα περιεχόμενα του κελιού αναφοράς, χωρίς μορφοποίηση.

TYPE

Επιστρέφει τον τύπο των περιεχομένων του κελιού.

b = κενό. άδειο κελί

l = ετικέτα. Κείμενο, αποτέλεσμα ενός τύπου ως κείμενο

v = τιμή. Τιμή, αποτέλεσμα ενός τύπου ως αριθμός

WIDTH

Επιστρέφει το πλάτος της στήλης αναφοράς. Η μονάδα είναι ο αριθμός των μηδενικών (0) που χωράνε στη στήλη, στο προεπιλεγμένο κείμενο και στο προεπιλεγμένο μέγεθος.

PREFIX

Επιστρέφει τη στοίχιση του κελιού αναφοράς.

' = αριστερή στοίχιση ή αριστερή πλήρης στοίχιση

" = δεξιά στοίχιση

^ = στοίχιση στο κέντρο

\ =επανάληψη (ανενεργό προς το παρόν)

PROTECT

Επιστρέφει την κατάσταση της προστασίας κελιών για το κελί.

1 = το κελί προστατεύεται

0 = το κελί δεν προστατεύεται

FORMAT

Επιστρέφει ένα χαρακτήρα συμβολοσειράς που υποδηλώνει τη μορφή του αριθμού.

, = αριθμός με διαχωριστικό χιλιάδων

F = αριθμός χωρίς διαχωριστικό χιλιάδων

C = Μορφή νομίσματος

S = εκθετική απεικόνιση, για παράδειγμα, 1,234+E56

P = ποσοστό

Στις παραπάνω μορφοποιήσεις, ο αριθμός των δεκαδικών θέσεων μετά το δεκαδικό διαχωριστικό δίνεται ως αριθμός. Παράδειγμα: η μορφή αριθμού #,##0.0 επιστρέφει ,1 και η μορφή αριθμού 00.000% επιστρέφει P3

D1 = MMM-D-YY, MM-D-YY και παρόμοιες μορφές

D2 = ΗΗ-ΜΜ

D3 = ΜΜ-ΕΕ

D4 = ΗΗ-ΜΜ-ΕΕΕΕ ΩΩ:ΛΛ:ΔΔ

D5 = ΜΜ-ΗΗ

D6 = ΩΩ:ΛΛ:ΔΔ ΠΜ/ΜΜ

D7 = ΩΩ:ΛΛ ΠΜ/ΜΜ

D8 = ΩΩ:ΛΛ:ΔΔ

D9 = ΩΩ:ΛΛ

G = Όλες οι άλλες μορφές

- (μείον) στο τέλος = οι αρνητική αριθμοί μορφοποιούνται έγχρωμα

() παρενθέσεις) στο τέλος = υπάρχει μία ανοικτή παρένθεση στον κώδικα μορφοποίησης

COLOR

Επιστρέφει 1, αν αρνητικές τιμές έχουν μορφοποιηθεί με κόκκινο, αλλιώς επιστρέφει 0.

PARENTHESES

Επιστρέφει 1 αν ο κώδικας μορφοποίησης περιέχει άνοιγμα παρένθεσης (, αλλιώς 0.


Αναφορά (κατάλογος επιλογών) είναι η θέση του κελιού που θα εξεταστεί. Αν η Αναφορά είναι περιοχή, το κελί μετακινείται στο πάνω αριστερά μέρος της περιοχής. Αν λείπει η Αναφορά, το LibreOffice Calc χρησιμοποιεί τη θέση του κελιού στο οποίο βρίσκεται ο τύπος. Το Microsoft Excel χρησιμοποιεί την αναφορά του κελιού στο οποίο βρίσκεται ο δρομέας.

CURRENT

Αυτή η συνάρτηση επιστρέφει το αποτέλεσμα στην ημερομηνία αξιολόγησης του τύπου του οποίου είναι μέρος (με άλλα λόγια, το αποτέλεσμα όπου έχει φτάσει η αξιολόγηση). Χρησιμοποιείται κυρίως μαζί με την συνάρτηση STYLE() για την εφαρμογή επιλεγμένων τεχνοτροπιών σε ένα κελί ανάλογα με τα περιεχόμενα του κελιού.

Σύνταξη

CURRENT()

Παράδειγμα

=1+2+CURRENT()

Το παράδειγμα επιστρέφει 6. Ο τύπος υπολογίζεται από αριστερά στα δεξιά ως: 1 + 2 ισούται 3, και δίνει το αποτέλεσμα στην ημερομηνία όταν εμφανίζεται η CURRENT()· έτσι η CURRENT() δίνει 3, το οποίο προστίθεται στο αρχικό 3 και μας δίνει αποτέλεσμα 6.

=A2+B2+STYLE(IF(CURRENT()>10;"Κόκκινο";"Προεπιλογή"))

Το παράδειγμα δίνει αποτέλεσμα A2 + B2 (το STYLE δίνει 0 εδώ). Αν αυτό το άθροισμα είναι μεγαλύτερο από 10, στο κελί εφαρμόζεται το πρότυπο Κόκκινο. Δείτε τη συνάρτηση STYLE για περισσότερες εξηγήσεις.

="choo"&CURRENT()

Το παράδειγμα δίνεις ως αποτέλεσμα choochoo.

Τεχνικές πληροφορίες

Αυτή η συνάρτηση δεν αποτελεί μέρος του προτύπου Open Document Format for Office Applications (OpenDocument) Έκδοση 1.3. Μέρος 4: Μορφή επανυπολογισμένου τύπου (OpenFormula). Ο χώρος του ονόματος είναι

ORG.OPENOFFICE.CURRENT

FORMULA

Εμφανίζει τον τύπο ενός κελιού με τύπο ως συμβολοσειρά κειμένου.

Αυτή η συνάρτηση επανυπολογίζεται πάντα, όταν συμβαίνει επανυπολογισμός.

Σύνταξη

FORMULA(Παραπομπή)

Η Παραπομπή είναι μία αναφορά σε ένα κελί που περιέχει τύπο.

Μια μη έγκυρη παραπομπή ή μια παραπομπή σε κελί χωρίς τύπο έχει σαν αποτέλεσμα την τιμή σφάλματος #N/A.

Παράδειγμα

Αν το κελί Α8 περιέχει τον τύπο =SUM(1;2;3) τότε

η =FORMULA(A8) επιστρέφει το κείμενο =SUM(1;2;3).

IFERROR

Επιστρέφει την τιμή εάν το κελί δεν περιέχει τιμή σφάλματος ή την εναλλακτική τιμή εάν περιέχει.

tip

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.0.


Σύνταξη

IFERROR(Τιμή; εναλλακτική_τιμή)

Τιμή είναι η τιμή ή η παράσταση που επιστρέφεται αν δεν είναι ίση ή καταλήγει σε σφάλμα.

Εναλλακτική_τιμή είναι η τιμή ή παράσταση που επιστρέφεται, εάν η παράσταση ή η τιμή της Τιμής είναι ίση ή καταλήγει σε σφάλμα.

Παράδειγμα

Το =IFERROR(C8;C9) όπου το κελί C8 περιέχει το =1/0 επιστρέφει την τιμή του C9, επειδή το 1/0 είναι λάθος.

Το =IFERROR(C8;C9) όπου το κελί C8 περιέχει το =13 επιστρέφει 13, την τιμή του C8, που δεν είναι σφάλμα.

IFNA

Επιστρέφει την τιμή εάν το κελί δεν περιέχει την τιμή σφάλματος #Δ/Υ (η τιμή δεν είναι διαθέσιμη) ή την εναλλακτική τιμή εάν περιέχει.

tip

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.0.


Σύνταξη

IFNA(Τιμή; εναλλακτική_τιμή)

Τιμή είναι η τιμή ή η παράσταση που επιστρέφεται εάν δεν είναι ίση ή καταλήγει σε σφάλμα #N/A.

Εναλλακτική_τιμή είναι η τιμή ή η παράσταση που επιστρέφεται, εάν η παράσταση ή η τιμή του Τιμή είναι ίση ή καταλήγει σε ένα σφάλμα #N/A.

Παράδειγμα

=IFNA(D3;D4) επιστρέφει την τιμή του D3, εάν το D3 δεν καταλήγει σε ένα σφάλμα #N/A ή το D4 αν καταλήγει σε σφάλμα.

INFO

Επιστρέφει συγκεκριμένες πληροφορίες σχετικά με το τρέχον περιβάλλον εργασίας. Η συνάρτηση δέχεται ένα όρισμα κειμένου και επιστρέφει δεδομένα ανάλογα με αυτή την παράμετρο.

Αυτή η συνάρτηση επανυπολογίζεται πάντα, όταν συμβαίνει επανυπολογισμός.

Σύνταξη

INFO("Τύπος")

Ο παρακάτω πίνακας αναφέρει όλες τις τιμές για την παράμετρο κειμένου Τύπος και τις τιμές που επιστρέφει η συνάρτηση INFO.

Τιμή για τον "Τύπο"

Επιστρεφόμενη τιμή

"osversion"

Πάντα "Windows (32-bit) NT 5.01", για λόγους συμβατότητας

"system"

Ο τύπος του λειτουργικού συστήματος:
"ANDROID" για το λειτουργικό σύστημα Google για κινητά
"DRAGONFLY" για το λειτουργικό σύστημα DragonFly που διαχωρίστηκε από το FreeBSD
"EMSCRIPTEN" για το σύστημα περιήγησης WebAssembly
"FREEBSD ", "OPENBSD" ή "NETBSD" για λειτουργικά συστήματα που βασίζονται στο Berkeley Software Distribution (BSD)
"HAIKU" για συμβατό λειτουργικό σύστημα BeOS
"iOS" για λειτουργικό σύστημα κινητής τηλεφωνίας Apple
" LINUX" για λειτουργικά συστήματα που βασίζονται σε GNU/Linux
"MACOSX" για Apple macOS
"SOLARIS" για λειτουργικό σύστημα Oracle Solaris
"WNT" για Microsoft Windows

"release"

Το αναγνωριστικό έκδοσης της εφαρμογής, για παράδειγμα "300m25(Build:9876)"

"numfile"

Πάντα 1, για λόγους συμβατότητας

"recalc"

Τρέχουσα κατάσταση επανάληψης υπολογισμού τύπων, είτε "Αυτόματα" ή "Χειροκίνητα" (προσαρμοσμένο στη γλώσσα του LibreOffice)


note

Άλλες εφαρμογές λογιστικών φύλλων μπορεί να δέχονται τοπικές τιμές (στα ελληνικά) για την παράμετρο Τύπος αλλά το LibreOffice Calc δέχεται τις τιμές μόνο στα Αγγλικά.


Παράδειγμα

Το =INFO("release") επιστρέφει τον αριθμό έκδοσης του LibreOffice.

=INFO(D5) με το κελί D5 να περιέχει ένα αλφαριθμητικό κειμένου system επιστρέφει το τύπο της διεργασίας συστήματος.

ISBLANK

Επιστρέφει TRUE αν η παραπομπή σε ένα κελί είναι κενή. Αυτή η συνάρτηση χρησιμοποιείται για να καθορίσει αν το περιεχόμενο ενός κελιού είναι κενό. Ένα κελί με τύπο μέσα δεν είναι κενό.

Αν συμβεί κάποιο λάθος, η συνάρτηση επιστρέφει μια λογική ή αριθμητική τιμή.

Σύνταξη

ISBLANK(Τιμή)

Τιμή είναι το περιεχόμενο που θα ελεγχθεί.

Παράδειγμα

Η =ISBLANK(D2) επιστρέφει ως αποτέλεσμα FALSE.

ISERR

Ελέγχει για συνθήκες σφάλματος, εκτός από τη τιμή σφάλματος #N/A και επιστρέφει την TRUE ή FALSE.

Αν συμβεί κάποιο λάθος, η συνάρτηση επιστρέφει μια λογική ή αριθμητική τιμή.

Σύνταξη

ISERR(Τιμή)

Η Τιμή είναι οποιαδήποτε τιμή ή παράσταση που ελέγχεται για να καθοριστεί εάν υπάρχει παρούσα τιμή σφάλματος πέρα από την #N/Α.

Παράδειγμα

Το =ISERR(C8) όπου το κελί C8 περιέχει το =1/0 επιστρέφει TRUE, επειδή το 1/0 είναι λάθος.

Το =ISERR(C9) όπου το κελί C9 περιέχει το =NA() επιστρέφει FALSE επειδή η ISERR() αγνοεί το σφάλμα #N/A.

ISERROR

Ελέγχει για συνθήκες σφάλματος, περιλαμβανομένης της τιμής σφάλματος #N/A και επιστρέφει TRUE ή FALSE.

Αν συμβεί κάποιο λάθος, η συνάρτηση επιστρέφει μια λογική ή αριθμητική τιμή.

Σύνταξη

ISERROR(Τιμή)

Τιμή είναι ή αναφέρεται στην τιμή που θα ελεγχθεί. Η ISERROR() επιστρέφει TRUE αν υπάρχει σφάλμα και FALSE αν όχι.

Παράδειγμα

Το =ISERROR(C8) όπου το κελί C8 περιέχει το =1/0 επιστρέφει TRUE, επειδή το 1/0 είναι λάθος.

Το =ISERROR(C9) όπου το κελί C9 περιέχει το =NA() επιστρέφει TRUE.

ISEVEN

Επιστρέφει TRUE αν η τιμή είναι άρτιος ακέραιος, ή FALSE αν η τιμή είναι περιττός.

Σύνταξη

ISEVEN(Τιμή)

Τιμή είναι η τιμή που θα ελεγχθεί.

Αν η Τιμή δεν είναι ακέραιος, τότε τα ψηφία μετά την υποδιαστολή θα αγνοηθούν. Επίσης, δεν λαμβάνεται υπόψη το πρόσημο της τιμής.

Παράδειγμα

Η συνάρτηση =ISEVEN(48) επιστρέφει ως αποτέλεσμα TRUE.

Η συνάρτηση =ISEVEN(33) επιστρέφει ως αποτέλεσμα FALSE

Η συνάρτηση =ISEVEN(0) επιστρέφει ως αποτέλεσμα TRUE

Η συνάρτηση =ISEVEN(-2.1) επιστρέφει ως αποτέλεσμα TRUE

Η συνάρτηση =ISEVEN(3.999) επιστρέφει ως αποτέλεσμα FALSE

ISEVEN_ADD

Ελέγχει για άρτιους αριθμούς. Επιστρέφει 1, εάν ο αριθμός διαιρεθεί δια του 2 και δώσει ακέραιο αριθμό.

note

Οι συναρτήσεις των οποίων τα ονόματα τελειώνουν με _ADD ή _EXCEL2003 επιστρέφουν τα ίδια αποτελέσματα όπως οι αντίστοιχες συναρτήσεις του Microsoft Excel 2003 χωρίς την κατάληξη . Χρησιμοποιήστε τις συναρτήσεις χωρίς κατάληξη για να πάρετε αποτελέσματα βασισμένα στα διεθνή πρότυπα.


Σύνταξη

ISEVEN_ADD (Αριθμός)

Αριθμός είναι ο αριθμός που θα ελεγχθεί.

Παράδειγμα

Το =ISEVEN_ADD(5) επιστρέφει 0.

Το =ISEVEN_ADD(A1) επιστρέφει 1 αν το κελί Α1 περιέχει τον αριθμό 2.

ISFORMULA

Επιστρέφει την τιμή TRUE εάν το κελί είναι κελί τύπου.

Αν συμβεί κάποιο λάθος, η συνάρτηση επιστρέφει μια λογική ή αριθμητική τιμή.

Σύνταξη

ISFORMULA(Παραπομπή)

Η Παραπομπή υποδηλώνει την παραπομπή σε ένα κελί στο οποίο θα διενεργηθεί έλεγχος για να καθοριστεί εάν περιέχει τύπο.

Παράδειγμα

Το =ISFORMULA(C4) επιστρέφει FALSE αν το κελί C4 περιέχει τον αριθμό 5.

ISLOGICAL

Ελέγχει για μια λογική τιμή (TRUE ή FALSE).

Αν υπάρξει κάποιο σφάλμα, η συνάρτηση επιστρέφει την τιμή FALSE.

Σύνταξη

ISLOGICAL(Τιμή)

Επιστρέφει TRUE αν η Τιμή είναι λογική τιμή (TRUE ή FALSE), αλλιώς επιστρέφει FALSE.

Παράδειγμα

Το =ISLOGICAL(99) επιστρέφει FALSE, επειδή το 99 είναι αριθμός και όχι λογική τιμή.

Το =ISLOGICAL(ISNA(D4)) επιστρέφει TRUE όποια και αν είναι τα περιεχόμενα του κελιού D4, επειδή η ISNA() επιστρέφει λογική τιμή.

ISNA

Επιστρέφει την τιμή TRUE εάν ένα κελί περιέχει την τιμή σφάλματος #N/A (δεν υπάρχει).

Αν υπάρξει κάποιο σφάλμα, η συνάρτηση επιστρέφει την τιμή FALSE.

Σύνταξη

ISNA(Τιμή)

Τιμή είναι η τιμή ή η παράσταση που θα ελεγχθεί.

Παράδειγμα

Η =ISNA(D3) επιστρέφει ως αποτέλεσμα την τιμή FALSE.

ISNONTEXT

Ελέγχει εάν τα περιεχόμενα του κελιού είναι κείμενο ή αριθμοί και επιστρέφει FALSE, εάν τα περιεχόμενα είναι κείμενο.

Αν υπάρξει κάποιο σφάλμα, η συνάρτηση επιστρέφει την τιμή TRUE.

Σύνταξη

ISNONTEXT(Τιμή)

Η Τιμή είναι οποιαδήποτε τιμή ή παράσταση που ελέγχεται για να καθοριστεί εάν είναι κείμενο ή αριθμοί ή λογική τιμή.

Παράδειγμα

Το =ISNONTEXT(D2) επιστρέφει FALSE αν το κελί D2 περιέχει το κείμενο abcdef.

Το =ISNONTEXT(D9) επιστρέφει TRUE αν το κελί D9 περιέχει τον αριθμό 8.

ISNUMBER

Επιστρέφει TRUE, εάν η τιμή αναφέρεται σε αριθμό.

Αν συμβεί κάποιο λάθος, η συνάρτηση επιστρέφει μια λογική ή αριθμητική τιμή.

Σύνταξη

ISNUMBER(Τιμή)

Τιμή είναι μια παράσταση που θα ελεγχθεί για να διαπιστωθεί εάν πρόκειται για αριθμό ή κείμενο.

Παράδειγμα

Το =ISNUMBER(C3) επιστρέφει TRUE αν το κελί C3 περιέχει τον αριθμό 4.

Το =ISNUMBER(C2) επιστρέφει FALSE αν το κελί C2 περιέχει το κείμενο abcdef.

ISODD

Επιστρέφει TRUE αν η τιμή είναι περιττή ή FALSE αν ο αριθμός είναι άρτιος.

Σύνταξη

ISODD(τιμή)

Τιμή είναι η τιμή που θα ελεγχθεί.

Αν η Τιμή δεν είναι ακέραιος τότε τα ψηφία μετά την υποδιαστολή θα αγνοηθούν. Επίσης, δεν λαμβάνεται υπόψη το πρόσημο της Τιμής.

Παράδειγμα

Η συνάρτηση =ISODD(33) επιστρέφει ως αποτέλεσμα TRUE

Η συνάρτηση =ISODD(48) επιστρέφει ως αποτέλεσμα FALSE

Η συνάρτηση =ISODD(3.999) επιστρέφει ως αποτέλεσμα TRUE

Η συνάρτηση =ISODD(-3.1) επιστρέφει ως αποτέλεσμα TRUE

ISODD_ADD

Επιστρέφει TRUE (1), εάν ο αριθμός δεν δίνει έναν ακέραιο αριθμό όταν διαιρεθεί με το 2.

note

Οι συναρτήσεις των οποίων τα ονόματα τελειώνουν με _ADD ή _EXCEL2003 επιστρέφουν τα ίδια αποτελέσματα όπως οι αντίστοιχες συναρτήσεις του Microsoft Excel 2003 χωρίς την κατάληξη . Χρησιμοποιήστε τις συναρτήσεις χωρίς κατάληξη για να πάρετε αποτελέσματα βασισμένα στα διεθνή πρότυπα.


Σύνταξη

ISODD_ADD(Αριθμός)

Αριθμός είναι η τιμή που θα ελεγχθεί.

Παράδειγμα

Το =ISODD_ADD(5) επιστρέφει 1.

ISREF

Ελέγχει αν το όρισμα είναι παραπομπή. Επιστρέφει TRUE αν το όρισμα είναι παραπομπή, αλλιώς επιστρέφει FALSE. Όταν δίδεται μια παραπομπή, αυτή η συνάρτηση δεν εξετάζει την τιμή στην οποία γίνεται παραπομπή.

Αν συμβεί κάποιο λάθος, η συνάρτηση επιστρέφει μια λογική ή αριθμητική τιμή.

Σύνταξη

ISREF(τιμή)

Τιμή είναι η τιμή που θα ελεγχθεί για να καθοριστεί εάν πρόκειται για παραπομπή.

Παράδειγμα

Το =ISREF(C5) επιστρέφει το αποτέλεσμα TRUE επειδή το C5 είναι μια έγκυρη παραπομπή.

Το =ISREF("abcdef") επιστρέφει πάντα FALSE επειδή ένα κέιμενο δεν μπορεί ποτέ να είναι παραπομπή.

Το =ISREF(4) επιστρέφει FALSE.

Το =ISREF(INDIRECT("A6")) επιστρέφει TRUE επειδή η INDIRECT είναι μια συνάρτηση που επιστρέφει παραπομπή.

Το =ISREF(ADDRESS(1; 1; 2;"Sheet2")) επιστρέφει FALSE, επειδή η ADDRESS είναι μια συνάρτηση που επιστρέφει κείμενο, παρόλο που μοιάζει με παραπομπή.

ISTEXT

Επιστρέφει την τιμή TRUE, εάν τα περιεχόμενα του κελιού αναφέρονται σε κείμενο.

Αν υπάρξει κάποιο σφάλμα, η συνάρτηση επιστρέφει την τιμή FALSE.

Σύνταξη

ISTEXT(Τιμή)

Τιμή είναι μια τιμή, ένας αριθμός, μια λογική τιμή ή μια τιμή σφάλματος που θα ελεγχθεί.

Παράδειγμα

Το =ISTEXT(D9) επιστρέφει TRUE αν το κελί D9 περιέχει το κείμενο abcdef.

Το =ISTEXT(C3) επιστρέφει FALSE αν το κελί C3 περιέχει τον αριθμό 3.

N

Επιστρέφει την αριθμητική τιμή της δοσμένης παραμέτρου. Επιστρέφει 0 εάν η παράμετρος είναι κείμενο ή FALSE.

Εάν συμβεί σφάλμα η συνάρτηση επιστρέφει την τιμή σφάλμα.

Σύνταξη

N(Τιμή)

Τιμή είναι η παράμετρος που μετατρέπεται σε αριθμό. Το N() επιστρέφει την αριθμητική τιμή εάν μπορεί. Επιστρέφει τις λογικές τιμές TRUE και FALSE ως 1 και 0 αντίστοιχα. Επιστρέφει κείμενο ως 0.

Παράδειγμα

Η =N(123) επιστρέφει ως αποτέλεσμα 123

Η =N(TRUE()) επιστρέφει 1

Η =N(FALSE()) επιστρέφει 0

Η =N("abc") επιστρέφει ως αποτέλεσμα 0

=N(1/0) επιστρέφει #DIV/0!

NA

Επιστρέφει την τιμή σφάλματος #N/A.

Σύνταξη

NA()

Παράδειγμα

Η =NA() μετατρέπει τα περιεχόμενα του κελιού σε #N/Α.

TYPE

Επιστρέφει τον τύπο της τιμής, όπου 1 = αριθμός, 2 = κείμενο, 4 = τιμή Μπουλ, 8 = τύπος, 16 = τιμή σφάλματος, 64 =πίνακας.

Αν συμβεί κάποιο λάθος, η συνάρτηση επιστρέφει μια λογική ή αριθμητική τιμή.

Σύνταξη

TYPE(Τιμή)

Τιμή είναι μια συγκεκριμένη τιμή για την οποία καθορίζεται ο τύπος δεδομένων.

Παράδειγμα (δείτε τον πίνακα του παραπάνω παραδείγματος)

Η =TYPE(C2) επιστρέφει ως αποτέλεσμα 2.

Η =TYPE(D9) επιστρέφει ως αποτέλεσμα 1.

Παρακαλούμε, υποστηρίξτε μας!