Παραδείγματα προγραμματισμού στοιχείων ελέγχου στον επεξεργαστή διαλόγου

Τα ακόλουθα παραδείγματα είναι για ένα νέο διάλογο που ονομάζεται "Dialog1". Χρησιμοποιήστε τα εργαλεία της γραμμής Εργαλειοθήκη του επεξεργαστή διαλόγου για να δημιουργήσετε τον διάλογο και να προσθέσετε τα παρακάτω πεδία ελέγχου: ένα Πλαίσιο ελέγχου με το όνομα "CheckBox1", ένα Πεδίο ετικέτας με το όνομα "Label1", ένα Κουμπί με το όνομα "CommandButton1", και ένα Πλαίσιο καταλόγου με το όνομα "ListBox1".

Χρησιμοποιήστε μια σταθερή γραφή πεζών και κεφαλαίων κατά την προσάρτηση ενός πεδίου ελέγχου σε κάποια μεταβλητή αντικειμένου.

Καθολική συνάρτηση για φόρτωση διαλόγων


Function LoadDialog(Libname as String, DialogName as String, Optional oLibContainer)
Dim oLib as Object ' com.sun.star.script.XLibraryContainer
Dim oLibDialog as Object
Dim oRuntimeDialog as Object
    If IsMissing(oLibContainer) Then
        oLibContainer = DialogLibraries
    End If
    oLibContainer.LoadLibrary(LibName)
    oLib = oLibContainer.GetByName(Libname)
    oLibDialog = oLib.GetByName(DialogName)
    oRuntimeDialog = CreateUnoDialog(oLibDialog)
    LoadDialog() = oRuntimeDialog
End Function

Η συνάρτηση LoadDialog αποθηκεύεται στο Tools.ModuleControls που διατίθεται από τις μακροεντολές εφαρμογών και τους διαλόγους.

Εμφάνιση διαλόγου


REM γενικός ορισμός μεταβλητών
Dim oDialog1 AS Object
Sub StartDialog1
    With GlobalScope.BasicLibraries
       If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
    End With
    oDialog1 = Tools.ModuleControls.LoadDialog("Standard", "Dialog1")
    oDialog1.Execute()
End Sub

Ανάγνωση ή επεξεργασία ιδιοτήτων πεδίων ελέγχου στο πρόγραμμα


Sub Sample1
    With GlobalScope.Basiclibraries
       If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
    End With
    oDialog1 = Tools.LoadDialog("Standard", "Dialog1")
    REM λήψη προτύπου διαλόγου
    oDialog1Model = oDialog1.Model
    REM προβολή κειμένου της ετικέτας1
    oLabel1 = oDialog1.GetControl("Label1")
    MsgBox oLabel1.Text
    REM ορισμός νέου κειμένου για τον έλεγχο ετικέτας1
    oLabel1.Text = "Νέα αρχεία"
    REM εμφάνιση ιδιοτήτων προτύπου για τον έλεγχο ΠλαίσιοΕλέγχου1
    oCheckBox1Model = oDialog1Model.CheckBox1
    MsgBox oCheckBox1Model.Dbg_Properties
    REM ορισμός νέας κατάστασης για το ΠλαίσιοΕλέγχου1 για το πρότυπο ελέγχου
    oCheckBox1Model.State = 1
    REM εμφάνιση ιδιοτήτων προτύπου για τον έλεγχο ΠλήκτροΔιαταγής1
    oCMD1Model = oDialog1Model.CommandButton1
    MsgBox oCMD1Model.Dbg_Properties
    REM εμφάνιση ιδιοτήτων του ελέγχου ΠλήκτροΔιαταγής1
    oCMD1 = oDialog1.GetControl("CommandButton1")
    MsgBox oCMD1.Dbg_Properties
    REM εκτέλεση διαλόγου
    oDialog1.Execute()
End Sub

Προσθήκη καταχώρισης σε ένα πλαίσιο καταλόγου


Sub AddEntry
    With GlobalScope.Basiclibraries
       If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
    End With
    oDialog1 = ModuleControls.LoadDialog("Standard", "Dialog1")
    REM προσθέτει μια νέα καταχώριση στο ΠλαίσιοΚαταλόγου
    oDialog1Model = oDialog1.Model
    oListBox = oDialog1.GetControl("ListBox1")
    Dim iCount as integer
    iCount = oListbox.ItemCount
    oListbox.additem("Νέο στοιχείο" & iCount,0)
End Sub

Διαγραφή καταχώρισης από ένα πλαίσιο καταλόγου


Sub RemoveEntry
    With GlobalScope.Basiclibraries
       If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
    End With
    oDialog1 = Tools.ModuleControls.LoadDialogLoadDialog("Standard", "Dialog1")
    REM αφαιρεί την πρώτη καταχώριση από το ΠλαίσιοΚαταλόγου
    oDialog1Model = oDialog1.Model
    oListBox = oDialog1.GetControl("ListBox1")
    oListbox.removeitems(0,1)
End Sub

Αλλαγή των ιδιοτήτων των πεδίων ελέγχου στον επεξεργαστή διαλόγου

Δημιουργία διαλόγου Basic

Δημιουργία ελέγχων στον επεξεργαστή διαλόγου

Άνοιγμα διαλόγου με Basic