Συνάρτηση Str

Η συνάρτηση Str μετατρέπει τα περιεχόμενα των μεταβλητών σε συμβολοσειρά. Χειρίζεται αριθμητικές τιμές, ημερομηνίες, συμβολοσειρές και τιμές νομισμάτων.

Non-negative numbers are preceded by a blank space. Negative numbers are preceded by a minus sign.

Για αριθμητικές τιμές, η συμβολοσειρά που επιστρέφεται από τη συνάρτηση Str είναι ανεξάρτητη από τις τοπικές ρυθμίσεις. Ως εκ τούτου, η τελεία χρησιμοποιείται ως διαχωριστικό δεκαδικών όταν χρειάζεται.

Εάν μια συμβολοσειρά μεταβιβαστεί ως όρισμα, επιστρέφεται χωρίς αλλαγές.

Οι ημερομηνίες μετατρέπονται σε συμβολοσειρές που εξαρτώνται από τις τοπικές ρυθμίσεις.

Σύνταξη:


    Str (Τιμή ως μεταβλητή)

Return type:

String

Παράμετροι:

Τιμή: Οποιαδήποτε τιμή πρέπει να μετατραπεί σε συμβολοσειρά.

Κωδικοί σφάλματος:

5 Άκυρη κλήση διαδικασίας

Παράδειγμα:

Ακολουθούν ορισμένα αριθμητικά παραδείγματα που χρησιμοποιούν τη συνάρτηση Str.


    Sub ExampleStr_1
        ' Σημειώστε το κενό διάστημα στην αρχή των συμβολοσειρών που επιστρέφονται
        MsgBox Str(10) ' " 10"
        MsgBox Str(10.5) ' " 10.5"
        MsgBox Str(-12345 + 1.3) ' "-12346.3"
        MsgBox Str(10000 / 3) '  " 3333.33333333333"
        ' Οι συμβολοσειρές που περνούν ως ορίσματα παραμένουν αμετάβλητες
        MsgBox Str("A123") ' "A123"
    End Sub

Χρησιμοποιήστε τη συνάρτηση LTrim για να αφαιρέσετε το κενό διάστημα στην αρχή της συμβολοσειράς που επιστρέφεται.


    Sub ExampleStr_2
        MsgBox Str(10.5) ' " 10.5"
        MsgBox LTrim(Str(10.5)) ' "10.5"
    End Sub

Η συνάρτηση Str μπορεί επίσης να χειριστεί μεταβλητές Date.


    Sub ExampleStr_3
        Dim aDate as Date, aTime as Date
        aDate = DateSerial(2021, 12, 20)
        aTime = TimeSerial(10, 20, 45)
        Print Str(aDate) ' "12/20/2021"
        Print Str(aTime) ' "10:20:45"
    End sub

Συνάρτηση Val