udtrykket Resume

Nulstiller fejl-informationen og angiver, hvad der skal udføres som det næste.

Syntaks:

diagram over udtrykket Resume


     Resume [ [0] | label | Next ]

Parametre:

0: Nulstiller fejlinformationen og genudfører den instruktion, der gav fejlen. 0 er valgfri.

label: Nulstiller fejlinformationen og genoptager udførslen fra den angivne etiket i den aktuelle subrutine.

Next: nulstiller fejlinformationen og udfører den instruktion, der følger efter den, der udløste fejlen.

Fejlinformationen er bygget med funktionerne Erl, Err og Error$.

Erl: Linjenummer i modulet, hvor fejlen skete.
Err: Fejlnummer.
Error[$]: Fejlbeskrivelse.

Brug af Resume til at nulstille fejlinformationen forebygger, at udbredelse af den håndterede betingelse i at kalde rutiner.

Fejlkoder:

20 Resume uden fejl

Eksempler:

Typiske fejlhåndteringsrutiner er: alarmere brugeren, løse fejlen, logge fejlinformation eller genkaste bruger-fejl, som giver forklaringer med løsningsinstruktioner. Brug Resume label, når du har brug for en disse mekanismer.


      Sub Error_Handling
      try: On Error GoTo catch
          ' rutinekode skrives her
          Error 91 ' eksempelfejl
      finally:
          ' rutinerengøringskode skrives her
          Exit Sub
      catch:
          Print Erl, Err, Error$
          Resume finally
      End Sub ' Error_Handling

Brug Resume Next, når du for eksempel afrapporterer anomalier, du er stødt på i en gentagen proces, som ikke må afbrydes. I dette tilfælde kan flere håndteringsrutiner være påkrævet.


      Sub Iteration
          planets = Array("☿","♀","♁","♂","♃","♄","⛢","♆")
      try:
          On Error GoTo ReportAndProcessNext
          For ndx = -3 To 11 Step 1
              MsgBox planets(ndx)
          Next
          On Error GoTo 0 ' Stop error catching
      finally:
          Exit Sub
      ReportAndProcessNext:
          Print "Error "& Err &" at line "& Erl &" - "& Error$
          Resume Next
      End Sub ' Iteration

Brug af Resume uden parametre til at genudføre den fejlbehæftede instruktion kan passe til visse situationer. Dette kan dog medføre en uendelig sløjfe.