SUMMEWENNS

Ergibt die Summe der Werte der Zellen in einem Bereich, die mehrere Bedingungen in mehreren Bereichen erfüllen.

Diese Funktion ist seit LibreOffice 4.0 verfügbar.

Syntax

SUMMEWENNS(Funktionsbereich; Bereich 1; Kriterium 1 [; Bereich 2; Kriterium 2] [; … [; Bereich 127; Kriterium 127]])

Funktionsbereich – erforderliches Argument. Ist ein Zellbereich, der Name eines benannten Bereichs oder eine Spalten-/Zeilenüberschrift, der/die Werte enthält, für die die Summe berechnet wird.

Bereich 1 – erforderliches Argument. Ist ein Zellbereich, ein Name eines Bereichs oder eine Spalten-/Zeilenbeschriftung, welche(r) die Werte enthält, die bei erfüllter Bedingung gezählt werden sollen.

Kriterium: Ein Kriterium ist ein einzelner Zellbezug, eine Zahl oder ein Text. Es wird für Vergleiche mit Zellinhalten verwendet.

Ein Verweis auf eine leere Zelle wird als Zahlenwert 0 interpretiert.

Ein passender Ausdruck kann sein:

Eine Zahl oder ein logischer Wert. Ein übereinstimmender Zelleninhalt entspricht dem Zahlenwert oder dem logischen Wert.
Ein Wert, der mit einem Vergleichsoperator beginnt (<, <=, =, >, >=, <>).

Wenn der Wert für = leer ist, entspricht er leeren Zellen.

Wenn der Wert für <> leer ist, entspricht er nicht leeren Zellen.

Wenn der Wert für <> nicht leer ist, entspricht er jedem Zellinhalt außer dem Wert, einschließlich leerer Zellen.

Hinweis: "=0" stimmt nicht mit leeren Zellen überein.

Wenn der Wert für = und <> nicht leer ist und nicht als Zahlentyp oder einer seiner Untertypen interpretiert werden kann und die Eigenschaft Suchkriterien = und <> muss auf ganze Zellen zutreffen markiert ist, erfolgt der Vergleich mit dem gesamten Zellinhalt. Wenn sie nicht markiert ist, wird mit jedem Teil des Felds verglichen, der den Kriterien entspricht. Wenn der Wert für = und <> nicht leer ist und nicht als Zahlentyp oder einer seiner Untertypen interpretiert werden kann.
Anderer Textwert. Wenn die Eigenschaft Suchkriterien = und <> muss für ganze Zellen gelten wahr ist, erfolgt der Vergleich mit dem gesamten Zelleninhalt , wenn falsch, wird mit jedem Unterteil des Felds verglichen, der den Kriterien entspricht. Der Ausdruck kann Text, Zahlen, reguläre Ausdrücke oder Platzhalter enthalten (sofern in den Berechnungsoptionen aktiviert).

Bereich 2 – optional. Für Bereich 2 und folgende gilt dasselbe wie für Bereich 1.

Kriterium 2 – Optional. Kriterium 2 und alle Folgenden bedeutet dasselbe wie Kriterium.

Die Suche unterstützt Platzhalter oder reguläre Ausdrücke. Wenn reguläre Ausdrücke aktiviert sind, können Sie "all.*" eingeben, um beispielsweise das erste Vorkommen von "all", gefolgt von beliebigen Zeichen, zu finden. Wenn Sie nach einem Text suchen möchten, der auch ein regulärer Ausdruck ist, müssen Sie entweder jedem Metazeichen oder Operator eines regulären Ausdrucks ein "\" voranstellen oder den Text in \Q…\E einschließen. Die automatische Auswertung von Platzhaltern oder regulären Ausdrücken können Sie unter – LibreOffice Calc – Berechnen umschalten.

Wenn Sie Funktionen verwenden, bei denen ein oder mehrere Argumente Suchkriterien-Zeichenfolgen sind, die einen regulären Ausdruck darstellen, besteht der erste Versuch darin, die Zeichenfolgen-Kriterien in Zahlen umzuwandeln. Zum Beispiel wird in bestimmten Gebietsschemen ".0" in "0.0" konvertiert und so weiter. Bei Erfolg handelt es sich bei der Übereinstimmung nicht um eine Übereinstimmung mit regulären Ausdrücken, sondern um eine numerische Übereinstimmung. Wenn Sie jedoch zu einem Gebietsschema wechseln, in dem das Dezimaltrennzeichen nicht der Punkt ist, funktioniert die Konvertierung regulärer Ausdrücke. Um die Auswertung des regulären Ausdrucks anstelle eines numerischen Ausdrucks zu erzwingen, verwenden Sie einen Ausdruck, der nicht als numerisch falsch verstanden werden kann, beispielsweise ".[0]" oder ".\0" oder "(?i).0".

Funktionsbereich und Bereich 1, Bereich 2, … müssen alle dieselbe Größe haben, anderenfalls gibt die Funktion den Fehlerwert Err:502 – ungültiges Argument – zurück.

Die logische Beziehung zwischen Bedingungen kann als logisches UND (Konjunktion) definiert werden. In anderen Worten, wenn und nur wenn alle angegebenen Bedingungen zutreffen, wird ein Wert von der zugehörigen Zelle aus dem angegebenen Funktionsbereich in der Berechnung berücksichtigt.

Die Funktion kann bis zu 255 Argumente verarbeiten, bedeutet, dass Sie 127 Bereiche und Bedingungen festlegen können.

Wenn die Zelle WAHR enthält, wird sie wie 1 behandelt, wenn FALSCH, wie 0 (Null).

Diese Funktion ist Teil des OpenDocument-Standards (Open Document Format for Office Applications) Version 1.2. (ISO/IEC 26300:2-2015)

Beispiel

Betrachten Sie folgende Tabelle

	A	B	C
1	Produktname	Absatz	Einnahmen
2	Buntstift	20	65
3	Stift	35	85
4	Schulbuch	20	190
5	Buch	17	180
6	Buntstift-Set	nicht	nicht

In allen unten stehenden Beispielen enthält der Bereich für die Berechnung der Summe die Zeile 6, diese wird aber ignoriert, da sie Text enthält.

Einfache Verwendung

=SUMMEWENNS(B2:B6;B2:B6;">=20")

Berechnet die Summe der Werte im Bereich B2:B6, die größer oder gleich 20 sind. Ergibt 75, da die fünfte Zeile die Bedingung nicht erfüllt.

=SUMMEWENNS(C2:C6;B2:B6;">=20";C2:C6;">70")

Berechnet die Summe der Werte im Bereich C2:C6, die größer als 70 und deren entsprechende Zellwerte im Bereich B2:B6 größer oder gleich 20 sind. Ergibt 275, da die zweite und fünfte Zeile je mindestens eine Bedingung nicht erfüllen.

Verwendung mit regulären Ausdrücken und verschachtelten Funktionen

=SUMMEWENNS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Berechnet die Summe der Werte im Bereich C2:C6, die allen Werten im Bereich B2:B6, außer dem Minimum und dem Maximum, entsprechen. Ergibt 255, da die dritte und fünfte Zeile je mindestens eine Bedingung nicht erfüllen.

=SUMMEWENNS(C2:C6;A2:A6;".*stift";B2:B6;"<"&MAX(B2:B6))

Berechnet die Summe der Werte im Bereich C2:C6, die allen Zellen im Bereich A2:A6, die auf "stift" enden, und allen Zellen im Bereich B2:B6, außer dem Maximum, entsprechen. Ergibt 65, da nur die zweite Zeile alle Bedingungen erfüllt.

Bezüge zu einer Zelle mit einer Bedingung

Um eine Bedingung einfach zu ändern, bietet es sich an, diese in einer separaten Zelle festzulegen und für die Bedingung der Funktion SUMMEWENNS einen Bezug zur Zelle anzugeben. Beispielsweise kann obige Funktion geschrieben werden als:

=SUMMEWENNS(C2:C6;A2:A6;".*"&E2;B2:B6;"<"&MAX(B2:B6))

Wenn E2 = stift ist, ergibt die Funktion 65, da der Bezug zur Zelle derem Inhalt entspricht.

Datei mit Beispiel öffnen:

Wikiseite zu SUMMEWENNS.

SUMME, SUMMEWENN

ZÄHLENWENNS, MINWENNS, MAXWENNS, MITTELWERTWENNS, SUMMEWENNS

Liste der regulären Ausdrücke