Funktion MINWENNS

Gibt das Minimum der Werte der Zellen in einem Bereich zurĂĽck, die mehrere Bedingungen in mehreren Bereichen erfĂĽllen.

Syntax

MINWENNS(Funktionsbereich; Bereich 1; Kriterium 1 [; Bereich 2; Kriterium 2] [; … [; Bereich 127; Kriterium 127]])

Funktionsbereich – erforderliches Argument. Ist ein Zellbereich, der Name eines benannten Bereichs oder eine Spalten-/Zeilenüberschrift, der/die Werte enthält, für die das Minimum berechnet wird.

Bereich 1 – erforderliches Argument. Ist ein Zellbereich, ein Name eines Bereichs oder eine Spalten-/Zeilenbeschriftung, welche(r) die Werte enthält, die bei erfüllter Bedingung gezählt werden sollen.

Kriterium: Ein Kriterium ist ein einzelner Zellbezug, eine Zahl oder ein Text. Es wird fĂĽr Vergleiche mit Zellinhalten verwendet.

Ein Verweis auf eine leere Zelle wird als Zahlenwert 0 interpretiert.

Ein passender Ausdruck kann sein:

Bereich 2 – optional. Für Bereich 2 und folgende gilt dasselbe wie für Bereich 1.

Kriterium 2 – Optional. Kriterium 2 und alle Folgenden bedeutet dasselbe wie Kriterium.

Die Suche unterstützt Platzhalter oder Reguläre Ausdrücke. Wenn "Reguläre Ausdrücke" aktiviert sind, können Sie "ein. *" eingeben, um beispielsweise die erste Position von "ein" gefolgt von beliebigen Zeichen zu finden. Wenn Sie nach einem Text suchen möchten, der auch ein regulärer Ausdruck ist, müssen Sie entweder jedem Zeichen ein "\" voranstellen oder den Text in "\Q … \E" einschließen. Um die automatische Auswertung von Platzhaltern oder regulären Ausdrücken in ein- und ausschalten, wählen Sie – LibreOffice Calc – Berechnen.

warning

Wenn Sie Funktionen verwenden, bei denen ein oder mehrere Argumente Suchkriterien-Zeichenfolgen sind, die einen regulären Ausdruck darstellen, besteht der erste Versuch darin, die Zeichenfolgen-Kriterien in Zahlen umzuwandeln. Zum Beispiel wird in bestimmten Gebietsschemen ".0" in "0.0" konvertiert und so weiter. Bei Erfolg handelt es sich bei der Übereinstimmung nicht um eine Übereinstimmung mit regulären Ausdrücken, sondern um eine numerische Übereinstimmung. Wenn Sie jedoch zu einem Gebietsschema wechseln, in dem das Dezimaltrennzeichen nicht der Punkt ist, funktioniert die Konvertierung regulärer Ausdrücke. Um die Auswertung des regulären Ausdrucks anstelle eines numerischen Ausdrucks zu erzwingen, verwenden Sie einen Ausdruck, der nicht als numerisch falsch verstanden werden kann, beispielsweise ".[0]" oder ".\0" oder "(?i).0".


Funktionsbereich und Bereich 1, Bereich 2, … müssen alle dieselbe Größe haben, anderenfalls gibt die Funktion den Fehlerwert Err:502 – ungültiges Argument – zurück.

note

Die logische Beziehung zwischen Bedingungen kann als logisches UND (Konjunktion) definiert werden. In anderen Worten, wenn und nur wenn alle angegebenen Bedingungen zutreffen, wird ein Wert von der zugehörigen Zelle aus dem angegebenen Funktionsbereich in der Berechnung berücksichtigt.


Die Funktion kann bis zu 255 Argumente verarbeiten, bedeutet, dass Sie 127 Bereiche und Bedingungen angeben können.

Wenn die Zelle WAHR enthält, wird sie wie 1 behandelt, wenn FALSCH, wie 0 (Null).

note

Diese Funktion ist Teil des OpenDocument-Standards (Open Document Format for Office Applications) Version 1.2. (ISO/IEC 26300:2-2015)


Beispiel

Betrachten Sie folgende Tabelle

A

B

C

1

Produktname

Absatz

Einnahmen

2

Buntstift

20

65

3

Stift

35

85

4

Schulbuch

20

190

5

Buch

17

180

6

Buntstift-Set

nicht

nicht


warning

In allen unten stehenden Beispielen enthält der Bereich für die Berechnung der Summe die Zeile 6, diese wird aber ignoriert, da sie Text enthält.


Einfache Benutzung

=MINWENNS(B2:B6;B2:B6;"<20")

Berechnet das Minimum der Werte des Bereichs B2:B6, welche kleiner 20 sind. Gibt 17 zurĂĽck.

=MINWENNS(C2:C6;B2:B6;">=20";C2:C6;">90")

Berechnet das Minimum der Werte des Bereichs C2:C6, welche größer als 90 sind und für deren entsprechende Zellen des Bereichs B2:B6 die Werte größer oder gleich 20 sind. Gibt 190 zurück.

Verwendung mit regulären Ausdrücken und verschachtelten Funktionen

=MINWENNS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Berechnet das Minimum der Werte des Bereichs C2:C6, die allen Werten des Bereichs B2:B6 mit Ausnahme des Minimums und Maximums entsprechen. Gibt 65 zurĂĽck.

=MINWENNS(C2:C6;A2:A6;".*buch";B2:B6;">"&MIN(B2:B6))

Berechnet das Minimum der Werte des Bereichs C2:C6, die allen Zellen des Bereichs A2:A6 mit der Endung "buch" und allen Zellen des Bereichs B2:B6 mit Ausnahme des Minimums entsprechen. Gibt 190 zurĂĽck.

BezĂĽge zu einer Zelle mit einer Bedingung

Falls Sie eine Bedingung einfach ändern möchten, können Sie diese in einer eigenen Zelle festlegen und einen Bezug zu dieser Zelle in der Bedingung der Funktion MINWENNS verwenden. Beispielsweise kann die oben stehende Formel wie folgt umgeschrieben werden:

=MINWENNS(C2:C6;A2:A6;".*"&E2;B2:B6;"<"&MAX(B2:B6))

Wenn E2 = "buch" ist, ergibt die Funktion 180, da der Bezug zur Zelle derem Inhalt entspricht.

Datei mit Beispiel öffnen:

Technical information

tip

Diese Funktion ist seit LibreOffice 5.2 verfĂĽgbar.


This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.MINIFS

Bitte unterstĂĽtzen Sie uns!