MAXIFS funkce

Vrátí maximální hodnotu z buněk z oblasti, která splňuje více kritérií z více oblastí.

tip

Tato funkce je k dispozici od verze LibreOffice 5.2.


Syntaxe

MAXIFS(Oblast; Oblast1; Kritérium1 [; Oblast2; Kritérium2][; ... ; [Oblast127; Kritérium127]])

Oblast_funkce – povinný argument. Jedná se o oblast buněk, název pojmenované oblasti nebo popisek sloupce nebo řádku obsahujícího hodnoty pro výpočet maxima.

Oblast1 – vyžadovaný argument. Jedná se o oblast buněk, název pojmenované oblasti nebo popisek sloupce nebo řádku, na které se má odpovídající kritérium použít.

Kritérium1 – povinný argument. Řetězcový výraz reprezentující logický stav nebo odkaz buňky na takový řetězecový výraz. Výraz může obsahovat text, čísla, regulární výrazy nebo zástupné znaky (pokud jsou zapnuty v možnostech výpočtu).

Oblast2 – nepovinné. Oblast2 a všechny následující mají stejný význam jako Oblast1.

Kritérium2 – nepovinné. Kritérium2 a následující mají stejný význam jako Kritérium1.

Vyhledávání podporuje zástupné znaky nebo regulární výrazy. Zadáte-li například "all.*", najdete první výskyt "all" následovaný jakýmikoliv znaky. Chcete-li hledat text, který je rovněž regulárním výrazem, musíte před každý znak napsat znak \ nebo text uzavřít mezi \Q...\E. Vypnout a zapnout automatické vyhodnocování regulárních výrazů můžete v - LibreOffice Calc - Výpočty.

warning

Pokud použijete funkci, jejíž jeden nebo více argumentů představují řetězce s kritérii vyhledávání, nejprve dojde k pokusu převést tyto řetězce na číslo, například ".0" se převede na 0 a podobně. V případě úspěšného převodu se nebude vyhledávat regulární výraz, ale číslo. Pokud však používáte národní prostředí s jiným oddělovačem desetinných míst, než je tečka, regulární výraz bude fungovat. Chcete-li regulární výraz vždy vynutit místo číselného výrazu, použijte výraz, který nelze interpretovat jako číslo, například ".[0]", ".\0" nebo "(?i).0".


Oblast a Oblast1, Oblast2... musí mít shodnou velikost, jinak funkce vrátí chybu Chyba:502 - neplatný argument.

note

Logický vztah mezi kritérii lze definovat jako logické AND (konjunkce). Jinými slovy, pokud a pouze pokud jsou splněna všechna daná kritéria, hodnota z odpovídající buňky dané Oblasti se vezme do výpočtu.


Funkce může mít až 255 argumentů, což znamená, že pro ně můžete zadat 127 oblastí kritérií a kritérií.

Obsahuje-li buňka hodnotu PRAVDA, je považována za číslo 1, obsahuje-li hodnotu NEPRAVDA, je považována za 0 (nulu).

Ikona poznámky

Tato funkce je součástí standardu Open Document Format for Office Applications (OpenDocument) verze 1.2 (ISO/IEC 26300:2-2015).


Příklad

Uvažujme následující tabulku

A

B

C

1

Název zboží

Prodeje

Tržby

2

nůžky

20

65

3

nůž

35

85

4

poznámkový blok

20

190

5

známka

17

180

6

nůž na papír

ne

ne


warning

Ve všech níže uvedených příkladech rozsahy pro výpočet obsahují řádek číslo 6, který je ignorován, protože obsahuje text.


Základní použití

=MAXIFS(B2:B6;B2:B6;"<35")

Vypočítá maximální hodnotu z oblasti B2:B6, které jsou větší nebo rovny 20. Vrátí 35. Pátý řádek kritérium nesplňuje.

=MAXIFS(C2:C6;B2:B6;">=20";C2:C6;"<90")

Vypočítá maximální hodnotu z oblasti C2:C6, které jsou nižší než 90 a odpovídají buňkám oblasti B2:B6 s hodnotami většími nebo rovno 20. Vrátí 85, protože čtvrtý a pátý řádek nesplňují alespoň jednu kritérium.

Použití regulárních výrazů a vnořených funkcí

=MAXIFS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Vypočítá maximální hodnotu z oblasti C2:C6, které odpovídají všem hodnotám rozsahu B2:B6 s výjimkou minima a maxima. Vrací 190, protože pouze čtvrtý řádek splňuje kritéria.

=MAXIFS(C2:C6;A2:A6;"nůž.*";B2:B6;"<="&MAX(B2:B6))

Vypočítá maximální hodnotu z oblasti C2:C6, které odpovídají všem buňkám oblasti A2:A6 začínajícím "nůž" a všem buňkám rozsahu B2:B6 s výjimkou jeho maxima. Vrací 85, protože pouze třetí řádek splňuje všechna kritéria.

Odkaz na buňku jako kritérium

Pokud potřebujete snadno změnit kritérium, můžete jej určit v samostatné buňce a použít odkaz na tuto buňku v podmínce funkce MAXIFS. Například výše uvedená funkce může být změněna následovně:

=MAXIFS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

If E2 = "nůž", funkce vrátí 65, protože odkaz na buňku je nahrazen jejím obsahem.

Otevřít soubor s příkladem:

Podpořte nás!