Informationsfunktioner

Denne kategori indeholder Informationsfunktioner.

For at tilgĂĄ denne kommando...

Indsæt - Funktion - Kategori Information


Dataene i den følgende tabel tjener som grundlag for nogle af eksemplerne i funktionsbeskrivelserne:

C

D

2

X-værdi

Y-værdi

3

-5

-3

4

-2

0

5

-1

1

6

0

3

7

2

4

8

4

6

9

6

8


AKTUEL (CURRENT pĂĄ engelsk)

Denne funktion returnerer resultatet indtil nu, af beregning af formlen, som den indgår i (med andre ord resultatet så langt, som beregningen er nået til). Dens hovedanvendelse er sammen med funktionen TYPOGRAFI() for at anvende udvalgte typografier på en celle afhængigt af cellens indhold.

Syntaks

AKTUEL()

Eksempel

=1+2+AKTUEL()

Eksemplet returnerer 6. Formlen beregnes fra venstre mod højre som: 1 + 2 er lig med 3, giver resultatet til dato, når AKTUEL() bliver taget med i betragtning; AKTUEL() giver derfor 3, som bliver lagt til de originale 3, hvilket giver 6.

=A2+B2+TYPOGRAFI(HVIS(AKTUEL()>10;"Rød";"Standard"))

Dette eksempel returnerer A2 + B2 (TYPOGRAFI returnerer 0 her). Hvis summen er større end 10, bliver typografien Rød anvendt på cellen. Se funktionen TYPOGRAFI for yderligere forklaring.

="choo"&CURRENT()

Den eksempel returnerer choochoo.

CELLE (CELL pĂĄ engelsk)

Returnerer information om adresse, formatering eller indholdet af en celle.

Syntaks

CELLE("Infotype" [; Reference] )

Infotype er tekststrengen, som angiver typen af information. Denne streng er altid pĂĄ engelsk. Der er valgfrihed mellem store og smĂĄ bogstaver.

Infotype

Betydning

COL

Returnerer nummeret pĂĄ den refererede kolonne.

Celle("COL"; D2) returnerer 4.

ROW

Returnerer nummeret på den refererede række.

Celle("ROW"; D2) returnerer 2.

SHEET

Returnerer nummeret pĂĄ det refererede ark.

Celle("Sheet"; Ark3.D2) returnerer 3.

ADDRESS

Returnerer den absolutte adresse for den refererede celle.

CELLE("ADDRESS"; D2) returnerer $D$2.

=CELLE("ADRESSE";Ark3.D2) returnerer $Ark3.$D$2.

=CELLE("ADDRESS";'X:\dr\test.ods'#$Ark1.D2) returnerer 'file:///X:/dr/test.ods'#$Ark1.$D$2.

FILENAME

Returnerer filnavnet og arknummeret for den refererede celle.

CELLE("FILENAME"; D2) returnerer 'fil:///X:/dr/egen.ods'#$Ark1, hvis formlen i det aktuelle dokument X:\dr\egen.ods er tilstede i Ark1.

=CELLE("FILENAME";'X:\dr\test.ods'#$Ark1.D2) returnerer 'file:///X:/dr/test.ods'#$Ark1.

COORD

Returnerer den fuldstændige celleadresse i Lotus™ notation.

CELLE("COORD"; D2) returnerer $A:$D$2.

CELLE("COORD"; Ark3.D2) returnerer $C:$D$2.

CONTENTS

Returnerer indholdet af den refererede celle uden nogen formatering.

TYPE

Returnerer typen af celleindhold.

b = tom. Tom celle

l = etiket. Tekst, resultat af en formel som tekst

v = Værdi. Værdi, resultat af en formel som et tal

WIDTH

Returnerer bredden af den refererede kolonne. Enheden er antal nuller (0), som passer ind i kolonnen i standardskrifttypen og standardstørrelse.

PREFIX

Returnerer justeringen for den refererede celle.

' = juster venstre eller venstre-lige margener

" = juster højre

^ = centreret

\ = gentagende (for øjeblikket inaktiv)

PROTECT

Returnerer status for cellebeskyttelsen for cellen.

1 = celle er beskyttet

0 = celle er ikke beskyttet

FORMAT

Returnerer en tekststreng, som indikerer talformatet.

. = tal med tusindtalsskilletegn

F = tal uden tusindtalsskilletegn

C = valutaformat

S = eksponentiel repræsentation, for eksempel 1,234+E56

P = procentdel

I de ovennævnte formater er antal decimaler efter decimaltegnet givet som et tal. Eksempel: talformatet #.##0,0 returnerer .1 og talformatet 00,000% returnerer P3

D1 = MMM-D-YY, MM-D-YY og lignende formater

D2 = DD-MM

D3 = MM-YY

D4 = DD-MM-YYYY TT:MM:SS

D5 = MM-DD

D6 = TT:MM:SS AM/PM

D7 = TT:MM AM/PM

D8 = TT:MM:SS

D9 = TT:MM

G = Alle andre formater

- (Minus) til sidst = negativ tal er formateret med farve

() (parenteser) til sidst = der er en startparentes i formatkoden

COLOR

Returnerer 1, hvis negative værdier er formateret med farve, ellers 0.

PARENTHESES

Returnerer 1 hvis formateringskoden indeholder en startparentes (, ellers 0.


Reference (i listen af indstillinger) er den celleposition, som skal undersøges. Hvis Reference er et område, flyttes cellen til øverste venstre hjørne af området. Hvis Reference mangler, bruger LibreOffice Calc den celle, hvori denne formel er placeret. Microsoft Excel bruger henvisningen af cellen, hvori markøren er placeret.

ER.FEJL (ISERROR pĂĄ engelsk)

Tester for fejl, inklusiv fejlværdien #N/A, og returnerer SAND eller FALSK.

Hvis der opstår en fejl, returnerer funktionen en logisk eller numerisk værdi.

Syntaks

ER.FEJL(Værdi)

Værdi er eller refererer til den værdi, der skal testes. ER.FEJL()returnerer SAND, hvis der er en fejl og ellers FALSK.

Eksempel

=ER.FEJL(C8), hvor celle C8 indeholder =1/0, returnerer SAND, fordi 1/0 er en fejl.

=ER.FEJL (C9), hvor celle C9 indeholder =IKKE.TILGÆNGELIG(), returnerer SAND.

ER.FEJL (ISERROR pĂĄ engelsk)

Returnerer værdien hvis cellen ikke indeholder en fejl, eller den alternative værdi hvis den gør.

tip

Denne funktion er tilgængelig siden LibreOffice 4.0.


Syntaks

HVIS.FEJL(Værdi; Alternativ_værdi)

Værdi er værdien eller udtrykket som skal returneres, hvis det ikke et lige tal, eller hvis det returnerer en fejl.

Alternativ_værdi er værdien eller udtrykket som skal returneres, hvis værdien eller udtrykket i værdi er lig med eller resulterer i en fejl.

Eksempel

=ER.FEJL(C8;C9), hvor celle C8 indeholder =1/0, returnerer værdien af C9, fordi 1/0 er en fejl.

=ER.FEJL(C8;C9), hvor cellen C8 indeholder 13, returnerer 13, hvilket er værdien af C8, som ikke er en fejl.

ER.FJL (ISERR pĂĄ engelsk)

Tester for fejlbetingelser, dog undtaget fejlværdien #N/A, og returnerer SAND eller FALSK.

Hvis der opstår en fejl, returnerer funktionen en logisk eller numerisk værdi.

Syntaks

ER.FJL(Værdi)

Værdi er enhver værdi eller ethvert udtryk, som testes for at afgøre, om der forekommer en fejlværdi forskellig fra #N/A.

Eksempel

=ER.FJL(C8) hvor celle C8 indeholder =1/0 returnerer SAND, fordi 1/0 er en fejl.

=ER.FEJL(C9), hvor celle C9 indeholder =IKKE.TILGÆNGELIG(), returnerer FALSK, fordi ER.FJL() ignorerer fejlen #N/A.

ER.FORMEL (ISFORMULA pĂĄ engelsk)

Returnerer SAND, hvis en celle er en formel celle.

Hvis der opstår en fejl, returnerer funktionen en logisk eller numerisk værdi.

Syntaks

ER.FORMEL(Reference)

Reference angiver referencen til en celle, hvor det skal testes, om den indeholder en formel.

Eksempel

ER.FORMEL(C4) returnerer FALSK, hvis cellen C4 indeholder tallet 5.

ER.IKKE.TEKST (ISNONTEXT pĂĄ engelsk)

Tester om celleindholdet er tekst eller tal, og returnerer FALSK, hvis indholdet er tekst.

Hvis en fejl opstĂĄr, returnerer funktionen SAND.

Syntaks

ER.IKKE.TEKST(Værdi)

Værdi er en værdi eller et udtryk, som testes for at afgøre, om det er en tekst eller et tal eller en logisk værdi.

Eksempel

ER.IKKE.TEKST(D2) returnerer FALSK, hvis celle D2 indeholder teksten abcdef.

ER.IKKE.TEKST(D9) returnerer SAND, hvis celle D9 indeholder tallet 8.

ER.IKKE.TILGÆNGELIG (ISNA på engelsk)

Returnerer SAND, hvis en celle indeholder fejlværdien #N/A (værdi ikke tilgængelig).

Hvis en fejl opstĂĄr, returnerer funktionen FALSK.

Syntaks

ER.IKKE.TILGÆNGELIG(Værdi)

Værdi er en værdi eller et udtryk, som skal testes.

Eksempel

=ER.IKKE.TILGÆNGELIG(D3) returnerer FALSK som et resultat.

ER.IKKE.TILGÆNGELIG (ISNA på engelsk)

Returnerer værdien, hvis cellen ikke indeholder #N/A (value not available) fejl værdien.

tip

Denne funktion er tilgængelig siden LibreOffice 4.0.


Syntaks

HVIS.IKKE.TILGÆNGELIG(Værdi; Alternativ værdi)

Værdi er værdien eller udtrykket som skal returneres, hvis det ikke er lig med eller returnerer en #N/A-fejl.

Alternativ_værdi er værdien eller udtrykket som skal returneres, hvis værdien eller udtrykket i Værdi er lig med eller resulterer i en #N/A-fejl.

Eksempel

=HVIS.IKKE.TILGÆNGELIG(D3;D4) returnerer værdien af D3 såfremt D3 ikke resulterer i en #N/A fejl, ellers returneres D4.

ER.LIGE (ISEVEN pĂĄ engelsk)

Returnerer SAND, hvis værdien er et lige heltal, eller FALSK hvis værdien er ulige.

Syntaks

ER.LIGE(Værdi)

Værdi er værdien der skal undersøges.

Hvis Værdi ikke er et heltal, ignoreres alle cifre efter decimaltegnet. Fortegnet af Værdi ignoreres også.

Eksempel

=ER.LIGE(48) returnerer SAND

=ER.LIGE(33) returnerer FALSK

=ER.LIGE(0) returnerer SAND

=ER.LIGE(-2.1) returnerer SAND

=ER.LIGE(3.999) returnerer FALSK

ER.LIGE_ADD (ISEVEN_ADD pĂĄ engelsk)

Undersøger for lige tal. Returnerer 1, hvis tallet er et heltal efter division med 2.

note

De funktioner, hvis navne ender med _ADD eller EXCEL2003, returnerer de samme resultater som de tilsvarende Microsoft Excel 2003 funktioner uden endelse. Brug funktionerne uden endelse for at fĂĄ resultater baseret pĂĄ internationale standarder.


Syntaks

ER.LIGE_ADD(Tal)

Tal er det tal, der skal undersøges.

Eksempel

ER.LIGE_ADD(5) returnerer 0.

ER.LIGE_ADD(A1) returnerer 1, hvis celle A1 indeholder tallet 2.

ER.LOGISK (ISLOGICAL pĂĄ engelsk)

Tester for en logisk værdi (SAND eller FALSK).

Hvis en fejl opstĂĄr, returnerer funktionen FALSK.

Syntaks

ER.LOGISK(Værdi)

Returnerer SAND hvis Værdi er en logisk værdi (SAND eller FALSK) og returnerer ellers FALSK.

Eksempel

=ER.LOGISK(99) returnerer FALSK, fordi 99 er et tal, ikke en logisk værdi.

=ER.LOGISK(ER.IKKE.TILGÆNGELIG (D4)) returnerer SAND uanset indholdet af celle D4, fordi ER.IKKE.TILGÆNGELIG() returnerer en logisk værdi.

ER.REFERENCE (ISREF pĂĄ engelsk)

Tester om argumentet er en reference. Returnerer SAND hvis argumentet er en reference, og returnerer ellers FALSK. Hvis det er en reference, så undersøger denne funktion ikke værdien der refereres til.

Hvis der opstår en fejl, returnerer funktionen en logisk eller numerisk værdi.

Syntaks

ER.REFERENCE(Værdi)

Værdi er værdien, der skal testes, for at afgøre om det er en reference.

Eksempel

=ER.REFERENCE(C5) returnerer resultatet SAND, fordi C5 er en gyldig reference.

=ER.REFERENCE("abcdef") returnerer altid FALSK fordi en tekst ikke kan være en reference.

=ER.REFERENCE(4) returnerer FALSK.

=ER.REFERENCE(INDIREKTE("A6")) returnerer SAND, fordi INDIREKTE er en funktion som returnerer en reference.

=ER.REFERENCE(ADRESSE(1; 1; 2; "Ark2")) returnerer FALSK, fordi ADRESSE er en funktion, som returnerer en tekst, selv om denne ser ud som en reference.

ER.TAL (ISNUMBER pĂĄ engelsk)

Returnerer SAND, hvis værdien refererer til et tal.

Hvis der opstår en fejl, returnerer funktionen en logisk eller numerisk værdi.

Syntaks

ER.TAL(Værdi)

Værdi er et udtryk, som skal testes for, om det er et tal eller en tekst.

Eksempel

ER.TAL(C3) returnerer SAND, hvis cellen C3 indeholder tallet 4.

ER.TAL(C2) returnerer FALSK, hvis cellen C2 indeholder teksten abcdef.

ER.TEKST (ISTEXT pĂĄ engelsk)

Returnerer SAND, hvis celleindholdet henviser til tekst.

Hvis en fejl opstĂĄr, returnerer funktionen FALSK.

Syntaks

ER.TEKST(Værdi)

Værdi er en værdi, tal, logisk værdi, eller en fejlværdi, som skal afprøves.

Eksempel

ER.TEKST(D9) returnerer SAND, hvis celle D9 indeholder teksten abcdef.

ER.TEKST(C3) returnerer FALSK, hvis celle C3 indeholder tallet 3.

ER.TOM (ISBLANK pĂĄ engelsk)

Returnerer SAND hvis referencen til en celle er tom. Denne funktion bruges til at afgøre, om indholdet af en celle er tom. En celle, som indeholder en formel, er ikke tom.

Hvis der opstår en fejl, returnerer funktionen en logisk eller numerisk værdi.

Syntaks

ER.TOM(Værdi)

Værdi er indholdet, som skal testes.

Eksempel

=ER.TOM(D2) returnerer resultatet FALSK.

ER.ULIGE (ISODD pĂĄ engelsk)

Returnerer SAND, hvis værdien er ulige, eller FALSK hvis tallet er lige.

Syntaks

ER.ULIGE(Værdi)

Værdi er værdien der skal undersøges.

Hvis Værdi ikke er et heltal, ignoreres alle cifre efter decimaltegnet. Fortegnet af Værdi ignoreres også.

Eksempel

=ER.ULIGE(33) returnerer SAND

=ER.ULIGE(48) returnerer FALSK

=ER.ULIGE(3.999) returnerer SAND

=ER.ULIGE(-3,1) returnerer SAND

ER.ULIGE_ADD (ISODD_ADD pĂĄ engelsk)

Returnerer SAND (1) hvis tallet ikke giver et heltal ved division med 2.

note

De funktioner, hvis navne ender med _ADD eller EXCEL2003, returnerer de samme resultater som de tilsvarende Microsoft Excel 2003 funktioner uden endelse. Brug funktionerne uden endelse for at fĂĄ resultater baseret pĂĄ internationale standarder.


Syntaks

ER.ULIGE_ADD(Tal)

Tal er det tal, der skal undersøges.

Eksempel

=ER.ULIGE_ADD(5) returnerer 1.

FORMEL (FORMULA pĂĄ engelsk)

Viser formlen i en formelcelle som en tekststreng.

This function is always recalculated whenever a recalculation occurs.

Syntaks

FORMEL(Reference)

Reference er en reference til en celle, som indeholder en formel.

En ugyldig reference eller en reference til en celle uden nogen formel resulterer i fejlværdien #N/A.

Eksempel

Hvis celle A8 indeholder formlen =SUM(1;2;3), sĂĄ

=FORMEL(A8) returnerer teksten =SUM(1;2;3).

IKKE.TILGÆNGELIG (NA på engelsk)

Returnerer fejlværdien #N/A.

Syntaks

IKKE.TILGÆNGELIG()

Eksempel

=IKKE.TILGÆNGELIG() konverterer indholdet af cellen til #N/A.

INFO

Returnerer specifik information om det aktuelle arbejdsmiljø. Funktionen modtager et enkelt tekstargument og returnerer data afhængigt af denne parameter.

This function is always recalculated whenever a recalculation occurs.

Syntaks

INFO("Type")

Den følgende tabel er en liste med værdier for tekstparameteren Type og INFO-funktionens returværdier.

Værdi for "Type"

Returværdi

"osversion"

Altid "Windows (32-bit) NT 5.01", af kompatibilitetsgrunde

"system"

Typen af operativsystemet.
"WNT" for Microsoft Windows
"LINUX" for Linux
"MACOSX" for macOS
"SOLARIS" for Solaris

"release"

Produktets versionsid, for eksempel "300m25(Build:9876)"

"numfile"

Altid 1 af kompatibilitetsgrunde

"recalc"

Aktuel genberegningsmetode for formler, enten "Automatisk" eller "Manuelt" (oversat til LibreOffice sprog)


Noteikon

Andre regnearksapplikationer accepterer muligvis lokaliserede værdier for parameteren Type, men LibreOffice Calc accepterer kun de engelske værdier.


Eksempel

=INFO("release") returnerer produktversionsnummeret for LibreOffice i brug.

=INFO(D5) hvor cellen D5 indeholder tekststrengen system returnerer operativsystemets type.

N

Returnerer den numeriske værdi af den givne parameter. Returnerer 0 hvis parameteren er tekst eller FALSK.

Hvis der forekommer en fejl, returnerer funktionen fejlværdien.

Syntaks

N(Værdi)

Værdi er en parameter, som skal konverteres til et tal. N() returnerer den numeriske værdi hvis muligt. Logiske værdier TRUE og FALSE returneres som henholdsvis 1 og 0. Tekst returneres som 0.

Eksempel

=N(123) returnerer 123

=N(SAND) returnerer 1

=N(FALSK) returnerer 0

=N("abc") returnerer 0

=N(1/0) returnerer #DIV/0!

VÆRDITYPE (TYPE på engelsk)

Returnerer typen af værdi, hvor 1 = tal, 2 = tekst, 4 = Boolsk værdi, 8 = formel, 16 = fejlværdi, 64 = område.

Hvis der opstår en fejl, returnerer funktionen en logisk eller numerisk værdi.

Syntaks

VÆRDITYPE(Værdi)

Værdi er en specifik værdi, som datatypen skal afgøres for.

Eksempel (se eksempeltabel ovenover)

VÆRDITYPE(C2) returnerer 2 som et resultat.

VÆRDITYPE(D9) returnerer 1 som et resultat.

Støt os venligst!