Finanzmathematische Funktionen Teil zwei

So greifen Sie auf diesen Befehl zu:

Einfügen – Funktion… – Kategorie: Finanz


Zurück zu finanzmathematischen Funktionen Teil eins

Weiter zu finanzmathematischen Funktionen Teil drei

KAPZ

Ergibt für einen bestimmten Zeitraum den Zinsbetrag für eine Investition bei regelmäßigen Zahlungen und konstantem Zinssatz (Zinseszins).

Syntax

KAPZ(Zins; Zeitraum; ZZr; BW [; ZW [; Typ]])

Zins bestimmt den periodischen Zinssatz.

P ist der Tilgungszeitraum. P = 1 für den ersten und P = ZZr für den letzten Zeitraum.

ZZr ist die Gesamtzahl von Zeiträumen, in denen regelmäßige Zahlungen (Annuitäten) erfolgen.

BW ist der Barwert in der Reihe von Zahlungen.

ZW (optional) ist der gewünschte (zukünftige) Wert.

Typ (optional) definiert das Fälligkeitsdatum. F = 1 steht für die Zahlung am Anfang eines Zeitraumes und F = 0 für die Zahlung am Ende eines Zeitraumes.

In LibreOffice Calc-Funktionen dürfen Parameter, die als „optional“ gekennzeichnet sind, nur dann ausgelassen werden, wenn ihnen kein weiterer Parameter mehr folgt. So können Sie beispielsweise in einer Funktion mit vier Parametern, von denen die letzten beiden als „optional“ gekennzeichnet sind, den Parameter 4 oder die Parameter 3 und 4 auslassen, jedoch nicht den Parameter 3 allein.

Beispiel

Wie hoch ist die periodische Tilgung bei einem jährlichen Zinssatz von 8,75 % und einem Zahlungszeitraum von 3 Jahren? Der Barwert beträgt 5.000 Währungseinheiten, und es soll stets zu Beginn einer Periode gezahlt werden. Der zukünftige Wert beträgt 8.000 Währungseinheiten.

=KAPZ(8,75 %/12;1;36;5000;8000;1) = -350,99 Währungseinheiten.

KUMKAPITAL

Ergibt den Gesamtbetrag der Tilgungsanteile in einem Zeitraum für eine Investition bei konstantem Zinssatz.

Syntax

KUMKAPITAL(Zins; ZZr; BW; S; E; Typ)

Zins bestimmt den periodischen Zinssatz.

ZZr ist der Zahlungszeitraum mit der Summe der Zeiträume. ZZR kann auch ein nicht ganzzahliger Wert sein.

BW ist der aktuelle Wert in der Reihe von Zahlungen.

S ist der erste Zeitraum.

E ist der letzte Zeitraum.

Typ ist der Fälligkeitstermin der Zahlung am Anfang oder Ende jedes Zeitraumes.

Beispiel

Wie hoch sind die Tilgungsanteile bei einem jährlichen Zinssatz von 5,5 % und 36 Monaten? Der Barwert beträgt 15.000 Währungseinheiten. Es wird der Tilgungsanteil im Zeitraum zwischen der 10. und der 18. Periode berechnet. Die Fälligkeit ist auf das Ende jeder Periode festgesetzt.

=KUMKAPITAL(5,5 %/12;36;10;15000;18;0) = -3669,74 Währungseinheiten. Der Tilgungsanteil zwischen der 10. und 18. Periode beträgt 3.669,74 Währungseinheiten.

KUMKAPITAL_ADD

Berechnet die kumulierte Tilgung eines Darlehens in einem Zeitraum.

note

Die Funktionen, deren Namen mit _ADD oder _EXCEL2003 enden, geben dieselben Ergebnisse zurück wie die entsprechenden Funktionen in Microsoft Excel ohne Endung. Verwenden Sie die Funktionen ohne Endung, um Ergebnisse zu erhalten, die auf internationalen Standards basieren.


Syntax

CUMKAPITAL_ADD(Zins; ZZr; BW; Anfangszeitraum; Endzeitraum; Typ)

Zins ist der Zinssatz für jeden Zeitraum.

ZZr ist die Gesamtzahl von Zahlungszeiträumen. Der Zins und ZZR müssen sich auf die gleiche Einheit beziehen und auf diese Weise jährlich oder monatlich berechnet werden.

BW ist der aktuelle Wert.

Anfangszeitraum ist der erste Zahlungszeitraum für die Berechnung.

Endzeitraum ist der letzte Zahlungszeitraum für die Berechnung.

Typ ist die Fälligkeit einer Zahlung am Ende jedes Zeitraumes (Typ = 0) oder am Anfang des Zeitraumes (Typ = 1).

Beispiel

Für ein Haus wird folgendes Hypothekendarlehen aufgenommen:

Zins: 9,00 Prozent pro Jahr (9 % / 12 = 0,0075), Laufzeit: 30 Jahre (Zahlungsperioden = 30 * 12 = 360), Bw: 125000 Währungseinheiten.

Wie hoch ist die Tilgung, die Sie im zweiten Jahr des Hypothekendarlehens (also im Verlauf der Perioden 13 bis 24) zurück zahlen?

=KUMKAPITAL_ADD(0,0075;360;125000;13;24;0) ergibt -934,1071

Im ersten Monat zahlen Sie an Tilgung folgende Summe zurück:

=KUMKAPITAL_ADD(0,0075;360;125000;1;1;0) ergibt -68,27827

KUMZINSZ

Berechnet die kumulierten Zinseszinsen, das heißt die Summe aller Zinsen in einem Zeitraum für eine Investition. Der Zinssatz ist konstant.

Syntax

KUMZINSZ(Zins; ZZr; BW; S; E; Typ)

Zins bestimmt den periodischen Zinssatz.

ZZr ist der Zahlungszeitraum mit der Summe der Zeiträume. ZZR kann auch ein nicht ganzzahliger Wert sein.

BW ist der aktuelle Wert in der Reihe von Zahlungen.

S ist der erste Zeitraum.

E ist der letzte Zeitraum.

Typ ist der Fälligkeitstermin der Zahlung am Anfang oder Ende jedes Zeitraumes.

Beispiel

Wie hoch sind die Zinsanteile bei einem jährlichen Zinssatz von 5,5 %, einer Zahlungsperiode von 2 Jahren mit monatlichen Zahlungen und einem derzeitigen Barwert von 5.000 Währungseinheiten? Als Anfangsperiode soll die 4. und als Endperiode die 6. Periode gerechnet werden. Die Zahlung ist zu Beginn jeder Periode fällig.

=KUMZINSZ(5,5%/12;24;4;5000;6;1) = -57,54 Währungseinheiten. Die Zinszahlungen zwischen der 4. und 6. Periode betragen 57,54 Währungseinheiten.

KUMZINSZ_ADD

Berechnet die kumulierten Zinsen in einem Zeitraum.

note

Die Funktionen, deren Namen mit _ADD oder _EXCEL2003 enden, geben dieselben Ergebnisse zurück wie die entsprechenden Funktionen in Microsoft Excel ohne Endung. Verwenden Sie die Funktionen ohne Endung, um Ergebnisse zu erhalten, die auf internationalen Standards basieren.


Syntax

CUMZINSZ_ADD(Zins; ZZr; BW; Anfangszeitraum; Endzeitraum; Typ)

Zins ist der Zinssatz für jeden Zeitraum.

ZZr ist die Gesamtzahl von Zahlungszeiträumen. Der Zins und ZZR müssen sich auf die gleiche Einheit beziehen und auf diese Weise jährlich oder monatlich berechnet werden.

BW ist der aktuelle Wert.

Anfangszeitraum ist der erste Zahlungszeitraum für die Berechnung.

Endzeitraum ist der letzte Zahlungszeitraum für die Berechnung.

Typ ist die Fälligkeit einer Zahlung am Ende jedes Zeitraumes (Typ = 0) oder am Anfang des Zeitraumes (Typ = 1).

Beispiel

Für ein Haus wird folgendes Hypothekendarlehen aufgenommen:

Zins: 9,00 Prozent pro Jahr (9 % / 12 = 0,0075), Laufzeit: 30 Jahre (ZZR = 30 * 12 = 360), BW: 125000 Währungseinheiten.

Welchen Betrag an Zinsen müssen Sie im zweiten Jahr des Hypothekendarlehens (also im Verlauf der Perioden 13 bis 24) zahlen?

=CUMZINSZ_ADD(0,0075;360;125000;13;24;0) ergibt -11135,23.

Wie viel Zinsen müssen Sie im ersten Monat zahlen?

=CUMZINSZ_ADD(0,0075;360;125000;1;1;0) ergibt -937,50.

KURS

Berechnet den Kurswert eines festverzinslichen Wertpapiers mit dem Nennwert 100 Währungseinheiten abhängig von der beabsichtigten Rendite.

Syntax

KURS(Abrechnung; Fälligkeit; Zins; Rendite; Rückzahlung; Häufigkeit [; Basis])

Abrechnung ist das Kaufdatum des Wertpapiers.

Fälligkeit ist das Datum, an dem das Wertpapier fällig wird (abläuft).

Zins ist der jährliche Nominalzins (Kuponzins)

Rendite ist die jährliche Rendite des Wertpapiers.

Rückzahlung ist der Rückzahlungswert pro 100 Währungseinheiten des Nennwerts.

Häufigkeit ist die Anzahl von Zinszahlen im Jahr (1, 2 oder 4).

Basis (optional) wird aus einer Liste von Optionen ausgewählt und legt fest, wie das Jahr zu berechnen ist.

Basis

Berechnung

0 oder fehlend

US-Methode (NASD), 12 Monate je 30 Tage

1

genaue Anzahl Tage im Monat, genaue Anzahl Tage im Jahr

2

genaue Anzahl Tage im Monat, Jahr hat 360 Tage

3

genaue Anzahl Tage im Monat, Jahr hat 365 Tage

4

Europa-Methode, 12 Monate je 30 Tage


Beispiel

Ein Wertpapier wird am 15.2.1999 gekauft; der Fälligkeitstermin ist der 15.11.2007. Der Nominalzinssatz beträgt 5,75 %. Die Rendite beträgt 6,5 %. Der Rückzahlungswert beträgt 100 Währungseinheiten. Die Zinszahlung erfolgt halbjährlich (Häufigkeit = 2). Mit Basis 0 wird der Kurs wie folgt berechnet:

=KURS("15.02.1999"; "15.11.2007"; 0,0575; 0,065; 100; 2; 0) ergibt 95,04287.

KURSDISAGIO

Berechnet den Kurs pro 100 Währungseinheiten Nennwert eines unverzinslichen Wertpapiers.

Syntax

KURSDISAGIO(Abrechnung; Fälligkeit; Disagio; Rückzahlung [; Basis])

Abrechnung ist das Kaufdatum des Wertpapiers.

Fälligkeit ist das Datum, an dem das Wertpapier fällig wird (abläuft).

Disagio ist das Disagio eines Wertpapiers als Prozentwert.

Rückzahlung ist der Rückzahlungswert pro 100 Währungseinheiten des Nennwerts.

Basis (optional) wird aus einer Liste von Optionen ausgewählt und legt fest, wie das Jahr zu berechnen ist.

Basis

Berechnung

0 oder fehlend

US-Methode (NASD), 12 Monate je 30 Tage

1

genaue Anzahl Tage im Monat, genaue Anzahl Tage im Jahr

2

genaue Anzahl Tage im Monat, Jahr hat 360 Tage

3

genaue Anzahl Tage im Monat, Jahr hat 365 Tage

4

Europa-Methode, 12 Monate je 30 Tage


Beispiel

Ein Wertpapier wird am 15.2.1999 gekauft; der Fälligkeitstermin ist der 1.3.1999. Das Disagio beträgt 5,25 %. Der Rückzahlungswert ist 100. Mit Basis 2 wird das Disagio wie folgt berechnet:

=KURSDISAGIO("15.02.1999";"01.03.1999";0,0525;100;2) ergibt 99,79583.

KURSFÄLLIG

Berechnet den Kurs pro 100 Währungseinheiten Nennwert eines Wertpapiers, das Zinsen am Fälligkeitsdatum auszahlt.

Syntax

KURSFÄLLIG(Abrechnung; Fälligkeit; Ausgabe; Zins; Rendite [; Basis])

Abrechnung ist das Kaufdatum des Wertpapiers.

Fälligkeit ist das Datum, an dem das Wertpapier fällig wird (abläuft).

Ausgabe ist das Ausgabedatum des Wertpapiers.

Zins ist der Zinssatz des Wertpapiers zum Zeitpunkt der Ausgabe.

Rendite ist die jährliche Rendite des Wertpapiers.

Basis (optional) wird aus einer Liste von Optionen ausgewählt und legt fest, wie das Jahr zu berechnen ist.

Basis

Berechnung

0 oder fehlend

US-Methode (NASD), 12 Monate je 30 Tage

1

genaue Anzahl Tage im Monat, genaue Anzahl Tage im Jahr

2

genaue Anzahl Tage im Monat, Jahr hat 360 Tage

3

genaue Anzahl Tage im Monat, Jahr hat 365 Tage

4

Europa-Methode, 12 Monate je 30 Tage


Beispiel

Abrechnungstermin: 15. Februar 1999, Fälligkeitstermin: 13. April 1999, Emissionstermin: 11. November 1998. Zinssatz: 6,1 Prozent, Rendite: 6,1 Prozent, Basis: 30/360 = 0.

Der Kurs berechnet sich wie folgt:

=KURSFÄLLIG("15.02.1999";"13.04.1999";"11.11.1998";0,061;0,061;0) ergibt 99,98449888.

LIA

Ergibt die lineare Abschreibung eines Wirtschaftsgutes für eine Periode. Die Abschreibungshöhe ist über den gesamten Abschreibungszeitraum gleichbleibend.

Syntax

LIA(Anschaffungswert; Restwert; Nutzungsdauer)

Anschaffungswert ist der Anschaffungswert des Wirtschaftsgutes.

Restwert ist der Restwert eines Wirtschaftsgutes am Ende der Abschreibung.

Nutzungsdauer ist die Abschreibungsdauer, die die Anzahl von Zeiträumen innerhalb der Abschreibungsdauer des Wirtschaftsgutes bestimmt.

Beispiel

Eine Büroausstattung mit dem Anschaffungswert von 50.000 Währungseinheiten soll über 7 Jahre abgeschrieben werden. Der Restwert ist mit 3.500 Währungseinheiten veranschlagt.

=LIA(50000;3,500;84) = 553,57 Währungseinheiten. Die regelmäßig monatliche Abschreibung der Büroeinrichtung beträgt 553,57 Währungseinheiten.

MLAUFZEIT

Berechnet die modifizierte Macauley-Laufzeit eines festverzinslichen Wertpapiers in Jahren.

Syntax

MLAUFZEIT(Abrechnung; Fälligkeit; Coupon; Rendite; Häufigkeit [; Basis])

Abrechnung ist das Kaufdatum des Wertpapiers.

Fälligkeit ist das Datum, an dem das Wertpapier fällig wird (abläuft).

Coupon ist der jährliche Nominalzins (Couponzins)

Rendite ist die jährliche Rendite des Wertpapiers.

Häufigkeit ist die Anzahl von Zinszahlen im Jahr (1, 2 oder 4).

Basis (optional) wird aus einer Liste von Optionen ausgewählt und legt fest, wie das Jahr zu berechnen ist.

Basis

Berechnung

0 oder fehlend

US-Methode (NASD), 12 Monate je 30 Tage

1

genaue Anzahl Tage im Monat, genaue Anzahl Tage im Jahr

2

genaue Anzahl Tage im Monat, Jahr hat 360 Tage

3

genaue Anzahl Tage im Monat, Jahr hat 365 Tage

4

Europa-Methode, 12 Monate je 30 Tage


Beispiel

Ein Wertpapier wird am 1.1.2001 gekauft; der Fälligkeitstermin ist der 1.1.2006. Der Nominalzinssatz beträgt 8 %. Die Rendite beträgt 9,0 %. Die Zinszahlung erfolgt halbjährlich (Häufigkeit = 2). Wie lang ist die modifizierte Laufzeit bei taggenauer Berechnung (Basis 3)?

=MLAUFZEIT("01.01.2001";"01.01.2006";0,08;0,09;2;3) ergibt 4,02 Jahre.

NBW

Liefert den Barwert einer Investition basierend auf einer Reihe von regelmäßig auftretenden Cashflows und einem Diskontsatz. Um den Barwert zu erhalten, subtrahieren Sie die Projektkosten (den Anfangs-Cashflow zum Zeitpunkt Null) vom gelieferten Wert.

Falls die Zahlungen in unregelmäßigen Intervallen stattfinden, verwenden Sie die Funktion XNPV.

Syntax

NBW(Zins; Zahl 1 [; Zahl 2 [; … [; Zahl 254]]])

Zins ist das Disagio für jeden Zeitraum.

Zahl 1, Zahl 2, …, Zahl 254 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

note

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.


Beispiel

Wie lautet der Barwert von regelmäßigen Einzahlungen von 10, 20 und 30 Währungseinheiten mit einem Diskontsatz von 8,75 %. Zum Zeitpunkt Null wurden die Kosten als -40 Währungseinheiten gezahlt.

=NBW(8,75 %;10;20;30) = 49,43 Währungseinheiten. Der Nettobarwert ist der zurückgegebene Wert minus Anschaffungswert von 40 Währungseinheiten, also 9,43 Währungseinheiten.

NOMINAL

Berechnet die jährlichen Nominalzinsen zu einer Effektivverzinsung.

Syntax

NOMINAL(EffektiverZins; AproJ)

EffektiverZins ist der effektive Zins

AproJ ist die Anzahl von regelmäßigen Zinszahlungen pro Jahr.

Beispiel

Wie hoch sind die jährlichen Nominalzinsen zu einer Effektivverzinsung von 13,5 %, wenn zwölf Zinszahlung pro Jahr erfolgen.

=NOMINAL(13,5 %;12) = 12,73 %. Der Nominalzinssatz pro Jahr beträgt 12,73 %.

NOMINAL_ADD

Berechnet den jährlichen Nominalzins auf Basis des effektiven Zins und der Anzahl der Zinszahlungen pro Jahr.

note

Die Funktionen, deren Namen mit _ADD oder _EXCEL2003 enden, geben dieselben Ergebnisse zurück wie die entsprechenden Funktionen in Microsoft Excel ohne Endung. Verwenden Sie die Funktionen ohne Endung, um Ergebnisse zu erhalten, die auf internationalen Standards basieren.


Syntax

NOMINAL_ADD(EffektiverZins; AproJ)

EffektiverZins ist der effektive Jahreszins.

AproJ ist die Anzahl von Zinszahlungen pro Jahr.

Beispiel

Welcher Nominalzins ergibt sich bei 5,3543 % effektiven Zins und vierteljährlicher Zahlung?

=NOMINAL_ADD(5,3543%;4) ergibt 0,0525 oder 5,25 %.

NOTIERUNGBRU

Wandelt eine Notierung, die als Dezimalzahl angegeben wurde, in einen gemischten Dezimalbruch um.

Syntax

NOTIERUNGBRU(Dollardezimalzahl; Bruch)

Dollardezimalzahl ist eine Dezimalzahl.

Bruch ist eine ganze Zahl, die als Nenner des Dezimalbruchs verwendet wird.

Beispiel

=NOTIERUNGBRU(1,125;16) wandelt in Sechzehntel um. Das Ergebnis ist 1,02 für 1 plus 2/16.

=NOTIERUNGBRU(1,125;8) wandelt in Achtel um. Das Ergebnis ist 1,1 für 1 plus 1/8.

NOTIERUNGDEZ

Wandelt eine Notierung, die als Dezimalbruch angegeben wurde, in eine Dezimalzahl um.

Syntax

NOTIERUNGDEZ(Dollarbruchzahl; Bruch)

Dollarbruchzahl ist eine Dezimalbruchzahl.

Bruch ist eine ganze Zahl, die als Nenner des Dezimalbruchs verwendet wird.

Beispiel

=NOTIERUNGDEZ(1,02;16) steht für 1 und 2/16. Dies ergibt 1,125.

=NOTIERUNGDEZ(1,1;8) steht für 1 und 1/8. Dies ergibt 1,125.

PLAUFZEIT

Berechnet die Anzahl der Perioden (Zahlungszeiträume), die erforderlich sind, damit eine Investition den gewünschten Wert erreicht.

Syntax

PLAUFZEIT(Zins; BW; ZW)

Zins ist eine Konstante. Der Zinssatz wird für die gesamte Dauer (Zeitraum) berechnet. Der Zinssatz pro Zeitraum wird berechnet, indem der Zinssatz durch die berechnete Dauer dividiert wird. Der interne Zinsfuß für eine Annuität muss als Zins/12 eingegeben werden.

BW ist der gegenwärtige (aktuelle) Wert. Der Barwert ist die Bareinzahlung oder der aktuelle Barwert einer Sachleistung. Für eine Einzahlung muss ein positiver Wert eingegeben werden; die Einzahlung darf nicht 0 oder <0 sein.

ZW ist der erwartete Wert. Der zukünftige Wert bestimmt den gewünschten (zukünftigen) Wert des Guthabens.

Beispiel

Bei einem Zinssatz von 4,75 %, einem Gegenwartswert von 25.000 Währungseinheiten und einem zukünftigen Wert von 1.000.000 Währungseinheiten ergibt sich eine Laufzeit von 79,49 Zahlungsperioden. Die periodische Zahlung ergibt sich als Quotient aus zukünftigem Wert und Laufzeit, also: 1.000.000/79,49=12.580,20.

QIKV

Berechnet den modifizierten internen Zinsfuß einer Reihe von Investitionen.

Syntax

QIKV(Werte; Investition; Wiederanlagesatz)

Werte entspricht der Matrix oder dem Zellbezug für Zellen, deren Inhalt den Zahlungen entspricht.

Investition ist der Zinssatz der Investitionen (die negativen Werte der Matrix)

Wiederanlagesatz: der Zinssatz der Wiederanlage (die positiven Werte der Matrix)

Beispiel

Wenn von den Zellinhalten A1 = -5, A2 = 10, A3 = 15 A4 = 8, einem Anlagewert von 0,5 und einem Wiederanlagewert von 0,1 ausgegangen wird, ist das Ergebnis 94,16 %.

RENDITE

Berechnet die Rendite eines Wertpapiers.

Syntax

RENDITE(Abrechnung; Fälligkeit; Zins; Kurs; Rückzahlung; Häufigkeit [; Basis])

Abrechnung ist das Kaufdatum des Wertpapiers.

Fälligkeit ist das Datum, an dem das Wertpapier fällig wird (abläuft).

Zins ist der Jahreszinssatz.

Kurs ist der Kurs (Kaufpreis) des Wertpapiers pro 100 Währungseinheiten des Nennwerts.

Rückzahlung ist der Rückzahlungswert pro 100 Währungseinheiten des Nennwerts.

Häufigkeit ist die Anzahl von Zinszahlen im Jahr (1, 2 oder 4).

Basis (optional) wird aus einer Liste von Optionen ausgewählt und legt fest, wie das Jahr zu berechnen ist.

Basis

Berechnung

0 oder fehlend

US-Methode (NASD), 12 Monate je 30 Tage

1

genaue Anzahl Tage im Monat, genaue Anzahl Tage im Jahr

2

genaue Anzahl Tage im Monat, Jahr hat 360 Tage

3

genaue Anzahl Tage im Monat, Jahr hat 365 Tage

4

Europa-Methode, 12 Monate je 30 Tage


Beispiel

Ein Wertpapier wird am 15.2.1999 gekauft. Der Fälligkeitstermin ist der 15.11.2007. Der Zinssatz beträgt 5,75 %. Der Kurs entspricht 95,04287 Währungseinheiten pro 100 Einheiten des Nennwerts, der Rückzahlungswert beträgt 100 Einheiten. Die Zinszahlung erfolgt halbjährlich (Häufigkeit = 2) und die Basis ist 0. Wie hoch ist die Rendite?

=RENDITE("15.02.1999"; "15.11.2007"; 0,0575; 95,04287; 100; 2; 0) ergibt 0,065 oder 6,50 %.

RENDITEDIS

Berechnet die jährliche Rendite eines unverzinslichen Wertpapiers.

Syntax

RENDITEDIS(Abrechnung; Fälligkeit; Kurs; Rückzahlung [; Basis])

Abrechnung ist das Kaufdatum des Wertpapiers.

Fälligkeit ist das Datum, an dem das Wertpapier fällig wird (abläuft).

Kurs ist der Kurs (Kaufpreis) des Wertpapiers pro 100 Währungseinheiten des Nennwerts.

Rückzahlung ist der Rückzahlungswert pro 100 Währungseinheiten des Nennwerts.

Basis (optional) wird aus einer Liste von Optionen ausgewählt und legt fest, wie das Jahr zu berechnen ist.

Basis

Berechnung

0 oder fehlend

US-Methode (NASD), 12 Monate je 30 Tage

1

genaue Anzahl Tage im Monat, genaue Anzahl Tage im Jahr

2

genaue Anzahl Tage im Monat, Jahr hat 360 Tage

3

genaue Anzahl Tage im Monat, Jahr hat 365 Tage

4

Europa-Methode, 12 Monate je 30 Tage


Beispiel

Ein unverzinsliches Wertpapier wird am 15.2.1999 gekauft. Der Fälligkeitstermin ist der 1.3.1999. Der Kurs entspricht 99,795 Währungseinheiten pro 100 Einheiten des Nennwerts, der Rückzahlungswert beträgt 100 Einheiten. Die Basis ist 2. Wie hoch ist die Rendite?

=RENDITEDIS("15.02.1999";"01.03.1999";99,795;100;2) ergibt 0,052823 oder 5,2823 %.

RENDITEFÄLL

Berechnet die jährliche Rendite eines Wertpapiers, dessen Zinsen am Fälligkeitstermin gezahlt werden.

Syntax

RENDITEFÄLL(Abrechnung; Fälligkeit; Ausgabe; Zins; Kurs [; Basis])

Abrechnung ist das Kaufdatum des Wertpapiers.

Fälligkeit ist das Datum, an dem das Wertpapier fällig wird (abläuft).

Ausgabe ist das Ausgabedatum des Wertpapiers.

Zins ist der Zinssatz des Wertpapiers zum Zeitpunkt der Ausgabe.

Kurs ist der Kurs (Kaufpreis) des Wertpapiers pro 100 Währungseinheiten des Nennwerts.

Basis (optional) wird aus einer Liste von Optionen ausgewählt und legt fest, wie das Jahr zu berechnen ist.

Basis

Berechnung

0 oder fehlend

US-Methode (NASD), 12 Monate je 30 Tage

1

genaue Anzahl Tage im Monat, genaue Anzahl Tage im Jahr

2

genaue Anzahl Tage im Monat, Jahr hat 360 Tage

3

genaue Anzahl Tage im Monat, Jahr hat 365 Tage

4

Europa-Methode, 12 Monate je 30 Tage


Beispiel

Ein Wertpapier wird am 15.3.1999 gekauft. Der Fälligkeitstermin ist der 3.11.1999. Das Ausgabedatum ist der 8.11.1998. Der Zinssatz beträgt 6,25 %, der Kurs entspricht 100,0123 Einheiten. Die Basis ist 0. Wie hoch ist die Rendite?

=RENDITEFÄLL("15.03.1999"; "03.11.1999"; "08.11.1998"; 0,0625; 100,0123; 0) ergibt 0,060954 oder 6,0954 %.

RMZ

Ergibt die regelmäßigen Zahlungen (Annuitäten) für eine Investition bei konstantem Zinssatz.

Syntax

RMZ(Zins; ZZr; BW [; [ZW] [; Typ]])

Zins bestimmt den periodischen Zinssatz.

ZZr ist die Gesamtzahl von Zeiträumen, in denen regelmäßige Zahlungen (Annuitäten) erfolgen.

BW ist der Barwert in einer Reihe von Zahlungen.

ZW (optional) ist der gewünschte (zukünftige) Wert, der am Ende der regelmäßigen Zahlungen erreicht werden soll.

Typ (optional) ist der Fälligkeitstermin für die periodischen Zahlungen. Typ=1 ist die Zahlung am Anfang und Typ=0 ist die Zahlung am Ende jedes Zeitraumes.

In LibreOffice Calc-Funktionen dürfen Parameter, die als „optional“ gekennzeichnet sind, nur dann ausgelassen werden, wenn ihnen kein weiterer Parameter mehr folgt. So können Sie beispielsweise in einer Funktion mit vier Parametern, von denen die letzten beiden als „optional“ gekennzeichnet sind, den Parameter 4 oder die Parameter 3 und 4 auslassen, jedoch nicht den Parameter 3 allein.

Beispiel

Auf welchen Betrag belaufen sich die periodischen Zahlungen bei einem jährlichen Zinssatz von 1,99 %, einem Zahlungszeitraum von 3 Jahren und einem Barwert von 25.000 Währungseinheiten? Es gelten 36 Monate als 36 Zahlungsperioden und ein Zinssatz pro Zahlungsperiode von 1,99 %/12.

=RMZ(1,99 %/12;36;25000) = -715,96 Währungseinheiten. Die regelmäßige monatliche Zahlung beträgt demzufolge 715,96 Währungseinheiten.

TBILLKURS

Berechnet den Kurs eines Schatzwechsels (Treasury Bill) pro 100 Währungseinheiten.

Syntax

TBILLKURS(Abrechnung; Fälligkeit; Disagio)

Abrechnung ist das Kaufdatum des Wertpapiers.

Fälligkeit ist das Datum, an dem das Wertpapier fällig wird (abläuft).

Disagio ist der prozentuale Abschlag (Disagio) auf die Anschaffung des Wertpapiers.

Beispiel

Abrechnungstermin: 31. März 1999, Fälligkeitstermin: 1. Juni 1999, Disagio: 9 Prozent.

Der Kurs des Schatzwechsels ergibt sich wie folgt:

=TBILLKURS("31.03.1999";"01.06.1999";0,09) ergibt 98,45.

TBILLRENDITE

Berechnet die Rendite eines Schatzwechsels (Treasury Bill).

Syntax

TBILLRENDITE(Abrechnung; Fälligkeit; Kurs)

Abrechnung ist das Kaufdatum des Wertpapiers.

Fälligkeit ist das Datum, an dem das Wertpapier fällig wird (abläuft).

Kurs ist der Kurs (Kaufpreis) des Schatzwechsels pro 100 Währungseinheiten des Nennwerts.

Beispiel

Abrechnungstermin: 31. März 1999, Fälligkeitstermin: 1. Juni 1999, Kurs: 98,45 Währungseinheiten.

Die Rendite des Schatzwechsels ergibt sich wie folgt:

=TBILLRENDITE("31.03.1999";"01.06.1999";98,45) ergibt 0,091417 oder 9,1417 %.

TBILLÄQUIV

Berechnet die jährliche Verzinsung eines Schatzwechsels. Ein Schatzwechsel wird zum Abrechnungstermin erworben und zum Fälligkeitstermin, der im selben Jahr liegen muss, zum vollen Nennwert verkauft. Vom Kaufpreis wird ein Disagio abgezogen.

Syntax

TBILLÄQUIV(Abrechnung; Fälligkeit; Disagio)

Abrechnung ist das Kaufdatum des Wertpapiers.

Fälligkeit ist das Datum, an dem das Wertpapier fällig wird (abläuft).

Disagio ist der prozentuale Abschlag (Disagio) auf die Anschaffung des Wertpapiers.

Beispiel

Abrechnungstermin: 31. März 1999, Fälligkeitstermin: 1. Juni 1999, Disagio: 9,14 Prozent.

Die einem Wertpapier entsprechende Verzinsung des Schatzwechsels ergibt sich wie folgt:

=TBILLÄQUIV("31.03.1999";"01.06.1999"; 0,0914) ergibt 0,094151 oder 9,4151 %.

Zurück zu finanzmathematischen Funktionen Teil eins

Weiter zu finanzmathematischen Funktionen Teil drei

Funktionen nach Kategorie

Bitte unterstützen Sie uns!