Funktionen TypeName und VarType

Gibt Text oder einen numerischen Wert zurück, der die Informationen über den Typ einer Variablen enthält.

Syntax:


  TypeName (Varname As Variant) As String
  VarType (Varname As Variant) As Integer

Rückgabewert:

Ein Text für TypeName mit angehängtem '()' für Matrizen.
Eine ganze Zahl für VarType. Bei Matrizen vom Typ VarType wird die Zahl 8192 zum Rückgabewert addiert.

Parameter:

Varname: Der Variablenname, dessen Typ Sie bestimmen möchten.

Die folgenden Werte werden zurückgegeben:

TypeName Werte	Named Konstante	VarType values	Variablentyp
…()		8192	Matrix mit Variablen
Boolean		11	Boolesche Variable
Byte		17	Byte-Variable
Date	V_DATE	7	Datums-Variable
Currency	V_CURRENCY	6	Währungs-Variable
Double	V_DOUBLE	5	Gleitkommavariable mit doppelter Genauigkeit
Error		11	Fehlertyp-Variable
Integer	V_INTEGER	2	Integer-Variable
Long	V_LONG	3	Long-Integer-Variable
Object		9	Objekt-Variable
Single	V_SINGLE	4	Gleitkommavariable mit einfacher Genauigkeit
String	V_STRING	8	String-Variable
Variant		12	Variant-Variable (kann alle durch die Definition spezifizierten Typen enthalten)
Empty	V_EMPTY	0	Nicht initialisierte Variant-Variable
Null	V_NULL	1	Keine gültigen Daten

Fehlercodes:

5 Ungültiger Prozeduraufruf

Beispiel:


  Sub TypeName_VarType_example
    Const __Object=9, __Error=10, __Boolean=11, __Variant=12, __Byte=17, _
      __Array = 8192, aText = "Lorem ipsum dolor sit amet, consectetur …"
    Dim int16 As Integer,  int32() As Long   ' V_INTEGER,  V_LONG
    Dim flt32!,            flt64() As Double ' V_SINGLE,   V_DOUBLE
    Dim curr@,             dat3 As Date      ' V_CURRENCY, V_DATE
    Dim strng() As String, objct() As Object ' V_STRING,   …
    Dim bool As Boolean,   unkwn(), byt3 As Byte ' …,      V_EMPTY, …
    Dim table(-3 To 5)
    MsgBox _
     TypeName(int16) &" "& Vartype(int16) &" "& V_INTEGER        &" "& Chr(13) &_
     TypeName(int32) &" "& Vartype(int32) &" "& V_LONG+__Array   &" "& Chr(13) &_
     TypeName(flt32) &" "& VarType(flt32) &" "& V_SINGLE         &" "& Chr(13) &_
     TypeName(flt64) &" "& VarType(flt64) &" "& V_DOUBLE+__Array &" "& Chr(13) &_
     TypeName(dat3)  &" "& VarType(dat3)  &" "& V_DATE           &" "& Chr(13) &_
     TypeName(curr)  &" "& VarType(curr)  &" "& V_CURRENCY       &" "& Chr(13) &_
     TypeName(atext) &" "& VarType(aText) &" "& V_STRING         &" "& Chr(13) &_
     TypeName(strng) &" "& VarType(strng) &" "& V_STRING+__Array &" "& Chr(13) &_
     TypeName(objct) &" "& VarType(objct) &" "& __Object+__Array &" "& Chr(13) &_
     TypeName(unkwn) &" "& VarType(unkwn) &" "& V_EMPTY          &" "& Chr(13) &_
     TypeName(bool)  &" "& VarType(bool)  &" "& __Boolean        &" "& Chr(13) &_
     TypeName(varnt) &" "& VarType(varnt) &" "& V_EMPTY          &" "& Chr(13) &_
     TypeName(table) &" "& VarType(table) &" "&__Variant+__Array &" "& Chr(13) &_
     TypeName(byt3)  &" "& VarType(byt3)  &" "& __Byte           _
     ,, "Datentypen in LibreOffice-Basic"
    Msgbox "TypeName(table): "&TypeName(table) &Chr(13)& _
      "VarType(table)="&Vartype(table) _
      ,, "Matrizen mit Variant-Werten"
  End Sub ' TypeName_VarType_example

Anweisung Const

Anweisung Dim

Anweisung MsgBox