Matematické funkce

Tato kategorie obsahuje Matematické funkce Calcu. Průvodce funkcí otevřete volbou Vložit - Funkce.

AGGREGATE

Tato funkce vrátí agregovaný výsledek výpočtu v oblasti. Je možné použít různé, dále uvedené agregační funkce. Funkce umožňuje při výpočtu vynechat skryté řádky, chyby a výsledky funkce SUBTOTAL nebo jiné výsledky funkce AGGREGATE.

RAWSUBTRACT

Odečte sadu čísel a vrátí výsledek, aniž by byly eliminovány malé zaokrouhlovací chyby.

COLOR

Vrátí číselnou hodnotu vypočtenou jako kombinace tří barev (červené, zelené a modré) a alfa kanálu v barevném systému RGBA. Výsledek závisí na barevném systému používaném počítačem.

SUMIFS

Vrátí součet hodnot buněk z oblasti, která splňuje více kritérií z více oblastí.

TRUNC

Odřízne z čísla desetinná místa.

Syntaxe

TRUNC(číslo; počet)

Vrátí číslo, jehož počet desetinných míst je nejvýše Počet. Nadbytečná desetinná místa jsou jednoduše odstraněna bez ohledu na znaménko.

TRUNC(číslo; 0) se chová stejně jako INT(číslo) pro kladná čísla, ale efektivně zaokrouhlí k nule záporná čísla.

warning

Počet viditelných desetinných míst výsledky se určuje v - LibreOffice Calc - Výpočet.


Příklad

=TRUNC(1.239;2) vrátí 1.23. Číslice 9 bude odříznuta.

=TRUNC(-1.234999;3) vrátí -1.234. Všechny devítky budou odříznuty.

SUBTOTAL

Počítá mezisoučty. Jestliže oblast již mezisoučty obsahuje, ty nebudou pro výpočet dalšího mezisoučtu použity. Chcete-li zpracovávat pouze filtrované záznamy, použijte tuto funkci spolu s automatickým filtrem.

Syntaxe

SUBTOTAL(Funkce; Oblast)

Funkce je číslo zastupující jednu z následujících funkcí:

Číslo funkce

(obsahuje skryté hodnoty)

Číslo funkce

(ignoruje skryté hodnoty)

Funkce

1

101

AVERAGE

2

102

COUNT

3

103

COUNTA

4

104

MAX

5

105

MIN

6

106

PRODUCT

7

107

STDEV

8

108

STDEVP

9

109

SUM

10

110

VAR

11

111

VARP


Použijte čísla 1-11 pro zahrnutí ručně skrytých řádků nebo 101-111 pro jejich vyloučení; odfiltrované buňky jsou vždy vyloučeny.

Oblast je oblast, jejíž buňky budou zpracovány.

Příklad

Máte tabulku s rozsahem buněk A1: B6 obsahující materiál pro 10 studentů. Řádek 2 (pero) je ručně skryt. Chcete vidět součet čísel, které jsou zobrazeny; to je jen mezisoučet pro filtrované řádky. V tomto případě by byl správný vzorec:

A

B

1

POLOŽKA

MNOŽSTVÍ

2

Pero

10

3

Tužka

10

4

Notebook

10

5

Guma

10

6

Ořezávátko

10


=SUBTOTAL(9;B2:B6) vrátí 50.

=SUBTOTAL(109;B2:B6) vrátí 40.

CONVERT_OOO

Převede hodnotu z jedné měrné jednotky na jinou. Koeficienty pro převod jsou dány v seznamu v nastavení.

Kdysi tento seznam pro převod zahrnoval bývalé evropské měny a euro (viz příklady níže). Pro převod těchto měn nyní doporučujeme použít novou funkci EUROCONVERT.

Syntaxe

CONVERT_OOO(hodnota;"text";"text")

Příklad

=CONVERT_OOO(100;"ATS";"EUR") vrátí hodnotu v eurech pro 100 rakouských šilinků.

=CONVERT_OOO(100;"EUR";"DEM") převede 100 eur na německé marky.

DEGREES

Převede radiány na stupně.

Syntaxe

DEGREES(číslo)

Číslo je úhel v radiánech, který má být převeden na stupně.

Příklad

=DEGREES(PI()) vrátí 180 stupňů.

RADIANS

Převede stupně na radiány.

Syntaxe

RADIANS(Číslo)

Číslo je úhel ve stupních, který bude převeden na radiány.

Příklad

=RADIANS(90) vrátí 1.5707963267949, což PI/2 v přesnosti aplikace Calc.

EUROCONVERT

Převádí mezi starými národními měnami EU a eurem.

Syntaxe

EUROCONVERT(Hodnota; "Z_měny"; "Do_měny" [; plná_přesnost][; přesnost_mezipřevodu])

Hodnota je hodnota měny, která má být překonvertována.

Z_měny a Do_měny jsou měny, z a do kterých se převádí. Musí být zadány jako text a oficiální zkratky měn (např. "EUR"). Kurzy byly určeny Evropskou komisí.

Plná_přesnost je volitelný parametr. Pokud je vynechán nebo Nepravda, výsledek je zaokrouhlen na desetinná místa výsledné měny. Pokud je Plná_přesnost Pravda, výsledek se nezaokrouhluje.

Přesnost_mezipřevodu je volitelný parametr. Pokud je Přesnost_mezipřevodu zadána a je >=3, mezivýsledek dvojitého převodu (měna 1, EUR, měna 2) se zaokrouhlí na určenou přesnost. Pokud je Přesnost_mezipřevodu vynechána, mezivýsledek se nezaokrouhluje. A také pokud je cílová měna "EUR", použije se Přesnost_mezipřevodu, jako by se počítel mezivýsledek a poté se použije převod z EUR do EUR.

Příklady

=EUROCONVERT(100;"ATS";"EUR") převede 100 rakouských šilinků na eura.

=EUROCONVERT(100;"EUR";"DEM") převede 100 euro na německé marky.

SUMIF

Sečte buňky určené kritérii. Tato funkce se používá pro procházení oblasti buněk v závislosti na jejich hodnotě.

Vyhledávání podporuje zástupné znaky nebo regulární výrazy. Zadáte-li například "all.*", najdete první výskyt "all" následovaný jakýmikoliv znaky. Chcete-li hledat text, který je rovněž regulárním výrazem, musíte před každý znak napsat znak \ nebo text uzavřít mezi \Q...\E. Vypnout a zapnout automatické vyhodnocování regulárních výrazů můžete v - LibreOffice Calc - Výpočty.

warning

Pokud použijete funkci, jejíž jeden nebo více argumentů představují řetězce s kritérii vyhledávání, nejprve dojde k pokusu převést tyto řetězce na číslo, například ".0" se převede na 0 a podobně. V případě úspěšného převodu se nebude vyhledávat regulární výraz, ale číslo. Pokud však používáte národní prostředí s jiným oddělovačem desetinných míst, než je tečka, regulární výraz bude fungovat. Chcete-li regulární výraz vždy vynutit místo číselného výrazu, použijte výraz, který nelze interpretovat jako číslo, například ".[0]", ".\0" nebo "(?i).0".


Syntaxe

SUMIF(Oblast; Kritéria [; SumaOblasti])

Oblast je oblast, která bude posuzována pomocí kritérií.

Kritéria: buňka, ve které se nachází vyhledávací kritéria, nebo přímo vyhledávací kritéria. Pokud jsou kritéria zapsána do vzorce, musí být uzavřena v uvozovkách.

SumaOblasti je oblast, ve které jsou sečteny hodnoty. Pokud není tento parametr zadán, hodnoty nalezené v dané oblasti jsou sečteny.

note

SUMIF podporuje operátor řetězení (~) pouze v parametru Kritéria a pouze tehdy, není-li zadán volitelný parametr SumaOblasti.


Příklad

Pro součet pouze záporných čísel: =SUMIF(A1:A10;"<0")

=SUMIF(A1:A10;">0";B1:B10) - sečte hodnoty z oblasti B1:B10, pouze pokud odpovídající hodnoty v oblasti A1:A10 jsou >0.

Podívejte se na nápovědu funkce COUNTIF(), najdete tam příklady syntaxe, které lze použít také se SUMIF();

SUM

Sečte množinu čísel.

Syntaxe

SUM(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])

Číslo 1, Číslo 2, … , Číslo 255 jsou čísla nebo odkazy na buňky či oblasti buněk s čísly.

tip

Funkce SUM ignoruje jakýkoli text nebo prázdnou buňku v oblasti nebo matici. Pokud máte podezření na nesprávné výsledky funkce SUM, hledejte v oblastech dat text. Textový obsah v oblasti, která má představovat čísla, zvýrazníte pomocí funkce zvýrazňování hodnot.


Příklad

Pokud vložíte čísla 2; 3 a 4 do textových políček 1; 2 a 3 , získáte výsledek 9.

=SUM(A1;A3;B5) vypočítá součet tří buněk. =SUM (A1:E10) vypočítá součet všech buněk v oblasti A1 až E10.

Podmínky spojené pomocí AND lze ve funkci SUM() používat v následujícím smyslu:

Modelová situace: Vložme fakturu do tabulky. Sloupec A obsahuje datum položek faktury, sloupec B částky. Chceme nalézt vzorec, který použijeme pro vypsání celkové částky pouze za zvolené měsíce, např. pouze za období >=2008-01-01 do < 2008-02-01. Oblast s hodnotami datumu je zahrnuta v buňkách A1:A40, oblast s částkami, které mají být sečteny, jsou zahrnuty v buňkách B1:B40. Buňka C1 obsahuje počáteční datum, 2008 -01-01 vložené faktury a buňka C2 datum 2008-02-01, které již není zahrnuto.

Zadejte následující vzorec jako maticový vzorec:

=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)

Abyste toto zadali jako maticový vzorec, musíte vzorec ukončit místo prostého stisknutí Enteru stisknutím kláves Shift+ Enter. Vzorec se poté zobrazí na liště Vzorec uzavřený ve složených závorkách.

{=SUM((A1:A40>=C1)*(A1:A40<C2)*B1:B40)}

Vzorec je založen na skutečnosti, že výsledek porovnání je 1, je-li kritérium splněno, a 0, není-li splněno. Jednotlivé výsledky porovnání budou zpracovány jako matice a použity při násobení matic. Výsledné hodnoty budou seskupeny do matice.

SERIESSUM

Sečte první prvky mocninné řady.

SERIESSUM(x;n;m;k) = k1xn + k2xn+m + k3xn+2m + ... + kixn + (i-1)m.

Syntaxe

SERIESSUM(X; N; M; Koeficienty)

X je vstupní hodnota mocninné řady.

N je počáteční mocnina.

M je přírůstek, o který se bude N zvětšovat.

Koeficienty je řada koeficientů. Každý koeficient přísluší v řadě součtu jednomu sčítanci.

LOG10

Vrací dekadický logaritmus z daného čísla.

Syntaxe

LOG10(číslo)

Vrací dekadický logaritmus čísla.

Příklad

=LOG10(5) vrátí dekadický logaritmus čísla 5 (přibližně 0.69897).

SQRT

Vrací druhou odmocninu čísla.

Syntaxe

SQRT(Číslo)

Vrátí kladnou druhou odmocninu Čísla.

Číslo musí být kladné.

Příklad

=SQRT(16) vrátí 4.

=SQRT(-16) vrátí chybu neplatný argument.

QUOTIENT

Vrací výsledek celočíselného dělení.

Syntaxe

QUOTIENT(Čitatel; Jmenovatel)

Vrátí celočíselnou část Čitatele děleného Jmenovatelem.

QUOTIENT je totéž jako INT(čitatel/jmenovatel)pro stejné čitatele a jmenovatele, kromě toho, že může hlásit chyby s různými chybovými kódy. Obecněji je ekvivalentní INT(čitatel/jmenovatel/SIGN(čitatel/jmenovatel))*SIGN(čitatel/jmenovatel).

Příklad

=QUOTIENT(11;3) vrátí 3. Zbytek po dělení 2 je zanedbán.

SIGN

Vrací znaménko čísla. Vrátí 1 pro kladná a -1 pro záporná a 0, pokud je to 0.

Syntaxe

SIGN(Čísla)

Číslo je číslo, jehož znaménko má být zjištěno.

Příklad

=SIGN(3.4) vrátí 1.

=SIGN(-4.5) vrátí -1.

MROUND

Vrací číslo zaokrouhlené na nejbližší násobek jiného čísla.

Syntaxe

MROUND(Číslo; Násobek)

Vrací Číslo zaokrouhlené na nejbližší násobek Násobku.

Alternativně lze použít Násobek * ROUND(Číslo/Násobek).

Příklad

=MROUND(15.5;3) vrátí 15, protože 15.5 je blíže k 15 (= 3*5) než 18 (= 3*6).

=MROUND(1.4;0.5) vrátí 1.5 (= 0.5*3).

PI

Vrátí 3.14159265358979, hodnotu matematické konstanty Pi na 14 desetinných míst.

Syntaxe

PI()

Příklad

=PI() vrátí 3.14159265358979.

ABS

Vrátí absolutní hodnotu čísla.

Syntaxe

ABS(Číslo)

Číslo je číslo, jehož absolutní hodnota se bude počítat. Absolutní hodnota čísla je jeho hodnota bez znaménka +/-

Příklad

=ABS(-56) vrátí 56.

=ABS(12) vrátí 12.

=ABS(0) vrátí 0.

SQRTPI

Vrátí druhou odmocninu z (PI krát číslo).

Syntaxe

SQRTPI(Číslo)

Vrátí kladnou hodnotu druhé odmocniny z (PI násobené Číslem).

Toto je ekvivalent k SQRT(PI()*Číslo).

Příklad

=SQRTPI(2) vrátí druhou mocninu (2PI), přibližně 2.506628.

MULTINOMIAL

Vrátí faktoriál součtu parametrů dělený součinem faktoriálů argumentů.

Syntaxe

MULTINOMIAL(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])

Číslo 1, Číslo 2, … , Číslo 255 jsou čísla nebo odkazy na buňky či oblasti buněk s čísly.

Příklad

=MULTINOMIAL(F11:H11) vrátí 1260, pokud F11 až H11 obsahují hodnoty 2, 3 a 4. Toto odpovídá vzorci =(2+3+4)! / (2!*3!*4!)

FACT

Vrátí faktoriál čísla.

Syntaxe

FACT(číslo)

Vrátí číslo!, faktoriál čísla vypočtený jako 1*2*3*4* ... *číslo.

=FACT(0) vrátí z definice číslo 1.

Faktoriál záporného čísla vrátí chybu "neplatný argument".

Příklad

=FACT(3) vrátí 6.

=FACT(0) vrátí 1.

CSCH

Vrátí hyperbolický kosekans čísla.

tip

Tato funkce je k dispozici od verze LibreOffice 3.5.


Syntaxe

CSCH(Číslo)

Vrátí hyperbolický kosekans Čísla.

Příklad

=CSCH(1) vrátí přibližně 0,8509181282, hyperbolický kosekans čísla 1.

Otevřít soubor s příkladem:

COSH

Vrátí hyperbolický kosinus zadaného čísla.

Syntaxe

COSH(Číslo)

Vrací hyperbolický kosinus Čísla.

Příklad

=COSH(0) vrátí 1, hyperbolický kosinus 0.

Otevřít soubor s příkladem:

COTH

Vrátí hyperbolický kotangens zadaného čísla (úhlu).

Syntaxe

COTH(Číslo)

Vrátí hyperbolický kotangens Čísla.

Příklad

=COTH(1) vrátí hyperbolický kotangens 1, přibližně 1,3130.

Otevřít soubor s příkladem:

SECH

Vrátí hyperbolický sekans čísla.

tip

Tato funkce je k dispozici od verze LibreOffice 3.5.


Syntaxe

SECH(Číslo)

Vrací hyperbolický sekans Čísla.

Příklad

=SECH(0) vrátí 1, hyperbolický sekans 0.

Otevřít soubor s příkladem:

SINH

Vrátí hyperbolický sinus zadaného čísla (úhlu).

Syntaxe

SINH(Číslo)

Vrátí hyperbolický sinus Čísla.

Příklad

=SINH(0) vrátí 0, hyperbolický sinus 0.

Otevřít soubor s příkladem:

TANH

Vrátí hyperbolický tangens zadaného čísla.

Syntaxe

TANH(Číslo)

Vrátí hyperbolický tangens Čísla.

Příklad

=TANH(0) vrátí 0, hyperbolický tangens 0.

Otevřít soubor s příkladem:

ACOSH

Vrátí inverzní hyperbolický kosinus zadaného čísla.

Syntaxe

ACOSH(Číslo)

Tato funkce vrátí inverzní hyperbolický kosinus Čísla, což je číslo, jehož hyperbolický kosinus je Číslo.

Číslo musí být větší nebo rovno 1.

Příklad

=ACOSH(1) vrátí 0.

=ACOSH(COSH(4)) vrátí 4.

Otevřít soubor s příkladem:

ACOTH

Vrátí inverzní hyperbolický kotangens zadaného čísla.

Syntaxe

ACOTH(Číslo)

Tato funkce vrací inverzní hyperbolický kotangens Čísla, což je číslo, jehož hyperbolický kotangens je Číslo.

Výsledkem je chyba, je-li číslo v uzavřeném intervalu od -1 do 1.

Příklad

=ACOTH(1,1) vrátí inverzní hyperbolický kotangens čísla 1,1, přibližně 1,52226.

Otevřít soubor s příkladem:

ASINH

Vrátí inverzní hyperbolický sinus zadaného čísla.

Syntaxe

ASINH(Číslo)

Tato funkce vrátí inverzní hyperbolický sinus čísla, což je číslo, jehož hyperbolický sinus je Číslo.

Příklad

=ASINH(-90) vrátí přibližně -5,1929877.

=ASINH(SINH(4)) vrátí 4.

Otevřít soubor s příkladem:

ATANH

Vrátí inverzní hyperbolický tangens zadaného čísla.

Syntaxe

ATANH(Číslo)

Tato funkce vrátí inverzní hyperbolický tangens Čísla, což je číslo, jehož hyperbolický tangens je roven Číslu.

Číslo musí vyhovovat podmínce -1 < číslo < 1.

Příklad

=ATANH(0) vrátí 0.

Otevřít soubor s příkladem:

ACOT

Vrátí inverzní kotangens (arkus kotangens) daného čísla.

Syntaxe

ACOT(Číslo)

Tato funkce vrátí inverzní kotangens Čísla, což je úhel (v radiánech), jehož kotangens je číslo. Vrácený úhel je mezi hodnotami 0 a PI.

Úhel ve stupních získáte použitím funkce DEGREES.

Příklad

=ACOT(1) vrátí 0,785398163397448 (PI/4 v radiánech).

=DEGREES(ACOT(1)) vrátí 45. Tangens 45 stupňů je 1.

Otevřít soubor s příkladem:

ACOS

Vrátí inverzní trigonometrický kosinus čísla.

Syntaxe

ACOS(Číslo)

Tato funkce vrátí inverzní trigonometrickou funkci kosinus Čísla, což je úhel (v radiánech), jehož kosinus je Číslo. Vrácený úhel je mezi 0 a PI.

Úhel ve stupních získáte použitím funkce DEGREES.

Příklad

=ACOS(-1) vrátí 3,14159265358979 (PI v radiánech)

=DEGREES(ACOS(0,5)) vrátí 60. Kosinus 60 stupňů je 0,5.

Otevřít soubor s příkladem:

ASIN

Vrátí inverzní trigonometrický sinus zadaného čísla.

Syntaxe

ASIN(Číslo)

Tato funkce vrátí inverzní sinus čísla, což je úhel (v radiánech), jehož hodnota je Číslo. Vrácený úhel je mezi -PI/2 a +PI/2

Úhel ve stupních získáte použitím funkce DEGREES.

Příklad

=ASIN(0) vrátí 0.

=ASIN(1) vrátí 1,5707963267949 (PI/2 v radiánech).

=DEGREES(ASIN(0,5)) vrátí 30. Sinus 30 stupňů je 0,5.

Otevřít soubor s příkladem:

ATAN

Vrátí inverzní trigonometrický tangens zadaného čísla.

Syntaxe

ATAN(Číslo)

Tato funkce vrátí inverzní tangens Čísla, což je úhel (v radiánech), jehož tangens je Číslo. Vrácená hodnota úhlu je mezi -PI/2 a PI/2.

Úhel ve stupních získáte použitím funkce DEGREES.

Příklad

=ATAN(1) vrátí 0,785398163397448 (PI/4 v radiánech).

=DEGREES(ATAN(1)) vrátí 45. Tangens 45 stupňů je 1.

Otevřít soubor s příkladem:

CSC

Vrátí kosekans zadaného úhlu (v radiánech). Kosekans úhlu se rovná 1 děleno sinem zadaného úhlu

tip

Tato funkce je k dispozici od verze LibreOffice 3.5.


Syntaxe

CSC(Číslo)

Vrátí (trigonometrický) kosekans Čísla, což je úhel v radiánech.

Pro získání kosekans úhlu ve stupních použijte funkci RADIANS.

Příklad

=CSC(PI()/4) vrátí přibližně 1,4142135624, což je inverzní hodnota sinus PI/4 v radiánech.

=CSC(RADIANS(30)) vrátí 2, kosekans 30 stupňů.

Otevřít soubor s příkladem:

COS

Vrátí kosinus daného úhlu (v radiánech).

Syntaxe

COS(Číslo)

Vrátí (trigonometrický) kosinus Čísla, což je úhel v radiánech.

Kosinus úhlu ve stupních získáte použitím funkce RADIANS.

Příklad

=COS(PI()*2) vrátí 1, kosinus 2*PI v radiánech.

=COS(RADIANS(60)) vrátí 0,5, kosinus 60 stupňů.

Otevřít soubor s příkladem:

COT

Vrátí kotangens daného úhlu (v radiánech).

Syntaxe

COT(Číslo)

Vrátí (trigonometrický) kotangens Čísla, což je úhel v radiánech.

Kotangens úhlu ve stupních získáte použitím funkce RADIANS.

Kotangens úhlu je roven 1/tangens tohoto úhlu.

Příklady:

=COT(PI()/4) vrátí 1, kotangens PI/4 v radiánech.

=COT(RADIANS(45)) vrátí 1, kotangens 45 stupňů.

Otevřít soubor s příkladem:

LOG

Vrátí logaritmus o daném základu ze zadaného čísla.

Syntaxe

LOG(Číslo [; Základ])

Číslo je číslo, jehož logaritmus se bude počítat.

Základ (nepovinné) je základ pro výpočet logaritmu. Není-li zadán, předpokládá se základ 10.

Příklad

=LOG(10;3) vrátí logaritmus 10 při základu 3 (přibližně 2.0959).

=LOG(7^4;7) vrátí 4.

LCM

Vrátí nejmenší společný násobek jednoho či více celých čísel.

Syntaxe

LCM(Celé číslo 1 [; Celé číslo 2 [; … [; Celé číslo 255]]])

Celé číslo 1, Celé číslo 2, … , Celé číslo 255 jsou celá čísla nebo odkazy na buňky či oblasti buněk s celými čísly.

Příklad

Pokud vložíte do polí Celé číslo 1, 2 a 3 čísla 512, 1024 a 2000, výsledkem bude 128000.

GCD

Vrátí největší společný dělitel dvou nebo více celých čísel.

Největší společný dělitel je největší kladné celé číslo, kterým lze beze zbytku dělit všechna zadaná celá čísla.

Syntaxe

GCD(Celé číslo 1 [; Celé číslo 2 [; … [; Celé číslo 255]]])

Celé číslo 1, Celé číslo 2, … , Celé číslo 255 jsou celá čísla nebo odkazy na buňky či oblasti buněk s celými čísly.

Příklad

=GCD(16;32;24) dá výsledek 8, protože 8 je největší číslo, které dělí čísla 16, 32, 24 beze zbytku.

=GCD(B1:B3), kde buňky B1, B2, B3 obsahují 9, 12, 9, dá 3.

RANDBETWEEN

Vrátí náhodné celé číslo ze zadaného intervalu.

Syntaxe

RANDBETWEEN(Od; Do)

Vrátí náhodné celé číslo mezi mezemi Od a Do (včetně mezí).

Funkce vytvoří nové náhodné číslo při každém přepočítání Calcu. Ručně spustíte přepočítání Calcu stisknutím klávesy F9.

Pro vytvoření náhodných čísel, která se nikdy nepřepočítají, zkopírujte buňky obsahující tuto funkci a použijte Úpravy - Vložit jinak (s neoznačenými možnostmi Vložit vše a Vzorce a s označenou možností Čísla).

Příklad

=RANDBETWEEN(20;30) vrátí celé číslo mezi 20 a 30.

RANDBETWEEN.NV

Vrátí náhodné celé číslo ze zadaného intervalu, které se po přepočítání nezmění.

tip

Tato funkce je k dispozici od verze LibreOffice 7.0.


Syntaxe

RANDBETWEEN.NV(Od; Do)

Vrátí náhodné celé číslo, které se po přepočítání nezmění, a to mezi mezemi Od a Do (uzavřený interval). Přepočítání nastává při nové vstupní události nebo při stisknutí klávesy F9. Výjimkami, kdy se i tato funkce přepočítá, jsou stisknutí klávesy F9, když se kurzor nachází na buňce obsahující funkci, při otevření souboru a při přepočítání hodnot Od nebo Do.

Příklad

=RANDBETWEEN.NV(20;30) vrátí číslo mezi 20 a 30, které se při přepočítání nezmění.

=RANDBETWEEN.NV(A1;30) vrátí nepřepočítávané celé číslo mezi hodnotou buňky A1 a 30. Funkce se však přepočítá, kdykoliv se změní obsah buňky A1.

RAND

Vrátí náhodné číslo z intervalu 0 až 1.

Syntaxe

RAND()

Funkce vytvoří nové náhodné číslo při každém přepočítání Calcu. Ručně spustíte přepočítání Calcu stisknutím klávesy F9.

Chcete-li vygenerovat náhodná čísla, která se nepřepočítají:

Příklad

=RAND() vrátí náhodné číslo mezi 0 a 1.

RAND.NV

Vrátí náhodné číslo mezi 0 a 1, které se po přepočítání nezmění.

tip

Tato funkce je k dispozici od verze LibreOffice 7.0.


Syntaxe

RAND.NV()

Vrátí náhodné číslo, které se po přepočítání nezmění. Takové číslo se nepřepočítá při nové vstupní události ani při stisknutí klávesy F9, výjimkou je případ, kdy se kurzor nachází na buňce obsahující tuto funkci. Funkce se rovněž přepočítá při otevření souboru.

Příklad

=RAND.NV() vrátí číslo mezi 0 a 1, které se při přepočítání nezmění.

COMBIN

Vrátí počet kombinací pro elementy bez opakování.

Syntaxe

COMBIN(Počet1; Počet2)

Počet1 je počet položek v sadě.

Počet2 je počet vybraných položek ze sady.

COMBIN vrátí počet uspořádaných množin pro výběr těchto položek. Například, máte-li 3 položky A, B a C v sadě, můžete vybrat 2 položky 3 různými způsoby takto: AB, AC a BC

COMBIN implementuje vzorec: Počet1!/(Počet2!*(Počet1-Počet2)!)

Příklad

=COMBIN(3;2) vrátí 3.

COMBINA

Vrátí počet kombinací s opakováním.

Syntaxe

COMBINA(Počet1; Počet2)

Počet1 je počet položek v sadě.

Počet2 je počet vybraných položek ze sady.

COMBINA vrátí počet jedinečných možností jak vybrat tyto položky, pokud nezáleží na pořadí výběru a pokud se položky mohou opakovat. Například pro 3 položky A, B a C v sadě můžete vybrat 2 položky 6 různými způsoby, konkrétně AA, AB, AC, BB, BC a CC.

COMBINA používá vzorec: (Počet1+Počet2-1)! / (Počet2!(Počet1-1)!)

Příklad

=COMBINA(3;2) vrátí 6.

LN

Vrátí přirozený logaritmus čísla, jeho základ je konstanta e. Konstanta e má hodnotu přibližně 2,71828182845904.

Syntaxe

LN(číslo)

Číslo je číslo, jehož přirozený logaritmus se má vypočítat.

Příklad

=LN(3) vrátí přirozený logaritmus čísla 3 (přibližně 1,0986).

=LN(EXP(321)) vrátí 321.

SEC

Vrátí sekans zadaného úhlu (v radiánech). Sekans úhlu se rovná 1 děleno kosinem zadaného úhlu

tip

Tato funkce je k dispozici od verze LibreOffice 3.5.


Syntaxe

SEC(Číslo)

Vrací (trigonometrický) sekans Čísla, které udává hodnotu úhlu v radiánech.

Pro získání sekans úhlu ve stupních použijte funkci RADIANS.

Příklad

=SEC(PI()/4) vrátí přibližně 1.4142135624, což je inverzní hodnota kosinu PI/4 radiánů.

=SEC(RADIANS(60)) vrátí 2, sekans 60 stupňů.

Otevřít soubor s příkladem:

SIN

Vrátí sinus daného úhlu (v radiánech).

Syntaxe

SIN(Číslo)

Vrátí sinus Čísla, což je úhel v radiánech.

Sinus úhlu ve stupních získáte použitím funkce RADIANS.

Příklad

=SIN(PI()/2) vrátí 1, sinus PI/2 v radiánech.

=SIN(RADIANS(30)) vrátí 0,5, sinus 30 stupňů.

Otevřít soubor s příkladem:

TAN

Vrátí tangens daného úhlu (v radiánech).

Syntaxe

TAN(číslo)

Vrátí (trigonometrický) tangens Čísla, úhel v radiánech.

Tangens úhlu ve stupních získáte použitím funkce RADIANS.

Příklad

=TAN(PI()/4) vrátí 1, tangens PI/4 v radiánech.

=TAN(RADIANS(45)) vrátí 1, tangens 45 stupňů.

Otevřít soubor s příkladem:

MOD

Vrátí zbytek po celočíselném dělení.

Syntaxe

MOD(Dělenec; Dělitel)

Pro celočíselný argument tato funkce vrátí dělenec modulo dělitel, tedy zbytek po dělení Dělence Dělitelem.

Tato funkce je implementována jako Dělenec - Dělitel * INT(Dělenec/Dělitel). Pomocí tohoto vzorce se vypočte výsledek, pokud argumenty nejsou celá čísla.

Příklad

=MOD(22;3)vrátí 1, což je zbytek po dělení 22 třemi.

=MOD(11,25;2,5) vrátí 1,25.

ATAN2

Vrátí úhel (v radiánech) mezi osou x a přímkou od počátku k bodu (číslo X|číslo Y).

Ikona poznámky

Tato funkce je součástí standardu Open Document Format for Office Applications (OpenDocument) verze 1.2 (ISO/IEC 26300:2-2015).


Syntaxe

ATAN2(Číslo X; Číslo Y)

Číslo X je hodnota souřadnice x.

Číslo Y je hodnota souřadnice y.

tip

Programovací jazyky mají obvykle opačné pořadí argumentů pro jejich funkci atan2().


ATAN2 vrací úhel (v radiánech) mezi osou x a přímkou od počátku k bodu (číslo X|číslo Y).

Příklad

=ATAN2(-5;9) vrátí 2,07789 radiánů.

Úhel ve stupních získáte použitím funkce DEGREES.

=DEGREES(ATAN2(12.3;12.3)) vrátí 45. Tangens 45 stupňů je 1.

note

LibreOffice vrací 0 pro ATAN2(0;0).


Funkce může být použita při převodu kartézských souřadnic na polární souřadnice.

=DEGREES(ATAN2(-8;5)) vrátí φ = 147,9 stupňů

Příklad převodu kartézských souřadnic na polární souřadnice

Otevřít soubor s příkladem:

EXP

Vrátí číslo e umocněné na zadané číslo. Konstanta e má hodnotu přibližně 2,71828182845904.

Syntaxe

EXP(číslo)

Číslo je mocnina, na kterou bude e umocněno.

Příklad

=EXP(1) vrátí 2,71828182845904, matematickou konstantu e s přesností aplikace Calc.

POWER

Vrátí číslo umocněné na jiné číslo.

Syntaxe

POWER(Základ; Exponent)

Vrátí Základ umocněný na Exponent.

Stejného výsledků docílíte použitím operátoru umocňování ^:

Základ^Exponent

Příklad

=POWER(4;3) vrátí 64,kde 4 je základ a 3 mocnitel.

=4^3 také vrátí 4 na 3.

PRODUCT

Vynásobí všechna zadaná čísla a vrátí jejich součin.

Syntaxe

PRODUCT(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])

Číslo 1, Číslo 2, … , Číslo 255 jsou čísla nebo odkazy na buňky či oblasti buněk s čísly.

Příklad

=PRODUCT(2;3;4) vrátí 24.

SUMSQ

Vypočítá součet druhých mocnin (kvadrátů) zadaných čísel.

Syntaxe

SUMSQ(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])

Číslo 1, Číslo 2, … , Číslo 255 jsou čísla nebo odkazy na buňky či oblasti buněk s čísly.

Příklad

Pokud zadáte jako argumenty Číslo 1; 2 a 3 hodnoty 2; 3 a 4, získáte výsledek 29.

LCM_EXCEL2003

Výsledkem je nejmenší společný násobek seznamu čísel.

note

Funkce, jejichž název končí na _ADD nebo _EXCEL2003, vrací stejné výsledky jako odpovídající funkce (bez přípony) programu Microsoft Excel 2003. Chcete-li získat výsledky podle mezinárodních standardů, použijte funkce bez přípon.


Syntaxe

LCM_EXCEL2003(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])

Číslo 1, Číslo 2, … , Číslo 255 jsou čísla nebo odkazy na buňky či oblasti buněk s čísly.

Příklad

=LCM_EXCEL2003(5;15;25) vrátí 75.

GCD_EXCEL2003

Výsledkem je největší společný dělitel seznamu čísel.

note

Funkce, jejichž název končí na _ADD nebo _EXCEL2003, vrací stejné výsledky jako odpovídající funkce (bez přípony) programu Microsoft Excel 2003. Chcete-li získat výsledky podle mezinárodních standardů, použijte funkce bez přípon.


Syntaxe

GCD_EXCEL2003(Číslo 1 [; Číslo 2 [; … [; Číslo 255]]])

Číslo 1, Číslo 2, … , Číslo 255 jsou čísla nebo odkazy na buňky či oblasti buněk s čísly.

Příklad

=GCD_EXCEL2003(5;15;25) vrátí 5.

ROUNDDOWN

Zaokrouhluje dolů, směrem k nule, na zadaný počet míst.

Syntaxe

ROUNDDOWN(Číslo [; Počet])

Vrátí Číslo zaokrouhlené dolů (směrem k nule) na určitý Počet desetinných míst. Pokud je Počet vynechán nebo je zadán jako nula, funkce zaokrouhlí dané číslo dolů na celé číslo. Pokud je Počet záporný, funkce zaokrouhlí dané číslo dolů na 10, 100, 1000, atd.

Tato funkce zaokrouhluje směrem k nule. Další možnosti nabízí ROUNDUP a ROUND.

Příklad

=ROUNDDOWN(1.234;2) vrátí 1.23.

=ROUNDDOWN(45.67;0) vrátí 45.

=ROUNDDOWN(-45.67) vrátí -45.

=ROUNDDOWN(987.65;-2) vrátí 900.

ROUND

Zaokrouhluje číslo na určitý počet desetinných míst.

Syntaxe

ROUND(Číslo [; Počet])

Vrátí Číslo zaokrouhlené na určitý Počet desetinných míst. Pokud je počet vynechán nebo zadán jako nula, funkce zaokrouhlí dané číslo na nejbližší celé číslo. Pokud je počet záporný, funkce zaokrouhlí dané číslo na nejbližších 10, 100, 1000, atd.

Tato funkce zaokrouhluje k nejbližšímu číslu. Další možnosti nabízí ROUNDDOWN a ROUNDUP.

Příklad

=ROUND(2.348;2) vrátí 2.35

=ROUND(-32.4834;3) vrátí -32.483. Změňte formát buněk, aby jste viděli všechny desetiny.

=ROUND(2.348;0)vrátí 2.

=ROUND(2.5) vrátí 3.

=ROUND(987.65;-2) vrátí 1000.

ODD

Zaokrouhlí kladné číslo na nejbližší vyšší liché celé číslo a záporné číslo na nejbližší nižší liché celé číslo.

Syntaxe

ODD(Číslo)

Vrátí Číslo zaokrouhlené nahoru na další liché celé číslo, a to směrem od nuly.

Příklad

=ODD(1,2) vrátí 3.

=ODD(1) vrátí 1.

=ODD(0) vrátí 1.

=ODD(-3,1) vrátí -5.

EVEN

Zaokrouhlí kladné číslo nahoru na nejbližší sudé celé číslo a záporné číslo dolů na nejbližší sudé celé číslo.

Syntaxe

EVEN(číslo)

Vrátí číslo zaokrouhlené na další sudé celé číslo, a to směrem od nuly.

Příklad

=EVEN(2,3) vrátí 4.

=EVEN(2) vrátí 2.

=EVEN(0) vrátí 0.

=EVEN(-0,5) vrátí -2.

INT

Zaokrouhlí číslo dolů na nejbližší nižší celé číslo.

Syntaxe

INT(číslo)

Vrátí číslo zaokrouhlené dolů na nejbližší celé číslo.

Záporná čísla jsou zaokrouhlována směrem dolů.

Příklad

=INT(5,7) vrátí 5.

=INT(-1,3) vrátí -2.

ROUNDUP

Zaokrouhlí číslo nahoru (směrem od nuly) na určitý počet desetinných míst.

Syntaxe

ROUNDUP(Číslo [; Počet])

Vrátí Číslo zaokrouhlené nahoru (pryč od nuly) na určitý Počet desetinných míst. Pokud je počet vynechán nebo zadán jako nula, funkce zaokrouhlí dané číslo nahoru na celé číslo. Pokud je počet záporný, funkce zaokrouhlí dané číslo na 10, 100, 1000, atd

Tato funkce zaokrouhluje směrem nahoru. Další možnosti nabízí ROUNDDOWN a ROUND.

Příklad

=ROUNDUP(1.1111;2) vrátí 1.12.

=ROUNDUP(1.2345;1) vrátí 1.3.

=ROUNDUP(45.67;0) vrátí 46.

=ROUNDUP(-45.67) vrátí -46.

=ROUNDUP(987.65;-2) vrátí 1000.

Podpořte nás!