Statistické funkce – část 5
SKEWP
Vypočítá šikmost rozdělení ze základního souboru náhodné veličiny.
SKEWP(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
Parametry by měly být alespoň tři hodnoty.
Tato funkce je součástí standardu Open Document Format for Office Applications (OpenDocument) verze 1.2 (ISO/IEC 26300:2-2015).
Tato funkce ignoruje veškerý text a prázdné buňky v oblasti dat. Jestliže se zdá, že funkce vrací chybné výsledky, vyhledejte v oblastech dat text. Textový obsah můžete zvýraznit pomocí zvýrazňování hodnot.
SKEWP(2;3;1;6;8;5) vrátí 0,2329985562
SKEWP(A1:A6) vrátí 0,2329985562, pokud oblast A1:A6 obsahuje hodnoty {2;3;1;6;8;5}
DEVSQ
Vrátí součet čtverců odchylek od střední hodnoty výběru.
DEVSQ(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
Tato funkce ignoruje veškerý text a prázdné buňky v oblasti dat. Jestliže se zdá, že funkce vrací chybné výsledky, vyhledejte v oblastech dat text. Textový obsah můžete zvýraznit pomocí zvýrazňování hodnot.
=DEVSQ(A1:A50)
FORECAST
Extrapoluje budoucí hodnoty podle stávajících hodnot x a y.
FORECAST(Hodnota; DataY; DataX)
Hodnota je hodnota x, pro kterou bude pomocí lineární regrese vrácena hodnota y.
DataY je matice nebo oblast známých dat y.
DataX je matice nebo oblast známých dat x.
=FORECAST(50;A1:A50;B1;B50) vrátí hodnotu Y očekávanou pro X rovné 50 za předpokladu, že mezi odkazovanými hodnotami X a Y existuje lineární závislost.
FORECAST.LINEAR
Extrapoluje budoucí hodnoty podle stávajících hodnot x a y.
FORECAST.LINEAR(Hodnota; DataY; DataX)
Hodnota je hodnota x, pro kterou bude pomocí lineární regrese vrácena hodnota y.
DataY je matice nebo oblast známých dat y.
DataX je matice nebo oblast známých dat x.
=FORECAST(50;A1:A50;B1;B50) vrátí hodnotu Y očekávanou pro X rovné 50 za předpokladu, že mezi odkazovanými hodnotami X a Y existuje lineární závislost.
COM.MICROSOFT.FORECAST.LINEAR
NORM.S.DIST
Vrátí distribuční funkci normovaného normálního rozdělení. Toto rozdělení má střední hodnotu nula a směrodatnou odchylku jedna.
NORM.S.DIST(Číslo; Kumulativní)
Číslo je hodnota, pro kterou se spočítá distribuční funkce normovaného normálního rozdělení.
Kumulativní: Pro 0 nebo NEPRAVDA se vypočítá hustota pravděpodobnosti. Pro jiné hodnoty nebo PRAVDA se vypočítá distribuční funkce.
=NORM.S.DIST(1;0) vrátí 0,2419707245.
=NORM.S.DIST(1;1) vrátí 0,8413447461. Plocha pod křivkou normovaného normálního rozdělení zleva po hodnotu X rovnou 1 tvoří 84 % celkové plochy.
COM.MICROSOFT.NORM.S.DIST
NORM.S.INV
Vrátí inverzní distribuční funkci normovaného normálního rozdělení.
NORM.S.INV(Číslo)
Číslo je pravděpodobnost, pro kterou se spočítá inverzní distribuční funkce normovaného normálního rozdělení.
=NORM.S.INV(0,908789) vrátí 1,333334673.
COM.MICROSOFT.NORM.S.INV
NORMSDIST
Vrátí distribuční funkci normovaného normálního rozdělení. Toto rozdělení má střední hodnotu nula a směrodatnou odchylku jedna.
Platí GAUSS(x)=NORMSDIST(x)-0.5
NORMSDIST(Číslo)
Číslo je hodnota, pro kterou se spočítá distribuční funkce normovaného normálního rozdělení.
=NORMSDIST(1) vrátí 0,84. Plocha pod křivkou normovaného normálního rozdělení zleva po hodnotu X rovnou 1 tvoří 84 % celkové plochy.
NORMSINV
Vrátí inverzní distribuční funkci normovaného normálního rozdělení.
NORMSINV(Číslo)
Číslo je pravděpodobnost, pro kterou se spočítá inverzní distribuční funkce normovaného normálního rozdělení.
=NORMSINV(0,908789) vrátí 1,3333.
PERMUT
Vrátí počet variací pro zadaný počet prvků.
PERMUT(Počet1; Počet2)
Počet1 je celkový počet prvků.
Počet2 je počet prvků v každé variaci.
=PERMUT(6;3) vrátí 120. Existuje 120 různých způsobů jak vybrat posloupnost 3 karet z balíku 6 hracích karet.
PERMUTATIONA
Vrátí počet variací pro zadaný počet prvků, když je povoleno jejich opakování.
PERMUTATIONA(Počet1; Počet2)
Počet1 je celkový počet prvků.
Počet2 je počet prvků v každé variaci.
Kolika způsoby lze vybrat 2 objekty z 11 objektů?
=PERMUTATIONA(11;2) vrátí 121.
=PERMUTATIONA(6;3) vrátí 216. Existuje 216 různých způsobů jak vybrat posloupnost 3 karet z celkem šesti hracích karet, pokud se karta po každém vytažení vrací zpět do balíku.
PROB
Vrátí pravděpodobnost toho, že hodnoty leží v oblasti mezi dvěma mezemi. Pokud není zadán Konec, funkce vypočítá pravděpodobnost toho, že se hodnoty dat rovnají hodnotě Začátek.
PROB(Data; Pravděpodobnosti; Začátek [; Konec])
Data je matice nebo oblast s daty výběru.
Pravděpodobnosti je matice nebo oblast odpovídajících pravděpodobností.
Začátek je počáteční hodnota intervalu, pro nějž budou pravděpodobnosti sečteny.
Konec (nepovinné) je koncová hodnota intervalu, jehož pravděpodobnosti se mají sčítat. Pokud tento parametr chybí, vypočítá se pravděpodobnost hodnoty Začátek.
=PROB(A1:A50;B1:B50;50;60) vrátí pravděpodobnost, se kterou se hodnota z oblasti A1:A50 nachází mezi hodnotami 50 a 60. Každá hodnota v oblasti A1:A50 má pravděpodobnost určenou v oblasti B1:B50.
RANK
Vrátí pořadí hodnoty v daném výběru.
RANK(Hodnota; Data [; Typ])
Hodnota je hodnota, jejíž pořadí má být určeno.
Data je matice nebo oblast s daty výběru.
Typ (nepovinné) určuje řazení dat.
Typ = 0 znamená sestupné pořadí, od posledního prvku matice k prvnímu (toto je výchozí chování).
Typ = 1 znamená vzestupné pořadí, od prvního prvku k poslednímu.
Tato funkce ignoruje veškerý text a prázdné buňky v oblasti dat. Jestliže se zdá, že funkce vrací chybné výsledky, vyhledejte v oblastech dat text. Textový obsah můžete zvýraznit pomocí zvýrazňování hodnot.
=RANK(A10;A1:A50) vrátí pořadí hodnoty z A10 v oblasti hodnot A1:A50. Pokud Hodnota v dané oblasti neexistuje, zobrazí se chybové hlášení.
RANK.AVG
Vrátí pořadí zadané hodnoty v dané matici hodnot. Pokud se v seznamu hodnoty opakují, vrátí se průměrné pořadí.
Rozdíl mezi RANK.AVG a RANK.EQ se projevuje tehdy, pokud se hodnoty v seznamu opakují. Funkce RANK.EQ vrátí vyšší pořadí, zatímco funkce RANK.AVG vrátí průměrné pořadí.
RANK.AVG(Hodnota; Data [; Typ])
Hodnota je hodnota, jejíž pořadí má být určeno.
Data je matice nebo oblast s daty výběru.
Typ (nepovinné) určuje řazení dat.
Typ = 0 znamená sestupné pořadí, od posledního prvku matice k prvnímu (toto je výchozí chování).
Typ = 1 znamená vzestupné pořadí, od prvního prvku k poslednímu.
=RANK.AVG(A10;A1:A50) vrátí pořadí hodnoty z A10 v oblasti hodnot A1:A50. Pokud Hodnota v dané oblasti neexistuje, zobrazí se chybové hlášení.
COM.MICROSOFT.RANK.AVG
RANK.EQ
Vrátí pořadí zadané hodnoty v dané matici hodnot. Pokud se v seznamu hodnoty opakují, budou mít stejné pořadí.
Rozdíl mezi RANK.AVG a RANK.EQ se projevuje tehdy, pokud se hodnoty v seznamu opakují. Funkce RANK.EQ vrátí vyšší pořadí, zatímco funkce RANK.AVG vrátí průměrné pořadí.
RANK.EQ(Hodnota; Data [; Typ])
Hodnota je hodnota, jejíž pořadí má být určeno.
Data je matice nebo oblast s daty výběru.
Typ (nepovinné) určuje řazení dat.
Typ = 0 znamená sestupné pořadí, od posledního prvku matice k prvnímu (toto je výchozí chování).
Typ = 1 znamená vzestupné pořadí, od prvního prvku k poslednímu.
=RANK.EQ(A10;A1:A50) vrátí pořadí hodnoty z A10 v oblasti hodnot A1:A50. Pokud Hodnota v dané oblasti neexistuje, zobrazí se chybové hlášení.
COM.MICROSOFT.RANK.EQ
SKEW
Vrátí šikmost rozdělení.
SKEW(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
Parametry by měly být alespoň tři hodnoty.
Tato funkce ignoruje veškerý text a prázdné buňky v oblasti dat. Jestliže se zdá, že funkce vrací chybné výsledky, vyhledejte v oblastech dat text. Textový obsah můžete zvýraznit pomocí zvýrazňování hodnot.
=SKEW(A1:A50) spočítá hodnotu šikmosti pro odkazovaná data.
SLOPE
Vrátí směrnici přímky lineární regrese. Směrnice je zjištěna podle datových bodů (hodnot x a y).
SLOPE(DataY; DataX)
DataY je matice nebo oblast dat Y.
DataX je matice nebo oblast dat X.
=SLOPE(A1:A50;B1:B50)
STANDARDIZE
Převede náhodnou veličinu na normovaný tvar.
STANDARDIZE(Číslo; StředníHodnota; StDev)
Číslo je hodnota, která bude normována.
StředníHodnota je střední hodnota rozdělení.
StDev je směrodatná odchylka rozdělení.
=STANDARDIZE(11;10;1) vrátí 1. Hodnota 11 je v normálním rozdělení se střední hodnotou 10 a směrodatnou odchylkou 1 o tolik větší než střední hodnota 10, o kolik je hodnota 1 větší než střední hodnota normovaného normálního rozdělení.
STDEV
Odhadne směrodatnou odchylku výběru.
STDEV(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
Parametry by měly být alespoň dvě hodnoty.
Tato funkce ignoruje veškerý text a prázdné buňky v oblasti dat. Jestliže se zdá, že funkce vrací chybné výsledky, vyhledejte v oblastech dat text. Textový obsah můžete zvýraznit pomocí zvýrazňování hodnot.
=STDEV(A1:A50) vrátí odhad směrodatné odchylky zjištěný z odkazovaných dat.
STDEV.P
Vypočítá směrodatnou odchylku z celého základního souboru.
STDEV.P(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
=STDEV.P(A1:A50) vrátí směrodatnou odchylku odkazovaných dat.
COM.MICROSOFT.STDEV.P
STDEV.S
Vypočítá směrodatnou odchylku z výběru ze základního souboru.
STDEV.S(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
Parametry by měly být alespoň dvě hodnoty.
=STDEV.S(A1:A50) vrátí směrodatnou odchylku odkazovaných dat.
COM.MICROSOFT.STDEV.S
STDEVA
Odhadne směrodatnou odchylku výběru.
STDEVA(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
Parametry by měly být alespoň dvě hodnoty, Text se vyhodnotí jako 0.
=STDEVA(A1:A50) vrátí odhad směrodatné odchylky zjištěný z odkazovaných dat.
STDEVP
Vypočítá směrodatnou odchylku z celého základního souboru.
STDEVP(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
Tato funkce ignoruje veškerý text a prázdné buňky v oblasti dat. Jestliže se zdá, že funkce vrací chybné výsledky, vyhledejte v oblastech dat text. Textový obsah můžete zvýraznit pomocí zvýrazňování hodnot.
=STDEVP(A1:A50) vrátí směrodatnou odchylku odkazovaných dat.
STDEVPA
Vypočítá odhad směrodatné odchylky z celého základního souboru.
STDEVPA(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
Text se vyhodnotí jako 0.
=STDEVPA(A1:A50) vrátí směrodatnou odchylku odkazovaných dat.
STEYX
Vrátí standardní chybu regresního odhadu hodnoty Y pro každé zadané X.
STEYX(DataY; DataX)
DataY je matice nebo oblast dat Y.
DataX je matice nebo oblast dat X.
=STEYX(A1:A50;B1:B50)
T.DIST
Vrátí t rozdělení.
T.DIST(Číslo; StupněVolnosti; Kumulativní)
Číslo je hodnota, pro kterou se má t rozdělení vypočítat.
StupněVolnosti je počet stupňů volnosti t rozdělení.
Kumulativní: Pro 0 nebo NEPRAVDA se vypočítá hustota pravděpodobnosti, pro 1 nebo PRAVDA distribuční funkce.
=T.DIST(1; 10; PRAVDA) vrátí 0,8295534338
COM.MICROSOFT.T.DIST
T.DIST.2T
Vypočítá dvoustranné Studentovo t rozdělení. Toto spojité rozdělení pravděpodobnosti se často používá k testování hypotéz založenému na malých výběrech.
T.DIST.2T(Číslo; StupněVolnosti)
Číslo je hodnota, pro niž se má t rozdělení vypočítat.
StupněVolnosti je počet stupňů volnosti t rozdělení.
=T.DIST.2T(1; 10) vrátí 0,3408931323.
COM.MICROSOFT.T.DIST.2T
T.DIST.RT
Vypočítá pravostranné Studentovo t rozdělení. Toto spojité rozdělení pravděpodobnosti se často používá k testování hypotéz založenému na malých výběrech.
T.DIST.RT(Číslo; StupněVolnosti)
Číslo je hodnota, pro niž se má t rozdělení vypočítat.
StupněVolnosti je počet stupňů volnosti t rozdělení.
=T.DIST.RT(1; 10) vrátí 0,1704465662.
COM.MICROSOFT.T.DIST.RT
T.INV
Vrátí inverzní distribuční funkci jednostranného t rozdělení.
T.INV(Číslo; StupněVolnosti)
Číslo je pravděpodobnost odpovídající jednostrannému t rozdělení.
StupněVolnosti je počet stupňů volnosti t rozdělení.
=T.INV(0.1;6) vrátí -1,4397557473.
COM.MICROSOFT.T.INV
T.INV.2T
Vypočítá inverzní distribuční funkci Studentova t rozdělení. Toto spojité rozdělení pravděpodobnosti se často používá k testování hypotéz založenému na malých výběrech.
T.INV.2T(Číslo; StupněVolnosti)
Číslo je pravděpodobnost odpovídající dvoustrannému t rozdělení.
StupněVolnosti je počet stupňů volnosti t rozdělení.
=T.INV.2T(0,25; 10) vrátí 1,221255395.
COM.MICROSOFT.T.INV.2T
T.TEST
Vrátí pravděpodobnost odpovídající Studentovu t-testu.
T.TEST(Data1; Data2; Režim; Typ)
Data1 je matice nebo oblast prvního záznamu závislých dat.
Data2 je matice nebo oblast druhého záznamu závislých dat.
Pro Režim = 1 se spočítá jednostranný test, pro Režim = 2 dvoustranný test.
Typ je druh prováděného t-testu. Typ 1 znamená párový test. Typ 2 znamená dvouvýběrový test se stejnými rozptyly (homoskedastický). Typ 3 znamená dvouvýběrový test s různými rozptyly (heteroskedastický).
=T.TEST(A1:A50;B1:B50;2;2)
COM.MICROSOFT.T.TEST
TDIST
Vrátí t rozdělení.
TDIST(Číslo; StupněVolnosti; Režim)
Číslo je hodnota, pro kterou se t rozdělení spočítá.
StupněVolnosti je počet stupňů volnosti t rozdělení.
Režim = 1 vrátí jednostranný test, Režim = 2 vrátí oboustranný test.
=TDIST(12;5;1)
TINV
Vrátí inverzní distribuční funkci t rozdělení.
TINV(Číslo; StupněVolnosti)
Číslo je pravděpodobnost příslušná k dvoustrannému t rozdělení.
StupněVolnosti je počet stupňů volnosti t rozdělení.
=TINV(0,1;6) vrátí 1,94
TTEST
Vrátí pravděpodobnost pro t-test.
TTEST(Data1; Data2; Režim; Typ)
Data1 je matice nebo oblast prvního záznamu závislých dat.
Data2 je matice nebo oblast druhého záznamu závislých dat.
Pro Režim = 1 se spočítá jednostranný test, pro Režim = 2 dvoustranný test.
Typ je druh prováděného t-testu. Typ 1 znamená párový test. Typ 2 znamená dvouvýběrový test se stejnými rozptyly (homoskedastický). Typ 3 znamená dvouvýběrový test s různými rozptyly (heteroskedastický).
=TTEST(A1:A50;B1:B50;2;2)
VAR
Odhadne rozptyl na základě výběru.
VAR(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
Parametry by měly být alespoň dvě hodnoty.
Tato funkce ignoruje veškerý text a prázdné buňky v oblasti dat. Jestliže se zdá, že funkce vrací chybné výsledky, vyhledejte v oblastech dat text. Textový obsah můžete zvýraznit pomocí zvýrazňování hodnot.
=VAR(A1:A50)
VAR.P
Vypočte rozptyl z celého základního souboru.
VAR.P(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
=VAR.P(A1:A50)
COM.MICROSOFT.VAR.P
VAR.S
Odhadne rozptyl na základě výběru.
VAR.S(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
Parametry by měly být alespoň dvě hodnoty.
=VAR.S(A1:A50)
COM.MICROSOFT.VAR.S
VARA
Odhadne rozptyl na základě výběru. Hodnota textu je 0.
VARA(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
Parametry by měly být alespoň dvě hodnoty.
=VARA(A1:A50)
VARP
Vypočte rozptyl z celého základního souboru.
VARP(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
Tato funkce ignoruje veškerý text a prázdné buňky v oblasti dat. Jestliže se zdá, že funkce vrací chybné výsledky, vyhledejte v oblastech dat text. Textový obsah můžete zvýraznit pomocí zvýrazňování hodnot.
=VARP(A1:A50)
VARPA
Vypočte rozptyl z celého základního souboru. Hodnota textu je 0.
VARPA(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])
=VARPA(A1:A50)
WEIBULL
Vrátí Weibullovo rozdělení.
Weibullovo rozdělení je spojité rozdělení pravděpodobnosti s parametry alfa > 0 (určuje tvar) a beta > 0 (určuje měřítko).
Je-li C 0, WEIBULL vypočítá hustotu pravděpodobnosti rozdělení.
Je-li C 1, WEIBULL vypočítá distribuční funkci.
WEIBULL(Číslo; Alfa; Beta; C)
Číslo je hodnota, pro kterou se vypočítá Weibullovo rozdělení.
Alfa je parametr tvaru Weibullova rozdělení.
Beta je parametr měřítka Weibullova rozdělení.
C značí typ funkce.
=WEIBULL(2;1;1;1) vrátí 0,86.
Viz také wiki stránku.
WEIBULL.DIST
Vrátí hodnoty Weibullova rozdělení.
Weibullovo rozdělení je spojité rozdělení pravděpodobnosti s parametry alfa > 0 (určuje tvar) a beta > 0 (určuje měřítko).
Je-li C 0, WEIBULL.DIST vypočítá hustotu pravděpodobnosti rozdělení.
Je-li C 1, WEIBULL.DIST vypočítá distribuční funkci.
WEIBULL.DIST(Číslo; Alfa; Beta; C)
Číslo je hodnota, pro kterou se vypočítá Weibullovo rozdělení.
Alfa je parametr tvaru Weibullova rozdělení.
Beta je parametr měřítka Weibullova rozdělení.
C značí typ funkce.
=WEIBULL.DIST(2;1;1;1) vrátí 0,8646647168.
Viz také wiki stránku.
COM.MICROSOFT.WEIBULL.DIST