Funktion MITTELWERTWENNS

Ergibt das arithmetische Mittel aller Zellen eines Bereichs, die vorgegebene Bedingungen erfĂĽllen. Die Funktion MITTELWERTWENNS addiert alle Werte, welche die Bedingungen erfĂĽllen, und teilt die Summe durch die Anzahl der zutreffenden Zellen.

tip

Diese Funktion ist seit LibreOffice 4.0 verfĂĽgbar.


Syntax

MITTELWERTWENNS(Funktionsbereich; Bereich 1; Kriterium 1 [; Bereich 2; Kriterium 2] [; … [; Bereich 127; Kriterium 127]])

Funktionsbereich – erforderliches Argument. Ist ein Zellbereich, der Name eines benannten Bereichs oder eine Spalten-/Zeilenüberschrift, der/die Werte enthält, für die der Mittelwert berechnet wird.

Bereich 1 – erforderliches Argument. Ist ein Zellbereich, ein Name eines Bereichs oder eine Spalten-/Zeilenbeschriftung, welche(r) die Werte enthält, die bei erfüllter Bedingung gezählt werden sollen.

Kriterium: Ein Kriterium ist ein einzelner Zellbezug, eine Zahl oder ein Text. Es wird fĂĽr Vergleiche mit Zellinhalten verwendet.

Ein Verweis auf eine leere Zelle wird als Zahlenwert 0 interpretiert.

Ein passender Ausdruck kann sein:

Bereich 2 – optional. Für Bereich 2 und folgende gilt dasselbe wie für Bereich 1.

Kriterium 2 – Optional. Kriterium 2 und alle Folgenden bedeutet dasselbe wie Kriterium.

Die Suche unterstützt Platzhalter oder Reguläre Ausdrücke. Wenn "Reguläre Ausdrücke" aktiviert sind, können Sie "ein. *" eingeben, um beispielsweise die erste Position von "ein" gefolgt von beliebigen Zeichen zu finden. Wenn Sie nach einem Text suchen möchten, der auch ein regulärer Ausdruck ist, müssen Sie entweder jedem Zeichen ein "\" voranstellen oder den Text in "\Q … \E" einschließen. Um die automatische Auswertung von Platzhaltern oder regulären Ausdrücken in ein- und ausschalten, wählen Sie – LibreOffice Calc – Berechnen.

warning

Wenn Sie Funktionen verwenden, bei denen ein oder mehrere Argumente Suchkriterien-Zeichenfolgen sind, die einen regulären Ausdruck darstellen, besteht der erste Versuch darin, die Zeichenfolgen-Kriterien in Zahlen umzuwandeln. Zum Beispiel wird in bestimmten Gebietsschemen ".0" in "0.0" konvertiert und so weiter. Bei Erfolg handelt es sich bei der Übereinstimmung nicht um eine Übereinstimmung mit regulären Ausdrücken, sondern um eine numerische Übereinstimmung. Wenn Sie jedoch zu einem Gebietsschema wechseln, in dem das Dezimaltrennzeichen nicht der Punkt ist, funktioniert die Konvertierung regulärer Ausdrücke. Um die Auswertung des regulären Ausdrucks anstelle eines numerischen Ausdrucks zu erzwingen, verwenden Sie einen Ausdruck, der nicht als numerisch falsch verstanden werden kann, beispielsweise ".[0]" oder ".\0" oder "(?i).0".


Funktionsbereich und Bereich 1, Bereich 2, … müssen alle dieselbe Größe haben, anderenfalls gibt die Funktion den Fehlerwert Err:502 – ungültiges Argument – zurück.

note

Die logische Beziehung zwischen Bedingungen kann als logisches UND (Konjunktion) definiert werden. In anderen Worten, wenn und nur wenn alle angegebenen Bedingungen zutreffen, wird ein Wert von der zugehörigen Zelle aus dem angegebenen Funktionsbereich in der Berechnung berücksichtigt.


Die Funktion kann bis zu 255 Argumente verarbeiten, bedeutet, dass Sie 127 Bereiche und Bedingungen angeben können.

Wenn die Zelle WAHR enthält, wird sie wie 1 behandelt, wenn FALSCH, wie 0 (Null).

note

Diese Funktion ist Teil des OpenDocument-Standards (Open Document Format for Office Applications) Version 1.2. (ISO/IEC 26300:2-2015)


Beispiel

Betrachten Sie folgende Tabelle

A

B

C

1

Produktname

Absatz

Einnahmen

2

Buntstift

20

65

3

Stift

35

85

4

Schulbuch

20

190

5

Buch

17

180

6

Buntstift-Set

nicht

nicht


warning

In allen unten stehenden Beispielen enthält der Bereich für die Berechnung der Summe die Zeile 6, diese wird aber ignoriert, da sie Text enthält.


Einfache Verwendung

=MITTELWERTWENNS(B2:B6;B2:B6;">=20")

Berechnet den Mittelwert der Werte im Bereich B2:B6, die größer oder gleich 20 sind. Ergibt 25, da die fünfte Zeile die Bedingung nicht erfüllt.

=MITTELWERTWENNS(C2:C6;B2:B6;">=20";C2:C6;">70")

Berechnet den Mittelwert der Werte im Bereich C2:C6, die größer als 70 und deren entsprechende Zellwerte im Bereich B2:B6 größer oder gleich 20 sind. Ergibt 137,5, da die zweite und fünfte Zeile je mindestens eine Bedingung nicht erfüllen.

Verwendung mit regulären Ausdrücken und verschachtelten Funktionen

=MITTELWERTWENNS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Berechnet den Mittelwert der Werte im Bereich C2:C6, die allen Werten im Bereich B2:B6, auĂźer dem Minimum und dem Maximum, entsprechen. Ergibt 127,5, da die dritte und fĂĽnfte Zeile je mindestens eine Bedingung nicht erfĂĽllen.

=MITTELWERTWENNS(C2:C6;A2:A6;".*stift";B2:B6;"<"&MAX(B2:B6))

Berechnet den Mittelwert der Werte im Bereich C2:C6, die allen Zellen im Bereich A2:A6, die auf "stift" enden, und allen Zellen im Bereich B2:B6, auĂźer dem Maximum, entsprechen. Ergibt 65, da nur die zweite Zeile alle Bedingungen erfĂĽllt.

BezĂĽge zu einer Zelle mit einer Bedingung

Um eine Bedingung einfach zu ändern, bietet es sich an, diese in einer separaten Zelle festzulegen und für die Bedingung der Funktion MITTELWERTWENNS einen Bezug zur Zelle anzugeben. Beispielsweise kann obige Funktion geschrieben werden als:

=MITTELWERTWENNS(C2:C6;A2:A6;".*"&E2;B2:B6;"<"&MAX(B2:B6))

Wenn E2 = stift ist, ergibt die Funktion 65, da der Bezug zur Zelle derem Inhalt entspricht.

Datei mit Beispiel öffnen:

Bitte unterstĂĽtzen Sie uns!