Funkce StrConv

Převede řetězec tak, jak určuje typ převodu.

Tato konstanta, funkce nebo objekt se povoluje příkazem Option VBASupport 1, který je umístěn v modulu před spustitelným programem.

Syntaxe:

StrConv(string As String, Conversion As Integer, [ LCID ])

Návratová hodnota:

String

Parametry:

string: Jakýkoliv řetězec.

Conversion: Typ převodu, který se má provést. Typy jsou uvedeny v následující tabulce.

Převod	Hodnota	Popis
vbUpperCase	1	Převede znaky argumentu Text na velká písmena.
vbLowerCase	2	Převede znaky argumentu Text na malá písmena.
vbProperCase	3	Převede první písmeno každého slova argumentu Text na velká písmena.
vbWide	4	Převede úzké znaky (s poloviční šířkou) v argumentu Text na široké (s plnou šířkou).
vbNarrow	8	Převede široké znaky (s plnou šířkou) v argumentu Text na úzké (s poloviční šířkou).
vbKatakana	16	Převede znaky písma hiragana v argumentu Text na znaky písma katakana.
vbHiragana	32	Převede znaky písma katakana v argumentu Text na znaky písma hiragana.
vbUnicode	64	Převede znaky v argumentu Text na znaky Unicode, a to pomocí výchozího kódování systému.
vbFromUnicode	128	Převede znaky v argumentu Text z Unicode na výchozí kódování systému.

LCID: Nepovinné. ID národního prostředí jako desítkové číslo. Je-li tento parametr vynechán, předpokládá se ID národního prostředí systému. Dostupné hodnoty LCID naleznete v souboru msi-encodinglist.txt.

Příklad:


Option VBASupport 1
Option Explicit
Sub Test_StrConv
    Print StrConv("abc EFG hij", vbUpperCase) '= "ABC EFG HIJ"
    Print StrConv("abc EFG hij", vbLowerCase) ' =  "abc efg hij"
    Print StrConv("abc EFG hij", vbProperCase) ' = "Abc Efg Hij"

    REM Převede úzké (jednobajtové) znaky řetězce na široké
    Print StrConv("ABCDEVB¥ì¥¹¥¥å©", vbWide) ' = "ＡＢＣＤＥＶＢ￥ì￥¹￥￥å©"

    REM Převede široké (dvoubajtové) znaky řetězce na úzké (jednobajtové)
    Print StrConv("ＡＢＣＤ＠＄％２３＇？ＥＧ", vbNarrow) ' = "ABCD@$%23'?EG"

    REM Převede znaky písma hiragana na znaky písma katakana
    Print StrConv("かたかな", vbKatakana) ' = "カタカナ"

    REM Převede znaky písma katakana na znaky písma hiragana
    Print StrConv("カタカナ", vbHiragana) '= "かたかな"

    REM Předpokládá se kódování CP-1252 a národní prostředí en-US
    Dim x() As Byte
    x = StrConv("ÉÏº£ÊÐABC", vbFromUnicode)
    Print UBound(x) ' 8 znaků
    Print x(2) ' = 186
    Print StrConv(x, vbUnicode)' = "ÉÏº£ÊÐABC"
End Sub

Funkce a příkazy pouze pro VBA